How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4802 comments

  1. Hi team,
    Why if functions excepts text greater than any number value? if I write values in A1 -100, A2-200, A3-300 and write function in B1 =if(A1>=250,"Fine",if(A1>=100,"Not so bad","")) when instead of 100 i write in cell A1 text NO VALUE - if function returns me "Fine"

    Thanks

    • up,, any info about why text values are greater than number values in logical functions?

  2. I am trying to write that if there is a 1 in Column B2 then write "refer to page 34". I have been using =IF(B2=1, "refer to page 34"). This works great when there is a 1 in the reference column but when the column is blank I keep getting a False statement. Help please

    • Hello, Dave,

      The point is that IF function uses 3 arguments. You specified what to return when the value is 1, but you didn't for when the value is not 1. If you need the cell to remain empty in that case, please try this formula:
      =IF(B2=1,"refer to page 34","")

      Hope this helps!

  3. Hello Ma'am Svetlana:

    Good day.

    Ma'am, I am working on a database using excel. In an if statement, how can I return the address of a particular cell if argument is true. The statement should go like this, as an example, "Please check entry in cell G26"

    The cell "G26" is the cell address being referred whose entry should be checked if argument is true. The formula will be repeated in the rows of the database therefore it is expected that when the formula is copied to the succeeding rows, excel should automatically adjust the row (the 26) corresponding to the row where it is pasted. This will spare me from editing the formula every time it is being copied into a new cell on another row. Is this possible?

    I managed to get a returned address of a cell but it doesn't automatically update once copied to another row and so need to keep on editing. Besides, if possible I wish to get an address which is relative (G26) not absolute ($G$26). Also, I wish that the column would be in alphabet, not number.

    Thanks in advance for any help I can get.

  4. Required formula for below condition
    Final result depend on 6 column status example as below
    If cell A1=2, and B1=2,C1=2,D1=2,E1=2,F1=2 result should be “U”
    If cell A1=1, and B1=2,C1=2,D1=2,E1=2,F1=2 result should be “V”
    If cell A1=1, and B1=1,C1=2,D1=2,E1=2,F1=2 result should be “W”
    If cell A1=1, and B1=1,C1=1,D1=2,E1=2,F1=2 result should be “X”
    If cell A1=1, and B1=1,C1=1,D1=2,E1=2,F1=2 result should be “Y”
    If cell A1=1, and B1=1,C1=1,D1=2,E1=2,F1=2 result should be “Z”
    There is so many permutation and combination but I need above combination in single formula

  5. The following vlookup function

    =(VLOOKUP($E12,'SPORTS'!$A$9:$G$162,6,FALSE))

    returns the value as "#N/A" because the data is not available in the "SPORTS" tab. How can I change the value to "0" from "#N/A"?

    Thanks

    • =IFERROR(VLOOKUP($E12,'SPORTS'!$A$9:$G$162,6,FALSE), "0")

  6. Hello Team,

    "If value of Cell d4 between -5 to +5 then display "Correct" Else "Error".

    Kindly help me with a formula for the above condition.

    Thanks in advance.

    • If you have Excel 2013 or higher, use the conditional formatting tool.

  7. Hi, I am trying to use multi IF function to show certain range of values. for the numbers I have got it right but when it comes to text it is not reading it. this is the formula:
    =IF(AS55<=(AS54*0.92),20,IF(AND(AS55=(AS54*0.92)),50,IF(AND(AS55(AS54)),80,IF(AS55>=(AS54*1.05),95,IF(AS55="s/d",330,331)))))

    The idea is to show cut-off values where eg.if the number I get in the cell is <92% shows 20. However, if it is just a text "S/D" then it should read =330. can you help please.

    Note: It is working for me as single IF function but in the combination it is not reading it!=IF(AS55="s/d",330,331)

  8. I want to achieve three outcomes from three arguments. I am attempting to compile a register containing current insurance policies. The policy dates are either current (OK), out of date or not provided at all.
    1. TODAY()
    2. Date registered (A4)
    2. OK (A5)
    3. Out of date (A6)
    4. Not submitted (A7)

    My attempt: =IF(TODAY()A4,"A6",IF(ISBLANK(A4),"A7")))

    This doesn't work and I suspect I don't understand functions well enough to achieve my desired outcome. Can you assist.

    • Oops typo. Should be =IF(TODAY()>A4,"A6",IF(TODAY()<A4,"A5",IF(ISBLANK(A4),"A7")))

  9. Hi I need help in applying if function for a range of cells which contains percentage and text. Ex. A1 contains 100% and B1 contains NA; while I applied if function, if(A1=>100%,1,if(A1<100%,2,0)), which worked when cell values had percentage but gives wrong output if cell contains any text, gives 1 for NA as well. Kindly assist.

  10. Please help on this

    =if(A3=E1&B1=C1, D3*G3,0)

    SIMILAR ABOVE I WANT TO CREAT.

    • =if(A3=E1&B1,C1, D3*G3)

  11. Hello Team,

    Can any one help with, Actually i want to find the things from 3 column,
    Eg i have 50 Servers list those i need to find from 1000 D column list which i can find by using =vlookup function but every servers having its status with retired, Decom, Active in H column, So i need to find if Server in D column status in H column with Retaied or Dcom then find as true.

    • Hello Rajesh thanks for looking into it, i have drop an email with my concern. Hope that clear to you.

  12. How to write the IF function in case of a dubble letter column.
    For Example
    =IF(AA18="";"Close";"Open")
    I get a ?NAME error.

    • =IF(AA18="","Close","Open")

  13. =IF(AND((FM22)>Q2,(FM22)<R2),1,0)

  14. Hello,

    I do not think any of the examples contain what I am after. I have Excel 2010 Pro Plus. I have a column of dates, I need a formula that will fill the empty cells with 01/01/1900 00:00:00 AM if they are empty, otherwise I need to keep the existing date. I do not seem to be able to find this any where.

    Could you help, please?

    Regards,
    Paul.

  15. Ok I need to look at 3 cell Column A, B, C. In D I figured out the first part IF(A1=B1,IF(B1=C1,A1,A1&"/"&C1),A1&"/"&C1). In E I figured out the second part IF(A1>B1,IF(B1>C1,A1&"/"&B1&"/"&C1,A1&"/"&C1),A1&"/"&C1). In F I tried to combine the two I have IF(A1=B1,IF(B1=C1,A1,IF(A1>B1,IF(B1>C1,A1&"/"&B1&"/"&C1,A1&"/"&B1&"/"&C1),A1&"/"&C1)),A1&"/"&C1). It works but not for all my number combination If A and B are the same or If B and C are the same it give me A B and C. I think I need a third part not sure. If A B and C are the same I want A. If A B and C are all different I want ABC. If AB or BC has the same number I want AC not ABC which is what I am getting.

  16. I need to check if a cell is blank then if another cell which is a date is past 30 days then change it to red

  17. Hi guys, Please assist with IF formula. 1. I wanna compare two columns and isolate all the numbers that are not duplicates into a separate column.
    2. I also wanna compare the isolated numbers to another column that has data.
    Example

    Column A *Column B Now the odd one out must go to Column C
    1234 1338 1338
    1245 1245
    1336 1336

    There after I would like to again see if column C data is not in another column, say Sheet 2 Column F

    your assistance will be highly appreciated

    • Hi, Andy,

      for starters, if the data begins from A1, you can enter the following formula into C1:
      =IF(A1<>B1,B1,"")

      and copy it down the column to isolate all non-duplicates.
      Then you can use one of these ways (to your liking, depending on what result you want to see) to compare column C with another one.

  18. Hi

    Could you please help me to find a solution for the below , I have made table in excel sheet like below, and Ihave nade aut list in colum a (Cash,Card, Cheq) what I need from ecel is if I select cash mode from colum a the amount what Iam entering cloum b should come in colum c automotically if I select card , colum b amount should come in colum d ,if select cheq colum b amount should come in cloum c.
    which formula I want to apply in order to work this table ?
    A b C D C
    mode rent cash card chq

  19. Hi all,

    I'm not even sure how to create a IF function for the following .. PLEASE HELP!

    I am trying to create a IF function formula.. if someone can help me create.

    If between 1-3 years you get 10 days
    If between 3-6 years you get 15 days
    if between 7-9 years you get 17 days
    if 10 plus years you get 20 days

    After your 10th, every 5th year anniversary you get an extra 5 days for example 15th year you get 25 days, 20th year so on...

  20. How to create an if then statement that follows as such:

    If A5 = "Orange" AND B5 = "Banana" then populate in C5 "Fruitbasket" with yellow background

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)