How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. I am having trouble finding a formula for defining the payment deadline for invoices.
    If the invoice is dated before the 15 of a month it should be paid by the 15th of the following month, otherwise it should be paid before the 30th of the following month.
    I've tried combining IF with DATE but it returns the formula as text...

    • Hello, Mara,

      Please try the following formula:

      =DATE(YEAR(EOMONTH(A1,1)), MONTH(EOMONTH(A1,1)), DAY(IF(DAY(A1)<15,15,EOMONTH(A1,1))))

      Hope it will help you.

  2. I have an excel document with three columns.

    Example; I have the Name of staff, Amount contributed (deposit), amount applied from loan. I want to insert another collumn to analyze how many have qualified to receive the loan. I the new collumn, I want to introduce clients who have paid the required deposit( qualification amount and bring in the new collunm the amount of loan applied. Eg If qualification amount is $500,and the clients has applied a loan of $100000, i want the $100000 to appear in the new collumn by use of the formullae.

    • Hello,

      For me to understand the problem better, please send me a small sample workbook with your source data and the result you expect to get to support@ablebits.com. Please don't worry if you have confidential information there, we never disclose the data we get from our customers and delete it as soon as the problem is resolved.
      Please also don't forget to include the link to this comment into your email.

      I'll look into your task and try to help.

  3. I need to have a formula for the following; exp, column D, if b1=1, then enter vc; if b1=2, then enter vce if b1=3, then enter pp, and so on up to #5
    thank you so very much for helping me

    • Hello, Wanda,

      Please try the following formula:

      =IFS(B1=1,"vc",B1=2,"vce",B1=3,"pp",B1=4,"value4",B1=5,"value5")

      Hope it will help you.

  4. Hi. I have a question on the IF logic: state the status in a column as COSTLY if total expense is above $20,000, or FAIR if total expense is less than $20,000 but greater than $10,000, or MAINTAIN if total expenses is below $10,000

    • our value in A1 cell

      =IF(A1="","",IF(A110000,A120000,"Costly"))))

  5. Hello, I am trying to get a cell AB3 to show "complete" and if not to show "pending" when Cells on the spreadsheet H3,N3,T3, and Z3 are all showing "complete". I do not have the slightest idea how to write the "IF" formula.

    Any suggestions are appreciated greatly!

    • If(and(H3="COMPLETE",N3="COMPLETE=,T3="COMPLETE",Z3="COMPLETE"),"complete","pending")

      I done by mobile but its correct check

  6. In cell A cell B
    apple 1x
    grape 1x
    strawberry 1x
    grape 2x
    melon 1x
    grape 3x
    what function do i need to complete my cell B automatically
    tq....

    • Hello,

      I'm afraid there's no easy way to solve your task with a formula. Using a VBA macro would be the best option here.

      However, since we do not cover the programming area (VBA-related questions), I can advice you to try and look for the solution in VBA sections on mrexcel.com or excelforum.com.

      Sorry I can't assist you better.

  7. In Cell A2:A20 I have numeric (200.00) data. some cells are blank.
    1)how to convert blank cells into 0.00 Format cells converts numbers into 0.00 format if number is present.otherwise it is blank
    2)How to use If Isblank() formula for this conversion of blanks to 0 or if number is present, retain the same number

  8. How do I get cells in Excel to equal set amounts? For example if I was holding a competition to see how many ribbons kids could find? The ribbons would be different colors, and depending on the color the ribbon would worth different points?

    Blue=100
    Red=75
    Yellow=25
    Green=15

    Thank you in advance!

  9. Dear friends,

    i need a help for applying if condition in excel, in a column few different different text is there and few cell having MRP, if it is mrp cells have to multiply with qtys (599*12)if it is text in a cell that cells consider 300 rs * qty hot to apply if condition, please find the below the details and help me

    MRP VARIANCE FORMULA VALUE DIFF
    799 1 =IF(I6="NA",J6*300,IF(I6="",J6*300,J6*I6)) 799
    -1 =IF(I7="NA",J7*300,IF(I7="",J7*300,J7*I7)) -300
    NA 4 =IF(I8="NA",J8*300,IF(I8="",J8*300,J8*I8)) 1200
    tata 3 =IF(I9="NA",J9*300,IF(I9="",J9*300,J9*I9)) #VALUE!
    immma 7 =IF(I10="NA",J10*300,IF(I10="",J10*300,J10*I10)) #VALUE!

  10. Help! I am working on an excel and I want to know the function that if the value of D column is yes then the true value lie between 2002/9/13 to 2005/12/29 and if its false then it shows "N/A" please tell me the function need help? :)

  11. What would be the equation for 1000 ≥ certain cell block ≥ 501 =30%? For instance if certain cell block equaled 5000 the answer would be 150.

    • But if certain cell block was 800 then the answer would be 90.

  12. Hello,
    I have a spreadsheet that tracks investigations at different facilities. I am trying to find a formula that can give me the most up to date status of the facility. Here is some background: Every time the site is inspected, a particular operating status is evaluated and "T" or "F" is entered in the cell. Since the status can change from time to time, I would like to capture the most up to date status. The spreadsheet is designed with one row per site so my range will have to be across the row. i.e. I am looking at the last time a T or F was entered in that row. I hope this makes sense.

    Thanks in advance for your help!

  13. is there a formula for multiple logical test
    example. I wanted to place a certain word into a certain cell if it contains an specific text. thank you

  14. I am inputting the follwoing formula into my spreadsheet:
    =+IF((BG2=1)*AND(BH2=1)*AND(BF2<40000),1,0)

    This is the data it is pulling:
    BF BG BH
    0.00 1 1

    My result is still showing as "0" when it should be showing "1". Can anyone explain what I am missing??

  15. hi , iam from egypt please i need to explain how to make comparison between old list numbers with new list ( ex. 1254as = 1254as
    5478ad # 5478ac
    4568ab = 4568ab )
    i know we can used if function but how by details ?
    thanks for your support

  16. =if ( 'Visual Assessment Summary'!Y7='Visual Assessment Summary'! 8, if ('Visual Assessment Summary'!Y7="M" ,6, if( 'Visual Assessment Summary'!Y7="L",5,0))

  17. I would like to show a value of yes or no depending if a vehicle reg is displayed in a colum of cells. i have tried =IF(N7="WA60 BHU","YES","NO") but this only works if wa60 appears in cell n7 i would like it to say yes if it appeared in cell n7 to n20 or no if it is not displayed.

    Thanks

  18. I want to have a formula in which if the issue date in G6 is the 1st 7 days of the month then the expiry date in H6 will be the end of that month, however if the issue date in G6 is 8th-end of month then the expiry date in H6 will be the end of the next month.

  19. I am attempting to devise a formula that will assist me to calculate the payroll for my employees. It needs to address number of hours worked & then various rates of pay for those hours.

    So far I have come up with the following:

    =IF(AJ6>=3,(AJ6-3)*AN6+(3*AK6))+IF(AJ6>=3,(AH6-AJ6)*AI6)+IF(AJ6=3 - in the first instance I need a 0 recorded if cell AJ6> cell AH6
    - should that not be the case then I need the following calculation to take place (cell AH6 - cellAJ6)*cell AI6 (where cells AH & AJ are hours worked & cell AI is a rate of pay.

    My many attempts have been close but do not seem to recognise the IF/OR component - I need this because if it calculates a negative number as it can in the first instance it decreases the pay of my employees.

    Can someone out there help me?

  20. Hi, please help in my formula. I only get the first part right. If cell AB=1/2/3/4, returns 'Closed', else 'Open'. And if cell AB=#value!, returns Open.
    This is the formula I am using right now.
    =IF(OR(AND(AB3=1),AND(AB3=2),AND(AB3=3),AND(AB3=4)),"Closed","Open")
    Thanks a lot for ur help.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)