by The tutorial explains the Excel REPLACE and SUBSTITUTE functions with examples of uses. See how to use the REPLACE function with text strings, numbers and dates, and how to nest several REPLACE or SUBSTITUTE functions within one formula.
Last week we discussed various ways of using FIND and SEARCH functions within your Excel worksheets. Today, we will be taking a deeper look at two other functions to replace text in a cell based on its location or substitute one text string with another based on content. As you may have guessed, I am talking about the Excel REPLACE and SUBSTITUTE functions.
Excel REPLACE function
The REPLACE function in Excel allows you to swap one or several characters in a text string with another character or a set of characters.
As you see, the Excel REPLACE function has 4 arguments, all of which are required.
- Old_text - the original text (or a reference to a cell with the original text) in which you want to replace some characters.
- Start_num - the position of the first character within old_text that you want to replace.
- Num_chars - the number of characters you want to replace.
- New_text - the replacement text.
For example, to change the word "sun" to "son", you can use the following formula:
=REPLACE("sun", 2, 1, "o")
And if you put the original word in some cell, say A2, you can supply the corresponding cell reference in the old_text argument:
=REPLACE(A2, 2, 1, "o")
Note. If the start_num or num_chars argument is negative or non-numeric, an Excel Replace formula returns the #VALUE! error.
Using Excel REPLACE function with numeric values
The REPLACE function in Excel is designed to work with text strings. Of course, you can use it to replace numeric characters that are part of a text string, for example:
=REPLACE(A2, 7, 4, "2016")
Notice that we enclose "2016" in double quotes as you usually do with text values.
In a similar manner, you can replace one or more digits within a number. For example:
=REPLACE(A4, 4, 4,"6")
And again, you have to enclose the replacement value in double quotes ("6").
Note. An Excel REPLACE formula always returns a text string, not number. In the screenshot above, notice the left alignment of the returned text value in B2, and compare it to the right-aligned original number in A2. And because it's a text value you won't be able to use it in other calculations unless you convert it back to number, for example by multiplying by 1 or by using any other method described in How to convert text to number.
Using Excel REPLACE function with dates
As you have just seen, the REPLACE function works fine with numbers, except that it returns a text string :) Remembering that in the internal Excel system, dates are stored as numbers, you may try to use some Replace formulas on dates. Results would be quite embarrassing.
For instance, you have a date in A2, say 1-Oct-14, and you want to change "Oct" to "Nov". So, you write the formula REPLACE(A2, 4, 3, "Nov") that tells Excel to replace 3 chars in cells A2 beginning with the 4th char… and got the following result:
Why's that? Because "01-Oct-14" is only a visual representation of the underlying serial number (41913) that represents the date. So, our Replace formula changes the last 3 digits in the above serial number to "Nov" and returns the text string "419Nov".
To get the Excel REPLACE function to correctly work with dates, you can convert dates to text strings first by using the TEXT function or any other technique demonstrated in How to convert date to text in Excel. Alternatively, you can embed the TEXT function directly in the old_text argument of the REPLACE function:
=REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov")
Please remember that the result of the above formula is a text string, and therefore this solution works only if you are not planning to use the modified dates in further calculations. If you do need dates rather than text strings, use the DATEVALUE function to turn the values returned by the Excel REPLACE function back to dates:
=DATEVALUE(REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov"))
Nested REPLACE functions to do multiple replacements in a cell
Quite often, you may need to do more than one replacement in the same cell. Of course, you could do one replacement, output an intermediate result into an additional column, and then use the REPLACE function again. However, a better and more professional way is to use nested REPLACE functions that let you perform several replacements with a single formula. In this context, "nesting" means placing one function within another.
Consider the following example. Supposing you have a list of telephone numbers in column A formatted as "123456789" and you want to make them look more like phone numbers by adding hyphens. In other words, your goal is to turn "123456789" into "123-456-789".
Inserting the first hyphen is easy. You write a usual Excel Replace formula that replaces zero characters with a hyphen, i.e. adds a hyphen in the 4th position in a cell:
=REPLACE(A2,4,0,"-")
The result of the above Replace formula is as follows:
Okay, and now we need to insert one more hyphen in the 8th position. To do this, you place the above formula within another Excel REPLACE function. More precisely, you embed it in the old_text argument of the other function, so that the second REPLACE function will handle the value returned by the first REPLACE, and not the value in cell A2:
=REPLACE(REPLACE(A2,4,0,"-"),8,0,"-")
As the result, you get the phone numbers in the desired formatting:
In a similar manner, you can use nested REPLACE functions to make text strings look like dates by adding a forward slash (/) where appropriate:
=(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))
Moreover, you can convert text strings into real dates by wrapping the above REPLACE formula with the DATEVALUE function:
=DATEVALUE(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))
And naturally, you are not limited in the number of functions you can nest within one formula (the modern versions of Excel 2010, 2013 and 2016 allow up to 8192 characters and up to 64 nested functions in a formula).
For example, you can use 3 nested REPLACE functions to have a number in A2 appear like date and time:
=REPLACE(REPLACE(REPLACE(REPLACE(A2,3,0,"/") ,6,0,"/"), 9,0, " "), 12,0, ":")
Replacing a string that appears in a different position in each cell
So far, in all the examples we have been dealing with values of a similar nature and have made replacements in the same position in each cell. But real-life tasks are often more complicated than that. In your worksheets, the characters to be replaced may not necessarily appear in the same place in each cell, and therefore you will have to find the position of the first character that should be replaced. The following example will demonstrate what I'm talking about.
Supposing you have a list of email addressing in column A. And the name of one company has changed from "ABC" to, say, "BCA". So, you have to update all of the clients' email addressing accordingly.
But the problem is that the client names are of different length, and that is why you cannot specify exactly where the company name begins. In other words, you do not know what value to supply in the start_num argument of the Excel REPLACE function. To find it out, use the Excel FIND function to determine the position of the first char in the string "@abc":
=FIND("@abc",A2)
And then, supply the above FIND function in the start_num argument of your REPLACE formula:
=REPLACE(A2, FIND("@abc",A2), 4, "@bca")
Tip. We include "@" in our Excel Find and Replace formula to avoid accidental replacements in the name part of email addresses. Of course, there's a very slim chance that such matches will occur, and still you may want to be on the safe side.
As you see in the following screenshot, the formula has no problem with finding and replacing the old text with the new one. However, if the text string to be replaced is not found, the formula returns the #VALUE! error:
And we want the formula to return the original email address instead of the error. So, let's enclose our FIND & REPLACE formula in the IFERROR function:
=IFERROR(REPLACE(A2, FIND("@abc",A2), 4, "@bca"),A2)
And this improved formula works perfectly, doesn't it?
Another practical application of the REPLACE function is to capitalize the first letter in a cell. Whenever you deal with a list of names, products, and the like, you can use the above-linked formula to change the first letter to UPPERCASE.
Tip. If you want to make the replacements in the original data, an easier way would be using the Excel FIND and REPLACE dialog.
Excel SUBSTITUTE function
The SUBSTITUTE function in Excel replaces one or more instances of a given character or text string with a specified character(s).
The syntax of the Excel SUBSTITUTE function is as follows:
The first three arguments are required and the last one is optional.
- Text - the original text in which you want to substitute characters. Can be supplied as a test string, cell reference, or a result of another formula.
- Old_text - the character(s) you want to replace.
- New_text - the new character(s) to replace old_text with.
- Instance_num - the occurrence of old_text you want to replace. If omitted, every occurrence of the old text will be changed to the new text.
For example, all of the below formulas substitute "1" with "2" in cell A2, but return different results depending on which number you supply in the last argument:
=SUBSTITUTE(A2, "1", "2", 1) - Substitutes the first occurrence of "1" with "2".
=SUBSTITUTE(A2, "1", "2", 2) - Substitutes the second occurrence of "1" with "2".
=SUBSTITUTE(A2, "1", "2") - Substitutes all occurrences of "1" with "2".
In practice, the SUBSTITUTE function is also used for removing unwanted characters from cells. For real-life examples, please see:
Note. The SUBSTITUTE function in Excel is case-sensitive. For example, the following formula replaces all instances of the uppercase "X" with "Y" in cell A2, but it won't replace any instances of the lowercase "x".
Substitute multiple values with a single formula (nested SUBSTITUTE)
As is the case with the Excel REPLACE function, you can nest several SUBSTITUTE functions within a single formula to do several substitutions at a time, i.e. substitute several characters or substrings with a single formula.
Supposing you have a text string like "PR1, ML1, T1" in cell A2, where "PR" stands for "Project, "ML" stands for "Milestone" and "T" means "Task". What you want is to replace the three codes with full names. To achieve this, you can write 3 different SUBSTITUTE formulas:
=SUBSTITUTE(A2,"PR", "Project ")
=SUBSTITUTE(A2, "ML", "Milestone ")
=SUBSTITUTE(A2, "T", "Task ")
And then nest them into each other:
=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A2,"PR","Project "),"ML","Milestone "),"T","Task ")
Notice that we've added a space at the end of each new_text argument for better readability.
To learn other ways to replace multiple values at a time, please see How to do mass find and replace in Excel.
Excel REPLACE vs. Excel SUBSTITUTE
The Excel REPLACE and SUBSTITUTE functions are very similar to each other in that both are designed to swap text strings. The differences between the two functions are as follows:
- SUBSTITUTE replaces one or more instances of a given character or a text string. So, if you know the text to be replaced, use the Excel SUBSTITUTE function.
- REPLACE changes characters in a specified position of a text string. So, if you know the position of the character(s) to be replaced, use the Excel REPLACE function.
- The SUBSTITUTE function in Excel allows adding an optional parameter (instance_num) that specifies which occurrence of old_text should be changed to new_text.
This is how you use the SUBSTITUTE and REPLACE functions in Excel. Hopefully, these examples will prove useful in solving your tasks. I thank you for reading and hope to see on our blog next week!
Download practice workbook
REPLACE and SUBSTITUTE formula examples (.xlsx file)
301 comments
Hi
I have a value in a cell, say 273.75 in A1. Everyday, I download a data into this cell.
I have another cell with value 275.00 in B1.
Now, whenever in future, the downloaded value in A1 exceeds 275 say 278, I want B1 to change to 278 automatically. Can we do this by writing a command in the relevant cell?
Hi madam
How we can replace only #NUM! with 0 and other remain same..
Plz
Thank U
Hello Harjeet,
Most likely #NUM! is the error value returned by your current formula. To check this, select any cell with #NUM! and look at the formula bar. If you see a formula there, enclose it in the IFERROR function, like this:
=IFERROR(your formula, 0)
If you want to change into below format:-
18-45-60-12-10 18004500600012010 (result)
18-45-60-12-11 18004500600012011 (result)
18-45-60-12-12 18004500600012012 (result)
=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A3,"18-","1800"),"45-","4500"),"60-","6000"),"12-","120")
I have date like name & value .. in that i want to know how many times that name occurs in that column..result will be name1 & name2 & name3 ...something like that....pls tell any formula to find out...
1A2DF2GH512J
How to find how many numeric value are in above text?
Plz help..
I want to change a particular column values to the different specific values as desired. like if in A1= 190000 it should change in 800000 in B1, if it is 190090 then it should change 800090, if it is 199120 then it should change 800120 n like wise..
i have lots on numbers in column A, which i want to change in specific values in column B.
Any suggestions..
I have two coloumn one is NARRATION and other is REMARKS.
I want to keep REMARKS coloumn intact if narration is XX..
any suggestions.
Hi, team,
I am trying to make a function that will convert shorthand strings of text to full notations based on a table of definitions, much like CUSTOX from March 25, 2016. We notate accounts shorthand in one system due to space limitations, but then are required to spell everything out in another. It is very time consuming to go through and edit the shorthand.
If we could simply paste in a string of shorthand in excel and it spit out the "translated" spelled-out version, based on a standard list of abbreviations, we could document account history much more efficiently.
Furthermore, if we could use a data table (again as CUSTOX mentioned) to manage the definitions much more easily, that would be a HUGE, DEFINITE plus.
So far, I have been successful using a nested substitute string like this:
substitute(substitute(substitute(A1,"acct","account"),"xfer","transfer"),"pd","paid")
only I am up to about 15 substitutions (excel 2013) and have more to input. It is getting difficult managing the linear, buried list within one cell. I would much rather use a table like this and have my substitute function reference it:
abbr definition
pif paid in full
cst customer
bal balance
od overdue
pd paid
chk check
crd card
...and so on....
Can anyone help me out???
I'm trying to replace someone's name with another in a specific column, so that the name "Mike" replaces "Michael" for example. How/where do I put the substitute rule so that every instance of "Michael" in column B is replaced with the name "Mike"?
Hi,
i want to replace space in my between my text tell me how can i do it
Hello Sunny,
You can use a formula similar to this:
=SUBSTITUTE(A1, " ", "text")
Where "text" is a text string that you want to replaces spaces with. If you want to remove spaces, i.e. replaces spaces with nothing, use this formula:
=SUBSTITUTE(A1, " ", "")
Hi Team, Really valuable information on this page, but i'm hoping you can help me with a slightly different formula?
I need to remove the "/" symbol from a date in a different cell, for example, in cell A1 it reads 14/03/1998, and in cell A2 I need it to remove the "/" so it reads 14031998. I have tried using SUBSTITUTE, however this gives me the answer 35868.
Any help would be greatly appreciated!
Thanks.
Just use a format or this should work:
=text(a1,"DDMMYYYY")
Hi,
i need repeated values like 1,22,333,4444,55555,666666, in row wise...
Wow, that was amazing....
Good information but ran into an issue converting:
FROM: 110000.350001.704898.104
TO: Fund^110000^Organization^350001^Account^Program^104
Used the formula: =(REPLACE(REPLACE(REPLACE(REPLACE(B7,1,0,"Fund^"),7,0,"^Organization^"),14,0,"^Account^"),21,0,"^Program"))
Which Resulted to: Fund^1^Organi^Accoun^Programt^zation^10000.350001.704898.104
Any suggestions?
Thank you.
Bob
use this formula ="fund^"&SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(T3,".","^C^",3),".","^B^",2),".","^A^",1)
Or you can use this the below. As the nested functions resolve the substitution so you can just use 1 (of the first occurrence)
="fund^"&SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(T3,".","^C^",1),".","^B^",1),".","^A^",1)
How do you set up excel to change a list of text to show a pre-set name when you enter it into a cell? For example:
you enter: the cell displays:
abc123 The Brown Corp
def456 Blue Inc
ghi789 Green Company
Let's say I have a column containing capitalized words. Of those words, there are some (but not all) that I want to be uppercase.
For example,
BEFORE:
Abc Apple
Xyz Qrs Pear Juice
Sweet Corn
Cherry
Mno Grapes
AFTER:
ABC Apple
XYZ QRS Pear Juice
Sweet Corn
Cherry
MNO Grapes
To make this happen, is it possible to have a couple of additional columns labeled “Old” and “New” that would contain these words I want to uppercase?
For example,
Old New
--- ---
Abc ABC
Xyz Qrs XYZ QRS
Mno MNO
And then use a combination of either SUBSTITUTE and VLOOKUP or SUBSTITUTE and INDEX-MATCH to uppercase only those words that I have set aside in those two additional columns?
The solution doesn’t have to solely rest with those aforementioned formulas, just it seems that is where maybe the answer lies.
Thanks!
There may be an easier way to achieve what you're asking.
If the old text started in cell A1 for example, you could simply use the formula =UPPER(A1) in the new text column.
If you also still need to use substitute, you could combine substitute and upper.
For example if you needed "abc Apple" to become "ABC APPLES"
=SUBSTITUTE(UPPER(A1),"APPLE", "APPLES")
The axample of substitue is incorrect, last two formulas are the same. See below. To substitue all occurences, the instance should be left blank.
=SUBSTITUTE(A2, "1", "2", 1) - Substitutes the first occurrence of "1" with "2".
=SUBSTITUTE(A2, "1", "2", 2) - Substitutes the second occurrence of "1" with "2".
=SUBSTITUTE(A2, "1", "2", 2) - Substitutes all occurrences of "1" with "2".
it should be like:
=SUBSTITUTE(A2, "1", "2", 1) - Substitutes the first occurrence of "1" with "2".
=SUBSTITUTE(A2, "1", "2", 2) - Substitutes the second occurrence of "1" with "2".
=SUBSTITUTE(A2, "1", "2") - Substitutes all occurrences of "1" with "2".
This is very use full.
Thanks a lot.
Is it possible to use "*" in SUBSTITUTE? I need to delete all texts containing ".com" plus any other text (I have .com .com.ar .com.ru .com.xxy)
I try this but it doesn´t work:
=SUBSTITUTE(A1,".com*","")
Any suggestion? Can I use wildcards with SUBSTITUTE?
Thanks!
Thanks!
Hello,
The SUBSTITUTE function in Excel doesn't support wildcard characters. You can either use a different formula or the standard Find and Replace tool:
- press Ctrl+H
- enter ".com*" in the "Find what" field, leave the "Replace with" field empty
- click Replace All.
If you prefer using a formula, here is one that can do what you need:
=IFERROR(LEFT(A1,LEN(A1)-FIND(".com",A1)-1),A1)
That is very much effective steps to post like this which can improve our skills in professional level.
Many thanks Cheusheva !
Wao, great team work... very helpful