Excel IF statement with multiple conditions

The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.

In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.

How to use IF function with multiple conditions

In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:

  • AND function - returns TRUE if all the conditions are met; FALSE otherwise.
  • OR function - returns TRUE if any single condition is met; FALSE otherwise.

To better illustrate the point, let's investigate some real-life formulas examples.

Excel IF statement with multiple conditions (AND logic)

The generic formula of Excel IF with two or more conditions is this:

IF(AND(condition1, condition2, …), value_if_true, value_if_false)

Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.

Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.

For the logical test, you use the following AND statement: AND(B2>50, C2>50)

If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".

=IF(AND(B2>50, B2>50), "Pass", "Fail")

Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right: Excel IF statement with multiple AND conditions

In a similar manner, you can use the Excel IF function with multiple text conditions.

For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:

=IF(AND(B2="pass", C2="pass"), "Good!", "Bad") Excel IF function with multiple text conditions

Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.

In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:

=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")

The avoid this, you should use a nested IF function:

=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")

For more information, please see IF AND formula in Excel.

Excel IF function with multiple conditions (OR logic)

To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:

IF(OR(condition1, condition2, …), value_if_true, value_if_false)

The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.

So, if in the previous formula, we use OR instead of AND:

=IF(OR(B2>50, B2>50), "Pass", "Fail")

Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :) Excel IF function with multiple OR conditions

Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.

For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:

=IF(OR(B2={"delivered", "paid"}), "Closed", "")

More formula examples can be found in Excel IF OR function.

IF with multiple AND & OR statements

If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.

In our sample table, suppose you have the following criteria for checking the exam results:

  • Condition 1: exam1>50 and exam2>50
  • Condition 2: exam1>40 and exam2>60

If either of the conditions is met, the final exam is deemed passed.

At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):

OR(AND(B2>50, C2>50), AND(B2>40, C2>60)

Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:

=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")

The screenshot below indicates that we've done the formula right: IF with multiple AND & OR statements

Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:

  • In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
  • In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.

Nested IF statement to check multiple logical tests

If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.

Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:

  • Good: 60 or more (>=60)
  • Satisfactory: between 40 and 60 (>40 and <60)
  • Poor: 40 or less (<=40)

Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.

In our case, the functions are arranged from largest to smallest:

=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))

Naturally, you can nest more functions if needed (up to 64 in modern versions). Nested IF statement in Excel

For more information, please see How to use multiple nested IF statements in Excel.

Excel IF array formula with multiple conditions

Another way to get an Excel IF to test multiple conditions is by using an array formula.

To evaluate conditions with the AND logic, use the asterisk:

IF(condition1) * (condition2) * …, value_if_true, value_if_false)

To test conditions with the OR logic, use the plus sign:

IF(condition1) + (condition2) + …, value_if_true, value_if_false)

To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.

For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:

=IF((B2>50) * (C2>50), "Pass", "Fail") IF array formula with multiple AND conditions

In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.

To evaluate multiple conditions with the OR logic, the formula is:

=IF((B2>50) + (C2>50), "Pass", "Fail") IF array formula with multiple OR conditions

Using IF together with other functions

This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.

Example 1. If #N/A error in VLOOKUP

When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:

IF(ISNA(VLOOKUP(…)), value_if_na, VLOOKUP(…))

For example:

If #N/A return 0:

If the lookup value in E1 is not found, the formula returns zero.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return blank:

If the lookup value is not found, the formula returns nothing (an empty string).

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return certain text:

If the lookup value is not found, the formula returns specific text.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE)) If #N/A error in VLOOKUP

For more formula examples, please see VLOOKUP with IF statement in Excel.

Example 2. IF with SUM, AVERAGE, MIN and MAX functions

To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.

In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:

=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))

If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor". Using the IF function with SUM

In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:

=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))

Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:

=IF(D2=MAX($D$2:$D$10), "Best result", "")

=IF(D2=MAX($D$2:$D$10), "Best result", "")

To have both labels in one column, nest the above functions one into another:

=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", "")) Using IF together with the MIN and MAX functions

Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.

In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:

  • COUNTIF - count cells that meet a condition
  • COUNTIFS - count cells with multiple criteria
  • SUMIF - conditionally sum cells
  • SUMIFS - sum cells with multiple criteria

Example 3. IF with ISNUMBER, ISTEXT and ISBLANK

To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:

=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", ""))) IF with ISNUMBER, ISTEXT and ISBLANK

Example 4. IF and CONCATENATE

To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:

=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

Looking at the screenshot below, you'll hardly need any explanation of what the formula does: Using IF and CONCATENATE

IF ISERROR / ISNA formula in Excel

The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.

The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.

For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:

=IF(ISERROR(A2/B2), "N/A", A2/B2) Using IF together with ISERROR

And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!

Practice workbook for download

Excel IF multiple criteria - examples (.xlsx file)

Table of contents

