How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. I want to know how can i use the calculation :

    i have a 2 dates one is Expected and one is actual if me actual is grater then expected then the total value will calculate

    • Hello Jeevan,

      Could you please clarify what you would like to get if the actual date is greater than the expected date?

  2. Hi,
    Please help,I want to try formula =IF(E7="value","E7*25.4","NA"), I want that if There is value then it will multiply by 25.4, & also if there is not value like some text then it will come NA, but it will not come so please help me

    • Hi ANKUR BANSAL,

      Use this formula

      =IF(ISNUMBER(E7),E7*25.4,"NA")

  3. My formula: = IF(C:C = "SAAS-WFC-CONV", "Yes", "No).

    Column C HAS SAAS-WFC-CONV listed in the column but my formula is returning No.

    How do I correct this? Are the hyphens throwing it off?

    • Hi,

      correct formula

      =IF(C:C="SAAS-WFC-CONV","Yes","No")

      • STILL NOT WORKING

  4. hi

    Please help, I have downloaded raw data from different months, I need to check and separate the data according to the months it was processed in. If a specific job was processed in Jan I need to return the job reference number from that month regardless of cell its currently located in.

    • Hi Evans,

      It is difficult to provide a solution without seeing the way your data are organized. Could you please send an example of what you have and of what you would like to get as a result? You can send a sample table to support@ablebits.com, please include a link to this blog post and your comment number.

  5. Hi S.Cheusheva
    I need your help, I just want to one cell contain text in other cell list i think formula =ISNUMBER(FIND(E47,B3:B991)) in this E47 is my targeted cell

  6. I wrote this formula =IF(OR(F2>=3,F2<=17),H34*E34,0) I am trying to get H34*E34 to calculate if F2 is between 3 and 17 and if not to put 0 in the cell. What did I do wrong?

    • Hi,

      use this formula
      =IF(AND(F2>=3,F2<=17),H34*E34,"0")

  7. hello,

    i want make a formula in excel with the below data:

    if the value of cell A1 is bigger than the value of cell A2 then the cell will be red otherwise the cell will be blue.

    thank you

  8. I Need some assistance with a formula please. If cell A1>=1 and Cell B1=ok then Cell C1 needs to return yes, if either of values are not met then Cell C1 must return No

    • Hi,

      u can use this formula in cell C1

      =IF(AND(A1>=1,B1="OK"),"YES","NO")

  9. hi, i want a formula to use for tax !
    i want to say if B43(value) >= W10(value) then use the value in R10
    and if B43(value) =< W10(value) then use the value in R9

    can someone assist ?

    regards
    Jakes

    • Hi,
      u can use this formula
      =IF(B43>=W10,R10,IF(B43<=W10,R9,""))

    • Hi Jakes,

      You can also use the following formula:
      =IF(B43>=W10,$R$10,$R$9)

      If you want to change references to R9 and R10 as you copy the formula down the column, then convert them to relative:
      =IF(B43>=W10,R10,R9)

  10. Hello again,

    I used your wonderful suggestion for a formula and it works, except for one part. Here's the formula I used: =IF(F14="Baby",3,IF(F14="Child",16,IF(F14="Teen",29,IF(F14="Young Adult",49,IF(F14="Adult",69,IF(F14="Elder",89))))+IF(F17="Child",13,IF(F17="Teen",13,IF(F17="Young Adult",20,IF(F17="Adult",20,IF(F17="Elder",20))))-F15)))

    It works for teen through elder, but not child or baby. Not sure why. And by not working anymore, it won't subtract the number from F15 and I can't figure out why.

    • Hello Wolfy,

      Your formula should look the following way:
      =IF(F14="Baby",3,IF(F14="Child",16,IF(F14="Teen",29,IF(F14="Young Adult",49,IF(F14="Adult",69,IF(F14="Elder",89))))))+IF(F17="Child",13,IF(F17="Teen",13,IF(F17="Young Adult",20,IF(F17="Adult",20,IF(F17="Elder",20)))))-F15

      However, please note that the condition "Baby" is missing from cell F17.

  11. Hi Debbie,

    Use the Text to column function under the Data tab.
    1.Select the column you want to split from the hyphen.
    2.Click on Text to columns and ensure that the "Delimited" option is enabled.
    3.Click on Next and enable "Other" and enter the hyphen sign in the box provided.
    4.Click on Next and you will see limited rows displaying the split on the numbers - before and after the hyphen.
    5.Click on Finish and you will be observe the column you had highlighted is split into two columns - first column: with numbers before the hyphen and the second column: with numbers after the hyphen.
    Regards,
    Ramki

  12. Hi
    I want to do a look up table but the code I want to use to look up exists as part of a large code separated by a hyphen.
    Is there any way to return the code e.g. digit numbers 6 to 12 or all numbers after the hyphen
    eg code is
    657321-807893
    I want 807893 only
    thanks!

    • Hi Debbie,

      You can use Text to columns, as Ramki suggested, or if you need to leave the original large values, you can use the RIGHT function to get the last 6 characters from the cell if the size of the values is always the same:
      =RIGHT(F3,6)
      Here F3 is the cell with the large code and "6" is the number of characters at the end of the string that you want to get.

  13. Hi, I need to write an excel calculation that when entering in a value in one cell (Eg. A2) it will provide a cost based on the following: 100% of the first $5,000, and 50% of the next $10,000 – to a maximum of $10,000.
    Your help with this is much appreciated!

  14. i need to write if function for attendacce calliculation of days caliculation As like a=0,P=1 if i enters a in cell now to caliculate total sum with if function.
    S.no Name 16 17 18 19 20 21 22 23 24 25 26 27 28 29 "Total
    Hours"
    Main Field
    1 KUMAR A p a p 0
    2 0
    3 0

    • Hello Chaitanaya,

      If your task is to count the number of cells with value "p" in a row, you can use the following formula in the "Total hours" column:
      =COUNTIF(B3:Q3,"p")

      Copy the formula down the column to get the result for each row.

  15. Dear Madam,

    i have done my attendance sheet - month wise - i need to calculate no. of leaves - I have marked as L for leave and Present as P, Kindly suggest - I am trying if formula.

    Thanks & Regards,

    Shantha

    • Hello Shantha,

      If you want to count the number of cells with the value "L" in a column, you can use the following formula:
      =COUNTIF(B2:B38,"L")
      It will count the occurrences of value "L" in column B.

  16. omg

    +1 2074
    1963
    -1 0852

  17. Hi Svetlana Cheusheva,

    i would like to know is there possible for me to do this calculation in excel for example:
    +1 2074
    1963
    -1 0852

    1) can i do this calculation formula in excel
    2) if 9+1 = 10 but, i need it to count as 0

    thank you

  18. Hi,
    I have one excel sheet where we have 28 field in which if "nok" capture by some one than 28 fields name come in one cell if have any body such formula so pls share as soon earliest

    Regards
    Bhajan

    • Hello Bhajan,

      Could you please describe your task in more detail? If possible, please send a sample table with the original data and the expected results to support@ablebits.com and include the link to this blog post and your comment number.

  19. Hello! I have a cell with numbers concatenated from another sheet, some of the cells from the sheet have 0 and they have to be there. when I go back to the cell where cells are concatenated shows me ex: 15-35-259-0-0-0-52-98-0-0
    what I am looking for is for those 0 not to show at all.

    I how you can help me

    • Hello Hernan,

      Could you please specify if you have a formula or a value in the cell with the concatenated numbers? What is the way you want to see the resulting value, is it this way: 15-35-259-52-98?

  20. I want to use if formula with the condition of day in the date.

    A1 - 3/1/2016 - format as "Mar 2016"
    I want B1 shows "1st half" if the date is 1st regardless of the month and year. and "2nd half" if the date is 16 again regardless of the month and year.

    • Hello Sonny,

      If we understand your task correctly, you can enter the following formula into B1:
      =IF(DAY(A1)<15,"1st half","2st half")

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)