How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. Struggling with an If statement.

    =(IF(D4="S", ((H4-F4)/(F4-I4), (IF(D4="L",((F4-H4)/(I4-F4))))

    what I tried entering. keeps rejecting the formula.
    It's my trade journal and looking to determine risk rewad. So when I go Long it needs the L formula and Short the S.

    Appreciate any help

    • Hello!
      I can’t test your formula as it uses your data.
      Try the following formula:

      =IF(D4="S", (H4-F4)/(F4-I4), IF(D4="L",(F4-H4)/(I4-F4),""))

      Hope this is what you need.

  2. I saw that you really active in replying comments ^^.
    I want some answers too for my problem.

    Is it possible to put/show results to another cell? (i dont know what this method called/its name; or this cant be implemented in Excel)

    Lets say:
    A1 value is 0
    A2 value is 0
    A3 value is 0
    A4 value is 0

    When A1 value turn to 1
    A2 = 200
    A3 = 400
    A4 = 600

    Its something like this,
    if A1 =1, A2 = 200*A1 | A3 = 400*A1 | A4 = 600*A1

    A single cell that using fuction, and write the results into other cell

    Is it possible?
    THanks

    • Hello!
      An Excel formula can only write the result to the cell in which it is located. If a value has already been written in a cell, then it can only be changed using a VBA macro

      • Thanks ya ~ i will look into VBA.

  3. I am working on a daily deployment graph where the hours someone begins a shift is in column A and the time they leave is in column B. If cell A1 shown 1100 and Cell B1 shows 1300, I want cell P1, Q1, AND R1 to turn white filled. =if(a1=1100, P1:Q1*WHITE) or something like this if that makes sense?

  4. How to formulate this into the function

    if cell A1 is multiplied by a number then put value of 1 in cell A2

  5. Hi.

    I'm trying to lookup if text matches to return a text string and if it doesn't match, to lookup in another sheet, but it only is seeming to check the first lookup, not the second.

    =IF(VLOOKUP(C2687,'Master Data'!A:A,1,FALSE)=C2687, "regular listed", IF(VLOOKUP(C2687,'Community Service - Master Data'!A:A,1,FALSE)=C2687, "community service", "No Master Data!"))

  6. Hello I'm looking to have the formula work: =ISTEXT(IF('Investment Center'!$B$6:B26=E46,'Investment Center'!$C$6:C26))

    All fields are text and I want to have the following logic. If anywhere within Investment Center'!$B$6:B26 equals to E46 then return value of 'Investment Center'!$C$6:C26. All entires are text.

    • Hello!
      If I understand you correctly, you want to return not one value, but an array. Then try this formula

      =IF(SUM(--(B6:B26=$E$46))>0,C6:C26,"")

      Hope this is what you need.

  7. =IF(L444<3,"PASS","FAIL")=IF 0 =N/A

    HELP Please

  8. Hello.
    I'm trying to us an IF function to a cell that has a small formula F7 has this formula(=F1-F2) but it wont work. It will work if I type the correct number in there but if it is coming from the small formula it is coming up up as "False" Can you help?
    F7 has this formula (=F1-F2)
    Example: If F7...
    is greater than or equal to 0.5 then 2
    is less than or equal to -0.5 then -2
    is in the range of 0.4 to -0.4 then 1
    All in one formula?
    I hope that makes sense.

    • Hello!
      If I understand your task correctly, the following formula should work for you:

      =IF((F1-F2) >= 0.5,2,IF((F1-F2) <= -0.5,-2,IF(AND((F1-F2) >= -0.4,(F1-F2) <= 0.4),1,"")))

      I hope it’ll be helpful.

  9. Hi.

    I am trying to do a product costing spreadsheet. working with 3 different rates of VAT. i'm hoping to indicate which one of the rates applies to the product with a check box? and then using the IF function to give me 'cost per item' based on what rate is selected because the others don't apply.

    Hope this makes sense :)

    • Hello!
      You can check 3 boxes for each VAT. With the IF function, you will check the value of 3 cells. You can also use the dropdown list and specify 3 VAT values in it. Then, in the formula, just use the value from the dropdown list.
      I hope this will help, otherwise please do not hesitate to contact me anytime.

  10. Hello, I'm working with a large amount of text in excel and trying to create a formula where text in one column (name of country) and text in another column (name of a political party) produces a specific pre-set code to identify a specific party. Dataset includes dozens of countries and hundreds of parties.

    • Hello!
      I’m sorry but your task is not entirely clear to me. Could you please describe it in more detail? What result do you want to get? Give an example of the source data and the expected result.

  11. I have a question I am using IF function to a cell, if the cell is FALSE, it will appear as blank. But when a date is inputted i want it to add 2 more days. Is that possible? or how can i do that?

    • Hello!
      If I understand your task correctly, the following formula should work for you:

      =IF(A1=FALSE,"",IF(CELL("format",A1)="D4",A1+2,""))

      You can learn more about CELL function in Excel in this article on our blog.
      I hope I answered your question. If something is still unclear, please feel free to ask.

  12. I WANT A HELP
    IF i= 5
    in cell A1 it shall write A1
    in cell A2 it shall write A2
    in cell A3 it shall write A3
    in cell A4 it shall write A4
    in cell A5 it shall write A5

    • Hi,
      I hope you have studied the recommendations in the tutorial above. It contains answers to your question.
      What does the condition i = 5 mean?

  13. Hi
    I have a problem to use IF statement to give me text value when a numeric value condition is met.
    Example:
    If cell "A" is more than "15" should give text "H" (High) in cell B, if value equals "5" but less than "15" should give "M" (Medium), and less than "5" should give "L" (Low).

    I will appreciate your help.
    Thanks

  14. I have an employee training log that goes back about three years. I need to know if and how I can write a formula in a different sheet to look at a list of required training, compare it to the training log and tell me on the new sheet what employee has not taken what training. Is this possible or are my hopes too high for excel?

    • Hello!
      Unfortunately, without seeing your data it is difficult to give you any advice. Please provide me with an example of the source data and the expected result.

  15. Good Morning!

    Hello Ma'am/Sir,

    I have some problems regarding date formula.

    =IF(EXACT($K9,"NOT DONE"),EXACT($K9,"DONE"),TODAY())

    That is the formula that i created if the value in the cell is "DONE" & "WIP" today Date will be shown in the cell. And if the value is different the cell value would be "NA" but the issue if i am putting next argument the excel showing an error "You've entered too many arguments for this function" this is the formula i created where error is showing =IF(EXACT($K9,"NOT DONE"),EXACT($K9,"DONE"),TODAY(),"NA") If you can help me with this it will be a big help.

    Another thing Ma'am & Sir,

    =IF(EXACT($K9,"NOT DONE"),EXACT($K9,"DONE"),TODAY()) for this formula once if i put the text "DONE" & "WIP" the today date will shown but the issue is once it is in the next day the next day date will be updated in the cell i want it like when i put Done and WIP today date will be there but if it is possible it will not change on the next day or the other date. Like when they put DONE or WIP in today date it will not change the date by tomorrow it self because it is updated once the date change by the next day.

    It will be a big help for me if you will answer it thanks and regards.

  16. Hi, I'm trying to use an if function to check if a string value matches it, it adds the corresponding numeric value to a cell but it doesn't work.

    =If(C10:C43="Income",J10:J43+H7, H7+0)

    So basically, I want the sheet to check that if Income is selected on the C range, the value from J is then added to the cell H7. This is for an expense tracker that I'm currently working on.

    I'm new to this and I really appreciate any help.

    • Hello!
      In a cell like K10, you can use a formula

      =IF(C10="Income",$H$7+J10, $H$7)

      Then copy this formula down the column.
      I hope my advice will help you solve your task.

  17. Hi Can any one tell me how can i fill the Colour in Excel file. For text like Green , Yellow, Red. Etc.

    • Just use conditional formatting

  18. how to write this function properly.

    =IF(J3 greater than 10,"1",IF(J3 is greater than 10 or less than 15,"2",IF(J3 greater than 15 or less than 20,"3",IF(J3 greater than 20 or less than 25,"4",IF(J3 greater than 25,"5")))))

  19. Hi,

    I need help in Excel cell. I want to fill the time only if if is not filled. To fill the time I am already using IF statement =IF(E2 "", NOW(), ""), so trying to solve with nested IF statements. But unfortunately it is not working.

    With statement =IF(E2 "", NOW(), "") - it is filled the value in Coloumn B2 with now time, but it if I enter in new row, the time in previous row get updated. Can you please help.
    Regards

    • If you want the formula to fill in the blanks then it should be =IF(E2="", NOW(),B2)

      Now() function is dynamic so it will continuously update. If you want previous entries to stay static then you need to copy+paste as values.

  20. Hi,

    I need help in Excel cell. I want to fill the time only if if is not filled. To fill the time I am already using IF statement =IF(E2 "", NOW(), ""), so trying to solve with nested IF statements. But unfortunately it is not working.

    With statement =IF(E2 "", NOW(), "") - it is filled the value in Coloumn B2 with now time, but it if I enter in new row, the time in previous row get updated. Can you please help.

    Regards, Surinder

    • Hello,

      I'm creating a Sales order form where I use the following formula -
      =if(and(F18>0, D18>0, E18>0),C18*D18*E18*(1-F18),"")

      So what I'm trying to do is to multiply cells C18 through E18 and if there is a discount amount in cell F18, then include it and get the final net price which includes the discount amount. This is fine and works.

      What I can't make work is to multiply cells C18 through E18, but if there's no discount amount (cell E18 is left blank), I would still get the net price without the discount code.

      I hope this makes sense! Any help would be greatly appreciated!

      Thanks!

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)