How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. Hi,

    What function would I use to say "If there is a value in this range of cells, input "yes", otherwise input nothing"

    • Hi Sony,

      You can use IF together with the COUNTA function that counts the number of cells in a range that are not empty. For example:

      =IF(COUNTA(A1:D1), "yes", "")

  2. Hi,
    I have two tables with different data. I want to create a new table, extracting information from both tables (some of the data in the first table may not be in the other table but I want to be shown all of them), because I want to find the difference from both tables.
    Thank you,

  3. Hi, i would like to ask you, if a cell has a value how can i ask to put an other value to the next cell which is empty?
    Thank you!

    • Hi Antigoni,

      You'll need an if statement similar to below:

      =IF(A1="VALUE","TRUE","FALSE")

  4. --=IF(C2=B2,"Equal",IF(C2>B2,"Over",IF(C2<B2,"Short"," ")))-- done

  5. Please help,
    what am I doing wrong? the cell just returns what is in AT2 regardles of what is in C9
    =IF($C$9="1",IF($C$9="2",IF($C$9="3",IF($C$9="4",IF($C$9="5",IF($C$9="6",IF($C$9="6",IF($C$9="8",IF($C$9="9",IF($C$9="10",BL2,),BJ2),BH2),BF2),BD2),BB2),AZ2),AX2),AV2),AT2)
    Thanks.

    • never mind fixed it
      =IF($C$9=0,"",IF($C$9=1,AT2,IF($C$9=2,AV2,IF($C$9=3,AX2,IF($C$9=4,AZ2,IF($C$9=5,BB2,IF($C$9=6,BD2,IF($C$9=7,BF2,IF($C$9=8,BH2,IF($C$9=9,BJ2,IF($C$9=10,BL2)))))))))))

  6. i have a formula to work out if stock is short over or equal how do it add the equal =if (c2>b2;"over";"short")

    • =IF(C2=B2,"EQUAL",IF(C2>B2,"OVER",IF(C2<B2,"SHORT","")

    • Amended =IF(C2=B2,"Equal",IF(C2>B2,"Over",IF(C2<B2,"Short"," ")

      • -- =IF(C2=B2,"Equal",IF(C2>B2,"Over",IF(C2<B2,"Short"," ") --

    • ---=IF(C2=B2,"Equal",IF(C2>B2,"Over",IF(C2<B2,"Short"," ")))----

  7. Hello, can you please help me with this?=IF(AM4=AM6,IF(AK4="MED""NWRK""CLL""RQO""OOS""WCMP",0,AK4-AO4-AP4-AQ4)-AL4)
    If there is data in AM6 I get the result I want. If MED, NWRK, CLL etc is entered in AK4 and there is no data in AM6 I get #value. I would like a blank cell. This was working when it was just"MED" and had not added the others.
    Thanks for your time.

    • Hi, The concept you put up is conflicting, please narrate the job properly in order to provide you with the correct format.

  8. Hello,Can you please help me with this?=IF(AM4=AM6,IF(AK4="MED""NWRK""CLL""RQO""OOS""WCMP",0,AK4-AO4-AP4-AQ4)-AL4)
    This formula does what I want when there is data in AM6 but if AM6 is blank it returns #Value. This happens only when MED, NWRK, RQO etc is typed in AK4. Why?
    Thanks in advance for your time.

  9. I need a function to determine if age greater than 23, and should return the text Yes if true and No if false.

    • =IF(A1>23,"YES","NO")

  10. IF THIS CELL IS LESS THAN OR EQUAL TO 30 COPY THE VALUE OF THIS ROW,IF NOT,ZERO,

    • Hi Ron,
      =IF(A1<=30,A1,0)
      The site may have issues showing the formula. If the above is broken, try the one below.
      =IF(OR(A1=30,A1<30),A1,0)

  11. Hi
    can you help me to find a value
    if A1,B1,C1,D1,E1 have values like that
    0, 0, 2, 0, 0
    How we found this value
    C1 value not specified its Formula based value
    Regards

  12. I am trying to calculate a commission for realtors here in BC. We have a tiered structure here which is as follows
    7% on the first 100k
    2.5% on the balance.

    This is then further broken to reflect
    3.22% on the first 100k and 1.15% on the balance (agent representing buyer)
    3.78% on the first 100k and 1.35% on the balance (agent representing seller)

    I want to be able to put a client name in a cell and following cell the type of transaction (buyer or seller) and have a cell trigger a calculation for the above commission level when the word seller or buyer appears in the cell.

  13. I am working on an inventory thing and all I want is for the drop list I have created for the cells to subtract 1 from the total in another cell.

    Example - If C3 is (I select an item from the drop down) then subtract 1 from V3.

    I just have a floor plan that I have layed out for deployed monitors and want to be able to select from the drop down a Samsung monitor for example and then it take 1 away from the total I have in another cell. Should be super simple however I can't get it work with the IF statement.

  14. Hi A, Perfecto! Works like a dream. Thank you very much.

  15. Hi Carrie,
    please try the formula below.
    =IF(COUNTIF(SoldDetails!C8:C21,"NO"),"INCOMPLETE","COMPLETE")

  16. Hello,
    I have 2 tabs in one spreadsheet. On tab 1, I want the cell to change to 'Complete', if the column range on tab 2 are all answered 'Yes'. Otherwise, I want it to say 'Incomplete'. The answers for column on tab 2 are either "Yes" or "No". If there is even one 'No' in that column, I want the column on tab 1 to pick it up.
    The following formula is what I've tried and it is not working, although I get no error.

    Where tab 1 is named "Sold' and tab 2 is named 'SoldDetails'. Thanks for any guidance. Perhaps I should be using CountA to determine cells that are either 'No' or 'NA', but any help is appreciated.
    =IF(SoldDetails!C8:C21="Yes","Complete", "Incomplete")

  17. Thank you works like a charm.

  18. Hello! I am having trouble writing a formula.
    I need the date(that is not final) in C22 to project 107 weeks out and then compare that new date to 12/31/2024 and pick the earlier of the two. This new date would automatically go to cell c32.

    I appreciate any help. Thank you

    • Hi Mallorie,
      Please try the formula below.
      =IF(C21<C22,C21,C22)
      You might have to format the columns to be shown in the date format.

  19. If *100 is not there it works for stocks, with the * 100 it works for options.

  20. =IF(OR(ISBLANK(N9),OR(ISBLANK(P9),ISBLANK(O9))),,(N9*(P9-O9))*100) I want to add a function so that it will only multiply by 100 if Row L9 to L123 says Debit or Credit. so if it does not show debit or credit it will put the number instead.

    • Hi Stephen,
      =IF(OR(L9="DEBIT",L9="CREDIT"),(N9*(P9-O9))*100,(N9*(P9-O9)))
      Formula above only checks per row. You get a value per row
      =IF(OR(COUNTIF(L9:L123,"DEBIT"),COUNTIF(L9:L123,"CREDIT")),(N9*(P9-O9))*100,(N9*(P9-O9)))
      Formula above checks the whole range of L9:L123 if it contains debit or credit.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)