by The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.
In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.
How to use IF function with multiple conditions
In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:
- AND function - returns TRUE if all the conditions are met; FALSE otherwise.
- OR function - returns TRUE if any single condition is met; FALSE otherwise.
To better illustrate the point, let's investigate some real-life formulas examples.
Excel IF statement with multiple conditions (AND logic)
The generic formula of Excel IF with two or more conditions is this:
Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.
Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.
For the logical test, you use the following AND statement: AND(B2>50, C2>50)
If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".
=IF(AND(B2>50, B2>50), "Pass", "Fail")
Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right:
In a similar manner, you can use the Excel IF function with multiple text conditions.
For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:
=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")
Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.
In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:
=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")
The avoid this, you should use a nested IF function:
=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")
For more information, please see IF AND formula in Excel.
Excel IF function with multiple conditions (OR logic)
To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:
The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.
So, if in the previous formula, we use OR instead of AND:
=IF(OR(B2>50, B2>50), "Pass", "Fail")
Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :)
Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.
For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:
=IF(OR(B2={"delivered", "paid"}), "Closed", "")
More formula examples can be found in Excel IF OR function.
IF with multiple AND & OR statements
If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.
In our sample table, suppose you have the following criteria for checking the exam results:
- Condition 1: exam1>50 and exam2>50
- Condition 2: exam1>40 and exam2>60
If either of the conditions is met, the final exam is deemed passed.
At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):
OR(AND(B2>50, C2>50), AND(B2>40, C2>60)
Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:
=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")
The screenshot below indicates that we've done the formula right:
Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:
- In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
- In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.
Nested IF statement to check multiple logical tests
If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.
Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:
- Good: 60 or more (>=60)
- Satisfactory: between 40 and 60 (>40 and <60)
- Poor: 40 or less (<=40)
Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.
In our case, the functions are arranged from largest to smallest:
=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))
Naturally, you can nest more functions if needed (up to 64 in modern versions).
For more information, please see How to use multiple nested IF statements in Excel.
Excel IF array formula with multiple conditions
Another way to get an Excel IF to test multiple conditions is by using an array formula.
To evaluate conditions with the AND logic, use the asterisk:
To test conditions with the OR logic, use the plus sign:
To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.
For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:
=IF((B2>50) * (C2>50), "Pass", "Fail")
In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.
To evaluate multiple conditions with the OR logic, the formula is:
=IF((B2>50) + (C2>50), "Pass", "Fail")
Using IF together with other functions
This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.
Example 1. If #N/A error in VLOOKUP
When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:
For example:
If #N/A return 0:
If the lookup value in E1 is not found, the formula returns zero.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return blank:
If the lookup value is not found, the formula returns nothing (an empty string).
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return certain text:
If the lookup value is not found, the formula returns specific text.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))
For more formula examples, please see VLOOKUP with IF statement in Excel.
Example 2. IF with SUM, AVERAGE, MIN and MAX functions
To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.
In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:
=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))
If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor".
In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:
=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))
Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:
=IF(D2=MAX($D$2:$D$10), "Best result", "")
=IF(D2=MAX($D$2:$D$10), "Best result", "")
To have both labels in one column, nest the above functions one into another:
=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))
Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.
In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:
Example 3. IF with ISNUMBER, ISTEXT and ISBLANK
To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:
=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))
Example 4. IF and CONCATENATE
To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:
=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
Looking at the screenshot below, you'll hardly need any explanation of what the formula does:
IF ISERROR / ISNA formula in Excel
The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.
The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.
For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:
=IF(ISERROR(A2/B2), "N/A", A2/B2)
And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!
Practice workbook for download
Excel IF multiple criteria - examples (.xlsx file)
4538 comments
Sir, please help me
If between AH5 cell is 0% TO 5% Results will be 0%
If between AH5 cell 5% TO 6% Results will be 3%
If between AH5 cell 6% TO 8% Results will be 5%
If More than AH5 cell 8% percent Results will be 8%
Please help me on this earliest
CAN YOU PLEASE HELP ON THIS SIR
6% >= Breach > 5% 3% of breached orders
8% >= Breach > 6% 5% of breached orders
Breach > 8% 8% of breached orders
I need formula
6% >= Breach > 5% 3% of breached orders
8% >= Breach > 6% 5% of breached orders
Breach > 8% 8% of breached orders
I need in between formula
Hello!
I’m sorry but your task is not entirely clear to me. Could you please describe it in more detail? What result do you want to get? Give an example of the source data and the expected result.
I hope you have studied the recommendations in the tutorial above.
I am trying to create a formula that allows a name (that is typed in cell A) to input when a value (that is typed in cell C) =<192
Hello!
If I understand your task correctly, the following formula should work for you:
=IF(C1<=192,A1,"")
I hope it’ll be helpful.
I have a sheet with 2 tabs. in the first sheet i have 4 different scores. 1, 0,5, 0 and blank. In the next tab I need a formula that return 1 and blank as 0 and the o and 0,5 as 1.
How do I do the formula
Hello!
Please use the following formula
=IF(OR(A1=1,A1=""),0,IF(A1=0.5,1,""))
or
=IFS(A1=1,0,A1="",0,A1=0.5,1)
I hope it’ll be helpful.
Thank you so much, Alexander, for such lucid explanation of these really useful Excel functions. All of these were a great help!
If the decimal number is lower than .5 then round down
If the decimal number is higher than .5 then round UP
if the decimal number is equal to 0.5 & if the number is odd then ROUND the int number to same odd number only
If the decimal number is equal to 0.5 & if the number is even ,then round UP the int number to nearest odd number
Okay I got the answer No need to reply!
Thanks
Hello!
If I understand your task correctly, the following formula should work for you:
=IF((A2-INT(A2))=0.5, IF(MOD(INT(A2),2)=1, INT(A2), ROUND(A2,0)), ROUND(A2,0))
Hello
I'm trying to combine a IF and SEARCH function in a formula where if it finds in S1 "WSPD" If true "WSPD" if false Search in S1 "WSTM" if True "WSTM" , if false Search "WSAC" in S1 if true "WSAC" if False Search in S1 for "WSAD" if true "WSAD" .... If any of does not contain WSPD or WSTM or WSAC or WSAD.... then "WSSC"
I've put this formula
=IF(SEARCH("WSPD",S4),"WSPD",IF(SEARCH("WSTM",S4),"WSTM",IF(SEARCH("WSAC",S4),"WSAC",IF(SEARCH("WSAD",S4),"WSAD",""))))
It work to detect WSPD, but doesn't work for all other condition it just puts #VALUE
Thanks for your help to find where I did wrong
Hello!
Please use the following formula
=IF(ISNUMBER(SEARCH("WSPD",S4)),"WSPD", IF(ISNUMBER(SEARCH("WSTM",S4)),"WSTM", IF(ISNUMBER(SEARCH("WSAC",S4)),"WSAC", IF(ISNUMBER(SEARCH("WSAD",S4)),"WSAD",""))))
Hope this is what you need.
Yes it worked perfectly fine many thanks
Is there a way to include multiple AND statements in the IF formula? I am trying to populate response in Col A based on amounts in Col B and Col C.
- If Col B and Col C are both less than 0, then response 'Loss'
- If Col B and Col C are both greater than 0, then response 'Income'
- If Col B less than 0 and Col C greater than 0, then response 'Loss / Income'
- If Col B greater than 0 and Col C less than 0, then response 'Income / Loss'
Currently excel is allowing only two conditions. When I add the third it says "You have entered too many arguments for this function".
This works =IF(AND(B1<0,C10,C1>0),"Income"))
This gives error message =IF(AND(B1<0,C10,C1>0),"Income"),IF(AND(B10),"Loss / Income"),IF(AND(B1>0,C1<0),"Income / Loss"))
Thanks!
Hello!
The formula below will do the trick for you:
=IF(AND(B1 > 0,C1 > 0),"Income",IF(AND(B1 < 0,C1 > 0),"Loss / Income",IF(AND(B1 > 0,C1 < 0),"Income / Loss","")))
Hope this is what you need.
I am wondering if the formula has to include the absolute value, or if it can be a range. For example: I am trying to use the formula if the value is between 5.8-6.1 it will read as "Good". Is this possible to achieve, or can it only ever be = to one absolute value? This is the formula I have tried to do this: =If(C:C>=6.2,"Excellent",if(C:C=5.8-6.1,"Good",if(C:C=5.1-5.7,"Fair","Poor")
Hello!
If you use a range in the IF function, then its result will also be a range (array) of values. You must have a lot of free space on the sheet to display this array. If there is not enough space, you will get a #SPILL error.
Expression C:C = 5.1-5.7 is incorrect. Read about using multiple conditions in an IF function in this article.
I need all 3 of these variables to play nice together in one formula and I've been trying for 3 days to get it to work.
HELP is greatly appreciated so that my brain can stop hurting.
Cell A3 will always be either "D, "N" or "U"
Cell E3 will always be a different value
=if(and(A3="D",E3>2000),E3*0.25,"500")
=if(and(A3="U",E3>900),E3*0.25,"300")
=if(and(A3="N",E3>800),E3*0.25,"200")
Thanks in advance
Hi! I am trying to have a cell return a value based on whether other values in the same row are greater than zero. To give more detail, the data is tracking steps in a hiring process, each column is a step in the process and the users will enter the date when that step is completed. I’d like to have an additional column that will say what step in the process that candidate is currently in. In other words, if for candidate A the most recent date entered is under the “interview complete” column, how do I make another column that will return “interview complete” as a value for candidate A?
Lets say
I have 1.0 -5.0 then I wan between 50 - 0 so the value of 1.0 is 50 then if it 1.1 that's 49 how would I convrt 2.8 into its specific range
Hi,
Try the following formula:
=50-(A1-1)*10
Can I convert 1.0 into 50 then 5.0 into 0?
I am getting the error message too mant arguements. Is there a way to have more than 2 options in an IF statement?
=IF(I3="USD",$B$1*G3,IF(I3="GBP",$D$1*G3),IF(I3="CAD",$F$1*G3),0)
This equation should work better for you. I took out your unnecessary brackets that had caused the "too many arguments" notifications. (You had your "false" outside of the conditions.)
=IF(I3="USD",$B$1*G3,IF(I3="GBP",$D$1*G3,IF(I3="CAD",$F$1*G3,0)
Hope this works!
Hello!
Please try the following formula:
=IF(I3="USD",$B$1*G3,IF(I3="GBP",$D$1*G3,IF(I3="CAD",$F$1*G3,0)))
I hope it’ll be helpful.
Hi
Im using the following formula but it doesnt seem to be working
=IF(OR(J1080:J20001="AUD","2021","2020","2019","2018","2017","2016"),'Economic Assumptions - Forex'!$M$9*K1080)=(OR(J1080:J20001="ZAR","2021","2020","2019","2018","2017","2016"),'Economic Assumptions - Forex'!$M$16*K1080)
Please can you tell me what is wrong
Hello!
I can’t test your formula as it contains unique references to your data. I do not have this data.
However, the condition
(J1080:J20001=”AUD”,”2021″,”2020″,”2019″,”2018″,”2017″,”2016″)
is incorrect. Can only be used
(J1080:J20001=”AUD”,J1080:J20001=”2021″, J1080:J20001=”2020″, J1080:J20001=”2019″, J1080:J20001=”2018″, J1080:J20001=”2017″,J1080:J20001=”2016″)
I hope it’ll be helpful.
I have to come up with a function with the criteria...
D2>5
G2= "B" or "C" or "D"
E2= "marketing" or "finance"
and then if those are true then C2* $Q$23 otherwise 0 is left in the cell.
Hi,
I hope you have studied the recommendations in the tutorial above. It contains answers to your question
This is the formula I came up with, can you help me with what I have wrong, thanks!
=IF(AND(D2>5,OR(G2="B",G2="C",G2="D",OR(E2="Marketing",E2="Finance")))),C2*$Q$23,0)
Hello!
Please use the following formula
=IF(AND(D2>5,OR(G2="B",G2="C",G2="D",OR(E2="Marketing",E2="Finance"))),C2*$Q$23,0)
Hi I am a bit of an excel novice and I, like many, I don't know what I don't know
I am currently using this formula =IF(I14<$G$9,0,IF(I1465,$W$9))) to determine value in a cell for the following conditions
- if age (F14) is less than planned retirement age (SG$9) then pension income is $0
- if age (F14) is <=65 but greater than retirement age ($G$9) then pension income is $T$9
- if age (F14) is greater than 65, then pension income is $W$9
But; the stated pension incomes ($T$9 and $W$9) are indexed to inflation and I cannot figure out how to accommodate the ever increasing values. Any suggestions or help would be really appreciated
Hello!
If I understand your task correctly, you can manually change the values in $T$9 and $W$9. Also in these cells it is possible to use a reference to a cell with an actual value or a hyperlink.
I hope I answered your question. If something is still unclear, please feel free to ask.
I have a range of cells that results in a text of "(All)"...when a selection is made, one of the range of cells will say something else, like, "January"....is there a way to have multiple conditions AND result in any text shown other than "(All)"?
Multiple conditions, and the "else" statement would be whatever that shows up other than "(All)"?
Hi,
I’m sorry but your task is not entirely clear to me. For me to be able to help you better, please describe your task in more detail. Please specify what you were trying to find, what formula you used and what problem or error occurred. Give an example of the source data and the expected result.
It’ll help me understand it better and find a solution for you.
HI, I am trying to create a formula that looks across a range.
Example is:
I have to select one of three different results. FAIL, COMPLETE or CUSTOMER REFUND on a daily basis.
At the end of the week, I need to have a formula to say that if it has COMPLETE in the range (which are the days) then the final result should be COMPLETE. If it has anything else, it should be FAIL.
My issue is, that during the week, you could have a FAIL on Monday but a COMPLETE on Friday, so How do I get the formula to ignore the FAIL in this instance.
Hi,
Unfortunately, without seeing your data it is difficult to give you any advice.
Please have a look at this articles - VLOOKUP with one or more criteria or COUNTIF with multiple criteria.
Or describe your problem in more detail. Include an example of the source data and the result you want to get. It’ll help me understand your request better and find a solution for you.
Sorry for misunderstanding.
In the top columns I have the days, in my sheet it would be C3:H3 (Mon-sat)
In columns A:B I have the customer name and order number.
So once I enter the order number and go to that particular day, I want to enter FAIL on whatever day the failed delivery was. Then when the problem is resolved I would enter either COMPLETE or CUSTOMER REFUND.
So at the end of the week against that order in I4,I should be able to see if the order was COMPLETED OR FAIL. So if they had a FAIL and CUSTOMER REFUND that would be COMPLETE, if they had a FAIL and COMPLETE, that would be COMPLETE but if they had a FAIL then that would be COMPLETE.
I did think maybe if I concatenated the selections, and then did an IF statement, but this is where I am stuck!
Hello!
If I understand your task correctly, the following formula should work for you:
=IF(SUM(--(C3:H3="Complete")) > 0,"Complete","Fail")
After that you can copy this formula down along the column.
I hope it’ll be helpful.
Thanks!