How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. Need Help please... Thank You in advance.

    I have 3 columns.
    Column A - list of country
    Column B - Yes or No
    Column C - country (example in C1="PERU")

    Column D - result should be "Yes" or "No"
    - if C = "PERU" and if all the data with "PERU" in column A has value
    of "YES" in Column B, then "Yes", otherwise "No"

  2. Hi

    I'm trying to figure out a formula using the function IFs where I have 3 conditions to return "e.g. 3 payable commission roles 10% 12% & 14%" - But I am not sure how to write this all in small function in excel !
    This is what I am after "between/equal 100% & 109% then multiple the revenue by 10% , between/equal 110% & 119% then multiple the revenue by 12% ,EQUAL or greater than 120% then multiple the revenue by 14%, return £0 if less than 100% " this is what I have done so far :
    A1 % to target
    B2 £ Revenue
    =IFS(A1=100%,"B2*10%",A1109%,"B2*10%", .....)

    I would really appreciate your help.

    Thank you
    Hasnaa

  3. I have different dates in column B1,B2... and amount in G1,G2... for which i have to calculate service tax pertaining to that date.
    I'm using below formula which is not calculating properly.
    =IF(B5<1/6/2015,G5*12.36%,IF(B5<15/11/2015,G5*14%,IF(B5<1/6/2016,G5*14.5%,G5*15%

    Please let me know in which format the date should be in formula as well as in column B

    Looking for your reply..

  4. Hi Svetlana

    Need a help

    If Cell A1 & B1 have no date Show C3 as Blank
    If Cell A1 have date show C3 as In-Progress
    If Cell B1 have date show C3 as Completed

  5. hi dear ,
    i have data sheet of fragrance product ,trying to find sizes from column to past in to aother column
    for instance column A1 hsd discription of perfume name and its sizes such as 1. oz , 1.5 oz , 2. oz and so on....i would like to just take ""sizes"" from column A1 to collum A2. what would the formula to do this coz i got 10000 products on sheet .
    *
    sizes are about 15 to 20 diffrent types on entire sheet or value which needs to be found and past in to specific collum . how to write formula for this action . thx .

  6. Hi I have query please
    In A2 is the status if I put date in B2 the A2 put "Requested" and if I put date in C2 the A2 change "Delivered" and if I put date in D2 the A2 change "Released".. Please help me thank you..
    What formula can I used.

  7. Hi good day,
    What formula can I used, example if I put date
    Status Request Delivered Released
    Request 10-5-16
    Delivered 10-5-16 10-10-16
    Released 10-5-16 10-10-16 10-15-16

    Please help. Thank you :)

  8. i am trying to get a result back from a cell that has a formula in another cell. =IF(AND(P48),$X$11,""). the results of this formula will be a number. the problem is that when put another formula (=IF(AND($Z$11>0,$W$11<0),$X$12,"")) in another cell it sees the formula not the results of the formula. how can I get excel to see the actual results in stead of the formula.

  9. Hi,

    I am trying to figure out how to format this formula. I need to create a formula that if either of the cells J3 or N3 are blank then S3 is 0. If none of the cells are blank, then I want S3 to be N3-J3

    Any thoughts?

  10. Hi, i was wondering is there any formula in excell that will be able to help me with the following. if i put in a value from 1-10 the following must happen, if i enter 1 it must calculate to 12 and 2 must go to 10 and 3 to 8 and so on, and it must calculate over a few cells.
    i hope you wil understand what i said here.

  11. I need a formula rule for formatting so that the current date is referenced and anything previous to it is highlighted and subsequently anything 30 days after the current date is highlighted differently?

  12. Can you help me with the formula.

    Suppose I want to find M in the formula

    [M-X]

    X is a known value
    and I want to find M .
    The criteria is
    1. M = x if X is between 98.5 and 101.5
    2. M = 98.5 if X is smaller than 98.5
    3. M = 101.5 if x is greater than 101.5

    All three conditions I want to include in one cell. How can I perform it. Please help.

  13. Hi,
    In Cell "AE2" I need to show always "URGENT" until CELL "V2" value is " " (Blank). when Cell "V2' goes Greater than 0, Cell "AE2" need to show the value of Cell "V2".
    Please some body help

    Thanks

  14. Works perfect. Thanks

  15. =IF($K3<=500,$K3*1900,IF($L3<=500,$L3*1900,IF($M3=1000,"High Power Distance", IF(M3="-","No Grid")))))

    For above formula, i will get High power distance for "-" in cells.
    I want to display "No grid" for value - or blank space.

  16. Hello,

    I'm using the following formula:
    =IF(OR($J34="CM",$J34="PDC"),$M34,0)
    In the cell it show #name?. What is wrong with the formula.

    Regards,

    Jercon

    • Hi Jercon,

      The problem is in smart quotes (”CM” and ”PDC”), which is often the case when copy/pasting formulas. Just retype the quotes directly in the formula bar, and your formula will start working properly.

  17. Dear how to use if below formula
    0-30 and 31-60 and 61-90 and Over 90 days

  18. Help with this?
    =IF('Menses Tracker'!E2="Re-Occuring", "=DATE(YEAR(C2)=1,MONTH(C2)+1,DAY(C2))", "=DATE(YEAR(C2),MONTH(C2),DAY(C2)+90)")

    Basically what I want is if on the first sheet(menses tracker) in cell E2 is says Re-Ocurring then I want it to calculate a date using the date in cell C2 + 1 year and 1 month, if it does not then I want it to calculate the a date using the date in cell C2 =90days.

  19. dear Svetlana Cheusheva,

    have a nice day,

    i have 2 quires please help.
    1- can we use if and count-ifs formula in one cell.
    2- i am using this formula =CONCATENATE(TEXT(K33,"(DD-mmm-yy")&" To ",TEXT(K34,"dd-mmm-yy)"))i 2nd date is less then first date how result show as massage " Wrong Date.

    i am expecting your kind and early response.
    thanks

  20. hi i have query please solve it

    NUMBERS REQUIRED ANSWER
    1 2,3,4
    5 6,7
    8 9,10,11
    12 13,14,15
    16 17
    18 19
    20

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)