by The tutorial explains the basic and advanced uses of the SUMPRODUCT function in Excel. You will find a number of formula examples to compare arrays, conditionally sum and count cells with multiple criteria, calculate a weighted average and more.
When you hear the name of SUMPRODUCT for the first time, it may sound like some useless formula that performs an ordinary sum of the products operation. But that definition does not show even a tiny fraction of what Excel SUMPRODUCT is capable of.
In fact, SUMPRODUCT is a remarkably versatile function with many uses. Due to its unique ability to handle arrays in smart and elegant ways, SUMPRODUCT is extremely useful, if not indispensable, when it comes to comparing data in two or more ranges and calculating data with multiple criteria. The following examples will reveal the full power of SUMPRODUCT and its effectiveness will become crystal clear.
Excel SUMPRODUCT function - syntax and uses
Technically, the SUMPRODUCT function in Excel multiplies the numbers in the specified arrays, and returns the sum of those products.
The syntax of the SUMPRODUCT function is simple and straightforward:
Where array1, array2, etc. are continuous ranges of cells or arrays whose elements you want to multiply, and then add.
The minimum number of arrays is 1. In this case, a SUMPRODUCT formula simply adds up all of the array elements and returns the sum.
The maximum number of arrays is 255 in Excel 365 - 2007, and 30 in earlier Excel versions.
Although SUMPRODUCT works with arrays, it does not require using the array shortcut. You compete a SUMPRODUCT formula in a usual way by pressing the Enter key.
Notes:
- All arrays in a SUMPRODUCT formula must have the same number of rows and columns, otherwise you get the #VALUE! error.
- If any array argument contains non-numeric values, they will be treated as zeros.
- If an array is a logical test, it results in TRUE and FALSE values. In most cases, you'd need to convert them to 1 and 0 by using the double unary operator (--) . Please see the SUMPRODUCT with multiple criteria example for more details.
- SUMPRODUCT does not support wildcard characters.
Basic usage of SUMPRODUCT in Excel
To gain a general understanding of how the Excel SUMPRODUCT function works, consider the following example.
Supposing you have quantity in cells A2:A4, prices in cells B2:B4, and you wish to find out the total. If you were doing a school math test, you would multiply the quantity by price for each item, and then add up the subtotals. In Microsoft Excel, you can get the result with a single SUMPRODUCT formula:
=SUMPRODUCT(A2:A4,B2:B4)
The following screenshots shows it in action:
Here is what's going on under the hood in terms of math:
- The formula takes the 1st number in the 1st array and multiplies it by the 1st number in the 2nd array, then takes the 2nd number in the 1st array and multiplies it by the 2nd number in the 2nd array, and so on.
- When all of the array elements are multiplied, the formula adds up the products and returns the sum.
In other words, our SUMPRODUCT formula performs the following mathematical operations:
=A2*B2 + A3*B3 + A4*B4
Just think how much time it could save you if your table contained not 3 rows of data, but 3 hundred or 3 thousand rows!
Tip. If you want to only multiply the numbers in each row without adding up the products, then use one of the formulas to multiply columns in Excel.
How to use SUMPRODUCT in Excel - formula examples
Multiplying two or more ranges together and then summing the products is the simplest and most obvious usage of SUBTOTAL in Excel, though not by far the only one. The real beauty of the Excel SUMPRODUCT function is that it can do far more than its stated purpose. Further on in this tutorial, you will find a handful of formulas that demonstrate more advanced and exciting uses, so please keep reading.
SUMPRODUCT with multiple criteria
Usually in Microsoft Excel, there is more than one way to accomplish the same task. But when it comes to comparing two or more arrays, especially with multiple criteria, SUMPRODUCT is the most effective, if not the only, solution. Well, either SUMPRODUCT or array formula.
Assuming you have a list of items in column A, planned sale figures in column B, and actual sales in column C. Your goal is to find out how many items have made less sales than planned. For this, use one of the following variations of the SUMPRODUCT formula:
=SUMPRODUCT(--(C2:C10<B2:B10))
or
=SUMPRODUCT((C2:C10<B2:B10)*1)
Where C2:C10 are real sales and B2:B10 are planned sales.
But what if you had more than one condition? Let's say, you want to count how many times Apples performed worse than planned. The solution is to add one more criterion to the SUMPRODUCT formula:
=SUMPRODUCT(--(C2:C10<B2:B10), --(A2:A10="apples"))
Or, you can use the following syntax:
=SUMPRODUCT((C2:C10<B2:B10)*(A2:A10="apples"))
And now, let's take a minute and understand what the above formulas are actually doing. I believe it is a worthy time investment because many other SUMPRODUCT formulas work with the same logic.
How SUMPRODUCT formula with one condition works
For starters, let's break down a simpler formula that compares numbers in 2 columns row-by-row, and tells us how many times column C is less than column B:
=SUMPRODUCT(--(C2:C10<B2:B10))
If you select the portion (C2:C10<B2:B10) in the formula bar, and press F9 to view the underlying values, you will see the following array:
What we have here is an array of Boolean values TRUE and FALSE, where TRUE means the specified condition is met (i.e. a value in column C is less than a value in column B in the same row), and FALSE signifies the condition is not met.
The double negative (--), which is technically called the double unary operator, coerces TRUE and FALSE into ones and zeros: {0;1;0;0;1;0;1;0;0}.
Another way to convert the logical values into the numeric values is multiple the array by 1:
=SUMPRODUCT((C2:C10<B2:B10)*1)
Either way, since there is just one array in the SUMPRODUCT formula, it simply adds up 1's in the resulting array and we get the desired count. Easy, isn't it?
How SUMPRODUCT formula with multiple conditions works
When an Excel SUMPRODUCT formula contains two or more arrays, it multiplies the elements of all the arrays, and then adds up the results.
As you may remember, we used the following formulas to find out how many times the number of real sales (column C) was less than planned sales (column B) for Apples (column A):
=SUMPRODUCT(--(C2:C10<B2:B10), --(A2:A10="apples"))
or
=SUMPRODUCT((C2:C10<B2:B10)*(A2:A10="apples"))
The only tech difference between the formulas is the method of coercing TRUE and FALSE into 1 and 0 - by using the double unary or multiplication operation. As the result, we get two arrays of ones and zeros:
The multiplication operation performed by SUMPRODUCT joins them into a single array. And since multiplying by zero always gives zero, 1 appears only when both conditions are met, and consequently only those rows are counted:
Conditionally count / sum / average cells with multiple criteria
In Excel 2003 and older versions that did not have the so-called IFs functions, one of the most common uses of the SUMPRODUCT function was to conditionally sum or count cells with multiple criteria. Beginning with Excel 2007, Microsoft introduced a series of functions specially designed for such tasks - SUMIFS, COUNTIFS and AVERAGEIFS.
But even in the modern versions of Excel, a SUMPRODUCT formula could be a worthy alternative, for example, to conditionally sum and count cells with the OR logic. Below you will find a few formula examples that demonstrate this ability in action.
1. SUMPRODUCT formula with AND logic
Supposing you have the following dataset, where column A lists the regions, column B - items and column C - sales figures:
What you want is get the count, sum and average of Apples sales for the North region.
In Excel 2007 and higher, the task can be easily accomplished by using a SUMIFS, COUNTIFS and AVERAGEIFS formula. If you are not looking for easy ways, or if you are still using Excel 2003 or older, you can get the desired result with SUMPRODUCT.
- To count Apples sales for North:
=SUMPRODUCT(--(A2:A12="north"), --(B2:B12="apples"))or
=SUMPRODUCT((A2:A12="north")*(B2:B12="apples")) - To sum Apples sales for North:
=SUMPRODUCT(--(A2:A12="north"), --(B2:B12="apples"), C2:C12)or
=SUMPRODUCT((A2:A12="north")*(B2:B12="apples")*C2:C12) - To average Apples sales for North:To calculate the average, we simply divide Sum by Count like this:
=SUMPRODUCT(--(A2:A12="north"), --(B2:B12="apples"), C2:C12) / SUMPRODUCT( --(A2:A12="north"), --(B2:B12="apples"))
To add more flexibility to your SUMPRODUCT formulas, you can specify the desired Region and Item in separate cells, and then reference those cells in your formula like shown in the screenshot below:
How SUMPRODUCT formula for conditional sum works
From the previous example, you already know how the Excel SUMPRODUCT formula counts cells with multiple conditions. If you understand that, it will be very easy for you to comprehend the sum logic.
Let me remind you that we used the following formula to sum Apples sales in the North region:
=SUMPRODUCT(--(A2:A12="north"), --(B2:B12="apples"), C2:C12)
An intermediate result of the above formula are the following 3 arrays:
- In the 1st array, 1 stands for North, and 0 for any other region.
- In the 2nd array, 1 stands for Apples, and 0 for any other item.
- The 3rd array contains the sales numbers exactly as they appear in cells C2:C12.
Remembering that multiplying by 0 always gives zero, and multiplying by 1 gives the same number, we get the final array consisting of the sales numbers and zeros - a sales number appears only if the first two arrays have 1 in the same position, i.e. both of the specified conditions are met; zero otherwise:
Adding up the numbers in the above array delivers the desired result - the total of the Apples sales in the North region.
Example 2. SUMPRODUCT formula with OR logic
To conditionally sum or count cells with the OR logic, use the plus symbol (+) in between the arrays.
In Excel SUMPRODUCT formulas, as well as in array formulas, the plus symbol acts like the OR operator that instructs Excel to return TRUE if ANY of the conditions in a given expression evaluates to TRUE.
For example, to get the count of all Apples and Lemons sales regardless of the region, use this formula:
=SUMPRODUCT((B2:B12="apples")+(B2:B12="lemons"))
Translated into plain English, the formula reads as follows: Count cells if B2:B12="apples" OR B2:B12="lemons".
To sum Apples and Lemons sales, add one more argument containing the Sales range:
=SUMPRODUCT((B2:B12="apples")+(B2:B12="lemons"), C2:C12)
The following screenshot shows a similar formula in action:
Example 3. SUMPRODUCT formula with AND as well as OR logic
In many situations, you might need to conditionally count or sum cells with AND logic and OR logic at a time. Even in the latest versions of Excel, the IFs series of functions is not capable of that.
One of the possible solutions is combining two or more functions SUMIFS + SUMIFS or COUNTIFS + COUNTIFS.
Another way is using the Excel SUMPRODUCT function where:
- Asterisk (*) is used as the AND operator.
- Plus symbol (+) is used as the OR operator.
To make things easier to understand, consider the following examples.
To count how many times Apples and Lemons were sold in the North region, make a formula with the following logic:
=Count If ((Region="north") AND ((Item="Apples") OR (Item="Lemons")))
Upon applying the appropriate SUMPRODUCT syntax, the formula takes the following shape:
=SUMPRODUCT((A2:A12="north")*((B2:B12="apples")+(B2:B12="lemons")))
To sum Apples and Lemons sales in the North region, take the above formula and add the Sales array with the AND logic:
=SUMPRODUCT((A2:A12="north")*((B2:B12="apples")+(B2:B12="lemons"))*C2:C12)
To make the formulas a bit more compact, you can type the variables in separate cells - Region in F1 and Items in F2 and H2 - and refer to those cells in your formula:
SUMPRODUCT formula for weighted average
In one of the previous examples, we discussed a SUMPRODUCT formula for conditional average. Another common usage of SUMPRODUCT in Excel is calculating a weighted average where each value is assigned a certain weight.
The generic SUMPRODUCT weighted average formula is as follows:
Assuming that values are in cells B2:B7 and weights are in cell C2:C7, the weighted average SUMPRODUCT formula will look like this:
=SUMPRODUCT(B2:B7,C2:C7)/SUM(C2:C7)
I believe at this point you won't have any difficulties with understanding the formula logic. If someone needs a detailed explanation, please check out the following tutorial: Calculating weighted average in Excel.
SUMPRODUCT as alternative to array formulas
Even if you are reading this article for informational purposes and the details are likely to fade away in your memory, remember just one key point - the Excel SUMPRODUCT function deals with arrays. And because SUMPRODUCT offers much of the power of array formulas, it can become an easy-to-use replacement for them.
What advantages does this gives to you? Basically, you will be able to manage your formulas an easy way without having to press Ctrl + Shift + Enter every time you are entering a new or editing an existing array formula.
As an example, we can take a simple array formula that counts all characters in a given range:
and turn it into a regular formula:
For practice, you can take these Excel array formulas and try to re-write then using the SUMPRODUCT function.
Excel SUMPRODUCT - advanced formula examples
Now that you know the syntax and logic of the SUMPRODUCT function in Excel, you may want to learn more sophisticated and more powerful formulas where SUMPRODUCT is used in liaison with other Excel functions.
Practice workbook for download
Excel SUMPRODUCT examples (.xlsx file)
245 comments
I have 3 columns. One is on the first tab and the other 2 are on the second tab. I want the column on the first tab to find any matching values in the column in the second tab. If there is a match/multiple matches, I want it to grab the values in the 3 column on the second tab and return the sum. Hope this makes sense and there is someone that can assist! Thank you,
I have problem with selecting right column when creating sumproduct formula.. How should define column depending on day number? For example when it is 6th may it must look 6th column which is marked as 6 in first row. Next day should look into 7th column etc....
Need to create dashboard for time log, we have data as date, task, activity and time spent.
Activities are with respective to Tasks but there was no condition given so people have mixed the task and activities. Need to prepare a dashboard to show the miss match data and correct data with time spent.
For example : Below date is miss match
Date Task Activity hours
12-Oct-19 Out of office Idle 8
13-Oct-19 Running Idle Leave/off 8
Below data is correct data
Date Task Activity hours
07-Oct-19 Out of office Leave/off 8
08-Oct-19 Running Idle Idle 8
Task and activities with respective time spent dash board needed. Please help. I'm missing the logic to write the formula for dashboard.
Thank you for this tip.
I am trying to use SUMPRODUCT to multiply the Hours * Rate of a data source for Timekeeper = X and for hours recorded in month =1.
Column B = Date
Column C = Hours
Column K = Rate
Column N = Timekeeper
Every time I do it I get zero or #value error and can't figure it out what I am doing wrong.
I have used the Sumifs formula to calculate the total Hours for the timekeeper X for Month 1 and that works great =SUMIFS(activities!$C:$C,activities!$N:$N,Monthly!C$5,activities!$B:$B,">="&Monthly!$A6,activities!$B:$B,"<="&EOMONTH($A6,0),activities!$L:$L,""&"")
Thank you for your assistance.
Hello Sir,
Good Evening
My Name is Niru Kumar. My problem is very simple I have Sheet1 raw Data sheet 2Class1,sheets3 Class2,sheets4 Class3
are three sheets, I tell your if sheet1 raw data put class1 go to sheets2Class1 sheet1 raw data put Class2 go to sheets3 Class2.this is my problem
I need assistance on extracting just the large index number of this column that contains. Not the text just the larger index.
CR 5006193154
Hi, I've searched the internet for a way to extract numbers only from a text string using a formula and found this
=SUMPRODUCT(MID(0&A5, LARGE(INDEX(ISNUMBER(--MID(A5, ROW(INDIRECT("1:"&LEN(A5))), 1)) * ROW(INDIRECT("1:"&LEN(A5))), 0), ROW(INDIRECT("1:"&LEN(A5))))+1, 1) * 10^ROW(INDIRECT("1:"&LEN(A5)))/10)
I would like an explanation how this works.
Many thanks in advance.
Thank you very much...
Hello!
Thank you for this post. It is very well done.
Any chance you know of a way to sumproduct only cells that are visible and exclude blank values from the calculation?
Kind Regards,
I appreciate you are busy and may not be able to Tokyo but I think it’s still worth and ask, fingers crossed. I am using the sumproduct formula below but can’t get it to work dynamically so I don’t have to edit it for different table headers of which Cit13_Hits is just one of many. In addition the conditional value 5 that it is summing for is also variable and can be from 1-9.
When I use cell references for these parts of the formula then the formula fails. Is here any way to carry out this so I can simply copy the formula without having to edit it manually for the changing variable name and values?
=(SUMPRODUCT(--(LEFT(Results[CIT13_Hits],1)="5"),--(INDEX(Results,0,MATCH($H$4,Results[#Headers],0))="CY")))
Many thanks
Gary
I'd like assistance on something that seems easy. I want A1*B1 + A1*C1 + A1*D1
I tried SUMPRODUCT(B1:D1, {A1,A1,A1}) but that doesn't work.
Can you help? Thank you in advance!
Thanks for teaching me the sumproduct formula in details
Hi Svetlana.
I am trying to create Sumproduct formula to calculate total sum of deviations between OB and CC if deviation is >0 (I need to calculate 9). With this formula '=SUMPRODUCT(B2:I2-B3) I receive 1 that is total of all deviations. How to add a criteria >0 to the formula?
wk1 wk2 wk3 wk4
OB 17 29 25 30
CC 25 25 25 25
0 4 0 5
Thank you in advance!
This formula works for 2 criteria, Region and Name...
'=SUMPRODUCT((($D$1:$O$1>=$Q$1)*($D$1:$O$1<=$R$1))*($A$2:$A$49=$S$1)*($C$2:$C$49=$U1)*$D$2:$O$49)
Hello Eric,
Our blog engine sometimes mangles comments, sorry for this.
Your formula won't work, firstly, because D1:O1 (text values) cannot be compared to Q1 and R1 (dates); and secondly because the ranges ($D$1:$O$1, $A$2:$A$49, etc.) are of different size.
If, in your summary table (Q1 or R1), you enter the target month exactly as it is written in $D$1:$O$1, then the task can be accomplished with an array formula that you can find in this sample sheet.
D1:O1 is the months of the year
Q1=1/1/19
R1=2/1/19
A2:A49 is the Region
S1=North
B2:B49 are the Items
T1=Apples
C2:C49 is the Name
U1=Bob
D2:O49 is the data.
Cont.
D1:O1 is the months of the year / Q1=1/1/19 / R1=2/1/19 / A2:A49 is the Region / S1=North / B2:B49 are the Items / T1=Apples
C2:C49 is the Name / U1=Bob / D2:O49 is the data.
This is the formula I'm trying...
'=SUMPRODUCT((($D$1:$O$1>=$Q$1)*($D$1:$O$1<=$R$1))*($A$2:$A$49=$S$1)*($B$2:$B$49=$T$1)*($C$2:$C$49,$U1)*$D$2:$O$49)
Why is half of my message missing.
I’m trying to create a SUMPRODUCT for 3 criteria and add multiple columns. Similar to Example 3 above, but add a column to the right of Item, call it Name, and the data is for a year across columns to the right. This is the formula I'm trying...
'=SUMPRODUCT((($D$1:$O$1>=$Q$1)*($D$1:$O$1=$Q$1)*($D$1:$O$1<=$R$1))*($A$2:$A$49=$S$1)*($C$2:$C$49=$U1)*$D$2:$O$49)
I’m trying to create a SUMPRODUCT for 3 criteria and add multiple columns. Similar to Example 3 above, but add a column to the right of Item, call it Name, and the data is for a year across columns to the right. This is the formula I'm trying...
=SUMPRODUCT((($D$1:$O$1>=$Q$1)*($D$1:$O$1=$Q$1)*($D$1:$O$1<=$R$1))*($A$2:$A$49=$S$1)*($C$2:$C$49=$U1)*$D$2:$O$49)
but when I try to add in the 3rd criteria the formula returns #VALUE :( help