by The tutorial shows how to create multiple IF statements in Excel with AND as well as OR logic. Also, you will learn how to use IF together with other Excel functions.
In the first part of our Excel IF tutorial, we looked at how to construct a simple IF statement with one condition for text, numbers, dates, blanks and non-blanks. For powerful data analysis, however, you may often need to evaluate multiple conditions at a time. The below formula examples will show you the most effective ways to do this.
How to use IF function with multiple conditions
In essence, there are two types of the IF formula with multiple criteria based on the AND / OR logic. Consequently, in the logical test of your IF formula, you should use one of these functions:
- AND function - returns TRUE if all the conditions are met; FALSE otherwise.
- OR function - returns TRUE if any single condition is met; FALSE otherwise.
To better illustrate the point, let's investigate some real-life formulas examples.
Excel IF statement with multiple conditions (AND logic)
The generic formula of Excel IF with two or more conditions is this:
Translated into a human language, the formula says: If condition 1 is true AND condition 2 is true, return value_if_true; else return value_if_false.
Suppose you have a table listing the scores of two tests in columns B and C. To pass the final exam, a student must have both scores greater than 50.
For the logical test, you use the following AND statement: AND(B2>50, C2>50)
If both conditions are true, the formula will return "Pass"; if any condition is false - "Fail".
=IF(AND(B2>50, B2>50), "Pass", "Fail")
Easy, isn't it? The screenshot below proves that our Excel IF /AND formula works right:
In a similar manner, you can use the Excel IF function with multiple text conditions.
For instance, to output "Good" if both B2 and C2 are greater than 50, "Bad" otherwise, the formula is:
=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")
Important note! The AND function checks all the conditions, even if the already tested one(s) evaluated to FALSE. Such behavior is a bit unusual since in most of programming languages, subsequent conditions are not tested if any of the previous tests has returned FALSE.
In practice, a seemingly correct IF statement may result in an error because of this specificity. For example, the below formula would return #DIV/0! ("divide by zero" error) if cell A2 is equal to 0:
=IF(AND(A2<>0, (1/A2)>0.5),"Good", "Bad")
The avoid this, you should use a nested IF function:
=IF(A2<>0, IF((1/A2)>0.5, "Good", "Bad"), "Bad")
For more information, please see IF AND formula in Excel.
Excel IF function with multiple conditions (OR logic)
To do one thing if any condition is met, otherwise do something else, use this combination of the IF and OR functions:
The difference from the IF / AND formula discussed above is that Excel returns TRUE if any of the specified conditions is true.
So, if in the previous formula, we use OR instead of AND:
=IF(OR(B2>50, B2>50), "Pass", "Fail")
Then anyone who has more than 50 points in either exam will get "Pass" in column D. With such conditions, our students have a better chance to pass the final exam (Yvette being particularly unlucky failing by just 1 point :)
Tip. In case you are creating a multiple IF statement with text and testing a value in one cell with the OR logic (i.e. a cell can be "this" or "that"), then you can build a more compact formula using an array constant.
For example, to mark a sale as "closed" if cell B2 is either "delivered" or "paid", the formula is:
=IF(OR(B2={"delivered", "paid"}), "Closed", "")
More formula examples can be found in Excel IF OR function.
IF with multiple AND & OR statements
If your task requires evaluating several sets of multiple conditions, you will have to utilize both AND & OR functions at a time.
In our sample table, suppose you have the following criteria for checking the exam results:
- Condition 1: exam1>50 and exam2>50
- Condition 2: exam1>40 and exam2>60
If either of the conditions is met, the final exam is deemed passed.
At first sight, the formula seems a little tricky, but in fact it is not! You just express each of the above conditions as an AND statement and nest them in the OR function (since it's not necessary to meet both conditions, either will suffice):
OR(AND(B2>50, C2>50), AND(B2>40, C2>60)
Then, use the OR function for the logical test of IF and supply the desired value_if_true and value_if_false values. As the result, you get the following IF formula with multiple AND / OR conditions:
=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")
The screenshot below indicates that we've done the formula right:
Naturally, you are not limited to using only two AND/OR functions in your IF formulas. You can use as many of them as your business logic requires, provided that:
- In Excel 2007 and higher, you have no more than 255 arguments, and the total length of the IF formula does not exceed 8,192 characters.
- In Excel 2003 and lower, there are no more than 30 arguments, and the total length of your IF formula does not exceed 1,024 characters.
Nested IF statement to check multiple logical tests
If you want to evaluate multiple logical tests within a single formula, then you can nest several functions one into another. Such functions are called nested IF functions. They prove particularly useful when you wish to return different values depending on the logical tests' results.
Here's a typical example: suppose you want to qualify the students' achievements as "Good", "Satisfactory" and "Poor" based on the following scores:
- Good: 60 or more (>=60)
- Satisfactory: between 40 and 60 (>40 and <60)
- Poor: 40 or less (<=40)
Before writing a formula, consider the order of functions you are going to nest. Excel will evaluate the logical tests in the order they appear in the formula. Once a condition evaluates to TRUE, the subsequent conditions are not tested, meaning the formula stops after the first TRUE result.
In our case, the functions are arranged from largest to smallest:
=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))
Naturally, you can nest more functions if needed (up to 64 in modern versions).
For more information, please see How to use multiple nested IF statements in Excel.
Excel IF array formula with multiple conditions
Another way to get an Excel IF to test multiple conditions is by using an array formula.
To evaluate conditions with the AND logic, use the asterisk:
To test conditions with the OR logic, use the plus sign:
To complete an array formula correctly, press the Ctrl + Shift + Enter keys together. In Excel 365 and Excel 2021, this also works as a regular formula due to support for dynamic arrays.
For example, to get "Pass" if both B2 and C2 are greater than 50, the formula is:
=IF((B2>50) * (C2>50), "Pass", "Fail")
In my Excel 365, a normal formula works just fine (as you can see in the screenshots above). In Excel 2019 and lower, remember to make it an array formula by using the Ctrl + Shift + Enter shortcut.
To evaluate multiple conditions with the OR logic, the formula is:
=IF((B2>50) + (C2>50), "Pass", "Fail")
Using IF together with other functions
This section explains how to use IF in combination with other Excel functions and what benefits this gives to you.
Example 1. If #N/A error in VLOOKUP
When VLOOKUP or other lookup function cannot find something, it returns a #N/A error. To make your tables look nicer, you can return zero, blank, or specific text if #N/A. For this, use this generic formula:
For example:
If #N/A return 0:
If the lookup value in E1 is not found, the formula returns zero.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return blank:
If the lookup value is not found, the formula returns nothing (an empty string).
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))
If #N/A return certain text:
If the lookup value is not found, the formula returns specific text.
=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))
For more formula examples, please see VLOOKUP with IF statement in Excel.
Example 2. IF with SUM, AVERAGE, MIN and MAX functions
To sum cell values based on certain criteria, Excel provides the SUMIF and SUMIFS functions.
In some situations, your business logic may require including the SUM function in the logical test of IF. For example, to return different text labels depending on the sum of the values in B2 and C2, the formula is:
=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))
If the sum is greater than 130, the result is "good"; if greater than 110 – "satisfactory', if 110 or lower – "poor".
In a similar fashion, you can embed the AVERAGE function in the logical test of IF and return different labels based on the average score:
=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))
Assuming the total score is in column D, you can identify the highest and lowest values with the help of the MAX and MIN functions:
=IF(D2=MAX($D$2:$D$10), "Best result", "")
=IF(D2=MAX($D$2:$D$10), "Best result", "")
To have both labels in one column, nest the above functions one into another:
=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))
Likewise, you can use IF together with your custom functions. For example, you can combine it with GetCellColor or GetCellFontColor to return different results based on a cell color.
In addition, Excel provides a number of functions to calculate data based on conditions. For detailed formula examples, please check out the following tutorials:
Example 3. IF with ISNUMBER, ISTEXT and ISBLANK
To identify text, numbers and blank cells, Microsoft Excel provides special functions such as ISTEXT, ISNUMBER and ISBLANK. By placing them in the logical tests of three nested IF statements, you can identify all different data types in one go:
=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))
Example 4. IF and CONCATENATE
To output the result of IF and some text into one cell, use the CONCATENATE or CONCAT (in Excel 2016 - 365) and IF functions together. For example:
=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))
Looking at the screenshot below, you'll hardly need any explanation of what the formula does:
IF ISERROR / ISNA formula in Excel
The modern versions of Excel have special functions to trap errors and replace them with another calculation or predefined value - IFERROR (in Excel 2007 and later) and IFNA (in Excel 2013 and later). In earlier Excel versions, you can use the IF ISERROR and IF ISNA combinations instead.
The difference is that IFERROR and ISERROR handle all possible Excel errors, including #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, and #NULL!. While IFNA and ISNA specialize solely in #N/A errors.
For example, to replace the "divide by zero" error (#DIV/0!) with your custom text, you can use the following formula:
=IF(ISERROR(A2/B2), "N/A", A2/B2)
And that's all I have to say about using the IF function in Excel. I thank you for reading and hope to see you on our blog next week!
Practice workbook for download
Excel IF multiple criteria - examples (.xlsx file)
4538 comments
Hi,
I'm newbie to excel, I hope you could help me, basically I'm trying to get the formula if two conditions are met
example: If A1="apple" and A4 contains %(eg.12345%Mango), then it will sum the C1/B4 and do nothing if not.
Appreciate your response.
Hello!
What does the “sum the C1/B4” phrase mean?
This formula shows the fulfillment of your conditions.
=IF(AND(A1="apple",ISNUMBER(SEARCH("%",A4,1))),"Yes","No")
You can write other values or formulas instead of Yes and No.
Hello! I'm pretty new to excel but I'm trying to get a status using the equation below. There are three different options that can happen "completed", "not started", and "waived". What I'm trying to figure out is how to get "completed" and "waived" to come out across a row as "True" but if there were to be a "not started" for example in cell E2 then for it to show the status as "False".
=IF(OR(AND(D2="completed",D2="waived"),AND(E2="completed",E2="waived"),AND(F2="completed",F2="waived"),AND(G2="completed",G2="waived"),AND(H2="completed",H2="waived"),AND(I2="completed",I2="waived")),"True","True")
Thank you!
Hi How would i set up formatting? using an If statement for example
if A1:A3 = yes color whole row green (A1:BE1)
thank you in advance!
Hello!
Here is the article that may be helpful to you: How to change the row color based on a cell's value in Excel
I hope my advice will help you solve your task.
Hello!
Trying to figure out how to do if statements to add up to a number between 1 and 4 if they hit certain if statements and then have that number multiple by 200
If( B1>=A1,0,1) + ( If B2>=A2,0,1) + (B3>=A3,0,1) + (B4>=B4,0,1) .....Then depending on how many 1's that adds up to that sum would be multiplied by 200
Hello!
If I understand you correctly, then you can use any of these formulas:
=(SUM(IF(B1>=A1,0,1),IF(B2>=A2,0,1),IF(B3>=A3,0,1),IF(B4>=B4,0,1)))*200
=(SUM(--(B1<A1),--(B2<A2),--(B3<A3),--(B4<B4)))*200
=((B1<A1)+(B2<A2)+(B3<A3)+(B4<B4))*200
Hope this is what you need.
Hi ,
Could you please help me to find formula
A | B | C | D | E | F | G | H | I | J | K | L | M |
WARD|Ward|Description|Average|Ward.|Wardwise|Total|RES |RES|COM |COM|INDUSTRY|INDSTRY|
1 |1 |RES |0.90% |1 |0.80% |3 |0.90%|2 |0.60%|1 | |
2 |1 |COM |0.60% |2 |0.60% |1 | | | | |0.60% | 1
3 |4 |RES |1.00% |3 |1.50% |1 | | |1.50%|1 | |
4 |5 |RES |1.10% |4 |1.00% |1 |1.00%|1 | | | |
5 |9 |RES |0.30% |5 |1.00% |2 |1.00%|2 | | | |
6 |2 |INDUSTRY |0.60% |6 | | | | | | | |
7 |1 |RES |0.90% |7 | | | | | | | |
8 |9 |COM |0.30% |8 | | | | | | | |
9 |5 |RES |0.90% |9 |0.30% |2 |0.30%|1 |0.30%|1 | |
10 |3 |COM |1.50% |10 | | | | | | | |
column A,B,C,D (data) (i wanted formula formula to sort column A-D in ascending )
Column F - ward wise average (used formula =IFERROR(AVERAGEIF($B$3:$B$12,(A2),$D$3:$D$12),"") )
Column H, J, L - used formula - IFERROR(AVERAGEIFS($D$3:$D$12,$B$3:$B$12,A2,$C$3:$C$12,$I$1),"")
i have used data - sort in coulmn G,I,K,M but i want formula to sort wardwise-RES, wardwise-COM, etc.)
in Column N - wanted highest average repeated in column D , and total highest average counts repeated in Column O
Please help me in find the solution ........ plz need help
cell A1 can have value "ok", "nok", or "n/a".
same cell B1 can have value "ok", "nok", or "n/a".
How can I in cell C1 return:
ok if both A1andB1 are ok.
nok if either is nok.
ok if A1orB1 is ok and the other is n/a.
n/a if both are n/a.
Below formula returns all except n/a.
=IF(OR(AND(DD3527="ok", DR3527="ok"),AND(DD3527="n/a",DR3527="n/a")), "ok", "nok")
Hello!
Please try the following formula:
=IF(OR(A1="nok",B1="nok"),"nok",IF(OR(A1="ok",B1="ok"),"ok",IF(AND(A1="na",B1="na"),"na","")))
Hope this is what you need.
You are AWESOME!! Thank you!!
Hi - can someone help me write this in a Boolean "IF" statement.
IF the years of experience is "0" or less than 5 years, the raise is 2%
IF the years of experience is 5 years and less than 10 years, the raise is 3%
IF the years of experience is 10 years and less than 14 years, the raise is 4%
IF the years of experience is 13 years and less than 18 years, the raise is 5%
IF the years of experience is greater than 17 the raise is "0"
Tanya
Hello!
I hope you have studied the recommendations in the tutorial above. It contains answers to your question.
Your conditions 4 and 5 contradict each other.
I just want to say that i greatly appreciated and was just amazed how you are still consistently and humbly solving questions of people without getting sick of it, even after more than 2 months of the publication date. Kudos to you man!
Hello! I'm trying to get excel to do an IF function but am having trouble with my formula. I want it to be if Field 1, Field 2, or Field 3 are selected then "Soccer". If Field 4, Field 5, or Field 6 are selected then "Baseball". I'm trying to get excel to automatically bring up with fields are soccer or baseball fields. Thanks!
Hi,
I hope you have studied the recommendations in the tutorial above. It contains answers to your question.
Your conditions contradict each other. If the values will be written in all 6 cells, what value do you want to get? “Soccer” or “Baseball”?
Hi, what can I do if I want to print a specific data-field(cell already typed in excel) depending upon a value entered by the user?
For instance, IF(B1="Petrol", (//I wish to print cell D1 adjacent to it))
Hi,
You can use the formula
IF(B1=”Petrol”, D1,"")
I hope you remember that an Excel formula can only change the value of the cell in which it is written.
Hello there!!
I am trying to analyze data from a google doc survey. The question I am interested in analyzing was a multiple checkbox response with multiple answers. I am wanting to take the data from that cell (that shows multiple text-based answers) and create a formula that pulls out a specific option/text response and then inputs a 0 or 1 if the option/response is present in the initial cell that has the multiple text answers. How would I create this formula?
Example of what I want:
Participant # | Response | Option 1 present | Option 2 present | Option 3 present - etc.
Participant A | Opt 1, Opt 4 | 1 | 0 | 0 |
Participant B | Opt 1, Opt 2, Opt 3 | 1 | 1 | 1 |
Participant C | Opt 3, Opt 4, Opt5 | 0 | 0 | 0 |
Participant D | Opt 2, Opt 3 | 0 | 1 | 1 |
Hi,
I’m not sure I got you right since the description you provided is not entirely clear. However, it seems to me that the formula below will work for you:
=IF(ISNUMBER(SEARCH(1,$B$1,1)),"Opt 1 "&C1,"")
I want formulae based on Num of Trainings
Num of Trainings
3
7
15
3
0
-7
Days1
Pls check where am doing mistake - '=IF(f20,f230,f260 Days"))) and help me in correction
Is there any formula for designing timetable for teachers in a school/ college or university?
Hi, I need a formula for my work,
I work on students results, in remarks I want to show if rank=1 ,"first position" and if percentage < 60, "fail"
Want to show the both in the same column.
I know to use rank formula for positioning, and if formula, but I want to merge them both.
Hi,
Could you help me, i'm trying to write formula to deduct certain value.
I have a table with certain numbers and i need to leave the same numbers lesser then 2000.
But numbes:
greater then 2000 and lesser then 4000 i need to deduct for 10
greater then 4000 and lesser then 6500 i need deduct for 20
greater then 6500 and lesser then 9000 deduct for 30
grater then 9000 deduct for 40.
Thank you in advance.
Dragan
Hello!
I hope you have studied the recommendations in the tutorial above. It contains answers to your question
=IF(A2>9000,A2-40,IF(A2 > 6500,A2-30,IF(A2 > 4000,A2-20,IF(A2 > 2000,A2-10,A2))))
Hi,
Sorry but i didn't see them.
Thank you very much, this resolved my problem.
Best regards,
Dragan
Hi!!
I am writing a formula to determine Pass/Fail. I used an IF .formula which states this =IF(D6>=75%,"P","F").
It is stating P/F correctly in every instance EXCEPT where the grade matches or is equal to the 75%. In that instance it is reporting and "F" even though 75% or above is passing. I have trying writing the formula 100 different ways and no matter what I try it will not give a "P" to any cell with a grade of 75%. Please Help!!
Hello!
I have not been able to replicate your problem. You may be calculating the value in cell D6. In this case, the value on the screen may not match the real one. In this case, you need to use the ROUND function.
If 3 out of any 6 cells of a ROW have a value greater than 0, then how to find it In google sheet.
Hello Vijay,
You can color such cells using conditional formatting.
Sir when I use the if condition in this type of example in many time but we can't find the actual right answer for this condition.so how were we do.
Example: =IF(B2= "MAHARASHTRA"),(A2*4%),(A2*12.5%))
Hello!
Please try the following formula:
=IF(B2= "MAHARASHTRA",A2*4%,A2*12.5%)
Thanks a lot very helpful website .
Can you use this to include text entry if two various criteria are met? I.e if the date matches, and the client name matches, what stage in the sales process was the deal at?
Hello!
I’m sorry but your task is not entirely clear to me. For me to be able to help you better, please describe your task in more detail. Please specify what you were trying to find, what formula you used and what problem or error occurred. Give an example of the source data and the expected result.
It’ll help me understand it better and find a solution for you