How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. I'm creating time sheets in Excel. I would like for a cell to automatically populate "8" if another cell contains any one of several dates. I am able to use the following formula successfully for one date:

    =IF(O9=DATEVALUE("12/23"),8,"")

    However, I would like to use multiple dates. For instance, show "8" if cell O9 contains 12/23, 4/14, or 11/24. Otherwise, leave the cell blank.

    Any ideas?

    • Sorry this a cut and paste from me elsewhere. Check if the cell does/does not exist in a named range of cells containing your exception dates.

      Hi, sorry I don't have a spreadsheet in front of me to syntax check.

      Eg.
      IF( OR( A1="Football" , A1="Basketball", A1="Hockey"), "Sport" , "Something Else" )
      -OR-
      I often flip my IF statements to check for Errors or Exceptions first.
      Eg.
      Define an area in Formula Tab, MySportList=$L$31:$L$59
      Fill these cells with your sports.
      IF( ISERROR( VLOOKUP( A1, MySportList, 1, false)), "Something Else", "Sport")
      # IF TEST is, if you get an error when trying to lookup the contents of A1 from your list of Sports in cells, L31:L59, then display "Something Else", else display "Sport".

  2. if A1 is 0 print 0 and if B1 is 0 print 0 and if ((A1 and B1)>0) print =A1+B1

    • IF( OR( A1=0, B1=0), 0, IF( AND( A1>0, B1>0), SUM(A1+B1), "A or B is less than Zero")

  3. Hi Svetlana Cheusheva,

    I am facing issue with this formula and need your guidance.

    i am preparing a sheet which contains Team attendance and would like to use IF condition. For ex: if a person is coming in the morning shift he has to number as 1, if afternoon it's 2 and Night it's 3, Leave it's 4. How can I write a formula for this. Please advice me on this.

  4. hello Emmanuel again =IF(D8"",D8+8,"OFF") this formula works on a same sheet but picking the source from a different sheet doesn't give me the correct answer example =IF(Sheet1!D3"", D3+8,"OFF". it only gives me 8 without adding the figure in the cell. can you help

  5. I am looking for some help and guidance. in Excel 2007

    basically I have 3 cells. In one cell I have a calibration date, In second cell I have due date, and in third cell i have frequency of calibration i.e. quarterly, annually and 2 years. Now at the moment I have to manually change all the dates whenever the due date is up, what I would like to do, is to be able to change the calibration date and for the due date to change automatically based on the frequency of calibration.

    Could someone please help me with this issue? Many thank

  6. Hi,

    I need a help.

    Assume that this values are in one cell "'C3, C4, C6, C10, C11, C12, C16, C17, C18, C22, C23, C24, C30, C31, C33, C34" .

    I need a formula that whether C17 is present in that cell or not.

  7. i want to create a formula where =IF(D8"","+8","OFF") where if not blank add 8 and if blank put off. But the formula is not given me the required result

    • Hello Emmanuel,

      Here's the correct syntax:
      =IF(D8<>"", D8+8, "OFF")

  8. Hello Svetlana,

    I have a conditional formula in Column F and am seeking a conditional formula for Column G. My goal is for Column F to affect Column G, dependent on the parameters I give Column G. I would like for Column G's logic to be as follows:

    If F1 is >=6 concurrently <11 [then] if true, G1 = 1. If false, G1 = "".

    Thank you for your valuable help.

  9. I want red font color if the logic is false.
    Pls. guide me.
    with thanks

  10. I have a date format in column e and in column f I have put a formula for it to automatially update it to 3 years later by adding 1095 to column e. Now, I am trying to get column a to turn red 60 days before column f is mature. I have tried conditional formatting but for some reason it doesn't work.

    • Hi, sorry I don't have a spreadsheet in front of me to syntax check.

      Checks:
      Column E has numbers that display as text and not text "12/09/2020".
      Column F should be the formula =E1+1095 and display 12/09/2023.
      Format:
      Condition Formatting on Cell Range =$E$1:$E$51 as a formula option.
      IF( TODAY() >= (F1 - 60), TRUE, FALSE)

  11. Is it possible to use OR commands in the logic function?

    Ie, something along the lines of

    =IF(A1="Football" OR "Basketball" OR "Hockey", "Sport", "Something Else")

    Thank you in advance

    • Hi, sorry I don't have a spreadsheet in front of me to syntax check.

      Eg.
      IF( OR( A1="Football" , A1="Basketball", A1="Hockey"), "Sport" , "Something Else" )
      -OR-
      I often flip my IF statements to check for Errors or Exceptions first.
      Eg.
      Define an area in Formula Tab, MySportList=$L$31:$L$59
      Fill these cells with your sports.
      IF( ISERROR( VLOOKUP( A1, MySportList, 1, false)), "Something Else", "Sport")
      # IF TEST is, if you get an error when trying to lookup the contents of A1 from your list of Sports in cells, L31:L59, then display "Something Else", else display "Sport".

  12. Hi,
    I need a formula as per below scenarios, can someone help on this:

    column 1 = Yes / NO
    Column 2 = Rural / Urban
    Column 3 = Balance dues in number months shown

    below is the requirement :

    Column 4 = if line item says Yes and Urban and no. of months due is 2 then 4 should be the resultant. second secenario if line item says No and urban then the 0 should be the resultant in the same cell.

    Thanks !

  13. Hi Gene

    can you help me develop IF syntax for:

    Youth (64)

  14. Hi All,

    I have formula in the Cell Z24 i.e. =((V24-L24)*E24)-AD24-AB24-AE24-AC24. Now my requirement to this is when CELL "E24" is "Not ZERO" or "BLANK", then it should process the formula =((V24-L24)*E24)-AD24-AB24-AE24-AC24 else, if CELL "E24" is "ZERO" or "BLANK", then the value in Z24 should be "0".

    Any help pls?

    • Hi, sorry I don't have a spreadsheet in front of me to syntax check.
      I often flip my IF statements to check for Errors or Exceptions first.
      Eg.
      IF( Value(E24) = 0, 0, CALCULATE)
      -OR-
      IF( OR( E24=0, Trim(E24)="", ISERROR(1/E24) ), 0, CALCULATE)

  15. Hi, so far I have this formula in cell I3 which works. My problem is that I don't know what to add to tell I3 that if D3 is blank then I3 should be blank too. I hope you can help

    =IF(D3>100,"50",IF(D3<100,"30"))

  16. I need your help, I have to calculate the interest amount on bases of delayed dates. Ex. 500 days. Base amount-Rs 10,000

    Interest rate slab mentioned below
    <180 days-18%
    365 days-30%

    So, I have to pay Interest for first 180 day@18%,Second 185 days@24%, remaining @ 30%.

    Can you give the excel formula for the above case.Please

  17. Hi. Please help.

    If($CC$2="AC",($CC$5*AC6),IF. . . . .

    That is my formula. How do I get that if cell CC2 is not equal to anything, that the cell then stays empty. Cause if I put in "", the return value is 0, and it has to return an empty cell and not 0.

    Thanks

  18. if A and D are both less than 75: 0
    if A is greater than or equal to 75 and D is less than 75: Calculate (A — 75) = X value.
    if D is greater than or equal to 75 and A is less than 75: Calculate (D — 75) = A/D value.
    if A and D are both greater than or equal to 75: Calculate [(A — 75) + (D — 75)] = A/D value.

  19. Hello everybody,

    I have a task, please help me to prepare it in excel. in one sheet column A, I have some barcode numbers and in coloum B i have its text name. In another sheet I want to make something like if i scan a barcode sticker with scanner and if it is present in Column A, it must display its text value from column B instead of number.

    thank you

  20. Hi, how can I extract a specific data based on condition from a range of cells, like below
    A1 B1 C1 D1 E1 Result
    Pass Pass Pass Fail Pass Fail

    Problem Statement: I want to print 'Fail' in result cell if any of cells from A1-E1 has FAIL in it, or else Pass if there is PASS in any of the cells from A1-E1.

    Any help is appreciated

    • Hi Sash,

      You can use the following formula:

      =IF(COUNTIF(A1:E1, "fail")>0, "Fail", IF(COUNTIF(A1:E1, "pass")>0, "Pass", ""))

      • Hi, how can I extract a specific data based on condition from a range of cells, like below
        A1 B1 C1 D1 E1 F1 Days
        35 39 32 34 36 42 Share price
        I want to know whether today share price is greater than last 5 days.
        If it is greater then alert message needs to be created "YES".
        It is easier for 5 days period however in case of 15 days or 30 days or 45 days, it is difficult to track.
        Need formula for daily tracking of stock for period of 15 days/30 days/45 days.

        • Hello!
          You can calculate the maximum value of the 5 preceding cells in a row using the formula

          =MAX(INDIRECT(CELL("address", INDIRECT("R2C"&(COLUMN(INDIRECT(CELL("address",L2)))-6),0))&":"& CELL("address", INDIRECT("R2C"&(COLUMN(INDIRECT(CELL("address",L2)))-1),0))))

          R2 means row 2. You can change the row number.
          L2 - cell with the current value.
          You can learn more about INDIRECT function in Excel in this article on our blog.
          If something is still unclear, please feel free to ask.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)