How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4800 comments

  1. I need an equation that does two things. I need it to count a range of cells that has any text value. Also if the count is greater than 5 I need the blank to say "no more off" if the count is less than 5 then cell is blank. This is one of the equations I tried in cell k4 I typed. =count(L6:L22,"*"),IF(k4>5,"no more off","") i tried several different variations of this concept.

  2. Hi, i am trying for if function when the one of cell value is True i need list of drop down values when False it should be Null

  3. sir Please help me to findout the solution IN EXCEL
    if i write AAA1,AAA2....AAA999 and if IT IS MORE THAN AAA999 THEN NEXT VALUE WILL BE AUTOMATICALLY AAB000
    AND THEN AAB000 TO AAB999 AND THEN AACOOO..

  4. Column A = Date 30-June-2020, Column B = Date 30-Sep-2020 (*Overdue morethan 2 months)

    How to condition formatting highlight the cell in Column B in red color

    • Hello!
      If I understand your task correctly, use this formula in a conditional formatting rule:

      =IF(EDATE(A1,2) < B1,TRUE,FALSE)

      Hope this is what you need.

  5. =if ((a1="g"),1,or(a1="mg"),1,0)
    i want 1 if a1=g and a1=mg also if a1=kg then 0 and so on.

    • = IF(OR(D32="g",D32="mg"),1,"")

      got it Thanks

  6. Hi Alexander,
    I have a column with some digital values. I am writing an IF statement on the neighbouring column to add paranthesis around the number in the previous column.
    Ex. =IF(D10>0,[D10],0)
    Hoping that if D10 ha a value 5, the IF statement returns [5] adding the square parenthesis. But it does not. How do I fix this? Thanks!

    • Hello!
      If I understand your task correctly, the following formula should work for you:

      =IF(D10>0,"["&D10&"]",0)

      But at the same time, the number will be converted to text.
      You can also use a custom format without formulas.

      Please go to Format Cells, choose Number -> Custom Format and set

      \[#\];-#,##0;0

      I hope this will help

  7. I need help to excel sheet formats can works auto print with data find as per order...
    Example :
    first name ()
    Second name (). Etc.
    I am working same method in word the mailmerge using for auto data print.
    Give me solution for excel. How can use to autoprint in excel.

  8. Hi sir,
    Please advice me the formula
    I have three ccolumn in excel sheet - Today date ,City and Departure date.for today date i used the formula =today().but i need the formula in departure date i person is coming from same city then today date = departure date and if outside from my city then today date less one day i.e yesterday date

    • Hello!
      Yesterday's date can be calculated using a simple formula
      =TODAY()-1
      But to give more detailed advice, I do not have the necessary information. Please describe your problem in more detail. Include an example of the source data and the result you want to get. It’ll help me understand your request better and find a solution for you. Thank you.

  9. I have a Date in B6, I want it to show a date in M6 thats 90 days out and if there is words in B6 regarding status "In installation or In permitting" I want it to be blank or show 0. Is that possible?

    • Hello Charles!
      Do you want the formula, text and date to be in B6 at the same time? It's impossible. If I misunderstood you, explain your problem in more detail.

  10. Hi,
    Please assist as my formula does not seem to be working. It gives wrong answers even for correct checks.
    Formula currently in use: =IF(A2=B2, "Wrongly Charged", "OK")
    The idea is to confirm if NUMBERS in A2 MATCH THOSE IN B2. IF SO THEN ANSWER SHOULD BE "OK"ELSE "WRONGLY CHARGED".
    Formula returns "WRONGLY CHARGED" even for numbers that are the same/equal.

    • Hello!
      I do not see your data, so I can only guess. Possible reasons why the equality condition for numbers in the IF formula does not work:
      1. Some of the numbers are saved as text. This is indicated by a green triangle in the upper left corner of the cell and left alignment.
      2. Numbers do not match in decimal places, which are hidden by number formatting.

  11. i am calculating the rent payment alert, where in sheet where rent is 2000
    month sr due date due amount paid balance
    1 1-04-2020 2000 1000 1000
    2 1-05-2020 2000 3000 0

    so i need logic for the due amount once the date of due smaller than todays date

    • Hello!
      I hope you have studied the recommendations in the above tutorial. Please specify what you were trying to find, what formula you used and what problem or error occurred. What do your numbers mean? It’ll help me understand the problem you faced better and help you.

  12. I have 3 columns, one column showing actual costs, one row showing the estimated cost and 3rd column showing my forecasted costs. I want to write an if statement for the forecasted column that will default to the value in the estimated column if our actual costs are zero. However if we do have actual costs I want it to reflect those costs. For example
    Actual Estimated Forecast
    12 5 12
    0 10 10
    3 0 3

    • Hello Candyce!
      If I understand your task correctly, the following formula should work for you:

      =IF(A1=0,B1,A1)

      I hope this will help

  13. I am working on a spreadsheet relating to points (for employees). Each employees late and/or sick is recorded and they are given .5 or 1 point depending on late/sick call. After a year the employees point is removed. To keep the spreadsheet updated, there are formulas in place to change the cell to red once a year has passed. We recently made a change that the employees late will now be removed after 6 months. I need a formula that after 6 months late calls (column E), date is highlighted (column C). For the late point to be removed.
    Columns are as stated below.
    B - Employee ; C - Date ; D - Status ; E - Actual Leave (sick, late etc.) ; F - Points ; G - Total points
    Thank you in advance for your help.

    • Hello!
      To highlight a cell with a date that happened more than 6 months ago, use the conditional formatting formula

      =EDATE(TODAY(),-6) > C1

      I hope this will help

      • Thank you for the reply, Alex. I appreciate your guidance.
        This is a running spreadsheet that is tracked daily, with different conditional formatting rules, making it easier for dates to be tracked and points to be removed/added.
        I was hoping there was a formula to only track lates from column E, within a 6 month time frame for dates from column C. Would this need to be an IF formula inputted as a rule?
        I am hoping this makes sense.
        Thanks again for your help.

        • Hello!
          Your problem is not entirely clear to me. If you want to compare dates with columns C and E, then you can use conditional formatting as a rule

          =EDATE(C1,6) > E1

          This condition is TRUE if between dates C1 and E1 is less than 6 months

          • Column C are specific dates the employee called in. Column E is what the employee called in (late, sick, FMLA etc.). I need only the lates (from column E), the dates (from column C) within 6 months to be highlighted in order to remove points the employee has accumulated.
            Again, your help is very much appreciated. Thank you for your time.

            • Hello!
              Each time you describe your problem in a different way.
              What does "I need only the lates (from column E)" mean?
              What do you mean by "lates"?
              What is wrong in the formula
              =EDATE(TODAY(),-6) > C1 ???
              What result do you get? What result would you like to get?
              Do you need dates for the last 6 months (you wrote "within 6 months") or older than 6 months (you wrote "after 6 months")?

              • I apologize for being so frustrating/confusing. Nothing is wrong with =EDATE(TODAY(),-6) > C1, except it is highlighting ALL dates from column C with 6 months or older. The formula works (and thank you for that), it's just missing one part I need.
                I only need dates highlighted from column C that are labeled "LATE" in column E. Column E has no dates, only words with the type of leave the employee was marked that particular date, e.g LATE, Sick, FMLA(family and medical leave act), LOA(leave of absence), NCNS(no call no show).
                Thank for for your continued help (because clearly I am no excel wizard).

  14. Dear Alex Hi,
    Small Query what to write today Date in cell:(A1) if i type "OK" in Cell:(B1).
    please note Date Should not be got changed as the day change.
    Thanks
    KP

  15. Hi,

    I have a spreadsheet which has one column of company names, and one column of numbers. There is a table at the bottom, what I need is for one line in the table to add all of the number cells for each company name? They are in date order so the company names are not in alphabetical order.

    How can I do this?

    Thanks,

  16. Hi,
    If my company is giving me salary on every mid month and month end basis (Eg. 15 and 30 or 31 (depend on month end date) / for Feb month 28 or 29).every fortnight i received the 10000 dollar.But suppose i am leaving the company on 12-06-2020 then how much amount i will get?
    I need advance formula where we can drag the formula and take it out the amount for other employee details also.
    E.g.
    Leaving date Amt
    12-06-2020 10000
    26-02-2020 10000
    please let me know if additinal details required.

    • Hello Sera!
      If I understand your task correctly, the following formula should work for you:

      =IF(DAY(A11) < = 15,DAY(A11)/15,(DAY(A11)-(DAY(EOMONTH(A11,0))-15)) / (DAY(EOMONTH(A11,0))-15))*10000

      I hope it’ll be helpful.

  17. I hope you're still able to respond to this thread! I'm creating a bonus tracker and I'm wanting Excel to add $50 whenever someone achieves $500 over their goal. For example, the goal is $1,000 and someone achieves $1,500, then they would get an additional $50 payout. Another example would be the goal is $1,000 and someone achieves $2,000 then they would get an additional $100 in payout. Thank you!

  18. Hello~
    I have a birth date in one cell (example 7/22/15), and I need to another cell to auto populate the age in years based on the date 9/1/20. The value would be 4, but what would be a formula to populate that automatically?

  19. Hi,
    i need help with a formula
    If column "M" is less than £3.50 then it needs to say £3.50 and if its higher than £3.50 it needs to return the value stated in column "M"
    =IF(M5<3.49,"£3.50","M5")
    My formula is this so far but the higher value is saying M5 instead of the values higher than £3.50

  20. IF MY CELL CONTAINED #N/A FROM A VLOOKUP VALUE HOW TO PUT 0

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)