by In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.
IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.
In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.
IF function in Excel
IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.
The syntax of the IF function is as follows:
As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.
Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.
Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.
Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.
Basic IF formula in Excel
To create a simple If then statement in Excel, this is what you need to do:
- For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
- For value_if_true, specify what to return when the logical test evaluates to TRUE.
- For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.
As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:
=IF(B2>80, "Good", "Bad")
This formula goes to C2, and then is copied down through C7:
In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:
=IF(B2>80, "Good", "")
This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise:
Excel If then formula: things to know
Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.
If value_if_true is omitted
If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:
=IF(B2>80, , "Bad")
To return a blank cell instead, supply an empty string ("") for the second parameter, like this:
=IF(B2>80, "", "Bad")
The screenshot below demonstrates the difference:
If value_if_false is omitted
Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.
If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:
=IF(B2>80, "Good")
Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:
=IF(B2>80, "Good",)
The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:
=IF(B2>80, "Good", "")
Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.
Using IF function in Excel - formula examples
Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.
Excel IF function with numbers
To build an IF statement for numbers, use logical operators such as:
- Equal to (=)
- Not equal to (<>)
- Greater than (>)
- Greater than or equal to (>=)
- Less than (<)
- Less than or equal to (<=)
Above, you have already seen an example of such a formula that checks if a number is greater than a given number.
And here's a formula that checks if a cell contains a negative number:
=IF(B2<0, "Invalid", "")
For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell.
Excel IF function with text
Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.
For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:
=IF(B2="delivered", "No", "Yes")
Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise.
Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:
=IF(C2<>"delivered", "Yes", "No")
Notes:
- When using text values for IF's parameters, remember to always enclose them in double quotes.
- Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".
Case-sensitive IF statement for text values
To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.
For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:
=IF(EXACT(B2,"DELIVERED"), "No", "Yes")
If cell contains partial text
In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.
A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).
For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:
=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes")
For more information, please see:
Excel IF statement with dates
At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.
For example, here's how you can check if a given date is greater than another date:
=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")
This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date.
Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:
=IF(B2>$E$2, "Coming soon", "Completed")
To compare a date with the current date, use the TODAY() function. For example:
=IF(B2>TODAY(), "Coming soon", "Completed")
Excel IF statement for blanks and non-blanks
If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:
- Use the IF function together with ISBLANK, or
- Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).
The table below explains the difference between these two approaches with formula examples.
| Logical test | Description | Formula Example | |
| Blank cells | ="" |
Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string. Otherwise, evaluates to FALSE. |
=IF(A1="", 0, 1)
Returns 0 if A1 is visually blank. Otherwise returns 1. If A1 contains an empty string (""), the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings. Otherwise, evaluates to FALSE. |
=IF( Returns 0 if A1 is absolutely empty, 1 otherwise. If A1 contains an empty string (""), the formula returns 1. |
|
| Non-blank cells | <>"" | Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered blank. |
=IF( Returns 1 if A1 is non-blank; 0 otherwise. If A1 contains an empty string, the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered non-blank. |
=IF( Works the same as the above formula, but returns 1 if A1 contains an empty string. |
And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:
=IF(B2="", "", "Completed")
=IF(ISBLANK(B2), "", "Completed")
=IF($B2<>"", "Completed", "")
=IF(ISBLANK($B2)=FALSE, "Completed", "")
In case the tested cells have no zero-length strings, all the formulas will return exactly the same results:
Check if two cells are the same
To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:
=IF(B2=C2, "Same score", "")
To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.
For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:
=IF(EXACT(A2, B2), "Match", "Don't match")
IF then formula to run another formula
In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.
For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:
=IF(B2>80, B2*7%, B2*3%)
Multiple IF statements in Excel
In essence, there are two ways to write multiple IF statements in Excel:
- Nesting several IF functions one into another
- Using the AND or OR function in the logical test
Nested IF statement
Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.
Assume your goal is to assign different bonuses based on the score:
- Over 90 - 10%
- 90 to 81 - 7%
- 80 to 70 - 5%
- Less than 70 - 3%
To accomplish the task, you write 3 separate IF functions and nest them one into another like this:
=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%)))
For more formula examples, please see:
Excel IF statement with multiple conditions
To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:
For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:
=IF(AND(B2>80, C2>80), "Pass", "Fail")
To get "Pass" if either score is higher than 80, the formula is:
=IF(OR(B2>80, C2>80), "Pass", "Fail")
For full details, please visit:
If error in Excel
Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.
And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.
For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:
=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" )
For more information, please see IF ISERROR formula in Excel.
Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!
Practice workbook
Excel IF statement - formula examples (.xlsx file)
4800 comments
hi alex!, how are you, hope your doing fine, i have problem on my simple IF condition, i want to display the actual time upon updating a transaction but every rows that i updated it will give me the same time result. I've used the below condition and i hope you can share to me the correct formula.
=If(A1"",now(),"")
=If(A1"",now(),"") (not equal to blank)
Hi!
If I understand correctly, you want to get an unchangeable timestamp.
To prevent your date from automatically changing, you can use several methods:
1. Use Shortcuts to insert the current date and time
2. Use the recommendations from this article in our blog.
3. Replace the date and time returned by the TODAY function with their values. Copy the date (CTRL + C), then paste only the values using Paste Special or Shortcut CTRL + ALT + V.
Hi. How do I format my IF formula to return a numerical value instead of text? I need to sum all the values that are generated from my IF formula, but because the formula returns the values as "text" and not a "number" I cannot use my sum formula. Please advise. Thank you.
Hello!
I read some articles but still cant find my answer. I want to kind of like create a data base for C where we have "example1,example2,example3 etc."
when example1 is written in C add number 15 in L
when example3 is written n C add number 30 in L
Is there a way I can do that? Thank you for your time!
Hi!
Use Excel Nested IF statements. Follow the link for detailed explanations and examples.
I have data in column F and data in column U, with dates in column S. I'm trying to have the date in column S copy to another cell on another workbook, if exact matches are found for columns F and U on the same row.
Hello!
You use two criteria to search for a value. You can find examples and explanations in this article: Excel INDEX MATCH with multiple criteria - formula examples.
I hope I answered your question. If something is still unclear, please feel free to ask.
I am trying to have an excel report something as below for "Overall Status" for each username (e.,g User1). I would like to create condition to track the overall status in which even if one of the Status is "Not Completed", mark it as "Not Completed" for each username grouped (e.,g User1). Appreciate if you could provide some inputs on this.
UserName App Status Overall Status
User1 App1 Completed Not Completed
User1 App2 Not Completed
User1 App3 Completed
User1 App4 Not Completed
User1 App5 Completed
User2 App1 Completed Not Completed
User2 App2 Completed
User2 App3 Not Completed
User2 App4 Completed
User3 App1 Completed Completed
User3 App2 Completed
Hello!
To count cells by multiple criteria, use the COUNTIFS function. The answer to your question can be found in this article: How to use Excel COUNTIFS and COUNTIF with multiple criteria.
You can use this formula:
=IF(COUNTIFS($A$2:$A$20,A2,$C$2:$C$20,"Not Completed")=0, "Completed", "Not Completed")
I am trying to use IF, AND, INT functions to go about answering the question:
; I free sweet for every dozen after the first 2 dozens. I can calculate ,say for 36 but what about for 48, 60. What should the formula be in the same cell please?
Hi!
To find out the number of dozens, you can use the INT function.
=INT(A1/12)
Hello - the nested IF and other topics above appear to be insufficient in what should otherwise be a fairly straightforward process. I am simply trying to nest multiple IF statements with multiple conditions (though technically not necessary) to add qualitative descriptors/labels based on the z-score in another column. I can manage this basic process in R but need to use an Excel spreadsheet for this current task. I have tried several versions, beginning with the simplest form, and continue to confront error messages, with the below syntax being the most recent attempt:
=IF(AND(H6>=2.00, H6=1.34, H6=0.68, H6=-0.67, H6=-1.33, H6=-2.25, H6=-2.32, H6=-2.49, H6=-2.60, H6<-2.49), “Severely Impaired”, IF(H6<-2.60, “Profoundly Impaired”, “UNK”))))))))))
Any assistance would be appreciated. If there is an easier route, that is fine as well.
For some reason, the syntax did not post properly (excluded commands). I shall try again here:
=IF(AND(H6>=2.00, H6=1.34, H6=0.68, H6=-0.67, H6=-1.33, H6=-2.25, H6=-2.32, H6=-2.49, H6=-2.60, H6<-2.49), “Severely Impaired”, IF(H6<-2.60, “Profoundly Impaired”, “UNK”))))))))))
I give up. It excludes my IF(AND() commands and several "LABELS" upon posting. The post itself is nonsensical. I would check your code.
Hi!
The formula is written incorrectly. Also, the conditions in the AND function cannot be met at the same time. I recommend reading the manual - IF AND in Excel: nested formula, multiple statements.
=IF(AND(H6>=2,H6=1.34,H6=0.68,H6=-0.67,H6=-1.33,H6=-2.25,H6=-2.32,H6=-2.49,H6=-2.6,H6<-2.49),"Severely Impaired",IF(H6<-2.6,"Profoundly Impaired","UNK")) I can assume that you need to use an IF OR expression. Read: Excel IF OR statement with formula examples.
If K9 has the value, {"date_of_birth":"11/08/1995",category":"bank","last_name":"Singh","first_name":"Digant"} and want to only display the the value of date of birth in another cell, how do I do that?
Hi!
To extract a string from text, use the MID function.
You can use this formula:
=IF(K9<>"",MID(K9,19,10),"")
Hi, Hope you are fine, I have some lengthy records in excel, some columns value depend on previous column values, for example if A1 has a value no problem quiet it, if A1 was empty go to H1 column, How to do this in excel,Please.
Kind regard.
Abdul Wahab
Hi!
I kindly ask you to have a closer look at the article above. Your question is not very clear, but the formula could be something like this:
=IF(A1<>"",A1,H1)
Hello Alexander,
I am trying to copy some data from one workbook (sheet 1) to another (Sheet 2).
My situation is as follows-
I want IF formula to check cell X1 in Sheet 1 and if it is >0, then
copy cell Sheet 1(B1,C1, D1 and E1) to Sheet 2(A1,B1, C1 and D1)
Else, Simply skip to another row and check the cell X2 and so on and so forth until it has checked all cells in the Column X
Hi!
An Excel formula can only change the value in one cell in which it is written. Create a separate IF formula for each cell. How to create a reference to another worksheet, read this guide.
NO. Start Date End Date Total Days (Free Day) Chargeable Days (1 up to 3 Days) (4 up to 6 Days) (7 up to 9 Days) (10 Days) (11 Days)
1 01-Mar-22 12-Mar-22 12 1 11 880 USD 3300USD 4400USD 5500 5500
how calculate all days in one cell (Total Charges Days Fees)
If we 2 wheel of Wagon:
(1 up to 3 Days) 400 USD = 880$,
(4 up to 6 Days) 1200 USD with 25% = 1500$
(7 up to 9 Days) 1600 USD with 25% = 2000$
(10 Days) 2000 USD with 25% = 2500$
(11 Days) 2000 USD with 25% = 2500$
(12 Days) 2000 USD with 25% = 2500$
12 Days Total = 8900$
If we 4 wheel of Wagon:
(1 up to 3 Days) 880 USD = 880$,
(4 up to 6 Days) 2640 USD with 25% = 3300$
(7 up to 9 Days) 3520 USD with 25% = 4400$
(10 Days) 4400 USD with 25% = 5500$
(11 Days) 4400 USD with 25% = 5500$
(12 Days) 4400 USD with 25% = 5500$
12 Days Total = 19580$
My question and problem?
- When I select 2 wheels with Dum tract then adding 25% if we select 4 Wheels with Taxi not adding 25%
Hi!
Look for the example formulas here: Excel Nested IF statement: examples, best practices and alternatives.
Hi,
Can you see what I have done wrong with this formula, the first IF for single works, but Double and Unequal Double keep showing 0 as the answer?
=IF(E10="Single",1,IF(E10="Double",2,IF(E10="Unequal Double",2,)))
Shane
Hi!
The formula returns 2. Unfortunately, I couldn't see your problem in my workbook.
Hi sorry I should have said that E10 is a drop down box, the formula works if I select another cell and manually enter the works
shane
Hi, I have a very bizarre issue with the IF function. I am trying to return two different texts alternatively based on two pairs of criteria from two different cells. In clear, I have 3 columns H, AN and AO.
So, if, say, H30 is blank and AN30 is also blank, then I want AO30 to return "Open".
Then, if H30 has a date and AN30 is blank, then I want AO30 to return "Ongoing".
Then, if H30 has a date and AN30 also has a date, then I want AO30 to return "Closed".
Anyone can help, pleaseÉ
Hi!
Look for the example formulas here: IF AND in Excel: nested formula, multiple statements, and more.
The formula might look like this:
=IF(AND(H3="",N3=""),"Open", IF(AND(H3"",N3=""),"Ongoing", IF(AND(H3"",N3""),"Closed","")))
I have been trying to create a formula using IF_OR to return if an exam score (across 3 exams) is equivalent to a status (Y) if the score of one of the exams is >=70.
However, a student may have earned a grade of E (Excused) due to policies in place because of COVID.
If any one of the 3 exam scores is >=70, Y should be returned, even if there is an E in one or 2 of the other exams.
If the cells have one, 2, or 3 E's, the 3 cells are blank, or have a combination of E's and grades less than 70, the resulting status should be "N".
The formula I have written for the STATUS column (Illustration below) is =IF(OR(L2>=70,M2>=70,N2>=70),"Y","N")
Problem is...If all cells are blank, it returns N (Correctly).
If I place ANYTHING into any or all of the cells (numeric grade, E, or any other text), Y is returned.
Here is a visual:
Row Column K Column L Column M Column N
1 STATUS Exam 1 Exam 2 Exam 3
2 E
3 75 E
4 E 79 47
5 61 72 E
6
7 E E E
Any help would be greatly appreciated.
Hello!
Use the ISNUMBER function to check if a cell contains a number.
=IF(OR(AND(ISNUMBER(L2),L2>=70), AND(ISNUMBER(M2),M2>=70), AND(ISNUMBER(N2),N2>=70)),"Y","N")
I hope my advice will help you solve your task.
Fantastic!
That solved it!
Thank you so much!
Hello,
Well done Sir!
I have a little challenge, I am using Window 16 version computer,
I am working on student's scores of ten students who sat for Test 1. The grading scale was given as below.
80-100=D1
75-79=D2
70-74=C3
60-69=C4
55-59=C5
50-54=C6
45-49=P7
40-44=P8
00-39=F9
This is the formula I have applied to workout the solution
=IF(B2>=80,"D1",IF(B2>=75,"D2",IF(B2>=70,"C3",IF(B2>=60,"C4",IF(B2>=55,"C5",IF(B2>=50,"C6",IF(B2>=45,"P7",IF(B2>=40,"P8","P9") I closed nine brackets. But result failed to reach arguments needed.
What could have been my mistake.
Hello!
Please try the following formula:
=IF(B2>=80,"D1",IF(B2>=75,"D2", IF(B2>=70,"C3",IF(B2>=60,"C4", IF(B2>=55,"C5",IF(B2>=50,"C6", IF(B2>=45,"P7",IF(B2>=40,"P8","P9"))))))))
Hello!
I need a formula that compares text from column 1 and 2, then outputs text in column 3.
For example, column 1 I can select text from a list (text="High, Medium, or Low"), I can do the same in column 2. In column 3 I need it to output text="". If the values were Low and High then output would be Medium, low and low would output low, etc.
Can you help?
Hello!
Look for the example formulas here: IF AND in Excel- nested formula, multiple statements, and more.
The formula might look like this:
=IF(AND(A1="Low",B1="High"),"Medium", IF(AND(A1="Low",B1="Low"),"Low",""))
I would like the results of a formula to be TRUE if the value in cell A1 is the same as the value in cell B1, and FALSE if the values are different.
What character or characters should be entered in the blank space below to give the desired formula?
A1 ____ B1
Hi!
Please re-check the article above since it covers your case.
Sir ,
1.Form attendance register when a employee takes leave in a month how to get only that particular date .eg if AA take leave on 3-Aug, then on 13-Aug, how to extract only the date based on the text entered as CL on that particular day.
Hi!
The information you provided is not enough to understand your case and give you any advice.
Dear Sir/Madam,
Hot write If formula for contunation series auto fill in excel below for series
FT20240001
FT20240002
FT20240003
Hello!
If you want to create a sequence, use this instruction: SEQUENCE function - create a number series automatically.
Here is an example that will work for you.
Hello,
I am trying to have one tab recoginize when a number is scanned in that number equals the name on the master tab.
Example:
Master Tab column A starts with 100001 and that number belongs to Raelyn
Attendance Tab column A is a date/time stamp, column B is controled by a scanner that enters the number of the bar code (100001) I would like column C to enter in the name (Raelyn)
Is this a IF function?
Hello!
If you need to search for a value in another worksheet and extract the corresponding data, use this instruction: How to Vlookup from another sheet in Excel.
I hope my advice will help you solve your task.