How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. Dear Mam,

    I am Working as Business Analyst. how can i give a ranking to the companies based on their MAT score with IF function.

    please clarify

  2. I am working on a spreadsheet for a game challenge. I have a list of options: Baby, Child, Teen, Young Adult, Adult. The values are respectively: 0, 3, 16, 29, 49. I'm unsure how to write an IF function to add an option from the list's value + another cell that will be filled in. I think it should be =IF(A1="Baby", 0) But how would I put all the options in there? Basically, how would I make it so that whatever option is chosen, it would return the right value and then add it to the cell?

    • Hi Wolfy,

      This can be done by using nested If functions, e.g.:

      =IF(A1="Baby",0, IF(A1="Child",3, IF(A1="Teen",16, IF(A1="Young Adult",29, IF(A1="Adult",49,"")))))

  3. Hello, I just ran into a problem with a formula i had help on before. I have 5 vehicles that i use in a spread sheet. i need a formula that will prevent from incorrect information because of odometer numbers running together. i use another spreadsheet with additional vehicles and the odometer readings are similar. =IF(C14>=174121, 15, IF(C14>=227425, 5, IF(C14>=208012, 21, IF(C14>=143916=72700, 9, 0)))))
    #2 odometer is at 143916 #5 227425 #9 72749 #15 174121 #21 208012 Please help, thank you for your time, very much appreciated!

    • Hello, I believe I figured it out--- =IF(C33>=227425, 5, IF(C33>=208012, 21, IF(C33>=174121,15, IF(C33>=143916, 2, IF(C33>=72700, 9, 0))))) Formula in the correct sequence resolved problem, if incorrect, please let me know. Thank you

      Reply

      • Yes, the updated formula is correct. Putting logical tests in the correct order is critical because as soon as the first condition is met, other logical tests are not checked.

  4. Hi Svetlana. Thanks for the last reply, it was very helpful. However, I have a new problem I am struggling with.
    I have a list of names in column A and B and I want see all identical names as "true" in column C. I have only managed to make an if-function which compare e.g. A2 with B2, but what I would like to do is to compare A2 with the whole range of names in column B. Something like =IF(A2=B2:$B$5626, TRUE). This does not work for me for some reason, do you know why?

    • Hi Andreas,

      The IF function cannot compare ranges. I think you can use the following formula:

      =IF(COUNTIF($B$2:$B$5626, $A2)>0, TRUE, "")

  5. Please help, I need my formula to say if age is between 25-30 then its a certain cell, if its 31-40 than its another cell. how can I write it?

  6. Hello,
    How can I assign a number to a text value and then add it?

    Data Validation is present in A1, A2 & A3
    Yes, No, Maybe are the values

    I want to assign Yes=1, No=0; Maybe=.5 and then be able to add those values,

    Example:
    A1=Yes (1)
    A2=No (0)
    A3=Maybe (.5)
    Total should be 1.5

    Thank you in advance for your help!

    • Hello Michelle,

      You need to add a column for the formula that will assign a number to the values in column A:
      =IF(A1="Yes",1,IF(A1="No",0, IF(A1="Maybe",0.5,"")))

      Copy it down the new column to get a number for each cell in column A. Then you can use the SUM function to add the values you get.

  7. Светлана, would you be so kind to give me a hand on the following please? Assumption, in Sheet1 I have A1: toiletries ; A2: washing liquids A3: powders A4: toiletries; A5: conditioner etc. In Sheet2 I have B1: washing liquids; B2 powders, B3: shampoos; B4: toiletries; B5: shampoos etc. I Sheet2 I also have in C1: 213; C2: 325; C3: 564; C4: 912; C5: 487 etc.

    My objective is: In cell F1 to have the following result -> If value in A1 (sheet1) matches value in B1 (sheet2), then return value from C1 (sheet2).

    You help is very much appreciated. If you need more clarification on this matter please let me know. Зарание спасибо. Alex

    • Hi Alex,

      If my understanding of the task is correct, you can use the following formula:

      =IF(Sheet1!A1=Sheet2!B1, Sheet2!C1, "")

      • Светлана,thank you for your prompt response. Actually, I have realized the objective I have outlined is entirely incorrect. The actual output is: If VALUE in B1 matches the VALUE in the range A1:A5, then return the VALUE from C1. Correspondingly, when formula goes to B2 it has to check the range A1:A5 and if there is a match it returns the VALUE from C2.
        Apologies for the confusion caused.

        • Светлана, no need to bother. I have managed to figure it out. Thank you anyway! Best Regards, Alex

  8. Hi,

    I have 3 column A, B,C and if A=B=C is Thrue, if not is False

    Please can you help?

    Thanks,

    Loredana

  9. Hi,

    I need help trying to correct this formula.

    =IF(OR(SUM(G8:R8)=0,(D7+F8),(SUM(G8:R8)0)),(D7-E8))

    I am trying to have it read
    if the sum of G8:R8 = 0 then add D7 + F8
    if the sum of G8:R8 does not equal 0 then Subtract E8 from D7

    However, it currently only Subtracts E8 from D7

  10. Hi,
    I am trying to use the IF formula, but need it to have more than two options, and I can't make it work. Please can you help?
    e.g.
    Grades are listed in Column B of the sheet. Then in column C I want to add the grade description.
    If Column B = A, then I want column C to say Good.
    If Column B = B, then I want column C to say Medium.
    If Column B = C, then I want column C to say Bad.
    When writing the formula please use cell B2 and C2 as the cells that the data is in. Thanks
    Please can you advise the formula?

    • Hello Anna,

      You can include several conditions in one formula the following way:
      =IF(B2="A","Good", IF(B2="B","Medium", IF(B2="C","Bad","")))

      You need to enter the formula in C2 and copy it down to apply it to the cells below as well.

  11. Hi Carlos,

    Explanation of the formula -
    ROUND(VLOOKUP($O3,tbl_Premiums,5,FALSE)*(T3+U3+V3),0)

    Refer to number in cell O3 for a the matching number in the table "premiums" column 5 and if it matches, multiply sum of Cells T3,U3 and V3. The end result to be rounded of to zero decimal points.

    • Thank you very much Ramki. I really appreciate you help

  12. Hello,

    I translate this formula but I am not 100% sure if I am right. I was wondering if you can help me with it.

    A) =IF(OR($J3=99,$J3=98),CC3,VLOOKUP($I3,tbl_wages,6+$J3,FALSE))

    The IF(OR function means that if either of those two conditions are true ($J3=99. $J3=98) in my table, then my if function will give me my true result. On the other hand, VLOOKUP is looking for I3 and the next argument is that is looking for that information in the wages table or reference table and the final argument is telling me what do I want when I find I3 in column 6 and in this case it would be False

    Thanks,

  13. Hello,

    I was wonderinf if you could help me translate this formula:

    B) =ROUND(VLOOKUP($O3,tbl_Premiums,5,FALSE)*(T3+U3+V3),0)

    Thank you very much,

    Carlos

  14. Hello,
    I am creating a spreadsheet that returns the placement in a contest by percent. What I would like is a formula that tells me which place the resultant percentage (col G) is in. Col G has the following formula:

    =LARGE('Data Entry'!$E$3:$E$50,1)
    and ranked the percentages for me.

    Column B is where I am wanting to show placement.
    Column C returns the name of the competitor.
    Column A, I added the following formula to show duplicates in Column G:

    =C4&" "&COUNTIF($C$4:$C$52,C4)

    Columns D-F are the data entry cells for each competitor and result in the % in column G.

    Is there a way to show the placement (Col B) automatically by looking at

    Col G (%), but also taking into consideration if there is a tie (Col A shows second occurrences).

    ?

  15. Hi,

    If the cell A1 is more the 45 to add 15 and if A1 is less than 45 to times/multiply by 1.2

    Please if anyone could kindly help which formula i would have to use

    Many Thanks,

    Abe

  16. I'm working on Address Labels and want to save time on typing the zip codes. I want to say If Logan, 84321, If Smithfield, 84335, If Hyrum, 84319 I want to do If's for 6 towns. Any advice on how to do it?
    Thanks

    • Hello Johnnie,

      You can use a formula with nested IF function listing all 6 options, e.g. if the cities are in column A, it would look the following way:

      =IF(A2="Logan",84321, IF(A2="Smithfield",84335, IF(A2="Hyrum",84319,"")))

  17. Hi,

    Make separate column for name and Phone no.
    Example : column F for names and column G for phone no. (You Can use any column for names and Phone no)

    Use the below formula,if any column does not have phone no. but has name of the person. When your using this formula it will show as PHONE NO REQUIRED.
    formula.
    =IF(ISNA(VLOOKUP(A1,F:G,2,FALSE)),"phone no. requred",VLOOKUP(A1,F:G,2,FALSE))

  18. Hi
    i have 5 name and i am use if formula for phone number plz suggest

    like

    name is neeraj so number is 111 & select ravi so number is 2222

    =IF(K2="Neeraj","1111","Number Required")

    • Hi,

      Make separate column for name and Phone no.
      Example : column F for names and column G for phone no. (You Can use any column for names and Phone no)

      Use the below formula,if any column does not have phone no. but has name of the person. When your using this formula it will show as PHONE NO REQUIRED.
      formula.
      =IF(ISNA(VLOOKUP(A1,F:G,2,FALSE)),"phone no. requred",VLOOKUP(A1,F:G,2,FALSE))

  19. Hello Swetlana,

    I was wondering if you can help me translate this formula:
    =IF(ISBLANK(C12),"",IF(ISNA(VLOOKUP(V12,tbl_PatternCode,6,FALSE)),"new",VLOOKUP(V12,tbl_PatternCode,6,FALSE)))

    • Hi Carlos,

      1). its very simple range of column "c", Blank cell inside "c" column. it will show Blank only.
      2). if data in "C" column cell ,"VLOOKUP" formula applicable (if "#N/A" will come it showing "NEW")
      3). in "Vlookup" compare to "V12 column to tbl_PatternCode in '6' column"

      • Thank you very muchhhhhh

  20. =if(L2=A, '1','0')

    • Hi Syed,

      =IF(L14="A","1","0")

      • =IF(L2="A","1","0")

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)