How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. Hi cheusheva,
    I need to enter a formula that, if the given Date is lesser than or equal in a range of date exists; it should count the corresponding value of that particular date which is lesser than or equal, can you help me, I tried entering formula like here,
    ex: IF(A2<=D2:D234,COUNTIF(E2:E234,B2),""), but this isn't working...!

  2. if bob starts at 10am and ends at 12pm
    if sue starts at 10am and ends at 1pm

  3. I have a problem. it's a time sheet and across the top row is the times from open to close. next few rows down is the start and end times of all the workers from the time they start working to the time they end their shift. I need a formula to calculate their hours per work shift.

    Example of what I am working with

    A B C D total
    10am 11am 12pm 1pm
    bob start end 2
    sue start end 3

    • I've tried using this formula but it won't add the texted cells, it just shows a 0.

      =SUM(IF(ISTEXT(C5:K5),1,0))

  4. Hi Can you please help me.

    I have a data set where the question asks: How many of the above products are produced in Namibia?

    The options in the questionnaire were: I don't know, not applicable and giving specific numbers such as 1 or 100.

    Butt the results of the data: came with different formats i.e. 1 to 10, or +-100. who do i evaluate those results in a data set of 450 cases to get the total number of products?

  5. hi Svetlana,

    could you please help me to get this below readings to nearest ten. for

    Example
    4204 to 4200
    5403 to 5400
    8439 to 8440
    8360 to 8360

  6. can you help me to get nearest 10

    for example 1844 it should need 1840
    and 1846 it should come automatically to 1850

    like this so plea help me to to get this formula

  7. how do i indicate a value for a particular month:

    if month=January, above cell + 31 days else above cell + 30 days

    What is the syntax for this function ?

    • Hello Dharmesh,

      You can use a formula similar to this:
      =IF(month(A2)=1, A1+31, A1+30)

  8. Hello Svetlana,

    I wish to have something like this
    If M8 from 0 to 10% then 1
    If M8 from 10% to 20 % then 2
    If M8 from 20% to 30% then 3
    If M8 from 30% to 40% then 4
    If M8 more tjen 50% then 5

    So is this posibile in excel?
    Thank you in advanced

  9. I HAVE A FORMULA IN Cell J6 and I have another formula in g6. WHEN I ENTER ANOTHER FORMULA IN K6 =IF(SUM(G6*J6),G6*J6,"") i WILL GET RESULTS ONLY WHEN THE CELLS HAVE NUMBERS. BUT WHEN CELL J6 OR G6 IS EMPTY I GET THIS IN CELL K6 #VALUE! INSTEAD OF A BLANK CELL CAN YOU HELP ME

  10. hi,
    i have characters in row "A" in drop down box.
    i just need to display value depending on different products in row "A"
    for different products i have different value for multiplication . how can i do that on conditional bassis. suppose if i choose product A1 then it should choose multiply by 2, if i choose product "B" it should be multiply by 3 and so on

    • Hi!

      Assuming the dropbox is in cell A1, and the value to multiply in B1, the formula goes as follows:

      =IF(A1="a",B1*2, IF(A1="b", B1*3, IF(A1="c", B1*4, "")))

  11. I am trying to figure out how to use excel to figure my time sheets. I have a computer program that will send me a print out that looks like this, I can import in excel and it would look like this..
    Example:

    CARRIE EVANS - CLERK
    Punch In Punch Out Reported Tips Time (Hours)
    Thu, 10-20-16, 6:50 am Thu, 10-20-16, 2:03 pm 0 7.217
    Fri, 10-21-16, 6:50 am Fri, 10-21-16, 2:00 pm 0 7.167

    I need an excel spreadsheet that I can Import this into and figure to the 15 min increments. Punch In is one cell and Punch out is one cell. I wish it was day, date, time all in different cells, but that is not the way it imports. Can anyone help me with this. Thank you

    • each cell looks like this
      Punch in
      Thu, 10-20-16, 6:50 am
      Punch Out
      Thu, 10-20-16, 2:03 pm
      Reported Tips Time (Hours)
      0 7.217

  12. Please Help Me If Function below the condition

    1. From the basic salary of Rs 8250 to Rs 9700, Rs 4500 minimum basic salary at the rate of 50%.

    2. Base salary up to Rs 16,000 from Rs 9701, Rs 4800 minimum basic salary at the rate of 45%.

    3. From the basic salary of Rs 16001 to Rs 35500, Rs 7000 minimum basic salary at the rate of 40%.

    4. Rs 35501 and above base salary, up to 35% of the minimum wage of Rs 13800.

  13. hi,
    I am doing a template for quiz competition in excel, in excel book first sheet is for participants there is a questions and the seperate cells for typing ans
    if the answer is correct the mark will appear in the second sheet in the respective cells
    for this i am using if condition
    for ex: ans for 1st question "ABC" which enroll second sheet
    incase the participant gives the input as "BCA" instead of ABC how can i do

  14. Hi Svetlana

    Need a help to populate status on C3 based on A1 & B1 value on project tracker

    If Cell A1 & B1 is blank leave C3 value as Blank
    If Cell A1 have start date show C3 as "In-Progress"
    If Cell B1 have end date show C3 as "Completed"

    Thanks.

  15. Hello,

    How can i pull out birthday's of employee automatically using current date, for example, i have the list of the employee's with me , i just want the list to automatically pull out the employee's name who have their birthdays today.

    Thanks.

  16. Good day Svetlana,

    I have this simple formula,

    =if (A1B1, the function return "Failed".

    How can Excel compare a number with a string (5<N/A)?

    5<N/A should produce #Value or #Error...

    Kindly help.

  17. Hi! can you help me with a formula? i have sheet wherein C1=B1 multiplied to A1 but i want C1 to be blank if B1 is blank and C1=B1 if A1= 0 or blank..

    thanks

    • Hello Clark,

      Try this one:

      =IF(B1="", "", IF(OR(A1=0, A1=""), B1, ""))

  18. I am trying to do an if formula for a Y n that if it hits a yes it then goes on to do a sum... but I cant get it to work, am I using the wrong formula
    =IF(J7="Y",P7/5,IF(J7=n,"0"))

    Please be kind as I am a novice

    • Hi Peej,

      You need to enclose all text strings in double quotes, but not numbers:

      =IF(J7="Y", P7/5, IF(J7="n", 0, ""))

  19. Hi Svetlana
    I want to group golf scores into birdies, pars, bogeys and double bogeys. I have my golf scores in cells c4 - u4 and the course par for each hole is in c3 - u3

    eg hole 1 (c4) my score is 4 and par (c3) is 4 so I need a IF formula for cell k20 which is to add up all my pars for the round (18holes)
    If I scored 6 pars (6 times where my score in row 4 will equal the par for that hole in row 3)

    I want to do the same to record birdies (score is 1 less than par), bogeys (score 1 more than par), dbl bogeys (score 2 more than par) etc
    using different cells

    All the details of number of birdies, pars, bogeys and dbl bogeys will be using the data contained in cell ranges c4 - u4 and c3 - u3.

    Hope you can help

    • Hi Murray,

      To make things easier for me to understand, can you please send a sample sheet we well as expected results to support@ablebits.com, or copy a piece of data to Excel online and post a link here?

  20. I HAVE THIS FORMULA IN J6 =IF(ISNA(VLOOKUP((P4),'15-16'!$A$3:$F$2545,6,FALSE)),"",VLOOKUP((P4),'15-16'!$A$3:$F$2545,6,FALSE)) THIS FORMULA WORKS GREAT. BUT WHEN I ENTER ANOTHER FORMULA IN K6 =IF(SUM(G6*J6),G6*J6,"") THIS FORMULA ALSO WORKS BUT WHEN THERE IS NOT TEXT, THE COLUMN IS SUPPOSED TO BE BLANK, INSTEAD IT BRINGS BACK #VALUE! THE FORMULA IN K6 IS LOOKING AT THE FORMULA IN J6 INSTEAD OF THE RESULTS IN J6. CAN YOU HELP ME

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)