4538 comments

  1. I need to compare grades in two cells. like if D6=A+ and D7=A, than "A+". means show higher grade. grades are A+, A, B+, B, C, D and F. to get final grade, I need to compare two grades. if both grades are same, final grade will be same. if grades are different with one step, final grade will be higher one. if grades are different, with two steps, final grade will be in between. if grades are different and apart from each other, final grade will be in between higher one. examples given below:

    example 1 (same)
    A+ and A+ = A+
    A and A = A
    C and C = C

    example 2 ( different/higher)
    A+ and A = A+
    A and B+ = A
    D and C = C

    example 3 (2 step different/ in between)
    A+ and B+ = A
    A and B = B+
    D and B = C

    example 4 ( apart/ in between higher)
    A+ and B = A
    A and C = B+
    D and B+ = B

    Please guide formula

  2. im trying to see if there is a way to detect a zero in cells b2 to b9 if there is i want it to execute one function or the other how can i do this (started self teaching best to over explain thank you)

  3. HOW TO SOLVE THE PROBLEM ?
    20% ANS = 20
    =TEXT(P2,".00") This correct or ......

  4. Hi!

    I am trying to check for a valid response for a variable (P2), the code/conditions I have are meant for EpiInfo but I am having so much trouble getting the formula translated and working in Excel. Any help is greatly appreciated!

    The conditions are:

    P1=1 AND P2>0 AND P2<8
    OR
    P1=2 AND (P2=0 OR P2="." OR P2=99)

    The returned value is '1' and all ELSE is '2'

  5. Hi can u tell me how to use if and or function to get depreciation value with sln, dB and Syd method for the same data in same cell.

  6. if-or(L59>L60,L59>L61,L59>L62),''yes'',''no'' which button to click on the keyboard in order to get to yes or no. i am learning on line.please help

  7. Hi,
    I am trying to create a formula with 3 different conditions.
    If J3<5 and K3<5 it should calculate K3-J3+1
    If J34 it should calculate 4-J3+1
    If neither is true the result is 0

    I have tried different variations o the following but nothing works:
    @IF(OR(AND(J3<5,K3<5),k3-j3+1,AND(J34),=4-j3+1,0))

    Any advice would be greatly appreciated. Thank you

    • ERROR in 2nd "If" condition I posted.
      Should read: If J34, it should calculate 4-J3+1
      ERROR in formula I posted.
      Should read: @IF(OR(AND(J3<5,K3<5),=k3-j3+1,AND(J34),=4-j3+1,"0"))

      I copied and pasted so I am not sure what happened. So sorry for any confusion!

      • OK so strange - after hitting Send the text changes in my post!
        Where it says J34 it should say IF J3 is less than 5 and K3>4.
        Hope the 3rd time is a charm! Thanks again.

        • NEVER MIND - I figured out by studying at least 1,000 questions already answered here over the past few days.

          Correct formula: =IF(AND(J3<=4,K3<=4),K3-J3+1,IF(AND(J34),4-J3+1,0))

          Thanks to everyone who answers strangers very complex problems on this site. AMAZING!

          • And once again my formula changed upon posting.

            If anyone needs the correct formula - respond to this and I will try to write it again with some other method

  8. HI
    I NEED A FORMULAR THAT WILL HELP CHECK IF A STUDENT HAVE PASS ALL REQUIRED COURSE.
    THANK YOU

  9. Cell G16 shows total.
    I want G17 to display "Level One" if cell G16 falls between B4 on another sheet (number listed in cell B4 is 10-13). Need this nested with C4 (14-16), d4 (17-19), e4 (20-22), f4 (23-27), g4 (28-38)

  10. i have to design a excel sheet for calculating printing cost, which involves multiple conditions
    categories :paper size, quantity, paper quality (100 GSM), Lamination,etc., i have to calculate paper cost, plate cost, labour cost according to the inputs.

    under paper size category there are diff sizes like
    1.a4
    2.a3
    3.crown
    4.double crown
    5.dimmy
    etc

    under paper quality categery it also varies according to gsm like 100gsm,170gsm,300gsm etc

    by looking up and combining paper size and gsm i have to calculate paper cost and remaining calculations labour printing cost, plate charges are also have to be calculated using combined inputs.

    please suggest me formulas with example to use / provide me a model excel.

    Thanksalot,

  11. does any know
    I want to write an argument statement that if a number in a certain column >-999 or<999 then send me an email.
    does anyone know how I can write this?

  12. Hello,

    I'm working on a project with 3 criteria and my formula seems to super long.

    =IF(AND(K2=12,L2>2),6,IF(AND(K2=6,L2>2,L28,M211,M20,M22,L20,M25,L210,M28,M26,L20),2,IF(AND(K2=3,L2=8,M2>25),2,IF(AND(K2=6,L2=8,M2>25),4,IF(AND(K2=6,L2=8,M2>25),4,0)))))))))))))

    • Column K is fixed with 3 numbers = 3, 6 and 12
      Column L could be between from 1-12
      Column M could be between from 1-31

      This is my formula so far. It's Super long. Maybe you can help me.

      =IF(AND(K2=12,L2>2),6,IF(AND(K2=6,L2>2,L28,M211,M20,M22,L20,M25,L210,M28,M26,L20),2,IF(AND(B2="KSA",K2=3,L2>2,L26,L28,M28,M20,M212,M22,L25,L28,M28,M20,M22,L22,L22,L22,L22,L22,L22,L225),2,IF(AND(B2="UAE",K2=6,L2=8,M2>25),4,IF(AND(B2="KSA",K2=3,L2=8,M2>25),2,IF(AND(B2="KSA",K2=6,L2=8,M2>25),4,IF(AND(B2="UAE",K2=6,L2=8,M2>25),4,IF(AND(B2="Jordan",K2=6,L2=8,M2>11,M225),4,IF(AND(B2="Jordan",K2=4,L2=8,M2>11),2,0))))))))))))))))))))))))))))))))))))

  13. Hi all looking for help with and IF AND and Or function

    im trying to get it to either times by .25 if both parameters are met or if only one then times by .5

    And if none of the parameters are met then leave as is.

    =IF(AND(J45="Tigress",M45>100000),O45*0.25,O45)*(OR(IF(J45="Tigress",O45*0.5,O45)))

    Any help would be much appreciated

    • =IF(AND(J45="Tigress",M45>100000),O45*0.25,IF(OR(J45="Tigress",M45>100000),O45*0.50,0))

      This should work

      Explanation on the below

      If J45=Tigress and M45 less than 100000, value in cell O45 will multiply to 0.25
      If J45=Tigress or M45 is less than 100000, value in cell O45 will multiply to 0.50
      If neither of the equation, the answer will be 0 - or you can change it to "Not found" instead of 0

  14. Hello,

    I am trying to use the formula below, but it is not correctly categorizing my data and I cannot figure out why.
    =IF((AND(A2>=TIME(7,0,0),A2<=TIME(18,0,0))),"Diurnal","Nocturnal")

    While some categorizations are correct, others are not. For example one species was caught at 15:36 Army time, but is categorized as nocturnal when it should be diurnal. Any thoughts?

    Also, as a fun bonus question: is there any way I could add a third option for species that come out at dawn out at dawn or dusk?

  15. Aloha,
    Can someone please check this formula? =IF(C3:D3=E3:K3), "BALANCE")

  16. Not entirely sure how the non-sensical formula in my last post managed to get in there. Note to self: Friday afternoon is no time for troubleshooting and analysis. It was clearly Beer O'clock and I was not paying attention to my inner voice. :)
    Feeling bright and bushy tailed on this Saturday morning, I was able to solve the puzzle.
    =IF(OR(AND(I12>F2,I12F2,J12F2,K12F2,L12<G2)),"Y","")

  17. I am having a heck of a time trying to get an IF(OR(AND formula to work correctly. My rows contain maintenance requirements with varying frequencies or recurrence. I then have 15 date columns each holding the next projected date for each maintenance requirement. The statement below captures a search through 3 of the 15 columns to see if the projected maintenance falls prior to a planned maintenance time. I keep getting an #VALUE! error. Any help would be appreciated. I can't help but think it is something simple. I have had attempts where I can get it to return a "Y" for the first occurrence but nothing after that in subsequent years. Thx.
    =IF(OR(AND(I12>$F$2,I12$F$2,J12$F$2,K12<$G$2)),"Y","")

  18. Hi All,
    Need a help in sorting out a problem. I'm trying to use the combination of IFS, AND, OR here.
    (All values are dates)

    Condition 1:
    Today's date (C1) = 04-12-20
    A1 = 04-12-19, 04-12-18
    &
    A1 = 04-02-21, 04-12-21

    I want to merge these conditions into a single cell E2

    If (C1-A1365,"Past 13+ Months") and if(A1-C190,"Fcst 4+ Months")

    Problem is that, it is reading two conditions as same, if the value is 0, which I'm trying to avoid.

    I would really appreciate some help on this by anyone.

    • Hello!
      If I understand your task correctly, the following formula should work for you:

      =IF((C1-A1) > 365,"Past 13+ Months",IF((A1-C1) > 90,"Fcst 4+ Months",""))

      I hope it’ll be helpful.

  19. I am preparing examination results, that consist of thirteen subjects each subject has two scores, then i calculated the average for each subject by considering two score i need a help on how to find the result points by considering seven subjects that a student got higher marks.

  20. In Cell I5 Create a drop down list with MON,TUE,WED, THU, FRI, SAT, SUN
    In Cell I5 Select TUE from the drop down list
    In Cell I6 Create a drop down list with BKLYN, QNS, NYC, BX, SI
    In Cell I6 Select NYC from the drop down list
    In Cell J5 Create an IFS formula that will result "# of Drivers working" on the DAY selected in Cell I5 and
    the BORO selected in Cell I6
    I know, how many drivers were working on the selected day and borough as I am following the chart but I have a problem with the formula. I don't know, how the formula will be since it requires me to have a formula in one cell with two different condition. Need help in formula.

    MON in Bklyn, Nyc, Qns, Bx, Si is only 1 driver working
    TUE all the same monday results
    Wed all the same monday results
    Thur all the same monday results
    Fri all the same monday results
    Sat all the same monday results
    Sun all the same monday results
    Only 1 driver was working when the condition met with any options if its Days or Borough they all have a same answer which is 1.

    Thankyou.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)