How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. Hello,
    I have a spreadsheet layout as follows:
    Inv date

  2. Hi I run a works lotto syndicate and I would like my winnings spreadsheet to add up the number of wins to total the amount in money ie Cell A1 is 1 win the total cell I1 is £3, the next week A1 is 2 wins so I1 = £6 and so on, is this possible?
    Thank you
    Michael

  3. Hi all,
    In the cells of column C I'd like to get the following numbers, based on the numbers in the cells of column B:
    Bx = 0-14 -> Cx= 0; Bx = 15-30 -> Cx = 1; Bx = 30-60 -> Cx = 2; Bx > 60 -> Cx = 3

    I used the following formula in the cells of column C:
    =IF(B2>=60,3,IF=(B2>=30,2,IF=(B2>=15,1,0)))

    However, Excel does not recognise the final 'B2' as a cell in the formula (e.g. it does not get coloured and it returns a message that there is an error in the formula).

    Could you please tell me what I'm doing wrong?

    Thanks in advance!

  4. Hi
    I have a problem in DVI/o, How I can remove this error from Excel. the formula is ('S'!C2-'Dry-Phase'!C2)/('Sat-Phase'!C2-'Dry-Phase'!C2. How I can use IF formula to eliminate this error and used o instead of it?

  5. hey i need help for this, im making kind of a game in excel, like rock paper scissors and i need help.i have put in result if function and all is done but if i input something other than "scissors" "rock"or"paper" ,says false,so i put in if(...,"you win",c3"doesnt exist") /c3 is cell where i put user choice and i need help if it is possible to write whatever is written in user choice + "doesnt exist.".Example:

    C D E
    3 User choice Result
    4 Dog Dog doesnt exit! /so c3+"doesnt exit"

    if anyone knows please help, only that i need to finish

  6. Hi, I've looked through and couldn't find the answer to my particular question.

    I have four columns with 0/1/blank in them. Based on if they have 1 in it I'd like my new column to say International", Regional, National... HOWEVER, some countries have 1 in more than one column.

    This is what I've got so far, which is OK if they have one answer, but how do I get to an answer like, "International, National"?

    =IF(CB5=1,"International",IF(CC5=1,"Regional",IF(CD5=1,"National",IF(CE5=1,"Intermediate"))))

    Many thanks in advance
    J

  7. i need the person to make 10.19, but if he does how can i get the IF function to work ?

  8. i want to know the below formula :

    if value is 10000>="200" and 10000< value "150"

    kindly show the formula with"and"...

  9. Hello

    I Hope you can help me with this,

    I want to create a formula where I can say this cell is = to a cell in another sheet, but if its blank, leave it blank, otherwise place the information

    example

    =IF(MASTER!D60,"","???") WHAT I WANT IS TO SAY THAT THIS CELL IS = TO THE OTHER CELL AND IF THE CELL IS BLANK, LEAVE IT BLANK DONT PLACE ANY NUMBER OR FORMULA OR ANYTHING

    thank you in advance

    • if i got it right, i think it goes like this:

      =if(D60="","",D60)

      /this says if the cell d60 is empty(""),leave it empty(""),and if not input the text from it here.

      • Good Day
        Thanks for the above answer
        if i got it right, i think it goes like this:

        =if(D60="","",D60)

        /this says if the cell d60 is empty(""),leave it empty(""),and if not input the text from it here.

        So I have a situation whereby I have 4 columns (A,B,C,D), I have information in either of the columns. I want the information to be populated in column E.
        I found the above if function don't work for multiple column ranges or maybe I just get it wrong. Please assist

  10. Need an IF THEN formula that covers multiple worksheets for a Quote template that users will be entering part numbers in to return certain prices.
    SHEETS - 1.Intro - where promo code is selected from drop down cell,2.Pricing - where the user enters the part number and the desc & price auto-populates, 3. - Data Sheet)
    I want the formula to look at a cell in the Intro Sheet and IF it contains data (a promo code) THEN return the price associated with the part number, If there the promo Code cell is empty then return the non-discounted price.
    In my data sheet I have columns that contain part numbers and non-disc price and columns that have the promo code, part number and price associated with that code.

    Easy right?

    Basically If PROMO CODE is entered THEN apply promo pricing for material entered IF not THEN use normal pricing for material entered.

  11. Hi ...

    I'm a newbie with Excel

    I would like to create a formula that "average the number of failed in a column ... In the top of my report I have 2 cells one for "%Failed" and the other for "%Success" ... my column is populated with "F" and "S".

    So it's a "IF" follow by a "Count" or "Average" ?

    Thanks

  12. Hi
    How would i create formula for when in a word 4th letter is "c" then true or false

  13. How would I create a formula for getting a cell to populate a specific word related to a specific number? Example A1 = 01, I want B1 to always show FRONT, if A1 = 02, B1 = BACK

    I have a list of varying numbers 50 numbers and each number is associated with a word.

  14. Hi,

    I hope you can help

    I am using this formula, but the cell I am using it in shows £300 when C4 is 0.00.

    When C4 is 0.00, I also want the cell to show as 0.00 until any information in entered, how do I incorporate this into the formula?

    =IF(C4=300,0,C4))

    Thanks in advance

      • Sorry my formula didn't come up as I typed it, I'll try sending it in 2 parts

        =IF(C5<300,300-C5,

      • Part 2

        IF(C5>=300,0,C5))

        • James,

          Our blog engine often mangles formulas with comparison operators, sorry for that. If my understanding is correct you want the formula to return 300-C5 if cell C5 is less than 300, otherwise return 0:
          =IF(C5<300,300-C5,0)

          If you are looking for something different, please express the conditions in words and we will try to work out a proper formula.

      • I want a formula if the ans is NO in one column then 888 in the next coulum

  15. Can you sum up the results of an IF statement if the result is a number? How?

  16. hi, can you help me i have this if problem everytime i do more than 1 value i keep getting Error.. i have this this to appear on my excell

    Yes=Approved
    No=Location too far
    ?=Missing location

    -and if possible to add more kindly add

    e=Escalate
    i=inappropriate content
    p=no facebook photo

    thanks for the future help.. more power.. :)

  17. Hi Svetlana,

    I would like to combine these two formulas in one cell. I'd like to see results that are a positive number, replace a negative number with a blank cell and replace errors with "no data". I can get them to work independently but not sure how to combine them. Any help you could give would be greatly appreciated.

    =IF(ISERROR(NETWORKDAYS(J64,K64)-1),"no data",NETWORKDAYS(J64,K64)-1)
    or
    =IF((NETWORKDAYS(J68,K68)-1)<0,"",NETWORKDAYS(J68,K68)-1)

    Thank you,Sarah

  18. Hi ,

    I want formula for below value 0, 1 & -1 as ok, Excess & short respectively.

    What will be the formula.

    0 ok
    1 Excess
    -1 Short

  19. hello.....i have five different trucks for holding, each one has a serial of three numbers and each has different volume.. how can i use "if equation" or another one to gain more time inorder to not refill each time the repeated data for the driver..... i want when i type the driver name in cell A, i may have the truck number of this driver in cell B and the truck volume in cell C

  20. I need a formula that will satisfy these conditions. The nominee must be male or female with more than 500 votes to qualify. My formula was wrong. Any suggestions?

    • Hi Johnny,

      If you give more details about your data structure, I think we will figure out a proper formula.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)