How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4800 comments

  1. Hello,

    I need a cell to show"try again" if the answer is incorrect. Can you show me the formula.

    1+5=6 If answer incorrect to display "Try again"
    T6+V6 ANSWER ON W6

    Thank you

  2. +IFERROR(VLOOKUP($D$2:$D$495,JAN_TB!$A$2:$F$183,3,FALSE)," ",IF(VLOOKUP($D$2:$D$495,JAN_TB!$A$5:$F$441,3,FALSE)=0,0,VLOOKUP($D$2:$D$495,JAN_TB!$A$5:$I$203,3,FALSE))) there is an error of connecting IFERROR fomula Please help me

  3. +IFERROR(VLOOKUP($D$2:$D$495,JAN_TB!$A$2:$F$183,3,FALSE)," ",IF(VLOOKUP($D$2:$D$495,JAN_TB!$A$5:$F$441,3,FALSE)=0,0,VLOOKUP($D$2:$D$495,JAN_TB!$A$5:$I$203,3,FALSE)))

  4. =concatenate("Date",text(sheet no.2!$A$1,"mm/dd/yy") I use this formula and there is a date appear which is in sheet no. 2 are empty. I want is empty cell to be appear.. Please help me.. Thanks

  5. Hi Svetlana

    I'm trying to build a spreadsheet to progressively record a players best scores on each of 18 golf holes, over four rounds of golf.

    So on day one they will have a score on each of 18 holes. Their total for the 18 holes will be shown at the end.

    On each successive day, if they have a better score on one or more of those holes, then the score for those holes will change, along with their total for 18 holes.

    So as an example:

    Day 1

    HOLE 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18

    SCORE 2 2 3 2 0 2 3 3 0 2 1 1 2 2 2 1 1 0 29

    Day 2

    HOLE 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18

    SCORE 2 2 3 3 0 2 3 3 0 2 2 1 2 2 4 1 1 0 33

    On day two, they had a better score on holes 4, 11 and 15, so their overall total increased by 4 to 33.

    This would be repeated on days 3 and 4 and changes made depending on their scores for each individual hole.

    The objective is to determine the players best scores on each of 18 holes, over 4 rounds.

    I would appreciate any help you can give so that I can build my Excel spreadsheet.

    kind regards

    Dave

  6. Hello,
    I've been trying to figure this out, in the worksheet given to me as an assignment, the question is to use the if statement to recruit workers that have applied but the must be SLIM AND FEMALE and I have no idea on how to come up with a formula for that considering the fact that there are 2 conditions(slim and female)

  7. Going out on a limb & praying I get some help. It is more a 2 part issue and as a result I tried to break it apart. Thanks in advance if anyone does help out. If not, I completely understand.

    Overview: We have to record the absences at my job. When the agents call in we obtain some basic information. It is a voicemail inbox though. So sometimes it is extremely hard to understand things. The managers continue to add things they want us to track. With larger numbers of staff it has just become a nightmare.

    Issue 1:
    When the agents call in we obtain some basic information and send it out to our managers/supervisors/QA team. What I was trying to determine is if there was some way to take the data I have on an alternate spreadsheet, and make it so that when I enter the agent's phone number it will populate the basic data for us? Essentially, we have a field for last name, first name, supervisor, their reason for missing, shift start time, department, and site.

    What I have been working on for weeks was a table that actually contains the data I want to be pulled in when the phone number is entered. I've added some extra fields that would allow for alternate phone numbers and things like that. So if the agent ever uses a phone number not in the system we could just add it to their "profile" & increase the chances of the automatic entry. I was also going to build a list of generic reasons that contain no details. Just because that is yet another thing the managers & clients both want. Totals of each reason.

    My big question is: is this even possible? Making it so that when 1 thing of text is entered into a cell - the other data populates automatically?

    Issue 2: The main manager wanted a running total at the top of the page. I used =COUNTIF in order to make that operational. However, the client requests a more detailed breakdown. They basically want a total for each start time + what department they are. So for example, I'd have 20 for 7:45 - 2 are Claims / 1 is a Team Lead. 12 for 8:00 - 3 chat + 4 dual skilled etc. etc. etc.

    I was trying to figure a way to where as the call outs were entered in - the formula would automatically be totaling everything.

    Another thing that may be useful with this 2nd issue.... The last sentence basically explains why I felt that way:

    Our manager wanted a total at the top of the spreadsheet. I would often forget to tally it up. So I used =COUNTIF and.... Yeah... I'm not an expert. So I just added an extra row and I put the "bitcoin B" symbol in that row. Thus it only counts that symbol. When a new day starts I just delete the "B" out of that row. I also have a row called "Filter". They want us to keep all of the past data but want the column headers in the email. The easiest way for me was to just put an X in this "Filter" column for todays call outs. When tomorrow rolls around I just delete the X out, filter to show only the "X" (removing blank fields). And repeat daily. So it keeps all the past call outs (We average 20k per year) out of way. ----

    Reasoning mentioned above & possibly the only useful part of that ramble: I didn't know if having the unique symbol already active would help with the counting process since the range it is counting will be changing on a daily basis. I thought maybe the "B" symbol would help identify what needs to be counted.

    Very likely all of this is impossible and that is why no one else has done it already and I am just an idiot?

    • Hello!
      As you enter text in a cell, other data can be automatically filled in using the VLOOKUP or INDEX + MATCH function.
      Unfortunately, without seeing your data it is impossible to give you advice.
      I'm sorry, it is not very clear what result you want to get. Could you please describe your task in more detail and send us a small sample workbook with the source data and expected result to support@ablebits.com? Please shorten your tables to 10-20 rows/columns and include the link to your blog comment.
      We'll look into your task and try to help.

  8. Hi Svetlana,

    I have a range of cells across a sheet (24 rows x 27 columns).

    => First Column is Cycle (rows 1 to 24 )

    =>Last column(27th) is "Total Days" which is summation of columns "Days" having values ( 29 or 30 or 31 or 32 or 33 ) resulting to "Total Days" 364 or 365 or 366 for the year, which are derived as difference between two columns having dates. eg Col B2 = (17/03/2020) ; Col C2 = (16/04/2020) ; Col D2 = 30. Where D2 = C2-B2.

    =>In the sheet ,after "Cycle", Next two columns are having "Months" and third is "Days", but the subsequent columns after this are "Months" and "Days". Month cells are custom formatted as mmm-yy like:

    Cycle | Mar-20 | Apr-20 | Days | May-20 | Days | Jun-19 | Days | Jul-19 | Days | Aug-19 | Days | Sep-19 | Days | Oct-19 | Days | Nov-19 | Days | Dec-19 | Days | Jan-20 | Days | Feb-20 | Days | Mar-20 | Days | Total Days

    =>Each Month cell below is a linked formula to next date of the column Month cell across the range such that for Months, the formula is to avoid dates from a range of public holidays and Sundays between cells C33 and C103 which are maintained in col C64 onwards.
    eg.
    I2 cell formula is
    =IF(ISERROR(MATCH((G25+1),$C$33:$C$103,0)),(G25+1),IF(ISERROR(MATCH((G25+2),$C$33:$C$103,0)),(G25+2),(IF(ISERROR(MATCH((G25+3),$C$33:$C$103,0)),(G25+3),IF(ISERROR(MATCH((G25+4),$C$33:$C$103,0)),(G25+4),IF(ISERROR(MATCH((G25+5),$C$33:$C$103,0)),(G25+5),IF(ISERROR(MATCH((G25+6),$C$33:$C$103,0)),(G25+6),"More than 6 days")))))))

    I3 Cell Formula is
    =IF(ISERROR(MATCH((I2+1),$C$33:$C$103,0)),(I2+1),IF(ISERROR(MATCH((I2+2),$C$33:$C$103,0)),(I2+2),(IF(ISERROR(MATCH((I2+3),$C$33:$C$103,0)),(I2+3),IF(ISERROR(MATCH((I2+4),$C$33:$C$103,0)),(I2+4),IF(ISERROR(MATCH((I2+5),$C$33:$C$103,0)),(I2+5),IF(ISERROR(MATCH((I2+6),$C$33:$C$103,0)),(I2+6),"More than 6 days")))))))

    =>The whole idea is to match the difference between dates across the sheet to fit in (364 or 365 or 366) total days and Col "Days" between (28 to 32) such that each cycle average number of days is maintained close to 30.

    =>What formula can be set to fill dates in particular cell C33 onwards to achieve the above?

    Thanks and regards,
    Dev.

  9. Can i do such a formula: If value in column A has the letters CC at the beginning, then delete the CC?

    • Hi,
      Using a formula, you can display the value in another cell and remove extra characters:

      =IF(LEFT(A1,2)="CC",REPLACE(A1,1,2,""),A1)

      I hope my advice will help you solve your task.

      • Thank you so much Alex.
        Now how do i add to this formula that the last 3 letters should be removed as well?
        For example: if i have a list of the following
        CCGDR3M-1#1.
        CCG5M-05#2.
        CCGD34GM-11#5.
        and i want to remove the CC at the beginning and the #1. or the #2. or the #5. at the end (Note: i want to remove the . as well)

  10. How do I change a colum with (NO) to read (0) while Colum with (YES) to read (1),Column with (NOT RANGED) to read (-)

  11. Hi,

    I'm stuck with the following problem.

    I'm trying to work out loss and gain on a starting number so my formula is -

    =IF(C2<D2, "GAIN", "LOSS") and so on...

    However, It will always show "LOSS" in the cell when cell D2 is blank. I only want it to show LOSS if a number has been inputted in both cells. Would anyone know what I need to change for this?

  12. would it be possible to have two formulas in one cell

  13. how do i write a formula for
    if a value on a cell is less than or equal 3.99sf on a particular column it should always show and calculate as 4sf on my h column
    Reply

    Alexander Trifuntov (Ablebits.com Team) says:
    February 19, 2021 at 8:21 am

    Hello!
    If I got you right, the formula below will help you with your task:

    =IF(A1<4,4,A1)

    I hope this will help, otherwise please do not hesitate to contact me anytime.

    Hi
    Thank you for your response, it does work but i have assigned different formula already on cell, how can i apply your formula on an entire column, i tried this method and it doesnt work, by the way im doing all this on google sheet.

    • Hello!
      I wrote this formula based on the description you provided in your original comment. Explain what is not working. If you want to write 2 formulas in a cell, then this is not possible.

  14. how do i write a formula for
    if a value on a cell is less than or equal 3.99sf on a particular column it should always show and calculate as 4sf on my h column

    • Hello!
      If I got you right, the formula below will help you with your task:

      =IF(A1<4,4,A1)

      I hope this will help, otherwise please do not hesitate to contact me anytime.

  15. here is a digit X in B1. IFB1 80 it must be 80, otherwise x
    what is the formula? pls help

  16. Hi,

    I need help trying to create a formula that determines if the cell contains a numeric value or an alphanumeric value. If it is an alphanumeric value, leave it as is, but if it is a numeric value and letters. For example if 123456, then change to INV123456, and if INV123456 leave it alone.

    • Hi,
      Please check the formula below, it should work for you:

      =IF(ISNUMBER(--(A1)),"INV123456",A1)

      I hope I answered your question.

  17. Hi there
    I have what I believe a very simple comparison to make between two date columns:
    I want to compare column A2 and column B2 and have the formula tell me if A2 is less than B2.
    So far, what I'm using is giving me false results.
    I have tried:
    =A2<B2
    and also
    =IF (A2<B2,"Yes","No") but this also gave incorrect results.

    Example data:
    A2: 08/09/2020
    B2: 14/07/2020
    In this example the query about whether or not A2 is smaller than B2 should yield a "No" result but it is throwing out a "Yes" when it is clear that the A2 date is a greater date.

    My date format is DD/MM/YYYY.

    Can anybody help?

    • Hi all... please ignore my query! I've worked it out.

      Simply had to run Date - Text to Columns on my Date columns (already formatted as Date Format) in order to get the formula to compare the dates properly.

      Hope this helps someone else!

      cheers
      Kaz

      • Gah! Typo... that solution was:

        Data - Text to Columns (NOT Date - Text to Columns).

        Time to sign out!

        -Kaz

    • Hi,
      Check your dates. I think that cell B2 is written as text, not as a date. Maybe the date format of 14/07/2020 does not match your Windows date format. Maybe the correct format is 07/14/2020. Check the date and time settings in the Control Panel.

  18. Hello Alexander,
    If you are able to assist me with my request, it would be greatly appreciated. I am trying to have a cell be copied from sheet 1 to sheet 2 when an "if" value is met. For example:

    if a cell in the d column on sheet 1 reads "T", then I want the matching cell in e column to be copied to sheet 2.

    The context is, that when a task is Tabled (T), in my list of things done in that day (Sheet 1), then on the following sheet (Sheet 2), a list of future tasks will be created. As the task is completed, I would change the status on the original page, and the task would no longer be carried over to the corresponding cell on sheet 2 . This would assist me in organizing my weekly to-do list.

    Thank you for considering my request.
    M.Tucker

  19. THANKS
    USING YOUR IDEA I DONE MY FULL DAY WORK WITHIN 1 HOUR
    THANKYOU VERY MUCH

  20. Hi Alexander. I am blown away by the amount of answers you have addressed in this thread! Thank you for offering so much value out there...hoping that mine will be included ;-)

    I am trying to use an IF(ISNUMBER(SEARCH formula to perform a calculation based on whether a partial text match exists. I am wanting to pull the text from a cell and use that cell address in the formula to test for a partial match in another field. Otherwise I will be required to manually input the text multiple times throughout the formula. I'm having issues getting the formula to pull my text from a cell....for example:

    =IF(ISNUMBER(SEARCH("*b3*",B$15)), C$15, C$21) where the text I'm looking for is located in cell b3. Is there syntax that will accomplish this?

      • Thanks Alexander! That is so obvious now that I see it that I am embarrassed. I've tried it and it works perfectly. Thank you again for your quick, straightforward help!

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)