How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. If A7>=5.5 and A7<=13 then A7-0.5,

    if no then if A7<5.5,A7,A7-0.5

    Can you help me
    Pretty please!!! =)

  2. Hi Svetlana,
    there is a 9 figure number and a character(ex. 7730082766V) in a1. what I want is if the 3rd number of that number less than or equal 3, print "male" or if it is bigger than or equal 5, print "female" in b2. i tried with =if(mid(a1,3,1)<=3,"male","female") formula in b2. but it doesn't work. help me.

    • Hi Chaminda,

      The point is the MID function always returns a text string, even if the original value is a number. You can simply multiply the result by 1 to convert it back to number, like this:

      =IF(MID(A1,3,1)*1<=3,"male","female")

      Alternatively, you can use the NUMBERVALUE function:

      =IF(NUMBERVALUE(MID(A1,3,1))<=3,"male","female")

  3. hi
    iwant formulas Please explain i need help

  4. I am trying to write a formula using data from a different tab that says "if cell in column A is not blank, count the number of cells in column V which are not blank". And make this applicable for an unlimited number of rows.

    I have tried amongst others;
    =COUNTIF('Action Register'!A2:A100,"",'Action Register'!V2:V100"")

    =COUNT(IF('Action Register'!A2:A100,""), AND, IF('Action
    Register'!V2:V100""))

    I am getting a standard error message to say there is a problem with the formula every time. Any suggestions?

  5. Kindly help me,
    i want to apply formula ( IF function formula for text values ) to multi ple columns but i am not able to do

  6. I would like to create multiple condition in single column

    If 88000-44000 is more than 50% then multiply with 0.06% or equal to 50% then multiply with 0.14% of less than 50% then multiply with 0.21%

    please arrange the same formula.

  7. I have created 3 lists for date drop down menus. The lists are Month (Jan-Dec), Day (1-31), and Year (2016-2020). The problem I am trying to find a formula for is this: If February is selected as the Month, how do I prevent the days of 29 (for non-Leap Years) and 30-31 for all years to be selected from the Day drop down list? Not sure if Conditional Formatting or Data Validation is the way to go. If there is not a way to specifically prevent them from selecting 29-31 from the Day drop down list, then how to generate an error message when 29-31 is selected? Your help is greatly appreciated.

  8. HI,

    I need a small clarification in excel formula.

    =COUNTIF(J6:J27,"Not Met")

    I NEED A FORMULA FOR INDIVIDUAL DATES MET OR NOT MET. CAN ANY ONE HELP ON THIS
    E F G H I J K
    DATE START END TAT VOLUME SLA 13:00
    2/13/2016 4:47 PM 12:00 26 Met
    2/13/2016 15:00 35 Not Met
    2/13/2016 12:12 45 Met
    2/13/2016 13:14 82 Not Met
    2/13/2016 15:00 1 Not Met
    2/13/2016 12:12 45 Met
    2/13/2016 13:14 82 Not Met
    2/13/2016 15:00 1 Not Met
    2/14/2016 12:12 45 Met
    2/14/2016 13:14 45 Not Met
    2/14/2016 12:00 45 Met
    2/14/2016 15:00 45 Not Met
    2/14/2016 12:12 82 Met
    2/14/2016 13:14 26 Not Met
    2/15/2016 12:00 35 Met
    2/15/2016 15:00 45 Not Met
    2/15/2016 12:12 82 Met
    2/15/2016 13:14 1 Not Met
    2/15/2016 12:00 45 Met
    2/15/2016 15:00 82 Not Met
    2/15/2016 12:12 1 Met
    2/15/2016 13:14 45 Not Met

  9. Hello there
    Can anyone help me with this function, please: =IF(14<D9<17),"15"
    I need that the cell takes the value of number "15" if the value from the equation in "D9" is between 14 and 17.
    Thanks in advance

  10. Dear all

    Please tell me formula for

    If sheet1 cell A1 dated match with sheet 2 date's column A:A
    Ans will Sheet1 B1

    • Hi Ravi,

      Use this formula in Sheet1 B1 cell.

      =MATCH(A1,Sheet2!A1)

      • Hi Ravi

        if its match will show "match" not match will show "blank cell"

        =IF(MATCH(A1,Sheet2!A:A),"match","")

  11. I need a formula for a table which I'm making which shows if someone has been active on Social Media for more than 30 minutes or not.(project with many members). I also want the cell to be colored Green, if active and red if inactive. Is this possible and how can I do that? Can someone give me the formula. Will be appreciated.

    Thanks

  12. Hello,

    I have two columns, one contains names, the other contains numbers. I have the names sorted in order I need so there are blank cells (i.e. A1=John, A2=Blank, A3=Joe, etc.) The other columns contains the numbers to match the names. But there are no blank cells (i.e. C1=2, C2=3, C3=4, etc.) How do I match the numbers to show next to the names and skip the blanks? So B1=2, B2=Blank, B3=3) I tried the IF function to pull data that contains text but what do I enter so that the numbers are shown next to the names? Thank you in advance for any help.

  13. I have a question, can you help me please?
    If I have multiple sheets, for example sheet1, sheet2, sheet3 and sheet4. And each sheet has 4 columns. The first one has a reference number , the second has an information , the third has a time , the forth has a date.
    I want to put if statement, for example if i put reference number 25 in sheet4, I want it to do a search itself in the whole sheets and to copy whole the data from whole sheets & whole columns to this specific sheet
    How???
    can u help me ??

  14. Hi.
    In pivot table report I want to publish report in below format.

    Opening stock,REceived qty,Issued qty,Closing stock

    to get this report in pivot table, what should be the format of reference data.

    Thanking you..

  15. Good day,

    I can't get the border format to follow the cell I'm copying in value_if_true in the IF command.
    =IF(C13="Description",C18,"") where C18 is a value with the darken top border.
    Maybe it can't be done with the IF command but if so, I will appreciate any help in this matter. I have over 640 lines to correct and doing it by hand is time consuming.
    I could probably write a macro...

    Sincerely,

    Robert

    • Hello Robert,

      The only thing formulas can do is change the value of the cell where they are entered. If you need to change the format of the cell at the same time, please create a conditional formatting rule that will change its border or color the way you set. If you want to change the border of the cell if it contains the word "Description", you will need to use the following formula in your conditional formatting rule:
      =C13="Description"

  16. Hello,

    assume i have written in one column 100(Cell A1), 200(Cell A2), 300(Cell A3), 400(Cell A4), 500(Cell A5), 600(Cell A6). I want to multiply these by 1.25 and display the values in the same cell. eg. Cell A1 is currently display 100. Once it is multiply, the value is 125. Then that value should appear in the cell A1 instead of 100.
    Can someone support me.

    Dinesh

  17. Can you give me a formula for this? To get the current name... Cell A has name then the condition, if the the cell B is empty value Cell A, if the Cell C is empty value cell B, if the cell D is empty value cell C, otherwise value current cell. Thanks.

  18. hi
    need help in getting the value from another sheet if one condition is matched. the condition could be a unique number. can this be done by IF formula.
    i did on a sample sheet and it was correct, however when i actually implemented on the actual sheet, the result shows 'FALSE'.
    formula used i was as under
    =IF(A2=DCR!B2,DCR!A2)

    thanks

  19. Hello, Is there a formula which would be able to tell me the following. I have already an if formula to find out if it equals 80% of a gross loan(which also has other factors such as fees, interest charged depending on how long the loan has been held for,) however if they don't equal 80% I have to have a calculation to find out what the value needs to be to equal 80% is this possible?

    This is so I can have a calculator where someone can put the all the details in and it tells them what the figures need to be.
    Many thanks in advance

    Amy

  20. dear madam,
    i want to =if(c2"","completed","") please inform me to learning it.
    WARM REGARDS,
    NAVEEN.R

    • Hello Naveen,

      Most likely you need the following formula:
      =if(c2<>"","completed","")

      You can learn how to work with the IF function from the blog post above.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)