by In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.
IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.
In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.
IF function in Excel
IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.
The syntax of the IF function is as follows:
As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.
Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.
Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.
Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.
Basic IF formula in Excel
To create a simple If then statement in Excel, this is what you need to do:
- For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
- For value_if_true, specify what to return when the logical test evaluates to TRUE.
- For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.
As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:
=IF(B2>80, "Good", "Bad")
This formula goes to C2, and then is copied down through C7:
In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:
=IF(B2>80, "Good", "")
This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise:
Excel If then formula: things to know
Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.
If value_if_true is omitted
If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:
=IF(B2>80, , "Bad")
To return a blank cell instead, supply an empty string ("") for the second parameter, like this:
=IF(B2>80, "", "Bad")
The screenshot below demonstrates the difference:
If value_if_false is omitted
Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.
If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:
=IF(B2>80, "Good")
Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:
=IF(B2>80, "Good",)
The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:
=IF(B2>80, "Good", "")
Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.
Using IF function in Excel - formula examples
Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.
Excel IF function with numbers
To build an IF statement for numbers, use logical operators such as:
- Equal to (=)
- Not equal to (<>)
- Greater than (>)
- Greater than or equal to (>=)
- Less than (<)
- Less than or equal to (<=)
Above, you have already seen an example of such a formula that checks if a number is greater than a given number.
And here's a formula that checks if a cell contains a negative number:
=IF(B2<0, "Invalid", "")
For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell.
Excel IF function with text
Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.
For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:
=IF(B2="delivered", "No", "Yes")
Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise.
Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:
=IF(C2<>"delivered", "Yes", "No")
Notes:
- When using text values for IF's parameters, remember to always enclose them in double quotes.
- Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".
Case-sensitive IF statement for text values
To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.
For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:
=IF(EXACT(B2,"DELIVERED"), "No", "Yes")
If cell contains partial text
In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.
A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).
For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:
=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes")
For more information, please see:
Excel IF statement with dates
At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.
For example, here's how you can check if a given date is greater than another date:
=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")
This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date.
Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:
=IF(B2>$E$2, "Coming soon", "Completed")
To compare a date with the current date, use the TODAY() function. For example:
=IF(B2>TODAY(), "Coming soon", "Completed")
Excel IF statement for blanks and non-blanks
If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:
- Use the IF function together with ISBLANK, or
- Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).
The table below explains the difference between these two approaches with formula examples.
| Logical test | Description | Formula Example | |
| Blank cells | ="" |
Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string. Otherwise, evaluates to FALSE. |
=IF(A1="", 0, 1)
Returns 0 if A1 is visually blank. Otherwise returns 1. If A1 contains an empty string (""), the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings. Otherwise, evaluates to FALSE. |
=IF( Returns 0 if A1 is absolutely empty, 1 otherwise. If A1 contains an empty string (""), the formula returns 1. |
|
| Non-blank cells | <>"" | Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered blank. |
=IF( Returns 1 if A1 is non-blank; 0 otherwise. If A1 contains an empty string, the formula returns 0. |
| ISBLANK() |
Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.
Cells with zero-length strings are considered non-blank. |
=IF( Works the same as the above formula, but returns 1 if A1 contains an empty string. |
And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:
=IF(B2="", "", "Completed")
=IF(ISBLANK(B2), "", "Completed")
=IF($B2<>"", "Completed", "")
=IF(ISBLANK($B2)=FALSE, "Completed", "")
In case the tested cells have no zero-length strings, all the formulas will return exactly the same results:
Check if two cells are the same
To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:
=IF(B2=C2, "Same score", "")
To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.
For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:
=IF(EXACT(A2, B2), "Match", "Don't match")
IF then formula to run another formula
In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.
For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:
=IF(B2>80, B2*7%, B2*3%)
Multiple IF statements in Excel
In essence, there are two ways to write multiple IF statements in Excel:
- Nesting several IF functions one into another
- Using the AND or OR function in the logical test
Nested IF statement
Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.
Assume your goal is to assign different bonuses based on the score:
- Over 90 - 10%
- 90 to 81 - 7%
- 80 to 70 - 5%
- Less than 70 - 3%
To accomplish the task, you write 3 separate IF functions and nest them one into another like this:
=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%)))
For more formula examples, please see:
Excel IF statement with multiple conditions
To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:
For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:
=IF(AND(B2>80, C2>80), "Pass", "Fail")
To get "Pass" if either score is higher than 80, the formula is:
=IF(OR(B2>80, C2>80), "Pass", "Fail")
For full details, please visit:
If error in Excel
Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.
And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.
For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:
=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" )
For more information, please see IF ISERROR formula in Excel.
Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!
Practice workbook
Excel IF statement - formula examples (.xlsx file)
4804 comments
having a hard time getting this to work.
voice and screen true - yes, false = no
I have door numbers listed in boxes across. I need a formula that totals the number of boxes filled in with any number. 201, 202, 203 = 3
=@COUNT( DID IT.
i want to know haw to get value to close value by if function
Hi
I am trying to create if statement that has both text and number here is the code:
=IF(U18="YES",VLOOKUP(W18,'Assumptions and Factors (2)'!U148:U150,1,VLOOKUP(Q18,'Assumptions and Factors (2)'!W110:X135,2),VLOOKUP(Q18,'Assumptions and Factors (2)'!Z110:AA135,2)))
it is to create manhours on specific pipe sizes (Q18=3.00,'ADDS IN A MODIFIER,but if W18 is not None,1B,ET1, it goes to another table modifier)
I do get #value when I do a calculation step it shows me but I just cannot seem to get pass this.
any direction would be helpful
Thank you
I am attempting to return a set of responses should a series of the following exist...
If Material/Service/Other COlumn = "Service", MSA column = "N" , COI Column = "N" , & COI Valid/Expired = "Expired"......= "No COI and MSA"
and then in the same cell
if(and(Material/Service/Other Column="Service", MSA Column="N", COI Column="Y",& COI Valid/Expired="Expired"...="Expired COI and No MSA"
and continuing with the same cell and adding on to the above...
If(and(material/service/other column="Service", MSA Column="Y", COI Column="N",& COI Valid/Expired="Expired"....="No COI"
Due Date Date of Deposite Delayed days Penalty Amt
10/21/2015 10/26/2015 5 2000
Interest for Late Filing of Return
Particular Amount
Up to 30 day 2,000.00
Above 30 day 5,000.00
how to put IF formula in penalty amt column if file the return before 30 days (penalty Rs.2000) after 30 days (penalty Rs.5000) and on the same day (no late file the return)
Hi,
I need a =if(or) formula
=IF(OR(G153="Sta",451)=IF(G153="Fra",939)=IF(G153="LOG",294)
Hi, I have to collect samples of employees dust exposure at a underground mine.
Here are the conditions of re-sampling a sample dependent on the lab results:
Underground
• Below 0.3 mg/m3 (Re-sample one sample)
• Above 5 mg/m3 (Re-sample one sample)
• Above 10 mg/m3 (Re-sample two samples)
Can you please help me with a formula?
Hi I want a formula which is suitable for my data entry sheet Ex: if any party name or amount entered into sheet1 would change the amount in sheet2 simultaneously with the same name and amount.
I am writing a spreadsheet where column d has a validation so only 6 options are available from a drop down menu. I would like to have the next cell auto populate with a specific value based on the previous choice what would my formula look like.
ex: row 1column d reads refrigerator column e should populate 0001
row 2 column d reads stove column e should populate 0002
Thanks for your response Ahmed. However your formula did not work.
Here is a portion of my worksheet.
Date Achieved
(mm/yy) CARRY (5 Points)
Feb-2015 1.Carry an object held against body with 2
hands.
Apr-2016 2.Carry an object held against body with 1
hand.
Apr-2016 3.Carry an object away from body with 2 hands.
4.Carry an object away from body with 1 hand.
May-2017 5.Carry two (2) objects – one in each hand.
As you can see in this sample, the skill of Carry has 5 parts. In Feb. 2015 the student achieved 1 part in the skill of Carry. In April 2016, the student achieved 3 parts and in 2017 the student achieved 4 parts of the skill.
Now in my chart. What happens when I use the formula =COUNT(A1:A5)EXCEL adds all the parts achieved which is what I want it to do BUT NOT change the number in the previous year. So my chart should look like this:
(the dates are linked to years in another worksheets so they come in when a new year is added)
Feb-2015 Apr-2016 May-2017
1 3 4
Hope someone can help with this.
Thanks, Debra
Hi
I want to translate the following equation
IF($D$35>0;D35-C35;0)
I do hope you can help. I have tried numerous IF, COUNT,COUNTIF,COUNTA formulas to no avail.
I am trying to track the progress of the number of skills achieved each year over the course of multiple years. Each skill is broken into multiple parts. When a part of the skill is achieved a date (such as Mar -2015) is recorded in the cell next to that part of the skill.
I wanted to create a chart to show the date and the number of skills that was achieved for each year over the course of multiple years.
So I created a chart with 2 rows with 10 columns under the skill. The first row records the dates, the second row records the number of items achieved in that year. I want EXCEL to automatically record this information
I need Excel to count the number of skills the student achieved for the year and put it in the cell under the date. Now each year I give the test I want it to record how many skills the student achieves without Excel changing the number of skills achieved from the previous year.
Hi,
Can you please help me to get the data using "if" function..
Data....
Batch Joining Date
Batch 1 10/10/2015
Batch 2 10/17/2015
Batch 3 10/24/2015
Batch 4 11/7/2015
Batch 5 11/14/2015
Batch 6 11/21/2015
Batch 7 12/5/2015
Batch 8 12/12/2015
Batch 9 12/19/2015
Batch 101/2/2016
Type of training
Induction training 2 weeks IT
Technical Training 3 weeks TT
Process training 6 weeks PT
I need to know, how many members would attend the training from which batch for which training
can I get this data please
Hi,
I have trouble with formula, i want make formula will show the specific value if found specific text/string in row, i want to make simple formula for java bytecode you can see the byte code here https://en.wikipedia.org/wiki/Java_bytecode_instruction_listings
so if i type Mnemonic in first coloum and i get the OpCode (hexdec) as a result in second coloum
I AM HAVING TROUBLE I HAVE A FLOW CHART WITH DUE DATES ON THEM EXAMPLE I HAVE WORK THAT NEEDS TO BE COMPLETED WITH IN 3,6 AND 9 MONTHS HOWEVER IF THEY GET COMPLETED BEFORE I WANT TO NEXT SET OF DATES TO GET TRIGGERED BY COMPLETED TIME IF LESS THEN THE ACTUAL DUE DATE HOW WOULD I DO THIS?
Hi
If i have to pay someone who has secured the below marks
Equal to 70% - 89% - 10 USD
90% and above - 20 USD
Below 69% - 0 USD
What formula do you use ?
have a formula i have been trying to fix -
=IF(AND(X16>99.9999%, Y16>99.9999%),(IF(TRUE,W33),IF(AND(X16<99.9999%, Y16<99.9999%),(IF(FALSE,W32)))))
what im wanting is the X16 + Y16 if both are true to show the info in cell W33 BUT if ether is False to show info in cell W32 - is there something im missing?
Hi I am trying to use check boxes to add up a list of items one might purchase and give me a sum total. I tried the formula for just one box but it keeps giving me zero instead of the dollar amount I expecting ($5).
The formula I am using is =IF(D3="true",C3, 0)
In this case D3 is true
C3 is $5
The result comes back as 0
Any ideas?
Hi Paul,
Because TRUE and FALSE are Boolean values, you don't need to enclose them in quotes, and your formula will work perfectly:
=IF(D3=TRUE,C3, 0)
Svetlana that works perfectly, now for part two which I thought I could figure out if part one worked. I have a list of prices that if they are true I would like them to total up at the bottom. I tried =IF(D3:D14=TRUE,SUMC3:C14, 0) but it doesn't work
Paul,
For this, you'd better use the SUMIF function:
=SUMIF(D3:D14, TRUE, C3:C14)
The above formula sums values in column C if a cell in the corresponding row in column D is TRUE.
Thank you again, that worked.
Hi I've got a problem on a question with IF Functions. The problem I'm stuck on is saying to enter a formula in cell H6 that determines total cost based on the number of days the vehicle was rented and the discount indicated in B42(Discount). If the payment was Express Miles or Rewards(B42) then the customer should receive the discount.
Days rented is= E6
Daily rate is= G6
This is what I have so far.
=IF(F6="Express Miles",G6*E6(1-Discount),G6*E6)
Thanks for helping if thats enough info!