by In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.
IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.
In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.
IF function in Excel
IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.
The syntax of the IF function is as follows:
As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.
Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.
Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.
Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.
Basic IF formula in Excel
To create a simple If then statement in Excel, this is what you need to do:
- For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
- For value_if_true, specify what to return when the logical test evaluates to TRUE.
- For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.
As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:
=IF(B2>80, "Good", "Bad")
This formula goes to C2, and then is copied down through C7:
In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:
=IF(B2>80, "Good", "")
This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise:
Excel If then formula: things to know
Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.
If value_if_true is omitted
If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:
=IF(B2>80, , "Bad")
To return a blank cell instead, supply an empty string ("") for the second parameter, like this:
=IF(B2>80, "", "Bad")
The screenshot below demonstrates the difference:
If value_if_false is omitted
Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.
If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:
=IF(B2>80, "Good")
Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:
=IF(B2>80, "Good",)
The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:
=IF(B2>80, "Good", "")
Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.
Using IF function in Excel - formula examples
Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.
Excel IF function with numbers
To build an IF statement for numbers, use logical operators such as:
- Equal to (=)
- Not equal to (<>)
- Greater than (>)
- Greater than or equal to (>=)
- Less than (<)
- Less than or equal to (<=)
Above, you have already seen an example of such a formula that checks if a number is greater than a given number.
And here's a formula that checks if a cell contains a negative number:
=IF(B2<0, "Invalid", "")
For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell.
Excel IF function with text
Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.
For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:
=IF(B2="delivered", "No", "Yes")
Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise.
Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:
=IF(C2<>"delivered", "Yes", "No")
Notes:
- When using text values for IF's parameters, remember to always enclose them in double quotes.
- Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".
Case-sensitive IF statement for text values
To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.
For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:
=IF(EXACT(B2,"DELIVERED"), "No", "Yes")
If cell contains partial text
In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.
A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).
For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:
=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes")
For more information, please see:
Excel IF statement with dates
At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.
For example, here's how you can check if a given date is greater than another date:
=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")
This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date.
Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:
=IF(B2>$E$2, "Coming soon", "Completed")
To compare a date with the current date, use the TODAY() function. For example:
=IF(B2>TODAY(), "Coming soon", "Completed")
Excel IF statement for blanks and non-blanks
If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:
- Use the IF function together with ISBLANK, or
- Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).
The table below explains the difference between these two approaches with formula examples.
| Logical test | Description | Formula Example | |
| Blank cells | ="" |
Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string. Otherwise, evaluates to FALSE. |
=IF(A1="", 0, 1)
Returns 0 if A1 is visually blank. Otherwise returns 1. If A1 contains an empty string (""), the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings. Otherwise, evaluates to FALSE. |
=IF( Returns 0 if A1 is absolutely empty, 1 otherwise. If A1 contains an empty string (""), the formula returns 1. |
|
| Non-blank cells | <>"" | Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered blank. |
=IF( Returns 1 if A1 is non-blank; 0 otherwise. If A1 contains an empty string, the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered non-blank. |
=IF( Works the same as the above formula, but returns 1 if A1 contains an empty string. |
And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:
=IF(B2="", "", "Completed")
=IF(ISBLANK(B2), "", "Completed")
=IF($B2<>"", "Completed", "")
=IF(ISBLANK($B2)=FALSE, "Completed", "")
In case the tested cells have no zero-length strings, all the formulas will return exactly the same results:
Check if two cells are the same
To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:
=IF(B2=C2, "Same score", "")
To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.
For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:
=IF(EXACT(A2, B2), "Match", "Don't match")
IF then formula to run another formula
In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.
For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:
=IF(B2>80, B2*7%, B2*3%)
Multiple IF statements in Excel
In essence, there are two ways to write multiple IF statements in Excel:
- Nesting several IF functions one into another
- Using the AND or OR function in the logical test
Nested IF statement
Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.
Assume your goal is to assign different bonuses based on the score:
- Over 90 - 10%
- 90 to 81 - 7%
- 80 to 70 - 5%
- Less than 70 - 3%
To accomplish the task, you write 3 separate IF functions and nest them one into another like this:
=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%)))
For more formula examples, please see:
Excel IF statement with multiple conditions
To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:
For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:
=IF(AND(B2>80, C2>80), "Pass", "Fail")
To get "Pass" if either score is higher than 80, the formula is:
=IF(OR(B2>80, C2>80), "Pass", "Fail")
For full details, please visit:
If error in Excel
Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.
And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.
For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:
=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" )
For more information, please see IF ISERROR formula in Excel.
Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!
Practice workbook
Excel IF statement - formula examples (.xlsx file)
4804 comments
=IF(J10="","",(IF(J10>=75%,"HIGH"),(IF="",""(IF(J10,˂49"LOW,"MODERATE"))) my formula dont work
Hi All ,
I hope everyone is well !
I currently have the following in a cell =((H21-G21)*24-1)
this simple formula allows me to count the number of hours between two times ( when working out working hours for my staff)
I am looking to have this cell note that if a time is not put into the cells ( h21/g21 ) this information is current data validation from another sheet - and instead the word "holiday" is added the cell will generate an automatic number ? is this possible ? any help would be great !
Out normal working hours for a "holiday is 8 hours" so if the cell says holiday i would like it to default this to "8"
thanks again
trying to write a formula that will look at 3 inputs and assign a point value.
i need a formula that will assign 3 points to the highest score, 2 points to the second highest and 1 point for the lowest.
thanks
I am pulling my hair out on a formula. I have a workbook with 5 tabs ( Gen212, Poe,360 BWS, sample, Production). What would the formula be to have a flow number from tab 5 (production) in column H row 7 automatically populate into tab 3 (360 BWS) in column C row 18?
Can someone help with formulas for the following 2 scenarios:
1. Groups submitted from the 25th of the previous month
-For month of February: statement is true if the date is 1/25/19 thru 2/28/19
2. Groups submitted from the 25th of the current month
-For month of February: statement is true if the date is 2/25/19 thru 2/28/19
Thank you!
I have two columns. Column G is my due date and column J says whether I have approved or denied the application. If the due date is in the next 7 days, from today, and the corresponding cell in column J is blank (meaning I have not approved or denied the application) I want the cell in column G to highlight, or the row, to let me know the due date is coming up and I have not taken action on the application yet.
Hello-
I am in desperate help of trying to figure out an if statement that can help me calculate # of days past due.
I have a column for start date, end date and actual date of completion. I have a column with a formula for today’s.
Originally, I used the networkdays formula to calculate the days from due date to today’s date, but when I put in the actual completion date, the past due days keeps updating and I don’t want that.
Have no idea if that made any sense. But hopefully someone can help me out !!
Hi,
May i Know how to use TODAY function when my table has different dates,
Date-1, Date-2,Date-3,
How to get the same data on one column based on IF Function,
thanx
Hi,
I want to write a function that will find alternate minimum value for a range where logical value TRUE equal 1 and the logical value FALSE equals 0, and the text and blanks equals 0.
Thanks,
G 12 is an unknown which is a value where i keyed in, meanwhile E12 is a value which i obtained through a returned value from another keyed in a value, both G 12 & E 12 multiply each other and should not give you more than 220, if it does, it supposed to print out 220 or else the value is supposed to be the the equation provided,need some help as i am getting errors when executing it
Problem getting IFS formula to work.
Problem I want the formula to read the cell and if it contains a certain text,then it is to input certain text, and if it is another text,then input another text,if the cell contains a certain text,then input a certain text.
Example:
Cell: =IFS(C1="CAR","A.V",C1="NQR",C1="SCAR")
Formula only regonizes CAR and inputs A.V.,but will not work for other two conditions.
Hi Svetlana,
How would I write a formula for time zone conversion sample:
Cell D2 Local Time, E2 is the GMT Conversion and L2 is the Converted TIME Zone
is it like; =IF (E2=+2), D2+600
My logic is: The time in L2 is the equivalent of D2+600 if E2 has value of +2
Hope you could reply.
What my goal is to have a set of cell content only (B4:K6)to empty at 6am daily. Is it possible and if so how do I accomplish this task?
Thank you.
I'm trying to use this formula for these three qualifiers. Can't get it to work. Any suggestions?
=IF(AND(ToCSDIncidents[@[Assignment Group Final],"CSD_SERVICES",ToCSDIncidents[@[Reassignment Count]],"0",ToCSDIncidents],ToCSDIncidents[[Exclusion]],""),"TRUE","FALSE"))
=IF( ((G12 * E12) + 14)> 220), 220, ((G12*E12)+14)
Hi everyone i need help on these if statement on excel, G 12 is an unknown which is a value where i keyed in, meanwhile E12 is a value which i obtained through a returned value from another keyed in a value, both G 12 & E 12 multiply each other and should not give you more than 220, if it does, it supposed to print out 220 or else the value is supposed to be the the equation provided,need some help as i am getting errors when executing it
that looks at the contents of a particular cell (either Global Brokerage or USA Brokerage) and then, depending on Global vs. USA, I want to point to a 1 of 2 cells that contains a percentage. The percentages can change and I do not want to type the actual percent into the formula. I want to point to the % in 1 of 2 cells.
Please assist me as I am trying to create if then function in excel but I don't know how to include if the cell is blank =IF(K2335="eamc","YES","NO") but this statement also put "no" if the cell is blank. how can I make it like if there is no data then it has to be blank as well.
Thanks
Hello,
I have tried several ways to do this,please help.
if A2:21 says complete it equals a % and totals all within
Thank you
I have an simple If function in B1 for example =IF(A1>=1,"1","0").
The entry number works if I use it in a =SUM formula horizontally in D1 =SUM(C1-B1). Example: A1 entry is 2, B1 becomes 1. C1 entry is 4, D1 becomes 3. Works great.
Here is where I run into trouble. I copy formulas vertical example: B2, B3, B4... then attempt a simple SUM formula =SUM(B1:B4) the result is always 0 even if B1 thru B4 all have 1 as a result.
IF Cell A1 IS NOT EQUAL TO Cell B2 or Cell A1 is blank then it is to be considered as Cell C1 data