Excel IF statement with multiple conditions

The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.

In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.

How to use IF function with multiple conditions

In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:

  • AND function - returns TRUE if all the conditions are met; FALSE otherwise.
  • OR function - returns TRUE if any single condition is met; FALSE otherwise.

To better illustrate the point, let's investigate some real-life formulas examples.

Excel IF statement with multiple conditions (AND logic)

The generic formula of Excel IF with two or more conditions is this:

IF(AND(condition1, condition2, …), value_if_true, value_if_false)

Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.

Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.

For the logical test, you use the following AND statement: AND(B2>50, C2>50)

If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".

=IF(AND(B2>50, B2>50), "Pass", "Fail")

Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right: Excel IF statement with multiple AND conditions

In a similar manner, you can use the Excel IF function with multiple text conditions.

For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:

=IF(AND(B2="pass", C2="pass"), "Good!", "Bad") Excel IF function with multiple text conditions

Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.

In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:

=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")

The avoid this, you should use a nested IF function:

=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")

For more information, please see IF AND formula in Excel.

Excel IF function with multiple conditions (OR logic)

To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:

IF(OR(condition1, condition2, …), value_if_true, value_if_false)

The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.

So, if in the previous formula, we use OR instead of AND:

=IF(OR(B2>50, B2>50), "Pass", "Fail")

Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :) Excel IF function with multiple OR conditions

Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.

For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:

=IF(OR(B2={"delivered", "paid"}), "Closed", "")

More formula examples can be found in Excel IF OR function.

IF with multiple AND & OR statements

If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.

In our sample table, suppose you have the following criteria for checking the exam results:

  • Condition 1: exam1>50 and exam2>50
  • Condition 2: exam1>40 and exam2>60

If either of the conditions is met, the final exam is deemed passed.

At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):

OR(AND(B2>50, C2>50), AND(B2>40, C2>60)

Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:

=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")

The screenshot below indicates that we've done the formula right: IF with multiple AND & OR statements

Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:

  • In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
  • In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.

Nested IF statement to check multiple logical tests

If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.

Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:

  • Good: 60 or more (>=60)
  • Satisfactory: between 40 and 60 (>40 and <60)
  • Poor: 40 or less (<=40)

Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.

In our case, the functions are arranged from largest to smallest:

=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))

Naturally, you can nest more functions if needed (up to 64 in modern versions). Nested IF statement in Excel

For more information, please see How to use multiple nested IF statements in Excel.

Excel IF array formula with multiple conditions

Another way to get an Excel IF to test multiple conditions is by using an array formula.

To evaluate conditions with the AND logic, use the asterisk:

IF(condition1) * (condition2) * …, value_if_true, value_if_false)

To test conditions with the OR logic, use the plus sign:

IF(condition1) + (condition2) + …, value_if_true, value_if_false)

To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.

For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:

=IF((B2>50) * (C2>50), "Pass", "Fail") IF array formula with multiple AND conditions

In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.

To evaluate multiple conditions with the OR logic, the formula is:

=IF((B2>50) + (C2>50), "Pass", "Fail") IF array formula with multiple OR conditions

Using IF together with other functions

This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.

Example 1. If #N/A error in VLOOKUP

When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:

IF(ISNA(VLOOKUP(…)), value_if_na, VLOOKUP(…))

For example:

If #N/A return 0:

If the lookup value in E1 is not found, the formula returns zero.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return blank:

If the lookup value is not found, the formula returns nothing (an empty string).

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))

If #N/A return certain text:

If the lookup value is not found, the formula returns specific text.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE)) If #N/A error in VLOOKUP

For more formula examples, please see VLOOKUP with IF statement in Excel.

Example 2. IF with SUM, AVERAGE, MIN and MAX functions

To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.

In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:

=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))

If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor". Using the IF function with SUM

In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:

=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))

Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:

=IF(D2=MAX($D$2:$D$10), "Best result", "")

=IF(D2=MAX($D$2:$D$10), "Best result", "")

To have both labels in one column, nest the above functions one into another:

=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", "")) Using IF together with the MIN and MAX functions

Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.

In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:

  • COUNTIF - count cells that meet a condition
  • COUNTIFS - count cells with multiple criteria
  • SUMIF - conditionally sum cells
  • SUMIFS - sum cells with multiple criteria

Example 3. IF with ISNUMBER, ISTEXT and ISBLANK

To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:

=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", ""))) IF with ISNUMBER, ISTEXT and ISBLANK

Example 4. IF and CONCATENATE

To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:

=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

Looking at the screenshot below, you'll hardly need any explanation of what the formula does: Using IF and CONCATENATE

IF ISERROR / ISNA formula in Excel

