by The tutorial explains the MAX function with many formula examples that show how to find highest value in Excel and highlight largest number in your worksheet.
MAX is one of the most straightforward and easy-to-use Excel functions. However, it does have a couple of tricks knowing which will give you a big advantage. Say, how do you use the MAX function with conditions? Or how would you extract the absolute largest value? This tutorial provides more than one solution for these and other related tasks.
Excel MAX function
The MAX function in Excel returns the highest value in a set of data that you specify.
The syntax is as follows:
Where number can be represented by a numeric value, array, named range, a reference to a cell or range containing numbers.
Number1 is required, number2 and subsequent arguments are optional.
The MAX function is available in all versions of Excel for Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007, and lower.
How to make a MAX formula in Excel
To create a MAX formula in its simplest from, you can type numbers directly in the list of arguments, like this:
=MAX(1, 2, 3)
In practice, it's quite a rare case when numbers are "hardcoded". For the most part, you will deal with ranges and cells.
The fastest way to build a Max formula that finds the highest value in a range is this:
- In a cell, type =MAX(
- Select a range of numbers using the mouse.
- Type the closing parenthesis.
- Press the Enter key to complete your formula.
For example, to work out the largest value in the range A1:A6, the formula would go as follows:
=MAX(A1:A6)
If your numbers are in a contiguous row or column (like in this example), you can get Excel to make a Max formula for you automatically. Here's how:
- Select the cells with your numbers.
- On the Home tab, in the Formats group, click AutoSum and pick Max from the drop-down list. (Or click AutoSum > Max on the Formulas tab in the Function Library group.)
This will insert a ready-to-use formula in a cell below the selected range, so please make sure there is at least one blank cell underneath the list of numbers that you've selected:
5 things to know about MAX function
To successfully use Max formulas your worksheets, please remember these simple facts:
- In the current versions of Excel, a MAX formula can accept up to 255 arguments.
- If the arguments do not contain a single number, the MAX function returns zero.
- If the arguments contain one or more error values, an error is returned.
- Empty cells are ignored.
- Logical values and text representations of numbers supplied directly in the list of arguments are processed (TRUE evaluates as 1, FALSE evaluates as 0). In references, logical and text values are ignored.
How to use MAX function in Excel – formula examples
Below you will find a few typical uses of the Excel MAX function. In many cases, there are a few different solutions for the same task, so I encourage you to test all the formulas to choose the one best suited for your data type.
How to find max value in a group
To extract the largest number in a group of numbers, supply that group to the MAX function as a range reference. A range can contain as many rows and columns as you desire. For example, to get the highest value in the range C2:E7, use this simple formula:
=MAX(C2:E7)
Find highest value in non-adjacent cells or ranges
To make a MAX formula for non-contiguous cells and ranges, you need to include a reference to each individual cell and/or range. The following steps will help you to do that quickly and flawlessly:
- Start typing a Max formula in a cell.
- After you've typed the opening parenthesis, hold down the Ctrl key and select the cells and ranges in the sheet.
- After selecting the last item, release Ctrl and type the closing parenthesis.
- Press Enter.
Excel will use an appropriate syntax automatically, and you will get a formula similar to this:
=MAX(C5:E5, C9:E9)
As shown in the screenshot below, the formula returns the maximum sub-total value from rows 5 and 9:
How to get max (latest) date in Excel
In the internal Excel system, dates are nothing else but serial numbers, so the MAX function handles them without a hitch.
For instance, to find the latest delivery date in C2:C7, make a usual Max formula that you'd use for numbers:
=MAX(C2:C7)
MAX function in Excel with conditions
When you wish to get the maximum value based on conditions, there are several formulas for you to choose from. To make sure that all the formulas return the identical result, we will test them on the same set of data.
The task: With the items listed in B2:B15 and sales figures in C2:C15, we aim to find the highest sale for a specific item input in F1 (please see the screenshot at the end of this section).
Excel MAX IF formula
If you a looking for a formula that works in all versions of Excel 2000 through Excel 2019, use the IF function to test the condition, and then pass the resulting array to the MAX function:
=MAX(IF(B2:B15=F1, C2:C15))
For the formula to work, it must press Ctrl + Shift + Enter simultaneously to enter it as an array formula. If all done correctly, Excel will enclose your formula in {curly braces}, which is a visual indication of an array formula.
It is also possible to evaluate several conditions in a single formula, and the following tutorial shows how: MAX IF with multiple conditions.
Non-array MAX IF formula
If you don't like using array formulas in your worksheets, then combine MAX with the SUMPRODUCT function that processes arrays natively:
=SUMPRODUCT(MAX((B2:B15=F1)*(C2:C15)))
For more information, please see MAX IF without array.
MAXIFS function
In Excel 2019 and Excel for Office 365, there is a special function named MAXIFS, which is designed to find the highest value with up to 126 criteria.
In our case, there is just one condition, so the formula is as simple as:
=MAXIFS(C2:C15, B2:B15, F1)
For the detailed explanation of the syntax, please see Excel MAXIFS with formula examples.
The below screenshot shows all 3 formulas in action:
Get max value ignoring zeros
This is, in fact, a variation of conditional MAX discussed in the previous example. To exclude zeros, use the "not equal to" logical operator and put the expression "<>0" in either the criteria of MAXIFS or the logical test of MAX IF.
As you understand, testing this condition only makes sense in case of negative numbers. With positive numbers, this check is superfluous because any positive number is greater than zero.
To give it a try, let's find the lowest discount in the range C2:C7. As all the discounts are represented by negative numbers, the smallest discount is actually the largest value.
MAX IF
Be sure to press Ctrl + Shift + Enter to correctly complete this array formula:
=MAX(IF(C2:C7<>0, C2:C7))
MAXIFS
It's a regular formula, and a usual Enter keystroke will suffice.
=MAXIFS(C2:C7,C2:C7,"<>0")
Find highest value ignoring errors
When you work with a large amount of data driven by various formulas, chances are that some of your formulas will result in errors, which will cause a MAX formula to return an error too.
As a workaround, you can use MAX IF together with ISERROR. Given that you are searching in the range A1:B5, the formula takes this shape:
=MAX(IF(ISERROR(A1:B5)), "", A1:B5))
To simplify the formula, use the IFERROR function instead of the IF ISERROR combination. This will also make the logic a bit more obvious – if there's an error in A1:B5, replace it with an empty string (''), and then get the maximum value in the range:
=MAX(IFERROR(A1:B5, ""))
A fly in the ointment is that you need to remember to press Ctrl + Shift + Enter because this only works as an array formula.
In Excel 2019 and Excel for Office 356, the MAXIFS function can be a solution, provided that your data set contains at least one positive number or zero value:
=MAXIFS(A1:B5,A1:B5,">=0")
Since the formula searches for the highest value with the condition "greater than or equal to 0", it won't work for a data set consisting of solely negative numbers.
All these limitations are not good, and we are evidently in need of a better solution. The AGGREGATE function, which can perform a number of operations and ignore error values, fits perfectly:
=AGGREGATE(4, 6, A1:B5)
The number 4 in the 1st argument indicates the MAX function, the number 6 in the 2nd argument is the "ignore errors" option, and A1:B5 is your target range.
Under perfect circumstances, all three formulas will return the same result:
How to find absolute max value in Excel
When working with a range of positive and negative numbers, sometimes you may wish to find the largest absolute value regardless of the sign.
The first idea that comes to mind is to get the absolutes values of all numbers in the range by using the ABS function and feed those to MAX:
This is an array formula, so don't forget to confirm it with the Ctrl + Shift + Enter shortcut. Another caveat is that it only works with numbers and results in an error in case of non-numeric data.
Not happy with this formula? Then let us build something more viable :)
What if we find the minimum value, reverse or ignore its sign, and then evaluate along with all other numbers? Yep, that will work perfectly as a normal formula. As an extra bonus, it handles text entries and errors just fine:
With the source numbers in A1:B5, the formulas go as follows.
Array formula (completed with Ctrl + Shift + Enter):
=MAX(ABS(A1:B5))
Regular formula (completed with Enter):
=MAX(MAX(A1:B5), -MIN(A1:B5))
or
=MAX(MAX(A1:B5), ABS(MIN(A1:B5)))
The below screenshot shows the results:
Return the maximum absolute value preserving the sign
In some situations, you may have a need to find the largest absolute value but return the number with its original sign, not the absolute value.
Assuming the numbers are in cells A1:B5, here's the formula to use:
=IF(ABS(MAX(A1:B5))>ABS(MIN(A1:B5)), MAX(A1:B5), MIN(A1:B5))
Complex at first sight, the logic is quite easy to follow. First, you find the largest and smallest numbers in the range and compare their absolute values. If the absolute max value is greater than the absolute min value, the maximum number is returned, otherwise – the minimum number. Because the formula returns the original and not absolute value, it keeps the sign information:
How to highlight max value in Excel
In situation when you want to identify the largest number in the original data set, the fastest way is to highlight it with Excel conditional formatting. The below examples will walk you through two different scenarios.
Highlight highest number in a range
Microsoft Excel has a predefined rule to format top ranked values, which suits our needs perfectly. Here are the steps to apply it:
- Select your range of numbers (C2:C7 in our case).
- On the Home tab, in the Styles group, click Conditional formatting > New Rule.
- In the New Formatting Rule dialog box, choose Format only top or bottom ranked values.
- In the lower pane, pick Top from the drop-down list and type 1 in the box next to it (meaning you want to highlight just one cell containing the largest value).
- Click the Format button and select the desired format.
- Click OK twice to close both windows.
Done! The highest value in the selected range is automatically highlighted. If there is more than one max value (duplicates), Excel will highlight them all:
Highlight max value in each row
Since there is no built-in rule to make the highest value stand out from each row, you will have to configure your own one based on a MAX formula. Here's how:
- Select all the rows in which you want to highlight max values (C2:C7 in this example).
- On the Home tab, in the Styles group, click New Rule > Use a formula to determine which cells to format.
- In the Format values where this formula is true box, enter this formula:
=C2=MAX($C2:$E2)Where C2 is the leftmost cell and $C2:$E2 is the first row range. For the rule to work, be sure to lock the column coordinates in the range with the $ sign.
- Click the Format button and choose the format you want.
- Click OK twice.
Tip. In a similar manner, you can highlight the highest value in each column. The steps are exactly the same, except that you write a formula for the first column range and lock the row coordinates: =C2=MAX(C$2:C$7)
For more information, please see How to create a formula-based conditional formatting rule.
Excel MAX function not working
MAX is one of the most straightforward Excel functions to use. If against all expectations it does not work right, it's most likely to be one of the following issues.
MAX formula returns zero
If a normal MAX formula returns 0 even though there are higher numbers in the specified range, chances are those numbers are formatted as text. It's especially the case when you run the MAX function on data driven by other formulas. You can check this by using the ISNUMBER function, for example:
=ISNUMBER(A1)
If the above formula returns FALSE, the value in A1 is not numeric. Meaning, you should troubleshoot the original data, not a MAX formula.
MAX formula returns #N/A, #VALUE or other error
Please check the referenced cells carefully. If any of the referenced cells contains an error, a MAX formula will result in the same error. To bypass this, see how to get the max value ignoring all errors.
That's how to find max value in Excel. I thank you for reading and hope to see you on our blog soon!
134 comments
Can I use maxifs or max(if.. to find the max value based on font color in a column where each cell text font is one of three different colors?
I retreived the font color numbers from get.cell(24.. The colors are based on value ranges.
10.0000 <-- font green (50)
0.7557 <-- font red (53)
0.0435 <-- font blue (42)
215.8094 <-- font green (50)
0.6836 <-- font red (53)
0.0524 <-- font blue (42)
0.5349 <-- font red (53)
Hi! If you add one more column of font color numbers to your table, you can use this column to find the maximum value based on the condition.
Instead of =MAX(range)
you can use =LARGE(range,1)
What if the header is number example:1990 which indicates year, and the column has more than 670 rows of values. While executing max formula how to turn off the header so that the formula does not count header as value?
N.B: I have formatted the header as text and the result is same. The result for max value turns out to be 1990 value. I have multiple dataset with variation of rows for a column so I dont want to go "=max(A2:A671)", I want to go "=max(A:A)" for simplicity, and I do not want header to counted while executing the formula.
Choose either simplicity or precision. max(A:A) uses the entire column.
How to change in X Simple to number
Example : (98XXXX86 to 98652786)
To replace characters in the text, use the SUBSTITUTE function.
Good Morning,
If there are several columns, with several values, then i have to highlight highest values in each column at a time by selecting the entire data rather than selecting single column and formatting the top most value in each column, Similarly, for many rows also, Can u pls suggest me an easy method.
Thanks in Advance,
Kotha Jyothi.
Hi! Use the MAX function and copy the formula MAX(A1:A20) to the right as far as necessary.
Dear Alexander,
If my question is irrelevant here, please direct me to where I can find the answer.
I am looking for a way to highlight a group of three adjacent cells that have the highest total (cumulative) value in a row. I can identify this value using an array formula, but it seems not to be working in the Conditional formatting tool (or I am doing it in the wrong way). Here is an example of my data:
_____A____B___C___D___E___F__
1___126__91__80__66__99__65
2___101__47__78__88__66__70
In the first row, cells A1, B1 and C1 produce the highest total value (126+91+80=297). I get it by using a formula =MAX(A1:D1+B1:E1+C1:F1), then pressing Ctrl-Shift-Enter. In the second row, the respective cells are C2, D2 and E2 (=232). Now I just need to highlight these tree cells with a color in each row, and then spread this rule onto next rows downwards (the whole data set takes several thousands of rows).
When I insert the above formula in the respective field of Conditional formatting tool, it produces no result. It either highlights all cells which are selected (even if the selected cells are empty or outside the range of data) when I use "$" to lock colums/rows, or neither of cells is highlighted when I do not use "$" in the formula.
I would greatly appreciate your help to find the answer.
PS: I need to color-mark these cells to use them as a condition for making calculations in a different (but associated) range of data. As I haven't found a direct formula for this, I am trying to do it through cell formatting. The color format of cells in the first data set will be copied to the second data set and the new colored cells (containing new values) will be summed.
Hi! You cannot do conditional formatting with your formula.
To do conditional formatting on cell A1, you have to compare its value to another value. If you tell me what cell A1 can be compared to, I will try to help.
I can help you make a formula, but I won't solve a logical task for you.
Thanks for your reply! I will try to figure out how to do it in a different way.
How to select the maximum value <100 from the command MAX(AO68;AQ68;AS68;AU68) if the max values change within the command? Thank you.
You can find the maximum value from non-adjacent cells by condition using this formula:
=MAX((A1*(A1<100)),(B1*(B1<100)),(C1*(C1<100)))
Thx..could you give the formula to return the region after finding the Max from the three months?
Regards,
Larry
Hi! If I understand correctly, use INDEX MATCH functions to find the row with the maximum value.
For example,
=INDEX(A1:A5,MIN(IF(C2:F5=MAX(C2:F5),ROW(A2:A5))))
This is very great. Please I want to find the MAX but to replace the value with the name how do I do that?
Hi! You cannot replace a number in a cell with a name using an Excel formula. If I have misunderstood, please explain your question in more detail.
This blog is the most comprehensive but I just need one more step.
My set of data is a measure of both positive and negative deviation from 0 with so called 'error' cells too. I'm looking for formula to give me maximum value from zero including its sign.
It looks like I could do with a combination of Index / match / aggregate. Data example is
Column A : #N/A, #N/A, 6, 5, -2, 0, 0, -5, -3, -4, #N/A, #N/A, -10, -15, -12, 0, 11
The formula result would then be -15
Thanks fro your help
Hi! Replace the errors with zero using the IFERROR function. Use the ABS function to take absolute values into account.
Try this formula:
=MAX(ABS(IFERROR(A1:A15,0)))
Team Runs for the day Team Runs for the day Leading Team
South Vizag 7 Coimbatore 1 12 Coimbatore 1
Tirupathi 2 Erode 11 Erode
Hosur 10 Guntur 23 Guntur
Nellore 10 Madurai 1 12 Madurai 1
Salem 8 Strategic Br-Hyderabad Main 3 Salem
In this above i have to compare two teams and should reflect highest team name?? how please suggest ???
Please clarify your specific problem or provide additional details to highlight exactly what you need. As it's currently written, it's hard to tell exactly what you're asking.
Hi,
Product SKU Current Location Age
FNSF51LGRU30003 47
FNSF51LGRU30003 46
FNSF51LGRU30003 46
If i use the max if formula for the above data. The data is identifying the high value number in it for all the same SKU.
I need to freeze it if once the answer used.
For Example : 47 should occur only once. Next answer for the FNSF51LGRU30003 should be 46. Not the same 47.
Plz help me out.
Hi!
Based on your description, it is hard to completely understand your task. However, I’ll try to guess and offer you MAXIFS formula
=MAXIFS(B1:B3,A1:A3,"FNSF51LGRU30003")
if three different numbers , make 2 sets of pair, find the minimum difference in that 2 sets of pair that should less than 15 and how to finalize the highest values minimum difference pair.
Hi!
To find the minimum difference, use the MIN function.
Article Material Desc BUn CC Code Base Rate
590000002 APPLE RED DELICIOUS (KG) KG AV53 145
590000003 APPLE GRANNY SMITH (KG) KG AM43 169.8
590000005 APPLE ROYAL GALA (KG) KG AV53 150
590000008 APPLE KINNOR (KG) KG AM42 126.4
590000008 APPLE KINNOR (KG) KG AM43 134
590000017 AVACADO (KG) KG AV53 240
590000024 PASSION FRUIT KG AV53 110
590000034 GRAPES IMPORTED (KG) KG AM42 366.3
590000036 GRAPES BANGALORE BLUE KG AK75 45
590000039 GRAPES FLAME SEEDLESS KG S577 77
590000042 GRAPES SONAKA SEEDLESS KG AK51 50.5
590000042 GRAPES SONAKA SEEDLESS KG AK74 51
590000042 GRAPES SONAKA SEEDLESS KG VX53 54
590000047 MANGO TOTAPURI KG AK74 125
590000047 MANGO TOTAPURI KG AM43 158
590000047 MANGO TOTAPURI KG SKAC 110
590000051 MUSK MELON (KG) KG AK74 20
590000051 MUSK MELON (KG) KG AM43 24.7
590000051 MUSK MELON (KG) KG SB81 22
How to highlight, each max value in E column, against data in A or B column
eg. For musk melon max value is 24.7, so only it has to highlighted..like that to do for each products
It would be of great help if I get solution for this
Hello!
To find the maximum value by condition, use the MAXIFS function. I recommend reading this article: MAXIFS function in Excel – find max value with multiple criteria.
For example,
=MAXIFS(E2:E20,B2:B20, "MUSK MELON")
I need to find the top 5 highest values from this set of data:
64.47
59.2
58.77
55.94
75.54
63.01
57.65
54.91
54.01
58.94
51.33
55.86
71.09
53.69
72.33
59.05
66.53
53.95
what formula should I use?
Hello!
The answer to your question can be found in this article: Excel LARGE function with formula examples to get n-th highest value.
Thanks, So helpful!!!
I have a data on Matrix and I also have the criteria data in Matrix as well See below
Data from the Matrix
Period 0.0 30 45 60 75 90 105 120 135 150 180
6.0 0.356 0.443 0.469 0.505 0.579 0.525 0.516 0.475 0.342 0.271 0.171
7.0 0.439 0.541 0.558 0.678 0.802 0.642 0.747 0.499 0.436 0.336 0.232
8.0 0.505 0.544 0.591 0.694 0.759 0.747 0.736 0.584 0.560 0.467 0.269
9.0 0.489 0.614 0.618 0.630 0.791 0.687 0.631 0.577 0.507 0.562 0.340
10.0 0.538 0.603 0.572 0.580 0.703 0.643 0.619 0.556 0.489 0.459 0.399
11.0 0.503 0.491 0.513 0.578 0.585 0.630 0.587 0.542 0.439 0.459 0.345
12.0 0.517 0.446 0.539 0.588 0.546 0.564 0.552 0.497 0.411 0.412 0.355
13.0 0.470 0.439 0.545 0.534 0.530 0.482 0.510 0.470 0.422 0.404 0.329
14.0 0.399 0.427 0.469 0.442 0.462 0.434 0.409 0.425 0.382 0.395 0.340
15.0 0.370 0.390 0.388 0.397 0.421 0.393 0.355 0.387 0.355 0.341 0.331
Criteria for the matrix
Period 0.0 30 45 60 75 90 105 120 135 150 180
6.0 3 5 5 6 7 6 6 5 3 2 0
7.0 5 6 7 9 10 8 10 6 5 3 1
8.0 6 6 7 9 10 10 9 7 7 5 2
9.0 6 8 8 8 10 9 8 7 6 7 3
10.0 6 7 7 7 9 8 8 7 6 5 4
11.0 6 6 6 7 7 8 7 6 5 5 3
12.0 6 5 6 7 6 7 7 6 4 4 3
13.0 5 5 6 6 6 5 6 5 4 4 3
14.0 4 5 5 5 5 5 4 5 4 4 3
15.0 4 4 4 4 4 4 3 4 3 3 3
Is there any way to find the maximum of no 3 or 10 from the criteria data on the criteria Matrix, and the max values should be taken the matrix data based on the location from the matrix criteria ?
So from the above No 10 should be the maximum from Matrix ( [7,75] or [7,105] or [8,75] or [8,90] or [9,75] )?
Thanks for your help and taughts
I like it
I need to get the list of highest defect type from the product type of highest defect contributor with list of data below.
Process Type Total NG Input Output Defect 1 Defect 2 Defect 3 Defect 4 Defect 5
A AA 10 20 10 5 5 0 0 0
A AC 15 20 5 0 7 8 0 0
A AD 12 20 8 0 6 2 4 0
A AB 10 20 10 3 3 4 0 0
A AD 10 20 10 0 5 5 0 0
A AG 10 20 10 0 0 5 5 0
B AF 16 20 4 0 10 3 3 0
B AC 13 20 7 0 0 6 7 0
B AR 10 20 10 0 0 4 6 0
B AD 10 20 10 0 0 0 5 5
B AB 10 20 10 0 0 0 5 5
B AR 10 20 10 0 0 5 5 0
C AJ 12 20 9 0 0 6 6 0
C AS 10 20 10 5 5 0 0 0
C AF 10 20 10 0 5 5 0 0
C AA 10 20 10 0 0 0 5 5
Where Output data should be like this
Process Type Total NG Input Output Highest Defect Quantity Highest Defect Type
A AC 15 20 5 7 Defect 2
B AF 16 20 4 10 Defect 2
C AJ 12 20 9 6 Defect 3
C AJ 12 20 9 6 Defect 4
Thank you for the response
Hi!
I don't really understand how you want to create a list. For example, why is it missing B AC 13 20 7 0 0 6 7 0. I don't think it's possible to do this with a single formula. Perhaps this guide will be helpful: How to get matches of largest N values.
If you have a specific question about the operation of a function or formula, I will try to answer it.
I scourged the net and found this helpful, but ran into a dead end. I have a spreadsheet that has incidents in other.
Sheet/tab #1: Overview tab of all collected incidents, with the latest comment copied/paste from the other tabs.
A2: Incident #, B2: Date Reported, C2: Status, D2: Latest Comment
Sheet #2: has information on the all the information on this incident 2 by date (A2:A100) including latest comments all in column D.
A2: Date, B2: Assignee, C2: Updated by, D2: Comment
Sheet #3: same as #2
...etc...
Each sheet is named the Incident Number. So for example, incident "#2" is also the same name of the reference sheet "#2".
As the incidents are growing, I need to automate this to pull the max date's "Comment" from each sheet directly to the overview sheet #1 corresponding to that incident # in each row (D2). Currently I'm manually updating D2 Comment cell's formula's sheet reference:
=VLOOKUP(MAX('#2'!$A$2:$A$100),'#2'!$A$2:$D$100,4,0)
which is becoming tedious. Is there a way to automate pulling from the sheets (e.g. #2, #3, etc.) other than manually naming the sheet reference in the formula? I tried to concatenate '#2' to pull from A2 but that didn't work.
Any help is greatly appreciated!
Hello!
To create a dynamic reference, use the INDIRECT function. For example,
=INDIRECT("'"&A2&"'!A2:A100")
where A2 = "#2".
For more information, please visit: Excel INDIRECT function - basic uses and formula examples
You probably already know this, BUT you're a genius! Got it working!**
I guess I was just off by missing a few small things. In case anyone else needs it:
=VLOOKUP(MAX(INDIRECT("'"&A2&"'!A2:A100")),INDIRECT("'"&A2&"'!A2:D100"),4,0)
Again, you guys are awesome!!!
TLDR:
**this works off my master list that pulls my comments (in column 4) from other sheets. The master references list is written in cell A2 (with the sheets/tab being the same name), and then looks at the max date in cell A2:A100, from the table A2:D100, pulling back the latest comment listed in column 4.