How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. Depending on the city, you will either take a shuttle to/from the airport or rent a car. Insert an IF function that compares to see if Yes or No is located in the Rental Car? Column for a city. If the city contains No, display the value in cell F2. If the city contains Yes, display the value in the Rental Car Total (F4)

  2. Hey,
    Your tutorial is great. I am trying to get this nested formula but somehow its only picking up last logical test values. Can you please check & advise.

    =IF(B$4>B7<B$3, "Expiring within 2 Weeks", IF(B$3<B7B$2, "Expired", "Valid")))

    Regards

    • What is the cell you're trying to find the value of? B7?

      I would trying using IF(AND and doing it that way
      Instead of =IF(B4>B7B3,B7<B4),"True","False")

      • oops, for some reason it got cut off.

        Instead of =IF(B4>B7B3,B7<B4),"True","False")

        • Not sure why it's cutting off so I'll try one more time. "=IF(AND(B7>B3,B7<B4),"True","False")"

    • Hello Syed,
      Here is the updated formula for you:

      =IF(AND(B$4 > B7, B7 < B$3), "Expiring within 2 Weeks", IF(AND(B$3 < B7, B7 > B$2), "Expired", "Valid"))

  3. Plz help.....
    If i write a number greater then 100 in a cell mistakenly. I want Excel shows an error in that cell.
    For example
    I write 23 26 56 100 in cells and write mistakenly 105. So i want to show 105 in error.

    • I would just highlight the whole column and do a Conditional Formatting, Highlight Cell Rules, Greater Than..., 100. Then if the cell is highlighted in red you'll know it's over 100.

  4. Please show me formula for the below. Thank you!
    IF A1 = ABC B1 = 1234; if A1 change to DEF then B1=5678; also if A1 change to GHI then B1=91110

    • This will only work on 4 letters at a time. I'm assuming you meant ABC = 123 and not 1234. If not this wont work for you.

      =IF(MID(A1,1,1)="", "", CODE(UPPER(MID(A1,1,1)))-64&""&IF(MID(A1,2,1)="", "", CODE(UPPER(MID(A1,2,1))) -64&""& IF(MID(A1,3,1)="", "", CODE(UPPER(MID(A1,3,1)))-64&""& IF(MID(A1,4,1)="", "", CODE(UPPER(MID(A1,4,1)))-64))))

      • Actually I need 6 digits (ABC=123456). So it doesn't work for me! Thanks for trying!

        • Here is the 6 letter version. To add more numbers you just have to copy everything from IF to the second & and change the number after the A1.
          =IF(MID(A1,1,1)="", "", CODE(UPPER(MID(A1,1,1)))-64&""&IF(MID(A1,2,1)="", "", CODE(UPPER(MID(A1,2,1))) -64&""& IF(MID(A1,3,1)="", "", CODE(UPPER(MID(A1,3,1)))-64&""& IF(MID(A1,4,1)="", "", CODE(UPPER(MID(A1,4,1)))-64&""&IF(MID(A1,5,1)="", "", CODE(UPPER(MID(A1,5,1)))-64&""&IF(MID(A1,6,1)="", "", CODE(UPPER(MID(A1,6,1)))-64))))

    • Hello Cindy,
      Please try to use the formula below to solve your task:

      =IF(A1="ABC", 1234, IF(A1="DEF", 5678, IF(A1="GHI", 91110, 0)))

      • I Tried several times, but it doesn't work. Could you please check and advise again. Thank you!

        • Hi Cindy,

          Try using commas instead of semicolons to separate the arguments (that depends on which character is set as the List Separator in your Regional Settings):
          =IF(A1="ABC", 123456, IF(A1="DEF", 5678, IF(A1="GHI", 91110, "")))

        • Thank you for replying, Cindy.

          Most likely it is the delimiter that was causing troubles. Please try this formula instead, it should work:
          =IF(A1=”ABC”, 1234, IF(A1=”DEF”, 5678, IF(A1=”GHI”, 91110, 0)))

          I've updated the formula in my previous comment as well. Sorry for the confusion.

  5. Assuming that A1 is 2006 and B1 is 2006
    =IF(A1=B1,"True","False") comes up True
    but
    =IF(A1="2006","True","False") comes up False.

    How do I resolve this within a formula since the 2006 is coming from a different formula.

    Thanks in advance.

  6. I would like to check a cell for currency format and if its in £ then multiply it by the $ factor to convert it to $s' and if its in $ then leave it in $s'.
    example: A1 is the £ to $ currency factor; A2 is the value in £ or $; A3 will be the value of A1 in $s.
    I have tried using the IF function, but it will not recognise A1 currency format! I would appreciate some help with this. Many thanks.

  7. Good Morning,

    I am trying an exercise in Excel, we have a sheet some details, however, in the first column A2, have some digit number in the same column digit will be sometime 7, 8, 10 and some case digit numbers with dots then TWO digits.

    I am looking for a formula that can help me to write text in the next column............

    Example : =IF(A2=(len)8,"NOBILIA",IF(A2=(len)7,"IMPULS",IF(A2=(len)10,"LINEA DÉCOR"))).

    Will you please help me with it.

    Sincerely yours
    Ikram Siddiqui

    • =IF(LEN(A4)=7,"IMPULS",IF(LEN(A4)=8,"NOBILIA",IF(LEN(A4)=10,"LINEA DECOR","")))

  8. Hi Svetlana,
    I am trying to achieve in the formula to show the following:
    If the cell drop down is selected with "CB2" is standalone to show "local", if "CB2" & "CB3" (combined) to show "local & far" and if "CB3" to show "far"
    How can I achieve this?
    TIA

    • Hi Tia,
      There seems to be a problem with the IF(AND()) function. The comment truncates the formula for some reason.
      =IF(A1="CB2","LOCAL",IF(AND(A1="CB2",A1="CB3"),"LOCAL & FAR",IF(A1="CB3","FAR","")))

  9. IF Early Bird criteria - Customers who want to avail of an Early Bird discount must place their orders on weekdays between 11:45 a.m. - 12:00 p.m. (for lunch) or 6:45 p.m. - 7:30 p.m. (for dinner).
    Write a logical function to find out whether a customer is an early bird. (refer to the 'Early Bird' criteria stated above) In your function, you will have to reference Column E values (day of week) and Column F (time of order) to determine whether customers are early birds. Think about how you will reference the early bird criteria.
    If a customer is an early bird, the function should return "Early Bird". Otherwise, the function should return a blank value.

  10. Can you help me to accurately represent this formula please:
    =IF(L4>0612,"High Risk")

  11. i using if condition formula it taking only 10 conditions is it only 10 conditions allowed

  12. Hi Sveetlana Cheusheva
    Is it possible that if I enter any text in column"P", "L" should show what is there in "K".
    =IF(NOT(ISBLANK(P7)),"0","=K7")
    =IF(ISBLANK(P7)),"=K7","0")

    • Hi Ashwini,

      I think you've overthought it :) A simpler formula will work:
      =IF(P7<>"", K7, 0)

  13. Can you help me write a formula for the following situation plse.
    If A1-A2 is less than zero, then show the negative value. If not, then show zero.
    Tks

  14. Can u direct me on the error of my formula? =IF(E22>0)B22+E22
    I want it to be cell B22+E22. But ONLY if there is an entry in E22. If E22 hasn't been filled in yet, then I want the formula to be in place but not to SHOW. Much Appreciated!

    • =IF(E22="","",IF(E22>0,B22+E22))

  15. hi! like to corelate data in 2 sheets of same excel file. e.g. sheet 1 and sheet 2
    I need help to create if or
    any formula like
    =if(sheet1b2=10,"sheet2A3=Sheet1A3","blank")

    plz help

    • write semicolon instead comma

    • =IF(Sheet1!B2=10,Sheet1!A3,"")

      Put this formula cell A3 of Sheet2.

  16. Hi,
    I have D9 = 0 to 2000, I would like to write this formula in C10
    if the value of D9 is equal or greater than 15, then cell C10 value will be 15, otherwise, the value of cell C10 should equal to the value in D9
    =IF(D9>=15,C10=15,C10=D9)
    But, it doesn't give what I want. anyone can help?
    Thank you

    • remove the C10=

  17. Very Nice, i got it what i wanted thank you.

  18. Make sure the brackets are full closed .This will prevent the repetion.

  19. Hi, I just want the formula like I just evolving each cell's values like marks. If more than (for example >=50) just want to show that value only using.
    For example, someone takes 40, 45, 50, 30 evolving all values and retrieve only more than 50 values.

  20. Assign sequential numeric numbers to each company with IF funciton. If a company name is repeated, it will have the same number.
    anyone please slve this?

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)