How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. =IF(G5=13,"1600",IF(G5=20,"1700",IF(G5=25,"2400",IF(G5=40,"12000",IF(G5=50,"22000",IF(G5=80,"30000",IF(G5=100,"41000",IF(G5=150,"145000",IF(G5=200,''322000'')? why it can not working? please kindly to help me! Thank you inadvance.

    • Hi Koung,

      Please use the following formula:
      =IF(G5=13, "1600", IF(G5=20, "1700", IF(G5=25, "2400", IF(G5=40, "12000", IF(G5=50, "22000", IF(G5=80, "30000", IF(G5=100, "41000", IF(G5=150, "145000", IF(G5=200, "322000")))))))))

  2. Can someone help me with this ...

    =IF(FIND(" (",D2),LEFT(D2,(FIND(" (",D2)-1)),E2)

    The True condition (finding a "(" in the string works) in row 2 but the False fails with a "#VALUE!" error in row 3

    D2 contains "Lafayette, LA (LFT)" and E2 contains "LA (LFT)" ... result should contain "Lafayette, LA" - it does!
    D3 contains "Neurnberg, Germany" and E2 contains "Germany" ... result should contain "Germany" - it fails!

    Thanks.

  3. hi

  4. Is there anyway to merge all this together in one field?

    If A1 is blank = Jack
    If A1 is not blank, and B1 is blank, and C1 is blank, and D1 is blank = Jill
    If A1 is not blank, and B1 is blank and D1 is blank = Sunny
    If A1 is not blank, and B1 is blank, and D1 is not blank, and E1 is not blank = Sunny
    If A1 is not blank and E1 is blank and B1 is not blank = Cookie
    If A1 is blank, B1 is not blank and D1 is not blank and E1 is blank = Mike
    If A1 is not blank and B1 is not blank, and C1 is not blank = Mike

    • This is what I have but there is two problem. One i'm not able to add the last statement in and the second the results just shows up false. Any guidance would be appreciated.

      =IF(ISBLANK(A1),"Jack", IF(AND(ISBLANK(B1), ISBLANK(C1), ISBLANK(D1)), "Jill", IF(AND(ISBLANK(B1), ISBLANK(D1)), "Sunny", IF(ISBLANK(B1), "Sunny", IF(ISBLANK(E1), "cookie", IF(AND(ISBLANK(A1), ISBLANK(E1)),"Mike"))))))

      • Oops my mistake. All my E1 are actually C1. Sorry.

        So here it is again.
        1. If A1 is blank = Jack
        IF(ISBLANK(A1),"Jack",

        2. If A1 is not blank, and B1 is blank, and C1 is blank, and D1 is blank = Jill
        IF(AND(ISBLANK(B1), ISBLANK(C1), ISBLANK(D1)), "Jill",

        3. If A1 is not blank, and B1 is blank and D1 is blank = Sunny
        IF(AND(ISBLANK(B1), ISBLANK(D1)), "Sunny",

        4. If A1 is not blank, and B1 is blank, and D1 is not blank, and E1 is not blank = Sunny
        IF(ISBLANK(B1), "Sunny",

        5. If A1 is not blank and C1 is blank and B1 is not blank = Cookie
        IF(ISBLANK(C1), "cookie",

        6. If A1 is blank, B1 is not blank and D1 is not blank and C1 is blank = Mike
        IF(AND(ISBLANK(A1), ISBLANK(C1)),"Mike",

        7. If A1 is not blank and B1 is not blank, and C1 is not blank = Mike
        ???

        Current code i'm stuck on without statement 7

        IF(ISBLANK(A1),"Jack", IF(AND(ISBLANK(B1), ISBLANK(C1), ISBLANK(D1)), "Jill", IF(AND(ISBLANK(B1), ISBLANK(D1)), "Sunny", IF(ISBLANK(B1), "Sunny", IF(ISBLANK(C1), "cookie", IF(AND(ISBLANK(A1), ISBLANK(C1)),"Mike"))))))

        • Hi TinWin,

          Please use the following formula:
          =IF(ISBLANK(A1), "Jack", IF(AND(ISBLANK(B1), ISBLANK(C1), ISBLANK(D1)), "Jill", IF(AND(ISBLANK(B1), ISBLANK(D1)), "Sunny", IF(AND(ISBLANK(B1), NOT(ISBLANK(D1)), NOT(ISBLANK(E1))), "Sunny", IF(AND(ISBLANK(E1), NOT(ISBLANK(B1))), "Cookie", IF(AND(NOT(ISBLANK(B1)), NOT(ISBLANK(D1)), ISBLANK(E1)), "Mike", "Mike"))))))

  5. Hi,

    If anyone can help?

    I am trying to use if function to show the text "probable" is ok. It is a very simple formula but I am completely baffled that "probable" comes as a false value when it should be a true value. Anyone have a solution to this? Results below with formula;

    certain ok =IF(B3="certain","ok","not ok")
    probable not ok =IF(B4="probable","ok","not ok")
    possible ok =IF(B5="possible","ok","not ok")
    probable not ok =IF(B6="probable","ok","not ok")
    red ok =IF(B7="red","ok","not ok")
    chair ok =IF(B8="chair","ok","not ok")
    laptop ok =IF(B9="laptop","ok","not ok")
    maybe ok =IF(B10="maybe","ok","not ok")
    probability ok =IF(B11="probability","ok","not ok")
    probable not ok =IF(B12="probable","ok","not ok")

    Why is "probable" seen as false(not ok)?

    Looked everywhere can't find a solution

    • Hi Mohammed,

      It seems you have spaces in your cells. Please try to trim the cell value before comparing.

      =IF(TRIM(B4)="probable","ok","not ok")

  6. i want to stop the TAT calculation after enter my final date, could you please let me know that formula for that, and i know how to use TAT calculation, only i want to know if i enter 3rd date it should be freeze.

  7. Scenario: You have been provided with a list of expenses for the month- eg Column A is the $, and column B is the cost centre (using a drop down list). eg $1,000 cost. Cost centre is ADMIN

    I want a spreadsheet whereby it can automatically move the expense into relevant cost centre, and then give me the total for the month.

    Dean

  8. If Cell A2 is greater than cell B2 then Cell C value is 1, If Cell A2 is smaller than cell B2 then Cell C value is 2, If Cell A2 is equal to cell B2 then Cell C value is 0. Can anyone let me know the function

      • Dear Taufiq,

        Put your values in A2 & B2 , PASTE this formula in C2.

        this formula can be make shorther but for your understanding i have used 3 formulas

        =IF(A2>B2,1,IF(A2<B2,2,IF(A2=B2,0)))

  9. Dear Sir,
    I want to do stock ageing.Our item reference sample is 89p25. Here each year represent different parcel number for eg.(p25,p26,27). How to set formula in another sheet.Please advise.

    Thanks & Regards

  10. Hi,

    We Want Excel Sheet of "How can used "=if".So, Kindly Provide to me As soon as possible.

    Thanks & Regards.

  11. Hi,

    I want a formula for timing.
    Ex: if my office time is 9:00 AM in morning when i came late 10 Mins , then the formula should reflect as "Minimal Delay" And if i came across 10 Mins > Greater to < 30 Mins lesser then it should have to reflect as "Maximum Delay", However the delay timings would get different colour for "Minimal Delay", "Maximum Delay", could you help me to get formula for this.

    Thanks in Advance

  12. I want to know a formula that could say If I should "follow up" a delivery 5 days prior to my actual request or "not", from the date I requested.

    Many thanks in advance!

  13. I'm trying to develop a formula that turns wealth ratings into numeric scores

    $100M+ = 8
    $50M-$99.9M = 7
    $25M-$49.9M = 6

    and on down the line.
    Here is the IFS statement I was starting with:

    =IFS(V2="$100M+"),8),(V2="$50M-$99.9M"),7),(V2="$25M-$49.9M"),6),(V2="$10M-$24.9M"),5), (V2="$5M-$9.9M"),4),(V2="$3M-$4.9M"),3),(V2="$2M-$2.9M"),2),(V2="$1M-$1.9M"),1),(ISBlank(V2),0)))))))

    It didn't work. Is there a way to do this?

  14. Kindly Resolve this

    If ( Column1 = 'Completed', Date (like 29-Apr-2016), Process)

  15. Hi
    Value in cell A3 is 10
    I want to check this value tn 4 Different Criteria
    1)Less than 20
    2)Greater than 20 but less than 50
    3)Greater than 50 but less than 80
    4)greater than 80
    Please help
    Regards
    Venkat

  16. i hv a value in say B2 such as these: BAHJHB16A0001 or BOHJHB16A0003.

    I want to put in a formula in A2 if value in B2 starts with BAH then A2 should be BAH.

    If B2 starts with BOH then A2 should return value as BOH.

    if i use the sign = or it is not accurate. I would appreciate some help. Thank you.

  17. Hey,

    Hows you ?

    I need a formula where if i select range from a2 to a300 than result will appear on E2 TO E300

    For Example , if my A from 1 to 300 Column contains all vendors name & my B contains all Vendors account no.

    I need a formula where if i select Vendors name in column A from Drop down list than Vendors account no should come automatically...

    Can you help me with this

  18. Trying to enter a formula to tell me if the word "error" is anywhere in a single row between columns H and BT. Is this possible?

  19. Please help me to figure out a formula for the below scenario :-

    If the cell value (G20) is less than 80%(C2) then F22 should be 0

    If the cell value (G20) is in between 80% to 90% (C2 to D2) then F22 should be C8*c3,
    If the cell value (G20) is in between 900% to 100% (D2 to E2) then F22 should be C8*D3,
    If the cell value (G20) is in between 100% to 110% (E2 to F2) then F22 should be C8*E3,
    If the cell value (G20) is in between 110% to 120% (F2 to G2) then F22 should be C8*F3,

  20. cell A1 containing 1:Mahabharat
    cell A2 containing 2:Ramayan
    cell A3 containing 3:Geeta

    i want give formula in "2" number containg in cell A2. i.e. i want result of "2" by formula of "1" + 1.

    kindly hepl me in above problem

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)