How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4800 comments

  1. well i can't change some number like 1-1.000.000.000.000,00 into a text like:
    234.567.891 into (Dua Ratus Tiga Puluh Empat Juta Lima Ratus Enam Puluh Tujuh Ribu Delapan Ratus Sembilan Puluh Satu - indonesian) or (Two Hundred thirty Four million Five hundred Sixty Seven Eight Hunred Ninety One - english).
    will someone help me?

  2. Hi Alexander,
    I'm trying to write a countif formula to only count the "PO-B" positions I have for my department and exclude the open ones or if they don't contain "PO-B".
    DATA
    PO-B-1 - Eisenhuth, Rebecca
    PO-B-17 - OPEN
    M-B-1 - O'Banion, Ruth Ann
    QC-B-1 - Thioune, Omar

    Thanks in advance

    • Hello Luis!
      If I understand your task correctly, the following formula should work for you:

      =SUM(--IFERROR((SEARCH("PO-B",$E$1:$E$28,1)>0),0)*(--ISERROR((SEARCH("OPEN",$E$1:$E$28,1)>0))))

      I hope this will help

  3. Hi Alexander,
    I am not able to formulate given below conditions with IF statements. My query is associated with number of questions, which I need to bind with time. I have no idea how to do formulate with IF conditions.

    Condition-1:
    If I type (greater than 10 questions but less than 16 questions) in 30 minutes then I will be getting 5 marks.

    Condition-2:
    If I type (greater than 5 questions but less than 10 questions) in 20 minutes then I will be getting 3 marks.

    Condition-3:
    If I type (greater than 2 questions but less than 5 questions) in 10 minutes then I will be getting 1 marks.

    • Hello Amit!
      If I understand your task correctly, the following formula should work for you:

      =IF(AND(OR(A1>10,A1<16),B15,A1<10),B12,A1<5),B1<10),1, 0)))

  4. Hi. I want to tag a certain person as "regular" or "probationary" based on the XX number of their tenure derived from a formula and formatted to " X yr, X mo". My condition is that if the tenure is equal or greater than "0 yr, 6 mo" it should be tagged as regular. My problem is that it returns "probationary" to other values that start with "0 yr" even if the "X mo" is equal or greater than 6 mo.

    Hope you could suggest a better formula. Thank you in advance.

    • Hello Mods!
      The information presented to you is not enough to give you advice. What format is “X yr, X mo” written in? Text or date? Please specify what formula you used and what problem or error occurred. Give an example of the source data and the expected result.
      It’ll help me understand it better and find a solution for you. Thank you.

  5. a. insert a formula using the IF function that tests whether the age of the invoice is greater than 30.
    b. If the age of the invoice is greater than 30, subtract the due date from the current date.
    c. If the age of the invoice is less than or equal to 30, display 0 to show that the invoice is not overdue.

    • Hello Adrienne!
      If I understand your task correctly, the following formula should work for you:

      =IF(TODAY()-A1>30,TODAY()-A1,0)

      I hope it’ll be helpful.

  6. Hi. I am generating a document that:
    A1 B1 C1
    A2 B2 C2
    A3 B3 C3
    A4 B4 C4
    Column A has dates, Column B is auto populated from C1 on the today date, but at the end pf the day C1 resets and on next day B2 gets auto populated.

    Can anyone help?

    • Hello Aurel!
      I’m sorry but your task is not entirely clear to me. For me to be able to help you better, please describe your task in more detail.
      What does the phrase e mean "Column B is auto populated from C1 on the today date"?
      Please specify what you were trying to find, what formula you used and what problem or error occurred. Give an example of the source data and the expected result.
      It’ll help me understand it better and find a solution for you. Thank you.

  7. Hi i'm trying to put an IF statement into a cell to show the amount of a transaction under the right category heading. So far I have =IF(D10="Office Equip.",C10,"") so it inputs the value in C10 but I need one IF statement specifically to cover a range of columns from I:AH all with different headings. How would I type this IF formula?

  8. Seeking help of below mentioned conditions.
    If I type greater than 10 but less than 16 questions in Phy/Chem/Maths in 30 minutes then I will be getting 5 points.
    If I type greater than 5 but less than 10 questions in Phy/Chem/Maths in 20 minutes then I will be getting 3 points.
    If I type greater than 2 but less than 5 questions in Phy/Chem/Maths in 10 minutes then I will be getting 0 points.
    If I type greater than 25 but less than 35 questions in Bio/Eng in 1 Hr then I will be getting 5 points.
    If I type greater than 15 but less than 25 questions in Bio/Eng in 1 Hr then I will be getting 3 points.
    If I type greater than 5 but less than 10 questions in Bio/Eng in 1 Hr then I will be getting 1 points.
    Sincere gratitude in advance. Thank You - Amit Sharma

  9. Seeking help of below mentioned conditions.
    If I type >10 but 5 but 2 but 25 but 15 but 5 but <10 questions in Bio/Eng in 1 Hr then I will be getting 1 points.
    Sincere gratitude in advance. Thank You - Amit Sharma

  10. I am not able to figure out while applying multiple If conditions. Seeking you help.

    Conditions-1 :
    If I type >10 but 5 but 2 but 25 but 15 but 5 but <10 questions in Biology/English/ in 1 Hr then I will be getting 1 points.
    Sincere gratitude in advance.
    Thank you
    Amit Sharma

  11. Hello there!
    Here is what I am trying to do:
    If text in Column D (from Workbook 1) matches text in Column E (from Workbook 2) then enter text from Column B (from Workbook 2) in Column F in Workbook 1.
    I cannot figure out how to use the vlookup function for this exercise...
    Help would be very much appreciated... thanks a lot.

    • Hello!
      In your case, you cannot use the VLOOKUP function. When a search occurs in one data range, and you need to return data from another range, use the INDEX + MATCH functions. Read more about it here.
      If you use Office365, pay attention to the XLOOKUP function

  12. i need a formula that i want to equal first column numbers to second column texts for example firs colum 25 34 56 second column love like hate 25=love 34=like 56=hate and excel learn these equalities and i want to use them after for ex. text sheet 25034 25789 25678 34567 34897 56987 excel and i use left operation and next column 25 25 34 34 56(think that it is a column) and excel write ney column love love love like like hate

    if i use matlab it gets easier or struggle or should i use only excel
    please teach this trick
    (sorry for my bad english)

  13. Good day,

    I need to calculate data into a worksheet from specific Columns on a Mastersheet where it links back to specific Unit (Column B:B), amount of Sessions (Column D:D), but then also just for specific month (Column I:I).

    I could only manage thus far: =SUMIF(Master!B:B,CEN!B6,Master!D:D), but then how do I just get it to consider data for a specific month (Column I:I)?

  14. =IF(B2="",A1,N(A1)+1)
    I am using this formulae, but I didnt understand why series in A showing multiple times
    for B merged cells? How to fix this formulae? I don't want series in A to show multiple times.

    • Hello!
      I’m sorry but your task is not entirely clear to me. For me to be able to help you better, please describe your task in more detail. Please specify what you were trying to find. Give an example of the source data and the expected result.
      It’ll help me understand it better and find a solution for you. Thank you.

        • Hello!
          You have 3 options:
          1. Cancel the merging of cells in column B
          2. Merge the cells in column A in the same way as in column B
          3. Remove formulas from cells A83: A88

  15. Dear Alexander.
    You've been more than kind, to help me before, and if it's not too much to ask, I would like to ask for your guidance ones again. I'm having a total of 30 cells (F10, F39, F68, F97, F126 and so forth) that contains the same dropbox of 8 different payment possibilities (PAGO, CARTÃO, CREDITO, DEBITO, DINHEIRO, TRANSFERENCIA, BOLETO, ASSINATURA). I'm trying to generate a formula that shows if one of more of the following 4 payment options (cartão, credito, debito, dinheiro) are listed in one or more of the 30 F-cells. For instance, if F10=BOLETO, F39="", F68=CARTÃO, F97=DINHEIRO, F126=CARTÃO... the formula would generate: "CARTÃO, DINHEIRO". Do you think you can help me with this? Sincere gratitude in advance!! Thank you!! Ronni

    • Hello Ronni!
      Excel formula cannot work with non-contiguous cells. So you can use something like this formula

      =CONCAT(IF(INDEX(COUNTIF($G$10:$G$40,$H$10:$H$13),1)>0,"debito, ",""), IF(INDEX(COUNTIF($G$10:$G$40,$H$10:$H$13),2)>0,"credito, ",""), IF(INDEX(COUNTIF($G$10:$G$40,$H$10:$H$13),3)>0,"dinheiro, ",""), IF(INDEX(COUNTIF($G$10:$G$40,$H$10:$H$13),4)>0,"cartão",""))

      Where
      formula in G10 is =F10
      formula in G11 is =F39 ....... etc
      in H10 written "debito"
      in H11 written "credito" ... etc

      I hope this will help, otherwise please do not hesitate to contact me anytime.

  16. Hi!

    I need a help with formula: IF A2 is 1, then 1, if A2 is 3 or 2, then 0.

  17. I have data in a 16R x 1C format. As per the formula given by me, only 1 cell will display the value in number based on some calculation and rest of the rows will display "Not Applicable". Cell which shows the number may vary depending upon the inputs, but rest 13 will show "Not Applicable". I want to report the number to another cell, Whether it appears on 1st row, or 2nd row or 12th row etc. only the number must be displayed on the reporting cell. Can you please help me to do the same?

  18. I NEED A FORMULA THAT IF= E:E = COMPLETED, THEN A1-(B1,C1,D1), E:E MEAN WHOLE COLUMN

  19. I would like to build a formula for calculating loan payable. Interest chargeable is 10% of the principal but if no payment is done by 10th of the following month, the interest gets compounded, meaning, interest is calculated on top of the added interest to the principal. Is this doable?

  20. i just want a formula where, there is a number like 364 ,now i want to put formula to find if last 2 digit is square of some number or not , if yes thn give value true(like in this case in 364 -----64 is square of 8) nd if not no thn give value false
    example 2 :- 382 in this 82 is not a square of any number therefore valuse come should be false.

    • Hello!
      If I understand your task correctly, the following formula should work for you:

      =IF(SQRT(--(RIGHT(A1,2)))/INT(SQRT(--(RIGHT(A1,2))))=1,TRUE,FALSE)

      I hope it’ll be helpful.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)