The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.

The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.

For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:

=IF(ISERROR(A2/B2), "N/A", A2/B2) Using IF together with ISERROR

And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!

Practice workbook for download

Excel IF multiple criteria - examples (.xlsx file)

Table of contents

4538 comments

  1. I a trying to create an if function in excel 2016 with multiple layers:
    if cell a1>50, cell a1*2,
    if cell a1<50, cell a1*1,
    if cell a1*1<20, must result as 20.

    Please help.

  2. I need formula like ( my last year leave balance has 10 and current year leave 30 and this year consumed 03 now the balance will be 27 ignore balance another way need formula that if my last year leave -10 (negative) current Year 30 Balance = 20 in one cell Please do the needful.???any one

    • Hi,
      I’m sorry but your task is not entirely clear to me. Could you please describe it in more detail? What result do you want to get? Give an example of the source data and the expected result.

      • -----Staff Leaves Record----

        Module 1
        Opening Current Year Availed Leave Balance
        *10 30 -2 28
        *if this number is in positive then ignore in formula
        Module 2
        Opening Current Year Availed Leave Balance
        *-5 30 -5 20
        *If this number is in negative then adjusted and less in balance

        now hope everything is clear

          • Thanks!

  3. =IF(Index!D2="EXISTING",(ROUND(IF(H73250000,H73500000,H731000000,112500+(H73-1000000)*30/100,0)))),0)),(ROUND(IF(H73250000,H73500000,H73750000,H731000000,H731250000,H731500000,112500+(H73-1500000)*30/100,0)))))))

  4. Please let me know how to write following

    1 to 30 = Manager
    31 to 45 = Regional Head
    46 to 60 = Head of Sale
    61 to 90 = Credit Operation Team
    91 and above = Recovery Team and Legal
    1 and below = Before Over Due

  5. Hi ,

    Could you please help me to find formula for below Question ?

    if Value of cell B is greater than and equal to 95 , its cell A*3% .
    If Value of cell B is greater than and equal to 85 & less than 95 , its cell A*2.5% .
    If Value of cell B is greater than and equal to 80 & less than 85 , its cell A*2% .
    If Value of cell B is greater than and equal to 70 & less than 85 , its cell A*1% .

    Please help me out .

  6. Sir I recruiting some employees for my office. I recevied many applications and I have prepared a list in excel there is a condition that the applcant shouldn't be over the 40years of age and not less than 18years. I have entered the date of birth in column b and calculated the age in column c now i have the values some thing like 30year 2months and 4days now I need a formala to be entered in column D to find out that if the applicant is overage, within age limit or is he underage....

  7. I am trying to create an IF/THEN from a drop down list.
    C1 would have the drop down LIst: Hamburgers, hot dogs, nachos, pizza

    So the cell with the formula would need to perform: IF C1 is hamburgers, $5. If C1 is hot dogs, $2. if C1 is nachos, $4. if C1 is Pizza, $10.

    Can anyone help give me a framework?

    • Hello!
      If I understand your task correctly, the following formula should work for you:

      =IF(C1="hamburgers",5,IF(C1="hot dogs",2,IF(C1="nachos",4,IF(C1="pizza",10,""))))

      In Excel 2016 and above, you can use the IFS function

      =IFS(C1="hamburgers",5,C1="hot dogs",C1="nachos",C1="pizza",10)

      If there are a lot of products and conditions, I recommend searching for the price using the VLOOKUP function.
      I hope my advice will help you solve your task.

      • Thank you! I will try this out

  8. Hi Everyone
    I am trying to write a formula that has few IF conditions eg:

    if A1>=25 (age), then if B1=>£8.91, B1 otherwise £8.91 (it does work when A1 (age ) is = 25, if I change it to any other age it throws an error. This is one part of a formula

    the full formula should calculate:
    if A1>=25 (age), then if B1=>£8.91, B1 but otherwise £8.91, if A1=21, then if B1>8.36, B1 or £8.36

    is it possible to calculate? I am really struggling with this, any help appreciated

    • Hello!
      If the number 9 is written in cell B1, then no Excel formula can change the value in B1 to 8.91. This is only possible with a VBA macro.

  9. Our clients have 4 scenarios that produce different outcomes. I am trying to produce a formula for those outcomes -
    Columns I & J are the scenario factors, K is the outcome

    I2=Y J2=N K2=N
    I2=Y J2=Y K2=Y
    I2=N J2=Y K2=Y
    I2=N J2=N K2=N

    I have tried the following, using " " for the Y & N variables, also trying it without the " " and the outcome produces #NAME? with both formulas. I'm sure there is something easy I am missing.

    =IF(OR(AND(I2=Y,J2=N)),N,IF(OR(AND(I2=Y,J2=N)),Y,IF(OR(AND(I2=N,J2=Y)),Y,IF(OR(AND(I2=N,J2=N)),N))))

  10. I'm trying to get two texts with the same number value...
    home=0.5
    office=0.5
    any other entry=0

    any thoughts on how to do that?

    =IF(B5="home"or"office", 0.5,0) didn't work

    • Hello!
      The formula below will do the trick for you:

      =IF(OR(B5="home",B5="office"), 0.5,0)

      I hope you have studied the recommendations in the tutorial above. It contains answers to your question.

  11. Hi! Can anyone please help me in the following situation:
    Delivery charges are based on two types of services i.e Overnight & Economy
    Barcode of both are like OVN123456 & ECO123456
    If weight is <=1 kg delivery charges for OVN are 100 & For ECO are 70
    If weight is <=3 kg delivery charges for OVN are 175 & For ECO are 150
    I want that Delivery charges cell check if B3 has code OVN and E3 is having weight <=1 then show 100 OR if B3 has code ECO and weight in E3<=1Kg it shows 70.
    I will be very thankful.

  12. I need to return 100% in a cell for cells B2/A2. If B2 = 0, and A2= 0, I want the result to be 100% as a goal attainment returning 100% in C2.

    • Hello!
      If I understand your task correctly, the following formula should work for you:

      =IF(AND(B2=0,A2=0),100%,B2/A2)

      I hope it’ll be helpful.

  13. A1=B1 B1=48 C1=62
    A2= (very long formula) B2=A5 C2=(A5 in case A1=C1)
    A3= (very long formula)
    A4= (very long formula)
    A5=A1*sum (A2:A4)

    How can I put a formula for C2 since it is so hard to repeat all the formulas in A2 to A4? Please help me with this.

  14. Hi,

    Can someone please help me with this formula.

    =if(F3="emergency loan"=1*D3,if(F3="short loan"=2*D3,if(F3="normal loan"=3*D3,if(F3="development loan"=5*D3))))

    Essentially, if cell f3 reads a certain type of loan, i'm supposed to multiply it with cell d3 and the figure next to it. I'm stuck and frustrated.

    Any help would be appreciated. Thanks in advance

  15. Hi,

    I'm horrible with formulas and I need help. I need to put a dollar amount in a cell based on data on a different cell. This is what I am trying to do;
    If row D = MB,CB.DB I want row I to show $2000, if row D = MB+,CB+,DB+ I want row I to show $3500 and so on. What formula would I need to use? Thanks in advance!

  16. Can someone help me to create a formula for this, please

    Payment Type - FB
    Amount - 100

    I want to get this if the payment type is FB it should be equal to the amount
    if not FB then 0

  17. I can't seem to figure out how to fix this formula. Any thoughts?

    =IF(AND(F6=”N’,G6=”N”,E6/2, IF(AND(F6=”Y”,G6=”N”,(E6/2)*0.75, IF(AND(F6=”N”,G6=”Y”,E6, IF(AND(F6=”Y”,G6=”Y”,E6*0.875,))))

    If F6="N" and G6="N" then E6/2
    If F6="Y" and G6="N" then (E6/2)*0.75
    If F6="N" and G6="Y" then E6
    If F6="Y" and G6="Y" then E6*0.875

    Example:
    e6=3780 f6=n g6=n then answer should be 1890
    e6=3780 f6=y g6=n then answer should be 1417.5
    e6=3780 f6=n g6=y then answer should be 3780
    e6=3780 f6=y g6=y then answer should be 3307.5

  18. HELLO ! Can someone help me PLEASE.
    i have 6 Names in 3 DIFFERENT CELL: in cell A1"Emo/nonEmo", in cell B1"Bio/nonBio", in cell C3"Sio/nonSio". I want in cell A4 to display automaticaly miscellaneous combination between 3.

    For example =IF(a1=bio,b1=nonBio,c1=nonSio) in A4 display"Anorganic". Thk

  19. Hi All,

    can you help me for below.

    i have 3 condition,

    region,

    manager,

    more then 50 days,

    so i have to find

    region : Delhi.

    manager : Alex.
    then less then 50 days how many business done by alex.
    after (region=delhi)(manager=alex)(days=<50)(total business done).

    i tried if and sumif but i didn't get correct answer

  20. Hello,
    I want to copy a formula to downward cells, the first value to be changed cell to cell but the second should copy with the same value to all down cells:
    Formula: B77-C4, to the down cell the formula should change to B78-B4, B79-B4 etc.
    I wish someone can help
    Regards.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)