How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. Hi,
    If I select name from dropdown list in cell A1, automatically name of country of the person should display in A2 and his identification number should display in A3.
    Please help me for setting this formula in excel.

  2. I want to use the if function to populate a cell with 1 of 3 possible values. I have a start time and a finish time which gives a total time worked. I want to take the total time worked and if it is less than 5:30 hours worked then 0:00 break, 5:30 hours to 7 hours is 0:30 break and over 7 hours is 1 hour break. Help would be appreciated.

    • Hello!
      If I got you right, the formula below will help you with your task:

      =IF(TIME(7,0,0)>B1,TIME(1,0,0),IF(TIME(5,30,0)>B1,TIME(0,30,0),0))

  3. Hello,

    I was wondering if anyone could help me - I am stuck with figuring out a formula to calculate a commission sheet with percentage according to a job role.
    example:
    Person A - gets a commission value in cellA1 and B1 added together however Person B only gets 10% of value in Cell A.

    Can anyone help me figure this formula out? - I tried to make it sound a little like:
    If cell J5="Y" then cell J6 = A1+B1 or if cell J5="N" then J6=10%ofCellA1

  4. I need help with the following

    cell E14 has check box
    cell I14 has check box

    cell E4 has data
    cell F4 has data

    cell F14 is the cell I need filed with the correct data

    What I am trying to accomplish
    if cell E14=true and cell I14=true then fill cell F14 with data from cell E4
    if cell E14=true and cell I14=false then fill cell F14 with data from cell F4

    thanks for your time
    Jason

  5. Im trying to have a column in excel that uses 2 equations based off of a word that is placed in another column .

    for example if J5 says Suburban i want the equation in N5 to be M5*9/100 and show the answer to the equation but if J5 doesn't say this and says Mercedes i want the equation to be M5*11/100 and show the answer.

    Also how do you copy to function down the column so it is using the right line number.

    I thought that I had it but its not giving me the totals

    Thank you!

  6. Thank you so much it is working now

  7. In the above formula "OP" condtion is working fine...But in the "IP" when i enter in the cell 4 ,then it is showing "OUTSIDE".

    As per my condition for "IP" G25 then "OUTSIDE"

    Please support to solve this

  8. Thank you so much...i will check

    If Cell G2 contain text ,then how we can solve

  9. And with this i also need to add one more condition....if G2 cell not cotain number then will show "blank"

      • In this formula "OP" condtion is working fine...But in "IP" when i enter 4 ,it is showing "OUTSIDE".

        As per my codtion it should only when i enter 5

        • Please help how to solve thiscalculation...In "IP" G25 then "OUTSIDE".

  10. Kindly help to combine below formula together...Actually i need to put below formula in one cell

    =IF(AND(K2="OP",G2<4),"WITHIN TIME","OUTSIDE")
    =IF(AND(K2="IP",G2<5),"WITHIN TIME","OUTSIDE")

  11. Hello,

    I have to IF/Then statement of

    =IF(DH53=DI53,"matches", "doesn't match")

    Cell DH53 = 0.00 and DI= 0.00

    For some reason it's returning a Doesn't Match result but it does match. I have multiple that return back the Matches results but a few that return back the doesn't match result even though the two cells do match. Am I doing something wrong? I've tried reformatting all the cells so they are all the same format but nothing seems to change. Why would the IF/Then statement return back a false result if it is in fact true

    Thanks so much for your help!

    • Hello!
      Unfortunately, without seeing your data it is difficult to give you any advice. 1. Perhaps one of the values is written as text. 2. If these values are calculated by formulas, then they may differ in decimal places. For example, 0.0002 and 0.000008. In the cell, you will see 0.00. I recommend using the ROUND function in this case.

  12. I have a problem please help I'm very new to this, sorry.
    I want to show the result only if the full operation is done for example.
    K15 =C15*E15+F15 otherwise 0

  13. Hi!

    I'm looking for some help in using an IF statement to perform a math operation, I can’t seem to get it right:

    I have:
    Column A: Firm (either A, B, C, D or E)
    Column B: Measure (either sales, price, or promotional price)
    Column C: Product (a lot, but coded as numbers)
    Column D-FB: Value of measure per week (155 weeks in total)

    I want a cell to return: ((sales 1 * price 1) + (sales 2 * price 2)) / (sales 1 + sales 2)

    Where:
    Sales 1: sales of firm A for product 1
    Price 1: price of product 1 of firm A
    Sales 2: sales of firm A for product 2
    Price 2: price of product 2 of firm A

    Thus, firm is always A, but measure and product differ. Then, I would autofill the cell to the right (from column D to FB to create a new row). I would like to do the same for promotional price.

    I hope I explained it well enough and any help would be much appreciated! Thank you!

      • Thank you for your quick reply!

        For example:

        A1: Firm (header)
        A2: A
        A3: A
        A4: A
        A5: A

        B1: Measure (header)
        B2: Sales
        B3: Sales
        B4: Price
        B5: Price

        C1: Product (header)
        C2: 1
        C3: 1
        C4: 2
        C5: 2

        D1: Week 1 (header)
        D2: 1,670
        D3: 9,813
        D4: 1.42
        D5: 1.83

        E1: Week 2 (header)
        F1: Week 3 (header)
        etc.

        =IF((D2+D3);((D2*D4)+(D3*D5))/(D2+D3);0) results in 1.77

        This 1.77 is then the new combined price of product 1 and 2 for firm A for week 1.

        In this example, I’ve already filtered on the right firm, measure, and product, but I would like to make a function where I would only have to type in the firm and product and not manually select them as I’m doing now. So for D2 * D4 for example, only multiply cells if one cell is sales of product 1 for firm A and the other is price of product 1 for firm A.

        I hope this makes sense, thank you in advance!

        • Hello!
          I’m not sure I got you right. If your criteria are firm, measure, and product, then you can find the desired cell in column D using the INDEX + MATCH function, as described in the article "Excel INDEX MATCH with multiple criteria".
          The criteria for cell D2 are "A", "Sales", 1. For D4, "A", "Price", 1. And so on.
          I hope it’ll be helpful.

          • Yes, I've managed to create the formula with the use of index and match! Thank you very much for your help!

  14. Hi there! I'm looking for assistance with an IF Function.

    I'm looking to create a formula that produces a value IF the value falls between a set of dates.

    For example -

    Date - 05/01/2021
    Value - 600

    Start Date 1 - 01/01/2021
    End Date 1 - 30/01/2021

    Start Date 2 - 01/02/2021
    End Date 2 - 28/02/2021

    The formula should return only 600 as it falls in between Start and End Date 1. Ideally I'd want it to be able to calculate the total value from a List i.e.

    I.e. list of Dates from A5:A55, return value if between Start and End Date 1, Return 0 Value if not between Start and End Date 1

    Hope that makes sense?

  15. I need a formulas for if the cell has a Y then this other cell will enter $25.00 if not it is $0. Please help me. Thank you .

  16. =If(A2=0,"Closed",(IF(istext(AA2),"Closed","Active"),(IF(AA2=Cancel,"Canceled",AA2=OnHold, "OnHold")))

    My formula will not work. It works when I only put
    =If(A2=0,"Closed",(IF(istext(AA2),"Closed","Active")
    Or
    =IF(AA2=Cancel,"Canceled",AA2=OnHold, "OnHold")
    But I need them together to show the status of the reports if they were to fo on hold or be canceled.

    Any help would be appreciated

  17. Hi there, im trying to put together IF function formula and im struggling.

    It goes something like this,

    =IF(D41="Something1", "$1.000",
    IF(D41="something2", "$1.400",
    IF(D41="something3", "$1.000",
    IF(D41="something4", "$1.000",
    IF(D41="something5", "$1.800",
    IF(D41="something6", "$1.000",
    IF(D41="something7", "$1.400",
    IF(D41="something8", "$1.300",
    IF(D41="something9", "$1.000",)))))))))

    IS this even possible ? how many IFs is possible this way?
    This would really help me .
    thanks in andvance

  18. Really good blog,thank so much for your time in writing the posts.

  19. Really good blog,thank you very much for your time in writing the posts.

  20. Very good blog,thank so much for your time in writing the posts.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)