How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. I am trying to get the the IF function for this problem, I need to give each person a raise based on their yearly salary (column M) and team (Column G): Green Team 5%, the Red Team 7% and the Blue team 3.5%

    =If(G2="Green",M2*.50,IF(G2="Red",M2*70),IF(G2="Blue",M2*.35)))

    I don't know if its correct, but only on green condition displayed correctly. I am new to this, can you help me.

    • Hello!
      Please try the following formula:

      =IF(G2="Green",M2*0.5,IF(G2="Red",M2*70,IF(G2="Blue",M2*0.35,"")))

      Hope this is what you need.

      • Hi! I tried using the formula you've gave but the Red isn't appearing.

  2. Hi,

    I am trying to make a ledger and there for using the formula
    =+IF(D16-G16>0,"Balance is"=D16-G16,""NIL"")
    What i am trying to do is that if the answer to the query is positive then i want the outcome to be as "Balance is___" else "NIL"
    However there is some error in the formula that i am not able to know

  3. How to get DateValue to work text in following format "Wednesday, July 7, 2021 11:09 AM" inside string ?

    • Hello!
      You can convert text to date using the formula

      =--MID(A11,SEARCH(",",A1,1)+2,100)

      We have a tool that can solve your task in a couple of clicks - Text to Date tool.
      It is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and check how it works for free.

  4. i cannot do the addition and subtraction in one cell in Total.
    like - if c3>1 add and if c3<1 than it is 0

  5. I'm trying to use a logic function to get standard pricing calculation from one worksheet to another. I thought this would be done through =if(A2:A22 = !sheet1$A$2:$A$22, c2:C22). What am I thinking incorrectly on the logic side?

  6. Hi,

    Im trying to set up the following:
    =IF(FOTB!A3="PID: Sync Identity to network"; "=FOTB!C3"; "0")

    So I'm trying to accomplish that:
    When A3 on sheet FOTB equals the text PID: Sync Identity to network
    the value from cell C3 should get copied to the cell i'm pasting this formula in.

    The issue here is that excel just shows =FOTB!C3 instead of the value of the cell.

    How can I fix this?

    kind regards,

    Glenn

  7. I am trying to write a formula that if A1=number AND F1>=different number, then A1 turns red. I'm trying to track mileage of my fleet and when they are due for oil changes. A1 is the unit # and F1 is the current mileage. If F1 is greater than or equal to the oil change needed mileage, then A1 would turn red.

    Thanks.

  8. how do we add an extra number to an formula that already has a existing formula. And how do we add a common number to a series of cell having different formula

  9. Hi! I need your help. What I want to happen is every letter that i enter should the next cell must present a number. for example
    W=1
    H= 2
    I= 3
    T= 4
    E= 5

    But not just one letter.. If I want to type "WH" the next cell should present "12" since W=1 and H=2 or if I want to type "WHI" next cell should display "123". and if it is shuffled like "HIW" it should display as "231".

    Thank you very much

  10. Thank you for the info. Is it possible to put in the If function a range of cells ?
    On a column (A) I have a list of emails that I need to classify. In Column B I was hoping to have the valid emails displayed and on column C the invalid emails. I have the list of valid emails on another sheet (Valid emails).
    The way I wanted it to work is: if an email in column A is on the 'valid email sheet', then it should display said email on column B, if not, display "no". I started with the following formula but it only works for the one email.
    (in cell B2) => IF(B2='Valid email'!$A$2:$A$70;B2;"no") (range of emails in valid sheet is from A2 to A70)
    My problem is when I copy it down to the rest of the column it does not work and all values are "no".
    What should I add to the formula so it looks for the value in the other sheet and displays said email or displays no?
    Thank you very much!

    • Hello!
      Please try the following formula:

      =IF(ISNUMBER(MATCH(B2,$A$2:$A$70,0)),B2,"No")

      I hope this will help, otherwise please do not hesitate to contact me anytime.

  11. Hi, I'm trying to combine two functions, I have a requirement to contact customers every 6 months before they begin receiving our services and once a year after. I'm trying to get the function to identify the last date contacted, then based on if there is a Yes or No in column B2 return a Next Contact date either 6 months or 12 months in the future. This is the formula I'm working with but I can't seem to make it work... Any thoughts?
    =IF(B2='Yes',[EDATE(A2,S2)],[EDATE(A2,S3)])

    (S2 refers to the 6 months and S3 refers to the 12 they are just single cells with a 6 or 12.)

    Thanks!

    • Hello!
      I have not been able to verify your formula. It doesn't work for me. This formula will return TRUE if the date in column A is the most recent.

      =A1=MAX($A$1:$A$100)

      You can copy this formula down along the column.
      For me to be able to help you better, please specify which formula you mean and describe the problem in more detail.

      • I'm not looking for it to return anything. I'm looking for it to find a different solution based on what the column says, for example if the Date in A is 1/1/2020, if column B says YES I want it to Return A2+6months = 7/1/2020 in Column C and if column B says NO I want it to return 1/1/2020+12 months = 1/1/2021 in column C Then I'm going to set up conditional formatting to highlight the column based on the time out from the Column C information but that part of the spreadsheet is working well.

  12. ( A )
    (ROW 1) TIME IN 24:00
    (ROW 2) TIME OUT 8:00
    (ROW 3) HOURS WORKED 8:00
    I have row 1 and 2 formatted as [h]:mm and the following formula in Row 3:
    =IF(A2>A1,A2-A1,1-A1+A2)
    What I need is for the formula to return blank or 0 if no times are listed in Row 1 or 2, right now it returns 24 if cells are empty.

    Any assistance would be greatly appreciated, thank you

    • Hello!
      If I got you right, the formula below will help you with your task:

      =IF(OR(ISBLANK(A1),ISBLANK(A2)),"",IF(A2>A1,A2-A1,1-A1+A2))

      You can learn more about ISBLANK function in Excel in this article on our blog.

      • It worked, thank you so much, I was missing the "ISBLANK" for A2, much appreciated.

  13. Hi, I am impressed that someone is actively replying to comments. plz help, all I wanna know is a function for this sort of rule. If A:A has a text of "name", B:B should be on E1, then E1 will add all value from B that has "name" on it. idk if thats clear but im no expert. help

  14. hello alexander i need you help

    formula for fresh eggs order

    given:

    guest count = 3515 heads
    days = 1
    daily consumption of eggs per guest = 1.46 pcs
    eggs left before ordering = 300 pcs

    How many eggs i have to order given below using a formula in excel?
    Consider also that i still have 300 eggs left, see above

    guest = 751 heads
    days = 15
    daily consumption of eggs per guest = 1.46 pcs

    Thanks

  15. hi good people i am hoping to get a help from you all .... i want to pull out all the data with the same name in a new cell how can i used or what conditional if function to use please help thank you

  16. What's the syntax for the following?

    If A1=Yes, then display value from Column L , Column B.

  17. This is very useful website. This article is really helpful. Thank you so much for sharing this great knowledge

  18. I want to select out a subset from a list(rows) of purchases- columns have date price, article, buyer etc.
    I can make a column with "yes" or "No" which defines the rows I want, but now how do I select the whole row and copy onto new chart, or hide the rest?

    • Hello!
      To get a list of rows conditionally, I recommend using the FILTER function. You can get detailed instructions in this guide.
      I hope I answered your question. If something is still unclear, please feel free to ask.

  19. Hi,
    Could you guys please help me to clear this below issues.

    Cell A1 "APPROVED"
    Cell A2 "APPROVED"
    Cell A3 "APPROVED"

    If(Cell A1:A3="APPROVED", Cell A4="APPROVED", "NOT APPROVED").

    How i can solve this issue.

  20. Hi I really hope I can explain myself well. So basically, if a column contains a 'No' entry, then most of the columns that come after will have an 'N/A' entry. I'm trying to automate this but what I'm struggling to do is if the condition is false, then I don't want anything to happen to the cell (whatever entry in the cell should remain). For instance, If it's a 'No' then I want 'N/A' but if it's a 'Yes' then I'll have to put a date. But what happens is that when I create the formula for the first cell and tries to drag, it changes all my dates to blank which is not what I want. I want the dates to remain.

    Any help would be greatly appreciated, thanks

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)