How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. Hai Sir,

    i need a formula for Marks to percentage,

    if the percentage is below 1% mark is 5

    if the percentage is 1% to 3% mark is 10

    if the percentage above 3% to 5% mark is 15

    if the percentage above 5% mark is 20....

  2. I'm trying to come up with a formula that will input words, so if a number is below 30 it will say "within 30 days then if it's between 30-365 it will say "within 12 months and anything over 365 will be blank. so far I can do the first part but I'm not sure how to add another condition.

    =IF(E6<30, "within 30 days")

  3. I want to make a formula that goes something like this

    =if(value>blank(G3:L3 add 80 to M3)

    Sorry I'm a real novice in excel. :-(

    Hope somebody can help me out.

    \Lars

    • Hello!
      Please use the following formula:

      =IF(SUM(--(G3:L3<>""))=0,M3+80,0)
      or
      =IF(SUM(--(G3:L3=""))=6,M3+80,0)

      Hope this is what you need.

  4. hi, i am trying to do a formula where the following occurs

    if the balance is greater than 37500 (say 50,000) then the excess 12500 needs to be multiplied by 40% and the original 37500 needs to be multiplied by 20%

    if its less than 37500 then only that balance needs to be multiplied by 20%

    i have tried a few IF formulas but they only do part of the task

  5. How do i return a result to be good or bad from a list of numbers

  6. HI,
    can anyone help me to set a formula with data validate I have three conditions in my data validation list Present Absent and Paid Leave which is denoted With P, A, and PL, what I want when my leave balance is equal to zero and then I select PL then popup message appeared no leave balance

  7. A B C D
    TOTAY

    346 INV-0354 30/06/2021 18901.52 =+IF(TODAY-B346>90<180,D346,0)
    347 INV-0355 30/06/2021 1330.20
    348 INV-0356 30/06/2021 2861.50

    Please Help On This Function and suggest me correct formula

  8. I am Trying to Use the Value(Text) in Cell E to determine the the condition in cell I to read (Pass, Fail) based on the Value(numerical) in field G. Example. IF E = Gram, Eight, Quarter, Half and G Numerical Value fits a given field then I = Pass or Fail. The Value in E will Determine if the Value in G is True. The True/Pass parameters for G will be Gram >=1.08 ,=3.7, =7.27, =14.16, <=14.4. As long as Cell G Falls Between these ranges for the appropriate value in Cell E then Cell I should show Pass. IF outside these then Fail.

    • Hi!
      I’m sorry but your description doesn’t give me a complete understanding of your task.
      But conditions >=1.08 ,=3.7, =7.27, =14.16, <=14.4 cannot be met at the same time. I recommend leaving two conditions: >=1.08, <=14.4

  9. I want to write an if formula that if the cell has a number >0 to return a certain value, if the cell has text to return it as zero.

    Example I have a time card Monday = 8 , Tuesday= FO, Wednesday = 8, Thursday =8, Friday = 8. I am trying to say everyday the person works they get an extra 2 minutes of pay. currently I have multiple if functions stating =if cell >0, 2,0 but the cell with the FO text is getting the true statement.

  10. Hello,

    i need a formula, that says: IF =H3-J3>0, and iF =H3-J3<0,121 (then it is ok),
    but: IF =H3-J30,121 (then rise or lower the G3 cell so it can be in the parameters from 0 to 0,121).

    If this is possible.

    • Something is wrong. So i will send the question in 2 parts.

      1. part

      i need a formula, that says: IF =H3-J3>0, and iF =H3-J3<0,121 (then it is ok).

      • 2. part

        but: IF =H3-J30,121 (then rise or lower the G3 cell so it can be in the parameters from 0 to 0,121).

        • again it is not good...grrr

  11. i need a formula that if cell B3 is "A" then put the 5% in cell D3????????

  12. Hello,

    While creating a time sheet that will auto calculate an invoice amount I have tried the above, referencing the "IF formula to perform a math operation and return a result".

    My data comes from a drop down list. I want the particular cell to say "ok, if this cell says "client A", then do this math formula in this other cell". The problem is, each of the names in my drop down list corresponds to a different percentage rate to multiply the payrate by in order to get the bill rate..make sense? So if the worker had x hours working for client A I want to be able to choose client A from the drop down list, manually enter the pay rate for that employee, and then have the sheet calculate the OT pay rate, regular bill rate, OT bill rate and total it all at the bottom to show what the invoice should be. I have all of the other work done, I just cannot seem to get past this part, and I wonder if I am trying to get Excel to do too much with too little. Please help.

    Here is how I have entered the formula.

    Client A Client B Client C pay rate
    =IF(AND(OR('Dropdown Lists'!A30,'Dropdown Lists'!A34,'Dropdown Lists'!A50)), N17 + N17*45%)

    • Hello!
      You can automatically find and insert the interest rate for the selected customer into a cell using the VLOOKUP function, as described in this article.
      I hope this will help, otherwise please do not hesitate to contact me anytime.

  13. Hello,

    Is it possible to make a formula so that IF cell A is Province ( Ontario, Alberta, Yukon, Manitobia ....) then multiply cell B Number with cell C (2%,3%,9%.... ?

    basically trying to calculate taxes depending on province.

    • Hello!
      You can read recommendations on how to use a nested IF function in this article.

      =IF(A1="Ontario",B1*2%,IF(A1="Alberta",B1*3%,""))

      You can use the IFS function for multiple conditions:

      =IFS(A1="Ontario",B1*2%,A1="Alberta",B1*3%)

      If the province's list and percentages are in columns D and E, you can find the percentage you want using the VLOOKUP function:

      =B1*VLOOKUP(A1,D1:E10,2,0)

      I hope it’ll be helpful.

  14. Hello,

    Is it possible to use a formula that says if CO or CM then 8?
    I'm keeping a score at work with my coworkers and how many days they've worked and how many days they've had pto (CO) or medical (CM). i need the formula to work for 30-31 entries per persona (the days of the month) and i need something when i put cm or co in the table to return 8 back as in hours not worked. is it possible? am i making any sense?

    • Oh. Forgot to mention. As i have 31 columns in a row, if there are more than 1 CO to sum them up. for example if i have 3 CO then the answer given should be 24. is it possible?

        • Thank you so much! I managed to make it work. You're awesome!

  15. Forecasting spreadsheet: There are start and end dates for each project. I want the corresponding dated cells to color fill based on if they fall between the start and end dates. If I change the date, I want it to automatically change the fill. No fill if outside of dates. Ex: Start 2/25/2021 End 8/30/2021. Cells dated 2/25/2021 to 8/30/2021 will be filled. If I change date, it will change fill.

    =IF($K39="TBD",2,IF(AND($L39=AH$1),IF($G39="OH",1,5),0))

  16. I'm trying to write a formula where if b4 is $14000 and is greater than c4 which is $10000 then the amount in c4 ($10000) needs to be displayed in d4. Could you please offer some assistance.

    Thank you

    • Hi!
      The formula for your conditions may look like this:

      =IF(B4>14000,C4,"")

      If B4> 14000, then B4 will always be greater than C4, where 10000 is written. Therefore, the second condition does not make sense.
      You can learn more about IF function with multiple conditions in this article.

  17. I want the formula such that value_if_false wouldn't affect other cells when I drag the formula dowwards

  18. Hi,

    I need help in Excel cell. I want a result from 2 conditions. if the cell i type 5 the answer is 100 and if i type 10 the anwer is 300 on the same cell. how to do using IF or other formula?

    • Hello!
      If I understand correctly, you want to write both the value and the formula in one cell. It's impossible. You need to use a VBA macro. If the formula and the value 5 or 10 are in different cells, use a nested IF function.

  19. Is it possible to get substracted value with suffix/test.
    to be precise,
    i want to get the following,

    10:00 PM-04:00 PM=06:00 hrs
    after subtraction i get 06:00, but not with hrs. I want to get with hrs "suffix".
    thanks

  20. I want to do the following work with IF function,
    If(A2=A-620,"Bose",""); can i do it.
    here A-620 is Mr. Bose's ID number.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)