How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. Hi, can someone help me with an IF formula as follows:

    If Cell C17 contains "PASS", and Cell C30 contains "PASS", then PASS should be returned, if not, FAIL should be returned.

    • Hi May,

      What you need is an If formula with nested AND like this:
      =IF(AND(C17="PASS", C30="PASS"), "PASS", "FAIL")

  2. How can get a formula to calculate the mark up on an item based on the category code. We have 3000 items and 40 categories. We have a master list on a separate worksheet for the categories with their markup. I want to markup the cost based on the category. For example:
    Worksheet #1 Worksheet #2
    Category Cost Sell Price Category Markup
    SNA 10.00 BOT 1.5
    CAP 15.00 SNA 1.8
    CAP 1.6

    I can use an IF formula, but I'm hoping there is something quicker as opposed to typing a 40 item nested IF formula. Thanks.

  3. hi , I am trying to write a nested formula. the formula I am using is
    =if(c4="jose","good",or(c4="jesus","better",""))
    The problem that I am running into is, that it reads the first nested formula but it will not read the second. can you help me with this formula. or recommend another

    • Hi Jesse,

      You don't need OR in nested IF's:

      =IF(C4="jose", "good", IF(C4="jesus","better",""))

      • thanks

  4. Hi,

    I am using an IF statement to check if 2 cells match.

    However where 1 cell is blank (not yet populated) it will reflect as "same"

    Can I use isblank in combination to bring back a blank cell if both referenced cells aren't populated.

    =IF(AC118"",(AC118=P118,"SAME","CHANGE"), "")

    • Hi!

      Try this formula:

      =IF(AND(AC118="", P118=""), "", IF(AC118=P118,"SAME","CHANGE"))

  5. Hi,

    Could somebody help me with this issue:

    I'd would like a formula where this condition is met.

    A1 B1 C1 D1
    A2 B2 C2 D2
    A3 B3 C3 D3
    A4 B4 C4 D4

    The formula for all cells in column A: if the cell below is empty return to the first cell in column D. So for example if cell A5 is empty I want the value of D1. But also A6 is empty so i want the value of D2. Can sb help me with this?

    Thanks you in advance

    Nicolas

  6. i'M SORRY I meant using the today statement...

  7. I need to create a if formula to populate an statement for this:

    5/29/16 10:25 PM

    I need to collect any data that if before today at 3:00 pm

    any help is welcome,

    Thanks !

  8. =IF(N8:N19="Completed","Yes","No")

    i have tried this to test list of cells which are updated thru a data validation list its not working please anyone can help.

    • The list of Data validation referes like this

      Completed , in progress , on hold , new

      these are the four validation can be selected now i want this above formula to work to tell me once are completed.

      =IF(N8:N19="Completed","Yes","No")

      i have tried this to test list of cells which are updated thru a data validation list its not working please anyone can help.

  9. Formula below wont halve the figure as it should
    result when c33 is 2 is 100%. When c33 is 0 the result is only changing to 95%
    =IF(C33="0", R16/2, R16)

  10. hi i need a follow for below.

    = 90% 1%
    >= 100% 1.30%
    >= 110% 1.50%
    >= 115% 1.75%

    thank you

  11. Hi.
    I need a formula
    Example
    Alpha123
    After a formula

    Cell-1.Alpha
    Cells -2..123

  12. Hi I'm setting up a stores system, I have set figures in the min & max and a stock level that can be adjusted by a user.
    Min is in row G13, Max is in row I13, Stock level is in row K13.

    I need help to put a formula in L13 to say "min stock" or "stock ok" or "no stock"
    So when the stock level in K13 is the same as the min level in G13 it says "min stock", if stock level in K13 is greater than min level in G13 it says "stock ok", if the stock level in K13 is zero it says "no stock".
    Thank You

  13. I need formula, if cell a1 is (3), cell b1 should be insert text "good"

    • hi Zvonko,

      =if(A1=3,"good","")

  14. I have a unit quantity in cells B5-J5.
    I have prices in cells B6-J6.
    When someone enters YES in cells B8-J8, then cell K8 should total units booked, but not allow units to exceed a quantity of 10.
    Cell L8 should total row 6 dollar value of cells with a yes placed in corresponding row (in this case row 8) from values in B6-J6.

    Thank You!

  15. sorry got working with

    =IF(ISBLANK(AE5), TODAY()-M5,AM5-M5)

    now just the colouring..?

    • Select the column(s) you want to color excluding header rows, and create a conditional formatting rule with the below formula (which checks if a cell in column AE is blank):
      =$AE5=""

      The detailed steps to create a formula-based rule can be found here.

  16. also if using todays date due to null can this appear in red so know not complete?

  17. Hello, I want AM5 to =AE5-M5 to count days between to dates. If AE5 null I want it to count to todays date. I can't get my logic to fit logic!!

  18. Hi,

    Please help me for getting the formula for below

    If B1 have some date mentioned then A1 has to come delivered
    if B1 dont have date it sould come in transit

    • Hello Bahubali,

      Try this one:

      =IF(B1="", "in transit", "delivered")

  19. hi,

    i have a issue in excel for using a formula. my problem is sum of range in a column.for example, a table contains data describe below:-
    sr.no. class student name marks
    1 sixth parmod 166
    2 sixth kamal 140
    3 sixth parmod 250
    4 seventh kamal 270
    5 seventh parmod 180
    i want the sum of parmod marks of six th class. how and which formula is used for it......

    please help
    i have to find parmod marks of class sixth

    • i used it but something wrong.
      =if(b:b="sixth",if(c:c="parmod",sumif(c:c,"parmod",d:d)))

      • Hello Parmod,

        To conditionally sum cells, use SUMIF or SUMIFS function to sum with one or several criteria, respectively.

        In your case, you can use this formula:
        =SUMIFS(D:D,C:C, "parmod",B:B, "sixth")

        Where column D contains marks, C - names, and B - classes.

  20. Hi,
    ordered qty,Produced qty ,bal to produce qty, ready for delivery qty, and delivered qty, delivery date .How can I follow up before one week of deadline ?
    And could you please provide me a gantt chart to solve this ?

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)