by In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.
IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.
In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.
IF function in Excel
IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.
The syntax of the IF function is as follows:
As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.
Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.
Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.
Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.
Basic IF formula in Excel
To create a simple If then statement in Excel, this is what you need to do:
- For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
- For value_if_true, specify what to return when the logical test evaluates to TRUE.
- For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.
As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:
=IF(B2>80, "Good", "Bad")
This formula goes to C2, and then is copied down through C7:
In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:
=IF(B2>80, "Good", "")
This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise:
Excel If then formula: things to know
Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.
If value_if_true is omitted
If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:
=IF(B2>80, , "Bad")
To return a blank cell instead, supply an empty string ("") for the second parameter, like this:
=IF(B2>80, "", "Bad")
The screenshot below demonstrates the difference:
If value_if_false is omitted
Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.
If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:
=IF(B2>80, "Good")
Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:
=IF(B2>80, "Good",)
The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:
=IF(B2>80, "Good", "")
Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.
Using IF function in Excel - formula examples
Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.
Excel IF function with numbers
To build an IF statement for numbers, use logical operators such as:
- Equal to (=)
- Not equal to (<>)
- Greater than (>)
- Greater than or equal to (>=)
- Less than (<)
- Less than or equal to (<=)
Above, you have already seen an example of such a formula that checks if a number is greater than a given number.
And here's a formula that checks if a cell contains a negative number:
=IF(B2<0, "Invalid", "")
For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell.
Excel IF function with text
Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.
For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:
=IF(B2="delivered", "No", "Yes")
Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise.
Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:
=IF(C2<>"delivered", "Yes", "No")
Notes:
- When using text values for IF's parameters, remember to always enclose them in double quotes.
- Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".
Case-sensitive IF statement for text values
To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.
For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:
=IF(EXACT(B2,"DELIVERED"), "No", "Yes")
If cell contains partial text
In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.
A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).
For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:
=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes")
For more information, please see:
Excel IF statement with dates
At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.
For example, here's how you can check if a given date is greater than another date:
=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")
This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date.
Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:
=IF(B2>$E$2, "Coming soon", "Completed")
To compare a date with the current date, use the TODAY() function. For example:
=IF(B2>TODAY(), "Coming soon", "Completed")
Excel IF statement for blanks and non-blanks
If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:
- Use the IF function together with ISBLANK, or
- Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).
The table below explains the difference between these two approaches with formula examples.
| Logical test | Description | Formula Example | |
| Blank cells | ="" |
Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string. Otherwise, evaluates to FALSE. |
=IF(A1="", 0, 1)
Returns 0 if A1 is visually blank. Otherwise returns 1. If A1 contains an empty string (""), the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings. Otherwise, evaluates to FALSE. |
=IF( Returns 0 if A1 is absolutely empty, 1 otherwise. If A1 contains an empty string (""), the formula returns 1. |
|
| Non-blank cells | <>"" | Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered blank. |
=IF( Returns 1 if A1 is non-blank; 0 otherwise. If A1 contains an empty string, the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered non-blank. |
=IF( Works the same as the above formula, but returns 1 if A1 contains an empty string. |
And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:
=IF(B2="", "", "Completed")
=IF(ISBLANK(B2), "", "Completed")
=IF($B2<>"", "Completed", "")
=IF(ISBLANK($B2)=FALSE, "Completed", "")
In case the tested cells have no zero-length strings, all the formulas will return exactly the same results:
Check if two cells are the same
To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:
=IF(B2=C2, "Same score", "")
To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.
For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:
=IF(EXACT(A2, B2), "Match", "Don't match")
IF then formula to run another formula
In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.
For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:
=IF(B2>80, B2*7%, B2*3%)
Multiple IF statements in Excel
In essence, there are two ways to write multiple IF statements in Excel:
- Nesting several IF functions one into another
- Using the AND or OR function in the logical test
Nested IF statement
Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.
Assume your goal is to assign different bonuses based on the score:
- Over 90 - 10%
- 90 to 81 - 7%
- 80 to 70 - 5%
- Less than 70 - 3%
To accomplish the task, you write 3 separate IF functions and nest them one into another like this:
=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%)))
For more formula examples, please see:
Excel IF statement with multiple conditions
To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:
For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:
=IF(AND(B2>80, C2>80), "Pass", "Fail")
To get "Pass" if either score is higher than 80, the formula is:
=IF(OR(B2>80, C2>80), "Pass", "Fail")
For full details, please visit:
If error in Excel
Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.
And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.
For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:
=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" )
For more information, please see IF ISERROR formula in Excel.
Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!
Practice workbook
Excel IF statement - formula examples (.xlsx file)
4800 comments
if have in one cell 196.513K, then i want another cell 196.513/1000. Can it possible?
Good day,
I am trying to create an 'If' formula for tasks that picks up a range from another sheet and returns the result on a summary tab.I am not sure if 'IF' is the correct formula as I can't get it to work.
If C38:C42 (on the detailed tab) status is completed then return the text 'Completed, if FALSE then return 'To Complete' on the Summary tab.
I have tried =IF(Revals!C38:C39="Complete","Completed","To Complete") but it didn't work.
Hello Nisha!
If I understand your task correctly, the following formula IF should work for you:
=IF(IFERROR(MATCH("Complete",C38:C39,0) > 0,0),"Completed","To Complete")
I hope this will help, otherwise please do not hesitate to contact me anytime.
Thanks Alexander. I tried it but when I change the status it still returns the same value as if completed. Meaning, if I then went to the detailed tab and changed the cells one to complete and the other to to be completed, it still gives me a result on the summary page that the tasks have been completed when it hasn't.
On the positive at least it is returning a value, i could not get it to even do that :-)
Thanks
Hello!
I expected that you pay attention to the fact that my formula does not have such cell references as yours. I do not have your workbook, so the links may not be the same. I think you just copied the formula and now want it to work? I have given you a sample. Use your cell references in it.
Hi Alexander, yes I changed to my cell references to pick up from the separate tab. However with me putting one as Complete and the rest as To complete, it still returned a value of Completed
Hello!
I wrote this formula based on the description you provided in your original comment. But now it’s clear that you didn’t say everything. How many cells in your range? 2 or more? There were 2 of them in your formula. But now, according to your words, I see that this is not so. Do you need at least 1 match or matches in all cells? The formula you wrote speaks of one coincidence. Now is this not so? Please note that if you’d provided me with the precise and detailed description of your task from the very beginning, I’d have created a different formula that would have worked for your case.
Sure, thank you for you help.
It will be ranges of cells in one column. In this particular example, there are 5 rows in the column. The user is required to change the status to either Completed or Not completed. This is on the detailed tab. There are about 5 different headings with a range of tasks in each one. So I wanted to create a summary sheet that will then Look at each area and then return a result. If all tasks are not completed, even if only one tassks is the summary sheet should say not completed for that particular area. Eg below
Sales
Column B Column C
Row 23 Payroll Reval Not Completed
Row 24 Orders Reval Not Completed
Row 25 Bank Reval Completed
Row 26 Tax Reval Not Completed
Row 27 Interco Reval Completed
I hope this clarifies a bit
Could some one help, please? I am trying to analyse the sales data for a new housing development. I have set up a table with my raw data for the 126 properties, with the following columns:
A = Street number
B = Street address
C = developer’s plot number
D = developer’s house type name (in text)
E = developer’s house type code number (mix of numbers and letters)
F = number of bedrooms the house has
G = whether the house is a flat/terraced/semi-detached/detached
H = size of house (ft2)
I = sale price
J = date of sale
K = sale price/ft2
I am trying to consolidate the raw data into a second table in the same worksheet so that I can calculate the average selling price for the 22 different house types. I find that if I sort the raw data table on house type name to group each house type together and then use the AVERAGE function In the consolidated table, when the raw data is then resorted on a different parameter (say street name) the data pull through for the average is the new cell content rather than the original cell content (ie the cell reference remains the same rather than changing to follow the original data). I have tried to set up a logic test (=IF(D5:D130)=D135,AVERAGE(I5:I130), ) where the range D5:D130 is the range of house type names in the raw data table, D135 is the specific house type name in the consolidated data table, and I5:I130 is the selling price in the raw data table. All I get is an error, either #VALUE! or #NAME! if I try fiddling with the logic test set up. What am I doing wrong?! Can anyone help, please?
Hello Andrew!
Try using the AVERAGEIF function, which calculates the average value based on the condition. Read this guide.
Thank you. It worked! Much appreciated. Gold star!
Hi!
I've been using the IF function with this formula:
=IF(C26-5*$G$25<0,"N/A","YES")
Now that equation is putting "YES" in the correct cells where I want them to. Now I want to change "YES" with a new condition that actually follows a recursive formula; I want to copy the column E7:E18 to another table I'm working on, but only start copying if that cell no longer satisfy the first condition I set up. Is there a way to create the formula such that if the previous IF function is false, I will still start at E7? Is there another way to do this?
I look forward to your response :D
Hello Hannah!
I’m sorry but your task is not entirely clear to me. What does E7: E18 have to do with your formula? What does "start at E7" mean? What condition do you want to include in your formula instead of “Yes”? Please describe your problem in more detail. It’ll help me understand it better and find a solution for you. Thank you.
Hi,
How do I, if condition met, the cell equals to the value of another cell?
For example;
Cell C4 is empty. If the formula in cell U2 generate a '1', the value of C4 will automatically be equal to the value stated in cell R2.
By the way, the value in cell R2 is 'A,B,C,D'.
Please advise and thank you.
Hello Nicholas!
If I understand your task correctly, the following formula should work for you:
=IF(U2=1,R2,"")
I hope it’ll be helpful.
Hi,
I could use some help please.
I have 3 variables that depend on the last letter of the main word and I would like to separate them as follows:
XXXXXXA Yesterday
XXXXXXD, XXXXXXXE, XXXXXXF Today
XXXXXXK, XXXXXXL, XXXXXXM, XXXXXXN Tomorrow
If try IF, OR, ISNUMBER SEARCH AND FIND but I can’t figure it out.
So I just want it to write ‘Yesterday’ if last letter A, ‘Today’ if D,E or F and ‘Tomorrow’ if K, L, M or N as last letter.
Thanks
Hello Matea!
If I understand your task correctly, the following IF formula with nested IF conditions should work for you:
=IF(SUM(--(RIGHT(N1,1)={"K","L","M","N"}))>=1,"Tomorrow", IF(SUM(--(RIGHT(N1,1)={"D","E","F"}))>=1,"Today", IF(RIGHT(N1,1)="A","Yesterday","")))
I hope this will help
Dear Alexander,
You've been so kind to help me with the following formula: =IF(OR(B35"";C35"";D35"");CONCATENATE(B35+C35+D35;"x ";C28);"")
Would you be so kind to also guide me on how to include a second IF-formula (just with following cells B56, C56 and D56 with the name from cell C49? Preferably separated with a comma between the formulas, so the output would look like e.g.: 5x Ronni, 2x Alexander
I've tried with following =IF(OR(B35"";C35"";D35"");CONCATENATE(B35+C35+D35;"x ";C28);IF(OR(B56"";C56"";D56"");CONCATENATE(B56+C56+D56;"x ";C49);"")) but I can't get it to work.
Once again, thank you very much for your kind help!!
Ronni
Hello Ronni!
You just need to add another formula with the condition
=IF(OR(B13<>"",C13<>"",D13<>""), CONCATENATE(B13+C13+D13,"x ",C7),"") & ", " & IF(OR(B35<>"",C35<>"",D35<>""), CONCATENATE(B35+C35+D35,"x ",C28),"")
I hope it’ll be helpful.
Dear Alexander! Thank you very much for your answer and time. I'm not really sure why, but the output of the cell ends up only calling the first IF formula (C7 without C28). I've checked all the cells, made sure that they aren't empty. If I change the order of the two formulas, it calls (C28 without C7). And I'm not getting any error messages on the formula. Do you have any idea why that can be? Once again, thank you for your time!!
=IF(OR(B13"",C13"",D13""), CONCATENATE(B13+C13+D13,"x ",C7),"") & ", " & IF(OR(B35"",C35"",D35""), CONCATENATE(B35+C35+D35,"x ",C28),"")
Hello Ronni!
In my Excel workbook, the formula works. There are no ideas other than copy error.
Try a different version of this formula, where instead of the & operator, the CONCATENATE function is used
=CONCATENATE(IF(OR(B13<>"",C13<>"",D13<>""), CONCATENATE(B13+C13+D13,"x ",C7),""),", ",IF(OR(B35<>"",C35<>"",D35<>""), CONCATENATE(B35+C35+D35,"x ",C28),""))
I have a data from an ERP system which gives the amount with a symbol suffix 'Dr' for debit balance, and a 'Cr' for a credit balance. I want to capture the debit balances as a positive value and the credits with a negative value. Please help
Hello Thomas!
I do not know how your values are written. You did not say anything about this. The IF function will not help here. But I think that you’ll find this formula useful
=IFERROR(VALUE(SUBSTITUTE(A20,"Dr","")), -VALUE(SUBSTITUTE(A20,"Cr","")))
I hope this will help, otherwise please do not hesitate to contact me anytime.
Hi,
My scenario is the following: if a date is more than 3 years old then Good...if is less than 3 years Not Good. For example if 04/17/2016 is more than 3 years old from 01/01/2020. Thanks.
Hello Chris!
To calculate the difference between dates, use the DATEDIF function. I recommend this article. Use DATEDIF with the Y parameter as a condition in the IF function.
I hope this will help, otherwise please do not hesitate to contact me anytime.
I believe I found the error in the formula. The parentheses were not placed correctly..... Correct formula: IF (A1>0,TEXT(B1-A1,"[mmmm]")," ")
I have three columns. Columns A and B contain date & time information and column C contains the difference (in minutes) between A and B. The formula being used in column C is TEXT(B2-A2), "[mm]". Currently if nothing is in column A or B the formula in column C shows 00. I would like for it to show blanks.
Please help me understand why I am unable to use the following formula so as to not see 00 in column C:
IF A2>0, TEXT(B2-A2), "[mm]", " ". Explanation: If columns A and B are not populated, column C should appear as blank and not contain 00.
Are you able to create an IF then statement in excel and embed another function formula?
Example:
Column A2 contains a start date and time: 5/15/20 14:15.
Column B2 contains an end date and time: 5/16/20 08:09.
Column C2 contains a formula to caculate the duration between columns A and B in minutes: TEXT(B2-A2), "[mm]".
I am looking for a formula where blanks will appear in column C2 if column A2 is not yet populated. I want to include the TEXT formula throughout column C, in order to auto populate the column C once columns A and B have data. Currently, using the formula TEXT(B2-A2), "[mm]" yields 00 in column C2 if A2 is blank.
I tried the following formula, but cannot get it to work: If A2>0, TEXT(B2-A2,"[mm]", " " Explanation: If nothing is in column A, column C should be blank (i.e. not show 00). Thanks in advance for your assistance.
Hello Joe!
Use the IF function with two conditions
=IF(AND(A2<>"",B2<>""), TEXT(B2-A2,"[mm]")," ")
If there is anything else I can help you with, please let me know.
Hi. I am trying to create a formula that says:
If (a1 =1 then c1 = 50) ( a1= 2 then c1 = 60) (a1= 3 then c1 = 70) (a1 = 4 then c3 = 10)
Thanking you in advance.
Hello Jeff!
A formula can only set a value in the cell in which it is written. The formula in C1 cannot change cell C3.Therefore, I assume that C3 is a mistake. Change C3 to C1. The formula in C1 is
=IFERROR(CHOOSE(A1,50,60,70,10),"")
Or use the If function
=IF(A1=1,50,IF(A1=2,60,IF(A1=3,70, IF(A1=4,10, "") ) ) )
Hi,
Could you please help me? I have column J as text - apple;orange;bananas;vegetables (spinach, fenugreek, etc); acai berry. I want to create Column K as 1 if there is orange in Column J and 0 if not OR 1 if there is spinach in Column J and 0 if not. How can I do that? Please advise. Thank you for your help!
The formula will return 1 if there is "orange" in column J.
=IF(COUNTIF(J:J,"orange") > 0,1,0)
Hope this is what you need.
Hi Alexander,
Thank you for your help but unfortunately the formula did not work. Just to clarify each row in J has continuous text such as Row 1 = apple;orange;bananas;vegetables(spinach,fenugreek,etc);acai berry
Row 2 = orange;bananas;vegetables(spinach,fenugreek,etc)
Row 3 = apple;orange;bananas
and so on
Also there is no space between the text and semi colon and following text
Please advise
Hello!
The formula I sent to you was created based on the description you provided in your first request.
However, as far as I can see from your second comment, your task is now different from the original one. Hence, the formula fails to work.
I also assume that the phrase "each row in J has continuous text" actually means "every cell in column J contains text."
Try the following formula:
=IF(IFERROR(SEARCH("orange",J2,1),0)>0,1,0)
After that you can copy this formula down along the column.
Hi,
Let say i have text "export" in C2 and C20 . Can I use formula =if(C2=C20,countifxxx,0) ?
So if I want to change the text 'export' I don't need change every formula. is that possible?
thanks to advice.
Hello!
In your IF formula, it is important that C2 = C20. What will be recorded in these cells does not matter. You can use nested functions as a TRUE or FALSE condition, including COUNTIF.
There are payroll list for June 2020
1) Fill June Payoff with this rule: if monthly Wage is less then 20 000, then pay 20 000. In other case pay just Wage itself.
What value should put in Value _if_ false
Hello Christina,
Please try the following formula:
=IF(A2<20000,20000,A2)
Hi Alexander!
Thank you for a great and helpful site!! I have three cells (B13, C13, and D13) that can contain numbers (usually nothing or somewhere between 1 to 10). If one (or more) of these three cells contain a number (if none of them are empty), I would like to extract a name that is written in cell C7 - and with the sum of the three cells (B13, C13 and, D13) listed with an "x" before the name. Example: B13 [1], C13 [empty], D13 [5], C7 [Ronni] - would generate: "6x Ronni". Is this possible to make? Thank you very much for your help!!
Sorry, let me correct my question:
I have three cells (B13, C13, and D13) that can contain numbers (usually nothing or somewhere between 1 to 10). IF one (or more) of these three cells contains a number, I would like to extract a name that is written in cell C7 - and with the sum of the three cells (B13, C13 and, D13) listed with an "x" before the name. Example: B13 [1], C13 [empty], D13 [5], C7 [Ronni] - would generate: "6x Ronni".
Hello Ronni!
Please use the following formula
=IF(OR(B13<>"",C13<>"",D13<>""),CONCATENATE(B13+C13+D13,"x ",C7),"")
I hope this will help, otherwise please do not hesitate to contact me anytime.
Thank you very much, Alexander! It works perfectly! Now, I'm trying to pull different cells with the formula that you helped me with, to list the names into the same cell/sentence, though I can't figure out why I can't make that work. Your single formula works.
=IF(OR(B14"";C14"";D14"");CONCATENATE(B14+C14+D14;"x ";C7);
=IF(OR(B35"";C35"";D35"");CONCATENATE(B35+C35+D35;"x ";C28);
=IF(OR(B56"";C56"";D56"");CONCATENATE(B56+C56+D56;"x ";C49);
=IF(OR(B77"";C77"";D77"");CONCATENATE(B77+C77+D77;"x ";C70);
=IF(OR(B98"";C98"";D98"");CONCATENATE(B98+C98+D98;"x ";C91);
=IF(OR(B119"";C119"";D119"");CONCATENATE(B119+C119+D119;"x ";C112);
=IF(OR(B140"";C140"";D140"");CONCATENATE(B140+C140+D140;"x ";C133);
=IF(OR(B161"";C161"";D161"");CONCATENATE(B161+C161+D161;"x ";C154);
=IF(OR(B182"";C182"";D182"");CONCATENATE(B182+C182+D182;"x ";C185);
=IF(OR(B203"";C203"";D203"");CONCATENATE(B203+C203+D203;"x ";C196);
=IF(OR(B224"";C224"";D224"");CONCATENATE(B224+C224+D224;"x ";C197);
=IF(OR(B245"";C245"";D245"");CONCATENATE(B245+C245+D245;"x ";C238);
=IF(OR(B266"";C266"";D266"");CONCATENATE(B266+C266+D266;"x ";C259);
=IF(OR(B287"";C287"";D287"");CONCATENATE(B287+C287+D287;"x ";C280);
=IF(OR(B308"";C308"";D308"");CONCATENATE(B308+C308+D308;"x ";C301);
=IF(OR(B329"";C329"";D329"");CONCATENATE(B329+C329+D329;"x ";C302);
=IF(OR(B350"";C350"";D350"");CONCATENATE(B350+C350+D350;"x ";C343);
=IF(OR(B371"";C371"";D371"");CONCATENATE(B371+C371+D371;"x ";C364);
=IF(OR(B392"";C392"";D392"");CONCATENATE(B392+C392+D392;"x ";C385);
=IF(OR(B413"";C413"";D413"");CONCATENATE(B413+C413+D413;"x ";C406);
=IF(OR(B434"";C434"";D434"");CONCATENATE(B434+C434+D434;"x ";C427);
=IF(OR(B455"";C455"";D455"");CONCATENATE(B455+C455+D455;"x ";C448);
=IF(OR(B476"";C476"";D476"");CONCATENATE(B476+C476+D476;"x ";C469);
=IF(OR(B497"";C497"";D497"");CONCATENATE(B497+C497+D497;"x ";C490);
=IF(OR(B518"";C518"";D518"");CONCATENATE(B518+C518+D518;"x ";C511);
=IF(OR(B539"";C539"";D539"");CONCATENATE(B539+C539+D539;"x ";C532);
=IF(OR(B560"";C560"";D560"");CONCATENATE(B570+C570+D560;"x ";C553);
=IF(OR(B581"";C581"";D581"");CONCATENATE(B581+C581+D581;"x ";C574);
=IF(OR(B602"";C602"";D602"");CONCATENATE(B602+C602+D602;"x ";C595);
=IF(OR(B623"";C623"";D623"");CONCATENATE(B623+C623+D623;"x ";C616);
;""))))))))))))))))))))))))))))))
Ideally, I'd also try to separate the strings with a comma and space, so it'd generate 5x Ronni, 2x Alexander, 1x Pedro - though trying to take small babysteps here, haha.
Once again, thank you for taking your time to help!
If A+ then "Outstanding"
If A then "Excellent"
If B+ then "Very Good"
If B then "Good"
If C+ then "Satisfactory"
If C then "Acceptable"
If D+ then "Partially Acceptable"
If D then "Insufficient"
If E then "Very Insufficient"
For this condition I used "=IF(N7, IF(N7="A+", "Outstanding", IF(N7="A", "Excellent", IF(N7="B+", "Very Good", IF(N7="B", "Good", IF(N7="C+", "Satisfactory", IF(N7="C", "Acceptable", IF(N7="D+", "Partially Acceptable", IF(N7="D", "Insufficient", "Very Insufficient")))))))))" but it show "VALUE!".
Pls Help me
Hello!
If I understand your task correctly, the following formulas should work for you
=IF(N7="A+","Outstanding",IF(N7="A","Excellent", IF(N7="B+","Very Good",IF(N7="B","Good", IF(N7="C+","Satisfactory",IF(N7="C","Acceptable",IF(N7="D+","Partially Acceptable", IF(N7="D","Insufficient","Very Insufficient"))))))))
I hope it’ll be helpful.
=IF(R3="CLower",V3*100%)
How can I make the above formula repeatedly and give me different relevant answers without false or true
Hello James!
I’m sorry but your task is not entirely clear to me.
For me to be able to help you better, please describe your task in more detail. Please let me know in more detail what you were trying to find, what problem or error occurred. Give an example of the source data and the expected result. It’ll help me understand it better and find a solution for you. Thank you.
Would it be possible to use an IF statement, to say if a cell is still empty after a date has passed the "True" would be "OK" and "False" would be "Late"?
Hello Doug!
If I understand your task correctly, the approximately this formula should work for you:
=IF(AND(B2 > A2,C2=""),"OK","Late")
I hope this will help, otherwise please do not hesitate to contact me anytime.