How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4800 comments

  1. I m using if conditions below
    =If(A1<=1000,"0",IF(A2001,"80")))

    BUT WHEN I USE SUN FUNCTION TO GRAND TOTAL, AMOUNT SHOWING ONLY '0'

    KINDLY ADVISE AND HELP PLEASE

  2. WHAT FORMULA CAN I use to look for the VALUE in cell 'A2" is equal to CELL VALUE IN "I14" in a different sheet - but I want it to do a search in multiple sheets (75 to be exact) then SEARCH IN MULTIPLE SHEETS and if there is a match to "A2" return back WITH THE VALUE IN CELL L34 of the sheet were the value was found.

  3. hi please cou;d you tell me where I am going wrong:
    I need a formula for the following:
    column O2 contains a due date, column P2 contains completed status of Yes or No. I need to add a status of overdue or Due within 90 days.
    so if the date in column O2 is over 90 days from today then the status is "Overdue" but if the date in column O2 is within 90 days from today then the status needs to be "Due within 90 days"

  4. I need a formula to calculate a value from a group of numbers in a column:
    Column A - has dollar figures
    Column B - has dates WHEN the amount in column A is paid.
    I want to calculate the unpaid amounts from column A when column B doesn't have a date entered or a blank cell.

  5. hello iam sandip mere ko aisa formate make karna he exm:-90 he to 75 ke above 10 ana chahiye 81 ke above 15 86 ke above 20 91 ke above 25 ager 75 ke below rahega to 0 ana chiye mene ye formate banaya he mager ye kam nahi kar rha he,
    =IF(C4>=76,"10",IF(C4>=81,"15",IF(C4>=86,"20",IF(C4>=91,"25",IF(C4<=75,"0")))))
    please help me my whatsapp no.8669800963

  6. I am trying to write a formula to distinguish between if a serial # starts with a Letter or a Number then multiply by two different % rates . Any help would be great.

  7. I am using an IFS function to write a color ("Red", "Yellow", or "Green") in cell F4. It is dependent upon the results (a number between 1 & 5) in another cell (AA4). If I type a number into the cell AA4, the formula yields the appropriate color. However, when I use a formula (Average) to generate the number, it does not work. I get an error message (#N/A in Excel and #Name? in Sheets). How do I get the IFS function to recognize the results in the cell instead of the formula?

    • Problem solved. It was a rounding issue. Even though I could only see a 1, 2, 3, 4, or 5, the underlying numbers were 1.??, 2.??, etc., so the IF statements were not true. I used the Round function in the Average formula and solved the problem.

  8. How to enter some number in another cell according to ented number in first cell. ie. If 1 is enterd in column 1st then atomatically 300 (rate per kg) is enterd in money column. Please answer quickly. Thankyou for readin and answering me.

  9. Hi All
    Can you please help me with a formula? I need to create a monthly report.
    Reporting period is from 26th previous month to 25th of the current month for example for May 2019 reporting commence from 26th April to 25th May.
    Can you help? Many thanks in advance.
    Jonathan

  10. Hi There,
    Please help me to come up with the formula i needed.
    In a column, if there is a value encoded the result must be 8 or 0 only.
    How is it?

    Thanks a lot.

  11. Hello,
    I'm trying to condition a cell (A) color based on 4 other cells (B,C,D,E).
    The first one is a case number and the 4 cells are attempts to reach a customer via phone.
    So, if a first call is made and the customer is not reached, B cell will contain text, A cell will change to yellow.
    When a second call attempt will be made, C cell will contain text and A cell will need to change to orange.
    After the third call attempt is made, D cell will contain text and A cell will need to change to red.
    If the customer is reached at any given point (1st,2nd,3rd attempt), E cell will change to value (Y) and A cell will need to change to green.
    Can you help with this?
    Thank you

  12. Hello Team
    How to find the TP value with IF condition by using TYPE.
    TYPE ENTRY PRICE TP
    Sell 1.34365 1.34165
    Buy 0.69792 0.69992
    Please help me with this.

    Thanks

  13. I am trying to write an equation that will do the following:
    If the value for B6*0.25 is less than 1,000, I want to display 1,000, and then if the value of B6*0.25 is greater than 1,000, I want it to print that value. Below is my failed attempt. Thank you for your help.
    =IF(B6*0.251000,B6*0.25))

    • =IF(K133*0.25<1000,"1000",0)

  14. Hello I'm trying to write an IF statement that results in showing two conditions when met. For example, I input -5 in the reference cell I want the IF statement to punch out 5 below or if the number is positive to punch out 5 above in the same cell.

    • Use this;
      =IF($R14<0,($R14*-1)&" Below",($R14*1)&" Above")

  15. Hi I am trying to use the if function but I am stumped.
    I need me S/Sheet to be blank is 0, if between 1 and 28 show yes and higher than 28 No.
    My current formula is =IF((AND(F2>=1, F2<=28)), "Yes", "No") but the everything with a 0 gets a no when I need it blank
    HELP PLEASE xx

    • Use this;
      =IF($F11=0,"",IF($F11<=28,"Yes","NO"))

  16. In excel there was 8 sheets, on that 1 sheet is the master sheet
    If we enter any email id in column A in any of the 8 sheets it has to auto reflect into Master sheet on another below.
    Ex. in sheet 2 I have entered abc@gmail.com
    in sheet 3 I have entered bcd@gmail.com
    in sheet 7 I have entered jkq@gmail.com
    result should be entered mail auto reflect into master sheet one another below

    Please help in this regard

  17. I am trying to do travel rates based on where an employee visits. I would like to create a formula that includes 50 states and top cities within those states.
    So if John travels to Washington State he choose WA from a drop down box. From there in the next cell cities will become available such as Seattle, Tacoma and Spokane. Based on which city John chooses travel rates will appear in the next cells such as acceptable hotel rates, breakfast, lunch and dinner. If John chooses AZ then Flagstaff, Phoenix, Sedona and Tucson appear...makes sense? Possible?

    Hope anyone can help

    • Yes it's possible with conditional drop down list.
      Need data work on it.

  18. COLUMN A COLUMN B COLUMN C RESULT

    OTE3‐L1‐IM‐300992‐01 12-Apr COMPLETE
    OTE3‐L1‐IM‐300992‐01 13-Apr COMPLETE
    OTE3‐L1‐IM‐300992‐02 13-Apr INCOMPLETE
    OTE3‐L1‐IM‐300992‐02 INCOMPLETE
    OTE3‐L1‐IM‐300992‐03 13-Apr INCOMPLETE
    OTE3‐L1‐IM‐300992‐03 INCOMPLETE
    OTE3‐L1‐IM‐300992‐03 INCOMPLETE
    OTE3‐L1‐IM‐300992‐03 INCOMPLETE
    I need a result of complete or incomplete when look at the

  19. StockName CurrentQty InvestmentPrice CurrentMarketPrice HoldingValue MarketValue
    BGRENERGY 14 483.00 58.25 6762.00 815.50
    BRIGADE 29 390.00 229.25 11310.00 6648.25
    BSE 18 806.00 610.45 14508.00 11132.10
    COALINDIA 100 232.75 250.50 23275.00 25050.00
    DIXON 8 1766.00 2353.95 14128.00 18831.60
    DLF 5 932.52 174.30 4662.60 871.50
    EDL 69 371.70 6.80 25647.30 469.20
    ENDURANCE 30 472.00 1156.20 14160.00 34686.00
    ERIS 24 603.00 632.75 14472.00 15186.00
    GICRE 32 433.50 244.60 13872.00 7827.20
    Please sum col E & F How to a cetain text numbers

  20. In column A (there are 4 sentence choices: I want an Apple, I don't like Bananas, I love coconuts, I need water)

    A1 I want an Apple
    A2 I don't like Bananas
    A3 I love coconuts
    A4 I need water

    In column B, I want to use a function to check column A and search for partial text, then past a value in cell. For example, in B1, checks for 4 possible conditions in A1, check for "ppl" and copy the value "Yes" to cell in B1 OR check for "Ban" and copy the value "No" to cell B1 OR check for "coco" and copy the value to B1 OR check for "wat" and copy the value "end" to B1.

    What function should I use?

    • If (AND condition works here..

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)