How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. I'm trying to do monthly columns from a previous column in same spreadsheet with random/multiple dates; pulling a dollar amount from ea month into it's own months' column. Is this possible?

  2. Hi,
    Could you help with the following that I want use in conjunction your Merge Two Tables Add In? I read through your "IF function in Excel" page and the comments but don't see an answer to my problem:

    I have the following headers for columns A to F
    Appointment Status, Session, Date, Consumed, No Show, Balance

    In column A I have 3 states: Complete, No Show, NoShow NoEmail
    In column B I have various possible text strings: e.g. "PhonePill Flexi 20" "PhonePill Flexi 30", "PhonePill Flexi 40" the last number represents minutes.
    In column D, I used this formula =RIGHT(B2,SEARCH("",B2,2)) to show that last number from the column B text string: 20, 30 or 40

    However, what I really want is for those numbers to go in the appropriate Consumed (D) or No Show (E) column: i.e. if the Appointment status =Complete the number should go in column D. If the Appointment Status= No Show or = NoShow NoEmail, the number should go in column E

    Thanks for your help.

  3. Hi , could some one help me to create a formula please
    i have two products alloy and carbon steel. these have composition in maximum and minimum range in percentage . if composition is different then given minimum and maximum range result of formula should say pass or fail . range is :
    Steel Type Carbon Manganese phosphorus sulphur nickel chromium
    Carbon Steel Max 2.1% 1.5% 0.5% 0.3% 0.25% 1.5%
    Min 0.5% 0% 0% 0% 0% 0%
    Alloy Steel Max 1.5% 5% 1% 1% 5% 15%
    min 0.5% 0% 0% 0% 2% 11%

  4. HOW TO USE IF FORMUALA IN CASE OF
    C=COMP
    P=IND
    OTHER ALFABATE IS =FIRM

  5. Good Day

    I have managed to ad the if formula no problem. thank you for that.
    How ever I would like the cell background to turn green if the result is favorable.

    regards

    Leanne

  6. Hello

    I want to create a list to automatically fill in my prices. I have two values to look at: 1. is the size of the item. 2. is the description of the item.

    Ex: 10 Straw
    So it looks up "10" which refers to a pricelist.
    Then it looks up "Straw" from the list it was just referred t by the number.
    It then should return a price that is in the list.

    Any ideas?
    Having a dropdown would be even better. So you can choose your size form a list, and then in the next cell choose the item that is in that list.

    Thank you in advance,

  7. I am trying to write a formula in E5 where if D5 is > $5,000.00 then subtract $5,000.00 from D5, if not then blank.

    Thanks,
    Larry

  8. Hi,

    I'm looking for a way to get an average from a set of values with "<" contingencies. For instance I need the average of cells A1:A6. If <10 is present I would like to use 5 instead. If there are "<" than I would like it to use the values given.

    thank you in advance
    -Esmeralda

  9. Hi.

    I have been googeling this for some time now, and cant find out how to:

    check if the cell value is less than another cell value, and if it is, add a cell value to the first cell.

    A1 = 120, A2 = 200, A3 = 300. I need some function to check if A1 is less than A2, which it is, and then add A3 to A1, so A1 becomes 120 + 300 = 420, and is no longer less than A2.

    if anyone have an answer for this, i'll be very thankful.

    thank you in advance.

    - Morten

    • Hi, Morten,

      I'm afraid you won't be able to put the formula in A1 and reference A1 at the same time. You will have to enter the formula to some other cell, say A4, to return the result:
      =IF(A1<A2,A1+A3,"")
      Also, note that if A1 is not less than A2 the cell with the formula will remain empty.

  10. Cell A1 Data like this "10+10"
    i want the result in B1 like "20"
    which formula i want to use. anybody help?

  11. I am trying to figure out how to use an if function when a cell contains a date in a format such as 1/1/2004. What I am trying to do is strip the month and day information and have an if statement that will return a result of "2004". For example if 5/5/1998 it should return a result of "1998". Can anybody help?

    • Hi,Soccer Guy

      use this formula if your data in A1 "=YEAR(A1)"

  12. Hi,

    If A1 cell value 1, B2 cell value 2 = i need result not more then value 2

    Do you help me? How to create formula in excel?

  13. Hi,

    I have a list of activities if I select any one of those activities in one cell then the other cell should reflect as Production. Could you please help me with the formula

  14. Hi I need help figuring out formula to do.
    =if cell is 1-3=0 if cell is 4-7=5 if cell is 8-11=10 if cell is 12-15=15. using signs.

    ex.=IF(D2>=4=5,IF(D2>=8=10,IF(D2>=12,15)))
    where d2 is number of disks used
    and working from G2 where it is discount given in currency

    0-3 disks= 0$
    4-7 disks= 5$
    8-11 disks= 10$
    12+ disks= 15$

    • Hi, Michael,

      If I understand your task correctly, you can try this formula in G2 (make sure to set the Currency format to the cell):
      =IF(AND(D2>=0,D2<=3),0,(IF(AND(D2>=4,D2<=7),5,(IF(AND(D2>=8,D2<=11),10,(IF(D2>=12,15,"")))))))

      Hope it helps!

  15. Good day. Instead of doing double entry on an excel spreadsheet, how do I link the sheet to read the following:
    Spreadsheet 1, Column C has number 12345, but spreadsheet 2 replaces the 1 with 70999 in Column C, thus creating 709992345. What formula would I use?
    Thank you in advance for your time.

  16. I have an excel sheet with three columns.
    I want to create a nested if formula that shows the following
    =If(RR>8,"P1",If(RR<=3,"P3","P2"))
    How do I re-write this formula in a situation I do not want a value returned when any RR cell is empty?

    Thanks

    • Hello, Peejay,

      If you reference RR1 cell, then
      =IF(RR1="","",IF(RR1>8,"P1",IF(RR1<=3,"P3","P2")))
      then copy the formula down the column to return the values for other RR cells.

      Also, note that the formula above will return the text values P1, P3, and P3.
      If you want those to be cell references, then use the following formula:
      =IF(RR1="","",IF(RR1>8,P1,IF(RR1<=3,P3,P2)))

      Hope this helps.

  17. I have an excel sheet with a single cell (Ctrl+;) showing 'TODAY'S DATE', and two columns:

    Today's Date: 24/04/2017

    NAME DATE JOINED WORK
    John Smith 24/04/2017
    Mary Jane 01/04/2017
    25/04/2017
    Paul Loyd 02/04/2017
    Robert Gray 29/03/2017
    25/04/2017
    Ann Buck 24/04/2017
    25/04/2017
    25/04/2017

    One column for NAMES of staff, and one column for DATE JOINED WORK.
    I would like to always have 'tomorrow's date' in all cells in the DATE JOINED WORK column. And, if a name is entered on the NAMES column, I would like 'today's date' to appear in the DATES cell.
    When a cell in the NAMES column is blank, the cell in the DATES JOINED WORK column should show 'tomorrow's date'

    How do I do that?

    Thanks!

  18. i want convert formula to values like below
    =sum(A1+B1+C1) A1=10,B1=10,C1=10 total result D1"30"
    i want convert the result to values but i cont.
    i tried all the way in formula bar its not showing 30 its showing formula only, after one time using formula its want to show only 30 in formula bar also

  19. i want convert formula to values like below
    =sum(A1+B1+C1) A1=10,B1=10,C1=10 total result D1"30"
    i want convert the result to values but i cont.
    i tried all the way in formula bar its not showing 30 its showing formula only, after one time using formula its want to show only 30 in formula bar also

  20. Hi,
    I need an excel formula for the following:
    IF A1 & B1 HAVE NUMBERS THEN ADD THOSE NUMBERS, IF B1 IS BLANK THEN RETURN A 0.
    I am working on a compensation spreadsheet containing market adjustments for some of the staff. I calculated the market adjustment and need to calculate the new base rate. If the base rate did not get an adjustment then I need the cell to show 0. If the base rate did get an adjustment I need it to add the current base rate with the calculated adjustment for the new base rate.
    Thank you in Advance

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)