by In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.
IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.
In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.
IF function in Excel
IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.
The syntax of the IF function is as follows:
As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.
Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.
Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.
Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.
Basic IF formula in Excel
To create a simple If then statement in Excel, this is what you need to do:
- For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
- For value_if_true, specify what to return when the logical test evaluates to TRUE.
- For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.
As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:
=IF(B2>80, "Good", "Bad")
This formula goes to C2, and then is copied down through C7:
In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:
=IF(B2>80, "Good", "")
This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise:
Excel If then formula: things to know
Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.
If value_if_true is omitted
If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:
=IF(B2>80, , "Bad")
To return a blank cell instead, supply an empty string ("") for the second parameter, like this:
=IF(B2>80, "", "Bad")
The screenshot below demonstrates the difference:
If value_if_false is omitted
Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.
If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:
=IF(B2>80, "Good")
Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:
=IF(B2>80, "Good",)
The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:
=IF(B2>80, "Good", "")
Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.
Using IF function in Excel - formula examples
Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.
Excel IF function with numbers
To build an IF statement for numbers, use logical operators such as:
- Equal to (=)
- Not equal to (<>)
- Greater than (>)
- Greater than or equal to (>=)
- Less than (<)
- Less than or equal to (<=)
Above, you have already seen an example of such a formula that checks if a number is greater than a given number.
And here's a formula that checks if a cell contains a negative number:
=IF(B2<0, "Invalid", "")
For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell.
Excel IF function with text
Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.
For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:
=IF(B2="delivered", "No", "Yes")
Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise.
Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:
=IF(C2<>"delivered", "Yes", "No")
Notes:
- When using text values for IF's parameters, remember to always enclose them in double quotes.
- Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".
Case-sensitive IF statement for text values
To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.
For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:
=IF(EXACT(B2,"DELIVERED"), "No", "Yes")
If cell contains partial text
In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.
A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).
For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:
=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes")
For more information, please see:
Excel IF statement with dates
At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.
For example, here's how you can check if a given date is greater than another date:
=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")
This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date.
Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:
=IF(B2>$E$2, "Coming soon", "Completed")
To compare a date with the current date, use the TODAY() function. For example:
=IF(B2>TODAY(), "Coming soon", "Completed")
Excel IF statement for blanks and non-blanks
If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:
- Use the IF function together with ISBLANK, or
- Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).
The table below explains the difference between these two approaches with formula examples.
| Logical test | Description | Formula Example | |
| Blank cells | ="" |
Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string. Otherwise, evaluates to FALSE. |
=IF(A1="", 0, 1)
Returns 0 if A1 is visually blank. Otherwise returns 1. If A1 contains an empty string (""), the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings. Otherwise, evaluates to FALSE. |
=IF( Returns 0 if A1 is absolutely empty, 1 otherwise. If A1 contains an empty string (""), the formula returns 1. |
|
| Non-blank cells | <>"" | Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered blank. |
=IF( Returns 1 if A1 is non-blank; 0 otherwise. If A1 contains an empty string, the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered non-blank. |
=IF( Works the same as the above formula, but returns 1 if A1 contains an empty string. |
And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:
=IF(B2="", "", "Completed")
=IF(ISBLANK(B2), "", "Completed")
=IF($B2<>"", "Completed", "")
=IF(ISBLANK($B2)=FALSE, "Completed", "")
In case the tested cells have no zero-length strings, all the formulas will return exactly the same results:
Check if two cells are the same
To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:
=IF(B2=C2, "Same score", "")
To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.
For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:
=IF(EXACT(A2, B2), "Match", "Don't match")
IF then formula to run another formula
In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.
For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:
=IF(B2>80, B2*7%, B2*3%)
Multiple IF statements in Excel
In essence, there are two ways to write multiple IF statements in Excel:
- Nesting several IF functions one into another
- Using the AND or OR function in the logical test
Nested IF statement
Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.
Assume your goal is to assign different bonuses based on the score:
- Over 90 - 10%
- 90 to 81 - 7%
- 80 to 70 - 5%
- Less than 70 - 3%
To accomplish the task, you write 3 separate IF functions and nest them one into another like this:
=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%)))
For more formula examples, please see:
Excel IF statement with multiple conditions
To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:
For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:
=IF(AND(B2>80, C2>80), "Pass", "Fail")
To get "Pass" if either score is higher than 80, the formula is:
=IF(OR(B2>80, C2>80), "Pass", "Fail")
For full details, please visit:
If error in Excel
Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.
And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.
For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:
=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" )
For more information, please see IF ISERROR formula in Excel.
Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!
Practice workbook
Excel IF statement - formula examples (.xlsx file)
4796 comments
I am try to count how many "Y"'s in a range of columns and convert that into a numeric value and place that value in a different cell.
Please help
=IF(SUM(D95:D106)="Y", "1")
Hi Darryl,
SUM can handle numeric values only, while the COUNTIF function works for text strings as well:
=COUNTIF(D95:D106, "y")
You can find more information in the following tutorial:
COUNTIF in Excel - count if not blank, greater than, duplicate or unique
Using Logical "IF" formula to determine if date in one cell is < date in another cell =IF(A1<B1,True,False). Returns the correct answer, however when I try to copy it to multiple rows....it does not! If however I go to each row and click the Insert Function menu option...it will change the answer to the correct one! Can't seem to figure it out! Please help
Hi Scarlet,
Usually copying a formula by selecting the cell and dragging down the fill handle works without a hitch. Are you coping it to other cells in the same column, or somewhere else? For example, the formula is in C1 and you need to have it in, say, C1:C100?
I am trying to add all of the values in column E that have the corresponding number 53017 in column G. I tried this formula but it didn't work.
=IF(G1:G53=53017,SUM(E2:E58))
Can anyone advise?
Thanks!
Hi Lisa,
You can use the formula similar to this:
=SUMIF(G1:G53, 53017, E1:E53)
I need help on an Excel formula. I have A group of cells containing text. The text in the range is either "In Process" or "Completed". If any of the cells in the range have text "In Process" the lead cell should return "In Process", if not, it should return "Completed". Please assist.
Hi, how do I get the value if true to be another formula? I have a list of customers (column A), and a list of corresponding dates (column B), I want to set the value if true to be, If cell A1 = Customer x, out put to be date (b1) + 2 days.
By having the formula as =IF(A1=Customer,"B1+2","") the output is B1+2 whereas I want it to display the date in B1 + 2 days?
Thansk
Hi Chris,
Just remove the quotes enclosing B1+2 because they turn any expression into a text string, and apply the Date format to the cell containing the formula:
=IF(A1="customer",B1+2,"")
In Cell L92 I am try to tally Cells F8, F12, F16, F20 if they say Yes. How do I do this?
Svetlana, why you ignore email from my question?
Can you please help me with following formula
i have a calculation in Cell A and another calculation in Cell B
in another cell i want to determine results as following
if value in cell A and Cell B are greater than or equal to .5 give me true otherwise false
if values in cell B is blank take value from cell A only and provide results
Hi Kamran,
You can use a formula similar to this:
=IF(AND(A1>0.5, B1>0.5), TRUE, IF(AND(A1>=0.5, B1=""), TRUE, FALSE))
Hi Svetlana
I am looking out for a formula to calculate an incentive structure
If My CTC is 10000 , and i have given a profit of 45000 , I want an formula to calculate the following slabs in incremental basis.
If employee achieved 3 times of ctc 5 % incentive
If employee achieved 3 to 4 times of ctc 10% incentive If employee achieved 4 to 5 times of ctc 15% incentive
5 to 6 times 20%
6 to 7 times 25%
Above 7 times 30 %
45000 split in 3 slabs
30000 = 30000 * 5 % Eligibility on 30000
30000 - 40000 = 10000 * 10 % Eligibility on 10000
40000 - 45000 = 5000 * 15 % Eligibility on 5000
Hi Svetlana,
I am referencing a date in cell L57 which is looking at a due date and my formulae works is written as:
=IF(L57>NOW(),"'OK'","OVERDUE")
My problem is if I enter a date in another cell,(Say L58)(that tells me that for example, a payment has been made) how can I add a multiple ÍF' function so that it that it references L58 also (which will have a date entry), and then correct cell L57 to read ÓK'' indicating visually that payment has been made.
Your help would be much appreciated.
Hi Jason,
You can embed an OR statement in your formula, e.g:
=IF(OR(L57>NOW(),L58>NOW()),"'OK'","OVERDUE")
Hi Svetlana
Thankyou so much for your response, however it still does not change the cell response to read OK (when a date value in cell L58 has been entered)
It is as if it does not overwrite the rule in the first statement.
Any ideas??
Jason,
It thought the formula should return OK when the date either in L57 or L58 is greater than the current date (i.e. greater than NOW()).
If you want it to return 'OK' when either a date in L57 is greater than NOW() or any date is entered in L58, then the formula should read as follows:
=IF(OR(L57>NOW(), ISNUMBER(L58)),"'OK'","OVERDUE")
Thankyou so much Svetlana, that worked!
I have in mind (maybe an IF) formula I want implement,
where I have a date of 6-17-15, in one cell (oh,say E7) when we started tracking it as "Open". Cell F7 (7/7/15) would be the date we closed it. Cell G7 would be the days it was open, If we closed it on 7/7/2015, the duration open would be 20 days and the formula would be simply =F7-E7. Correct?
But, let's say we had not filled in the Cell F7 yet and it is blank. How would I express the formula in Cell G7 to keep a tally of the open days, then when we fill in the G7 cell, it will fill in the open days?
I hope I explained it well.
Hi Svetlana! I'm trying to figure out an IF statement using dates. Something like, IF(B2=older than three years than NOW(),"Too old", "New"). So simple but I can't figure it out. Thank you!
Hi Michael,
You can use the DATEDIF function to calculate the difference between 2 dates in years. For example:
=IF(DATEDIF(B2, TODAY(), "y")>3, "too old", "new")
This worked perfectly! Thank you so much :D
I am trying to get this formula to reference one more cell. if the additional cell contains a date, the formulated cell will be blank.
any suggestions?
=IF(ISBLANK(Response_Due_Date),"",IF(Response_Due_Date<TODAY(),"PAST DUE",""))
Hi!
I think you can add an OR statement to the 1st logical test:
=IF(OR(ISBLANK(Response_Due_Date), ISNUMBER(additional_cell)), "", IF...
I'm trying to enter two IF functions in one cell for a toggle drop down. How do I connect the two formulas?
I'm getting #VALUE! with this
=IF($H$5="step-function",IF(I4<$D$3,$C$4,IF(I4<$E$3,$D$4,IF(I4<$F$3,$E$4,$F$4)))),IF($H$5="continuous",IF(I4=1,$C$4,IF(I4<$D$3,($D$4-$C$4)/($D$3-$C$3)+H6,IF(I4<$E$3,($E$4-$D$4)/($E$3-$D$3)+H6,IF(I4=$F$3,($F$4-$E$4)/($F$3-$E$3)+H6))))))
Hi Svetlana,
Need a little help. I have 4 text from which i have to choose, if 1st is present then others are false, if 1st missing and second is present then 2nd is true, if 1st and 2nd is missing and 3rd is present then 3rd is true and if 1st 2nd 3rd is missing then, if 4th is present then 4th value is true.
How do I use IF formula here so that I can get my desired result only from many?
Sorry for the confusion.
Right now I am using below formula but it seems to be working only with first column.
=IF(F6" ",F6,(OR(AND(G6=" ",OR(AND(G6" ",OR(AND(H6=" ",OR(AND(H6" ",OR(AND(I6=" ",OR(AND(I6" "))))))))))))))
Example is mentioned below for your reference
Column1 Column2 Column3 Column4 Result
A B -- D Sould be 'A' (A is first present text)
-- -- C -- Should be 'C' (C is first present text)
-- B -- D Sholud be 'B' (B is first present text)
-- -- -- D Should be 'D' (D is first present text)
-- B C -- Sholud be 'B' (B is first present text)
Took a little time but I have solved this problem.
Thanks so much for your help for creating this amazing blog though.
This formula is working for me: =VALUE(IF(E12="X","660",IF(E12="","0")))
but I need to make 2 additions:
E12="1","660"
E12="2","660"
When I've added them I get a #VALUE! entry in the cell. Can you please help me with the right formula? Thanks so much!
Hi Shannon,
I am not sure why you use the VALUE function in the formula. The following one works for me:
=IF(OR(E12="X", E12=1, E12=2), 660, IF(E12="", 0, ""))
Hi Svetlana,
How do i set the formula if i want to calculate the bonus based on 20% of their basic salary, and the salary is cap at maximum $6000. Meaning to say if someone basic salary is at $8000, still he will received the bonus at $6000x20%=$1200. And if someone basic salary is at $5000 then i would be $5000X20%=$1000. Your advice please. Thanks
Hi Low,
Supposing column A is salary, you can use a formula like this:
=IF(A2<6000, A2*20%, 6000*20%)
I have to use and “IF” formula to fill cells in a column at the end of a table. I have to formulate the new column so that if there is a 2-1 ratio from Field D data to field C data then field E data has a good result, otherwise it is a bad result. I have gotten this far, =IF(D2>C2, "Success","Failure") but cannot calculate the ratio. Seems simple, but I cannot figure out how to calculate that D2 needs to be twice the amount of C2, I can only figure it to be greater. I am new to Excel.
Area. TargetDate. Code. Aa. Aug 1 2015. 01. Ab. Aug 1 2015. 02. Aa. Aug 2 2015. 03. Ab. Aug 2 2015. 04. My question is what formula should i use to display automatically this value in the nxt table. . Aug 1 2015 Target. Area. Code. Aa. 01. Ab. 02. . Please help me! Thanks
Hai Svetlana,
Still waiting for your valuable reply for given below :
A is the date column, B Column is text which can be repeated in same column with another date, C column is another text which can also be repeated with column B,
Now I need formula if date is less than today and if text in column B and C matches then get cell data of day before yesterday with same text combination.
Pl. help
Brajesh,
Sorry, I cannot figure out a formula for this task.