How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. I have a row consists of 10 cells, each one is the mark for a test
    Test1, Test2, Test3, etc.

    Please I need your help as I am looking for a formula which subtract Last cell from the previous one. And then if the result is greater than 1 , add 1 to The total grade if equal to 0 then don't add anything, smaller than 0 then -1.
    Later the same cells should sum the total for example:
    1+1-1+0

    Thanks in advance for your help

  2. I have a raw consists of 10 cells, each one is the mark for a test, then I need the following please:
    Test1, Test2, Test3, etc.

    Please I need your help as I am looking for a formula which subtract Last cell from the previous one. And then if the result is greater than 1 , add 1 to The total grade if equal to 0 then don't add anything, smaller than 0 then -1.

    Appreciate any help

  3. I have data of pan card no & if pan card 4th letter is P,F,C then i want in the front of 4th character of pan like that
    P-non company dedcutee
    F-non company dedcutee
    C-Company Deductee

    pl suggest formuls

  4. Hi
    I am trying to create an table where one can only enter one value in a row of 4 cells i.e. if a value is entered in any cell the other 3 cells are zero or blank.
    Thanks for your help

  5. hi,
    i just want that if number is even then column become green else red,

    please help me

    • Hi Vibhash,

      =IF(ISNUMBER(A1),"Green","Red")

  6. Hi,

    I need help......
    How to command the balance at 2/16/2016

    date in out bal
    2/15/2016 10
    2/16/2016 2 2

    Thanks in advance.

    • date in out balance
      2/15 10
      2/16 2 2

  7. I use the following formula to determine representation in a fictional parliament:

    =IF(E31>999999999, E31/2000000, IF(E31>99999999, E31/1500000, IF(E31<100000000, E31/1000000)))

    However, if the value is less than 500,000 it will equal 0, but I want anything under 500,000 to equal 1. How do I do this and keep the above equation intact?

    • Hello,

      You can add the following condition:
      =IF(E31>999999999, E31/2000000, IF(E31>99999999, E31/1500000, IF(E31>=1000000, E31/1000000,1)))

  8. =IF(A3="RED","STOP",(A3="YELLOW","READY",("RED","STOP" ENTER COLOR)))

    WHAT IS WRONG WITH THIS

    • Hello Rah,

      It looks like your formula should look like this:
      =IF(A3="RED","STOP", IF(A3="YELLOW","READY", "ENTER COLOR"))

      Please note that when you want to include another condition, you need to start it with another IF statement. You also need to enter any text you want to see in a cell in quotes.

  9. Hi,
    I'm wanting my cell to look at the cell next to it and if there is a date in there to work out a calculation. If it's blank then it is blank as well. Is this possible?

    • Hi Maggie,

      You can use the following formula for your task:
      =IF(AND(LEFT(CELL("format",C1),1)="D",CELL("type",C1)="v"),A2+A4, "")

      You need to replace C1 with the cell address you want to check and "A2+A4" with the necessary calculation.

  10. what formula use if have more than 5 input and need one output

    • Hello Prabhu,

      Please describe your task in more detail. It would be great if you could give an example of what you have and what you want to get.

  11. Hi i need Help

    A B C D E Results
    2 5 1 3 4 B
    2 1 0 0 0 A
    0 0 0 0 0 -
    0 5 1 0 6 E
    1 2 4 0 1 C

    How Can i use IF Function on Results

  12. Hi could you please assist me: I have text in cell A1 and in cell A3. In cells B1 and B3 I have numeric values. all these data I enter myself. Now I have a formula: =IF(B1>B3;A1;A3) which works perfectly, but I want this to say that when B1 is higher then B3 it must result B1 into the cell provided (D1) and it does, now my problem is that when B1 and B3 has 0, then it results cell B3 automatically to D1 and it should rather say TIE or DRAW or even just make 0 (zero)

    • Hello,

      It looks like you need to add a condition to your formula:
      =IF(AND(B1=0,B3=0),"TIE", IF(B1>B3,A1,A3))

      Please note that you may need to replace commas with semicolons as these are the delimiters you use.

  13. I tried a lot to apply the formula
    =word()
    but I am never able to get the result to convert a number into words.
    where I find it used in some excel sheet working properly.
    thanks for helping me on this issue

  14. Hi, Phoenix

    this correct formula =IF(SUM(G27:P27)<=800,AI8,"")

    if its total (G27:P27) less then =800,it will taking Data cell "AI8"and greater then =800 it will showing cell empty

  15. Hello,

    Just want to ask how to work on this:
    IF (SUM(G27:P27)<=800, AI8, "")))

    I just want to know if this is correct. Thank you

  16. Hello,
    I have very strange question, I hope you will understand and answer.
    I want to apply Formula IF(C5>0,TRUE,FALSE) It's worked, Great. I understand.
    But in my data I have 0 values in Coloured Row. I want to get results also "True" or anything else, for Coloured 0 Cells. But as per above formula it is giving results "False".
    Please do you have any other formula or Logic to solve this case?
    My Focus on Coloured Cell.

    Looking forward to your reply.

    • Hi,
      use this formula

      =IF(C5>=0,TRUE,FALSE)

  17. How I can Use IF formula for colour Cells?
    If I want results as per colour of cells.

    Thank You.

  18. Hello,
    I have very strange question, I hope you will understand and answer.
    I want to apply Formula IF(C5>0,TRUE,FALSE) It's worked, Great. I understand.
    But in my data I have 0 values in Coloured Row. I want to get results also "True" or anything else, for Coloured 0 Cells. But as per above formula it is giving results "False".
    Please do you have any other formula or Logic to solve this case?
    My Focus on Coloured Cell.

    Looking forward to your reply.

  19. Old Lotus 123 had a function @dateinfo That would return a day for the date referenced with a switch to determine the day. How to in excel?

    (K10) (L10)
    Thursday 03-Mar-16
    @DATEINFO(L10,2)

  20. Need help please,
    I would like to automate my simple payroll to calculate PAYE for different Gross payments.
    here are the tax brackets
    From To Tax Rate
    1 10,164 10%
    10,165 19,740 15%
    19,741 29,316 20%
    29,317 38,892 25%
    38,893 and above 30%

    thank you.

    • Hi,
      you can use this formula

      =IF(A1>=38893,A1*30%,IF(A1>=29317,A1*25%,IF(A1>=19741,A1*20%,IF(A1>=10165,A1*15%,IF(A1>=1,A1*10%," ")))))

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)