How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4802 comments

  1. Hi,

    I want to use 'if' formula, I have 5 slabs 500000 to 999999 = 1%, 1000000 to 1499999 = 2%, 1500000 to 1999999 = 3%, 2000000 to 2490000 =4% & 2500000 to above = 5%
    so how to use IF formula, pls help me...Thanks

    • =IF(AND(D193>=5,D193=10,D193=15,D193=20,D193=25,"5%","")))))
      please change the values accordingly.

  2. Hi,
    I am new to IF Function. I am trying to create formula to find the Turn around time (tat).

    A COLUMN = DATE START
    B COLUMN = DATE END

    IF DATE END IS BLANK THEN TAT FORMULA IS TODAY()-DATE START
    THEN IF DATE END IS WITH DATE IT SHOULD BE DATE END MINUS DATE START

    WHAT WILL BE THE FORMULA FOR THIS USING THE IF FUNCTION?

    • Hello,

      Please try to use the following formula:

      =IF(ISBLANK(B1),TODAY()-A1,B1-A1)

      Where B1 is the cell with the end date, A1 is the cell with the start date.

  3. Hi,
    I'm new to IF function, I'm trying to write a formula but there's a problem on it, I need help.
    A = Date 1
    B = Date 2
    C = Status
    D = No otherwise overdue

    =IF(AND(A<TODAY(),"Overdue","No"),IF(AND(B<TODAY(),C"Approved & Closed","No","Overdue")))

  4. Hi Team,
    I need a formula for automatic calculation of age cycle..! Below mentioned example for your reference..!
    I have to convert data from below mentioned age format to cycle (below 20, 21-25, 26-30,30 above.)

    25yrs7m8days
    31yrs11m3days
    18yrs4m21days

    • Hi,

      Suppose your data are in column D, please try to enter the following formula in cell E1 and then copy it down along the column:

      =IF(VALUE(LEFT(D1,SEARCH("yrs",D1)-1))<=20, "20 and below", IF(VALUE(LEFT(D1,SEARCH("yrs",D1)-1))<=25, "21-25", IF(VALUE(LEFT(D1,SEARCH("yrs",D1)-1))<=30, "26-30", "30 and above")))

      Hope this is what you need.

  5. Hi,
    I have 3 columns and I have to create another column by concatenating :

    Last Name First Name DOB Alt

    Addison Ashley 10/12/2012 AddAO12
    Aguilar Jayden 7/2/2013 AguJ702
    Adkins Skyhe 12/28/2012 AdkSD28

    So in the Alt column I know how to get LastName and firstName but need to display month in letters as O for 10(october) , D for 12 (December) if birthday month is 2 digits and if single digit month the single digit has to be returned.

    Thank you

  6. I track mileage and other data on an Excel spreadsheet. I know the round trip mileage for each city I go to. I simply want it to autofill the round trip mileage of the city I type in. For example:

    If, in row 10, I type W.Roxbury in column A, I want Excel to autofill 58 in column B. If, in row 11, I type Sturbridge in column A, I want Excel to type 116 in column B, and so forth for each individual row.

  7. Coll A Coll B Coll C
    Y Y
    N N
    N Y

    I am trying to write an IFs formula for Coll C, that returns a Y if Coll A & B are Y, a blank if Coll A & B are N, and a N if Coll A is N and Coll B is Y.

    • Hello, Joe,

      Please try the following formula:

      =IF(AND(A1="Y",B1="Y"),"Y",IF(AND(A1="N",B1="Y"),"N",""))

      You haven' t mentioned what the formula should return if Coll A is Y and Coll B is N. Currently the formula returns nothing in this case. If you want to see N or something else in column C when this condition is met, you can just add IF(AND(A1="Y",B1="N"),"N" before the double quotes at the end of the formula above.

      Hope this will help.

  8. I'm trying to populate a manning layout.
    what formula would work across multiple tabs?
    Example:
    cell 1 = 1 for shift
    cell 2 = 4 for position
    cell 3 = 6 for area

    cell 1 & 3 moves name to spreadsheet in correct tab and cell 2 is what cell in that tab it populates.

  9. Please explain how can i have three answer using two columns as follows,

    Ex: in 1st column = column A and B if >0 = "yes", if not "NO"
    if it is a figure only in Column B the answer should be " Loading",

  10. Hi,

    in cell A1 value is 1000. In cell A2 value is 12. now I want formula in Cell A3. Formula would be like that.

    IF CELL VALUE OF A2 12 BUT 18 BUT <=24, THEN A1*3%.

  11. Greetings,

    please guide me on how to create the following formula: if the value of the cell is in (minus) then multiply by the value of a different cell. Let me know if it is possible.

    Thanks alot

    • =IF(D177<0,D177*F177,"")

  12. Hi
    Kindly explane what is the meaning of this formula =if(P12<=0,R12,P12*R12)

  13. Greeting sir
    Kindly explane what is the meaning of this formula =if(A12=false,C12,A12*C12)

    Thank you

  14. Can I return a text statement and a cell value in the return value of an If statement? For example if the logical test is false can my false value be a text with a cell value? i.e value_if_false is "Please change parameter to D19" where D19 is a cell value.

    syntax =if(D18=D19,No change necessary, Please change value to D19)

    Where D19 is the actual cell value that gets displayed and not the text D19

  15. What is the functionality of Marcor in excel, how macro creation help us in sorting data?

  16. Hi,

    I have a set of four cells that return either text or a number. I have a warning that arises if ALL of the cells are text, otherwise no warning (simple if statement - =IF(AND(ISTEXT(B5),ISTEXT(C5),ISTEXT(D5),ISTEXT(E5)),"WARNING:",...). For the false argument, I need something very specific. I need to produce another warning if ONLY ONE of the cells listed is a number, but as soon as two or more are numbers, then I want to do something else. How do I say, "Do this when ONLY EXACTLY ONE of the cells is a number"?

  17. I want a formula where
    Date in A column if equal to or less than B column, it should say Correct. If B column is greater than 2 then it should return "NO"

    A B C

    29-Jan-18 30-Jan-18 Yes
    29-Jan-18 1-Feb-18 No as the difference is more than 2 days
    29-Jan-18 2-Feb-18 No
    29-Jan-18 31-Jan-18 Yes

    • Hello,

      Please try to enter the following formula in cell C1 to get the result you need:

      =IF((B1-A1)>2,"No","Yes")

      Then just copy the formula down along column C.

      Hope this will help.

  18. I need to calculate the amount of drivers

    Duration is 8 hrs if he done more than 8hrs we pay 100/hr must with in the 8 we pay 68.75/hr

    Example if he done 10hr a day we pay 8*68.5 +2*100

    • =IF(A1>8,(A1-8)*100+8*68.75,A1*68.75)

  19. How to do formula for below cases.

    I have planned and Actual Dates (both have start & end date).

    (i) IF there is a value at the (H37) end date (actual) = COMPLETED
    (ii) IF (E37) end date planned = (H37) end date actual = ON TRACK
    (iii)IF only have(G37) start date (actual) = WORK IN PROGRESS
    (iv)IF (H37) end date (actual) is later than (E37) end date planned = DELAYED

    ELSE put as NOT STARTED

    =IF(H37,"COMPLETED",IF(H37=E37,"ON TRACK",IF((H37-E37)>1,"DELAYED",IF(G37,"WIP","NOT STARTED"))))

    Item (i) to (iii) works but not for item (iv). Can someone help please...

  20. How can I do the first cell to be written the sequence of the letter and second cell to become the letter with a formula?
    ie.
    cell1=1 cell2=A
    cell1=5 cell2=E
    cell1=8 cell2=H

    Such a formula would be ok:

    A. B
    1. =if(A1=1, B1=A)

    If necessary I can send you our data.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)