How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. Hi Guys i need Help,

    i have multiple cells around 1000+ contain dates and some blank.
    i already set condition if cell is blank it will change cell color otherwise white (if date is inserted).
    how can i set formula to give percentage of used cells (contain dates) vs blank cells? if it possible to formulate by cell color or by cell content?

    appreciate assistance!

  2. Hi !
    I am trying to write a formula where the cell (sheet 2, A3 should return true (=value of sheet 1, A3) if the value of C3 on sheet 1 is equal to "Option1" OR "Option2".
    If TRUE, 'Sheet2'A3 should get the same value as 'Sheet1'A3. If FALSE, it should stay empty.

    Writing the formula for only 1 text option worked. It looked like this in cell A3 on sheet 2: =IF('Sheet1'!C3="Option1";'Sheet1'!A3;"")
    Now I would like to have 2 TRUE options for 'Sheet1'!C3: "Option1"OR "Option2". How could I make this work? The following formula did not work :
    =IF(OR('Sheet1'!C3="Option1",'Sheet1'!C3="Option2") ;'Sheet1'!A3;"")

    Thanks in advance!
    Best, Veere

    • Hello!
      Your explanation is not very clear to me. Explain what's not working in your formula. What result do you get and what result would you like to get?

      • Hello,

        The message that pops up when I try to run the formula for multiple options ( =IF(OR('Sheet1'!C3="Option1",'Sheet1'!C3="Option2") ;'Sheet1'!A3;"") ) is the following:

        "There's a problem with this formula, Not trying to type a formula When the first character is an equal ("=") or ("-") sign, Excel thinks it's a formula. "

        I use "=" before the formula and I have checked the # of brackets, "" etc. I do have to mention that the options (here "Option1" and "Option2") come from a picklist. I have checked whether spelling mistakes or absence of the option in the picklist might me the problem, but that is not the case.

        The results that I would like to get in this formula would be as follows:

        - scenario 1 (TRUE): option 1 (a specific department of the company) is chosen in the picklist in 'Sheet1'!C3 --> then 'Sheet2'!A3 should contain the same value as in 'Sheet1'!A3 (which would be someones name)

        - scenario 2 (TRUE): option 2 (another specific department of the company) is chosen in the picklist in 'Sheet1'!C3 --> then 'Sheet2'!A3 should contain the same value as in 'Sheet1'!A3 (someones name)

        - scenario 3 (FALSE): another option (another department) is chosen from the picklist in 'Sheet1'!C3 (neither option 1 or 2) --> then 'Sheet2'!A3 should stay empty.

        I hope this information helps!

        • Hi!
          You use both a comma and a semicolon as an argument separator in a formula. Use one of these depending on your local settings. For Europe, this is most often a semicolon.

          =IF(OR(‘Sheet1′!C3=”Option1″;’Sheet1′!C3=”Option2″) ;’Sheet1’!A3;””)

          I hope my advice will help you solve your task.

      • Hello,

        When I try this formula

        =IF(OR('Sheet1'!C3="Option1",'Sheet1'!C3="Option2") ;'Sheet1'!A3;"")

        I get the following message: "There's a problem with this formula. Not trying to type a formula?When the first character is an equal (=) or minus (-) sign, Excel thinks it's a formula "

        I have checked the brackets, "", = signs and the spelling of the options in the formula (here shown as "Option1" and "Option2") and these should not be the problem.

        The result that I would like to get:

        - scenario 1: When in 'Sheet1'!C3 the option 1 (a specific company dept.) is chosen (TRUE), the cell selected in Sheet 2 should show the same value as in 'Sheet1'!A3 (the person's name).
        - scenario 2: When in 'Sheet1'!C3 the option 2 (another specific company dept.) is chosen (TRUE), the cell selected in Sheet 2 should show the same value as in 'Sheet1'!A3 (the person's name).
        - scenario 3: When in 'Sheet1'!C3 another option is chosen (neither option 1 or 2)
        (FALSE), the cell selected in Sheet 2 should stay empty ("")

        The main problem is in getting a second option in the formula. Using only 1 option gives the result that I am looking for.
        I hope this helps understanding my struggle. Thank you for your help!

        • Sorry, a double message! Thank you so much for your help! It works now!

        • Hi!
          You are repeating the same mistake. Look closely at the formula that I wrote. Please read my answer carefully. Use only commas or only semicolons as separators. I can't know your local settings.

  3. I am trying to create a formula that creates a pass / fail result from a column of Yes, No, N/A results. Can anyone help me please? Thanks

  4. Hi

    Can you help me with this......

    Only If A1 and B1 are both NOT empty, than these 2 column(A1 & B1) should be highlighted.

  5. Hello, I am attempting to write

    =IF(ISNUMBER(SEARCH("(NAME)",C2)), "NAME", "N/A")

    Where Cell C2 has the following text:
    Circle (White)

    And the new Cell with the formula will read:
    White

    D2 might have:
    Square (Blue)

    New Cell D3 reads:
    Blue

    But I can't figure out how to write the formula correctly where it understands that the value_if_true is equal to the value within the parenthesis of the search.

  6. 10000 to 10999 need value 1
    20000 to 20999 need value 2
    Same way what is the formula plz tell

  7. Hi
    I have two columns with dates A & B i need to pull the date from B to column C ,if there is no date in B then i need to pull the date from A to C can you please tell me what formula is required for this query

  8. I've multiple argument for If function, what's the ideal way for combining such arguments. In which way I've to separated them. I tried comma, or, and an semi comma but not succeeded. See here is how I did the formula. I've report with column showing different types and part of these types amount should be with credit value. I selected all types I want with credit and belt my formula and whatever other than these types will be debit values.

    =IF(H5="ZG2";"ZGS";"ZIG";"ZRE";"ZIR";"ZS1";"ZS3";"ZVS",AJ5*-1,AJ5*1)

    I did each one separately through formula wizard but it's adding them as it add plus sign between each argument.
    =IF(AJ3="ZG2",AJ3*-1,AJ3*1)+IF(AJ3="ZGS",AJ3*-1,AJ3*1)+IF(AJ3="ZIG",AJ3*-1,AJ3*1)+IF(AJ3="ZRE",AJ3*-1,AJ3*1)+IF(AJ3="ZIR",AJ3*-1,AJ3*1)+IF(AJ3="ZS1",AJ3*-1,AJ3*1)+IF(AJ3="ZS3",AJ3*-1,AJ3*1)+IF(AJ3="ZVS",AJ3*-1,AJ3*1)

    What's the correct way for building such IF formula?!

    • Hello!
      If I understand your task correctly, the following formula should work for you:

      =IF(SUM(--(H5={”ZG2″;”ZGS”;”ZIG”;”ZRE”;”ZIR”;”ZS1″;”ZS3″;”ZVS”})),AJ5*-1,AJ5*1)

      If at least one match is found, the SUM function will return 1, then set to TRUE.

  9. Hi,

    What is the best way to attack this. I have a list of how much was spent and then the corresponding company name next to it. I want to sum all the values together if they were spent at the same company. For example, I may have Apple $233.00 and below that Apple $54.80. I need a systematic method to sort this so that Apple total =233+54.80. Although this is only two values, the spreadsheet has hundreds of different expenses for the same company and it wouldn't be efficient to go through individually and sort manually.

    Thank you in advance,

  10. Hello, How to make a condition through this?
    IF $1-$9: A2 +2000
    $10-$19: A2 +2500
    $20-$29: A2+3000
    $30-$39: A2+3500
    $40 and up: A2+4000

    Thank you in advance!

  11. Halo Sir,I have a Question,
    My problem is i have 5 type of item list in Colum "A1" And It will calculate item price base on "item type- price discount=Answer" that will be display in colum "N1",and i want to make colum N1 Automatically change base on "A1" item type

    • Hi!
      I’m sorry but your description doesn’t give me a complete understanding of your task. Correct me if I’m wrong, you can find the right discount for each item type using the VLOOKUP function. Then multiply the price with this discount.
      I hope it’ll be helpful. If this is not what you wanted, please describe the problem in more detail.

  12. What is the formula for A1=1 & A2= 1 want to display "name"

  13. I Need a Rank formula where 1 column needs to be greater than 10 as well as other column needs to show "Advisor" for me to find top 5 and bottom 5. Thanks

  14. Hi,
    I want to right an Excel formula for the following problem :
    I have stored two different columns of figures, and I would like for a certain cell that Excel check when the value corresponds to a figure in the first column and shows the corresponding figure existing in the second column.
    Hope I'm clear enough ? Beg your pardon I'm requiring assistance from France.
    Thanks for your help.
    Rgds.
    Didier

  15. Hi Alex,
    what formula should be used if I have a specific requirements to the first and last 3 digits of the cell at the same time: for instance, if starts and ends with 3 specific letters then false.
    Starts with either ABC, or BCD, or CDE and ends with either ABC, or BCD, or CDE, then false.
    thank you!

      • Awesome, Alex! thank you for you prompt response. It works as required. Really appreciate it.

  16. Hi, I would like excel to recognize the same number in a column, so for example I have store numbers in columns that has several rows, each row is an employee. and we record several things per employee. I would like excel to change the colour of the store number when all employees have completed a particular task. Can i do this with an IF function in conditional formatting? if so, which if function? thanks!

  17. Can an Excel formula be created for this situation?

    If Field B12 contains a time
    Then Field C12 must have a number entered

  18. I'm trying to create a formula. if cells E2 and F2 have "Text" in both then divide by 2. If cell E2 has "Text" but F2 doesn't, divide by 1.

  19. In cell A2, type "Starting interest rate"; in B2, enter 4.25%—you must reference this cell in your adjustment calculations
    If the loan amount is over $400,000 subtract 1.00 percentage point (meaning that the Effective Interest Rate would be 3.25%)
    If the loan amount is equal to or under $400,000 and over $175,000 and 20 or fewer years subtract 0.50 percentage points
    If the loan amount is equal to or under $100,000 add 0.25 percentage points

    What If Function in excel should be used if the loan amount is equal to or under $400,000 and over $175,000 and 20 or fewer years subtract 0.50 percentage points?-- I am stuck in this part.

  20. i want to write an If-Then formula in Excel so when the date in B2 is => today the contents in cell E5 is deleted.

    • Hi!
      An Excel formula can only change the value of the cell in which it is written. It cannot change the value of any other cells. To do this, you can use a VBA macro.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)