How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4800 comments

  1. please help

    if a2 is >1 check if the date on b2 is > date on a1 and return yes if all statements are true no if false

  2. How do I do something like an IF with a random test and one of the outputs is the same random like this:

    =IF(random_number>0.5,same_random_number,0)

    I hope you know what I'm saying cause I don't.

    • Oh, wait I figured it out myself. Never mind.

      Thanks anyway!

  3. HI,

    I want to make a formula in which the value of A1 is less than or equal to 10, A2 will show "1" but if A1 is greater than 10 say 12 for example the excess 2 will multiplied to 0.5 then A2 will be 10+(X*0.5)/A1

    =IF(A1>=10,"10+0.5X"&FIXED(A1-10,0),1)

  4. Hi,
    i need a formula to do the following calculations:
    IF A2 and A3 are blank then to return blank but if there are values greater than zero to multiply A2*A3

  5. (auto result req)
    Packing sr no no of box
    D1 to D2 2
    D3 to d5 3
    D5 to D9 4
    as per above example i want auto sum in excel for packing sr no

  6. I need help with the below given formula. It has two sells to chose from. Cell AE5 is a date. The output required is taht if the date in AE% is lower than today then output cell should read "Note Due", However if the other cell that is AF5 is blank then output required is "Not Received" and if it is not blance the the output required is "Received"

    If the date criteia is satisfied then i do not want further output of "Not Received" or "Received"

    =IF(AND(AE5<TODAY(),"Not Due"),IF(AND(ISBLANK(AF5)),"Not Received","Received"))

    Requesting to please help.

    • Hello!
      If my understanding is correct, you can use this formula:

      =IF(AE5<TODAY(),"Not Due",IF(ISBLANK(AF5),"Not Received","Received"))

      • Dear Mr. Trifuntov,
        Thank you for your revert. You have made it amazingly simple. Sincerely appreciate. It fits well and resolves my query with exception to scenerio under option 4. The final formula i am using is:
        =IF(AE5>TODAY(),"Not Due",IF(ISBLANK(AF5),"Not Received","Received"))

        In the outputs below Amount is AD5 , Date due on is AE5, Received on is AF5 and output cell is the column marked Status that is AG5. Under option 4 we receive the amount before the due date. We wanted to give a preference that if the amount is received before due date then output should show "Received" instead of showing "Not Due". Would it be possible to incorporate such preference in the formula.

        Output 1
        Amount Date Status
        Due On Received On
        200,000 27-10-21 Not Received

        Output 2
        Amount Date Status
        Due On Received On
        200,000 27-10-21 28-10-21 Received

        Output 3
        Amount Date Status
        Due On Received On
        200,000 30-11-21 Not Due

        Output 4
        Amount Date Status
        Due On Received On
        200,000 30-11-21 29-10-21 Not Due

  7. Hi, i am trying to create an IF function that when you have typed "DONE", the exact date when the word was typed will be reflected on another cell. Whilst when "ONGOING" is typed, the date shown will be the date today, and will still continue only until the word DONE is typed. Thanks for the help.

  8. Hi,

    URGENT

    I am in urgent need to a formula to help me update a current file with new COGS and RRP pricing.

    But not all articles under a certain category need to be updated. So if I filtered original file to a specific category and did a VLOOKUP, will any data on not filtered rows change also if row numbers are not in running order and skips rows?

    Basically, I only want to update some articles with new data and retain existing data for those articles not on new data file.

    Thanking you.

    Chris

  9. what if I want to use VLOOKUP but the value is a specific word in the cell
    I mean the formula have to find text first and then make it value

  10. Hi, I am tracking 'aging overdue invoices', and I am creating an IF statement formula where it finds the total per days outstanding. My database output provides the days outstanding and many ROWS I get the text "NULL". All overdue days list correctly on second column with current formula. How can I insert the TEXT "NULL" on "column B" Aging Bucket when "Column A" reads NULL?

    Here is my current formula inserted on "Column "Aging Bucket" ROW "B2":

    =IF(A2>90,"91-120 Days Past Due ",IF(A2>60,"61-90 Days Past Due",IF(A2>15,"16-30 Days Past due",IF(A2>-0.1,"0-15 Days Past Due","0 Current"))))

    My current data output:

    Column A

    Days_Overdue
    NULL
    NULL
    280
    19

    Column B

    Aging Bucket
    181-365+ Days Past Due
    181-365+ Days Past Due
    181-365+ Days Past Due
    0-30 Current

  11. Hi

    Please could someone help me I am trying to create the following

    EX:
    If M2 is less or equal to 0.01-0.99 return the text in cell N2 "0"

    EX:

    iF M2 is less 12 return the N2 "12" and above 12, 13 14 is return N2 12,13,14.

  12. hi, i'd like to ask more about this

    How should I type if the value is between 1-200, it types 40%;
    201-300 type 15%;
    301-600 type 10%;
    601-900 type 5%

    Thank you

  13. Hi,
    I'm trying to find the right function to give me the following.
    For any price that is a full number, give me back 'reg price', ex. 5.00
    for any price ending with .98, give me back 'mkdn price', ex. 4.98.

    Can anyone help?
    Thanks,
    Alison

  14. Hello,

    I'm using an IF function so that if the ranking in table A is either 9, 10 or 11, we shall output the performance from another corresponding, yet separate table of data and leave blank if otherwise.

    The formula looks like:
    =IF(P166=9,AP166,"")&IF(P166=10,AP166,"")&IF(P166=11,AP166,"")

    This has worked to the point where the correct corresponding performance data has been outputted, however, these are in decimal format and it will not allow me to change these to a percentage format (despite allowing me to select the 'percentage option', nothing changes). Furthermore, I cannot alter the number of decimal points that the newly outputted data is displayed to.

    As the data is essentially the same, I thought this might not be too big of an issue. However, when I go to find the average of the 3 outputted performances, I get the error message:
    #DIV/0!
    Upon further digging, I found that when I go to simply sum up the three outputs, It gives me zero (when this shouldn't be the case).

    It's almost as if the IF function output isn't being recognised by excel despite being visible (and correct) on my screen.

    Any help is greatly appreciated, thanks!

  15. Hi, I'm trying to use an IF function with an email address.

    Example: =If(J3=123,name@domain.com,IF(j3=4567,anothername@domain.com,0))

    I've tried using " " around the email addresses, but nothing works.

    Thanks,

  16. Hello,

    I am unsure if this is possible though any assistance is appreciated.

    I have cell B2 with the value 4 (YVL)

    I am trying to write a formula that says IF(B2<10&" (YVL)","over","shift").

    Is this possible?

    Thank you in advance

    • Hello gain,

      Please ignore the above question. I tried a IF(COUNT(FIND formula and it seems to have worked.

      cheers,

  17. Hi, thank you for share all of functions above. This helped me a lot, ^^.

  18. Hi guys, i need help with something. I checked this text and cant find out if something like i need can be done in excel or not...

    For example, i have 12 values in dropdown menu in a cell (data validation) and i would like if i can set up something that when i change value from dropdown menu, excel can input predefined text (2 options only) in predetermined field.

    For example, if i select P-3340 from dropdown menu, i would like for excel to change cell below into From well.

    Can something like that be done? I actually dont need eny calculations, just that when i select something from dropdown menu, it changes next cell or two. I do a lot of repetitive reports and this would save a ton of time.

    • Hi!
      The drop-down list writes the selected value from this list to the cell.
      You cannot solve your problem using standard Excel tools.

  19. I'm trying to writ and IF statement that compares 2 cells with dates in them.

    IF( F4= A$1,B$1,M3)
    A1=a date pulled in via a VLOOKUP formula and is dynamic
    F4=09/15/2021
    F5=F4+1
    F6=F5+1
    ect.

    I tried the following:

    =IF(DATEVALUE(F4)=DATEVALUE(A$1),B$1,M3)

    But I got an Error, any suggestions?

    • Also tried =IF(DATEVALUE(9/15/2021)=DATEVALUE(E$4),K$4,L6)

    • Hello!
      The DATEVALUE function only works with dates that are written as text. You do have not a text in the F4 cell, but the date.
      Try formula

      =IF(F4=A$1,B$1,M3)

  20. Hi How about if example
    if 150.00 if the zero cents it will choose the cell d2
    if 150.50 then will choose the d4.

    How will i do that?

    Thank you

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)