Excel nested IF statement - multiple conditions in a single formula

The tutorial explains how to use multiple IF in Excel and provides a couple of nested If formula examples for most common tasks.

If someone asks you what Excel function you use most often, what would your answer be? In most cases, it's the Excel IF function. A regular If formula that tests a single condition is very straightforward and easy to write. But what if your data requires more elaborate logical tests with multiple conditions? In this case, you can include several IF functions in one formula, and these multiple If statements are called Excel Nested IF. The biggest advantage of the nested If statement is that it allows you to check more than one condition and return different values depending on the results of those checks, all in a single formula.

Microsoft Excel has limits to the levels of nested IFs. In Excel 2003 and lower, up to 7 levels were allowed. In Excel 2007 and higher, you can nest up to 64 IF functions in one formula.

Further on in this tutorial, you will find a couple of Excel nested If examples along with a detailed explanation of their syntax and logic.

Example 1. Classic nested IF formula

Here's a typical example of Excel If with multiple conditions. Supposing you have a list of students in column A and their exam scores in column B, and you want to classify the scores with the following conditions:

  • Excellent: Over 249
  • Good: between 249 and 200, inclusive
  • Satisfactory: between 199 and 150, inclusive
  • Poor: Under 150

And now, let's write a nested IF function based on the above criteria. It's considered a good practice to begin with the most important condition and keep your functions as simple as possible. Our Excel nested IF formula goes as follows:

=IF(B2>249, "Excellent", IF(B2>=200, "Good", IF(B2>150, "Satisfactory", "Poor")))

And works exactly as it should:
Classic nested IF formula

Understanding Excel nested IF logic

I've heard some people say that Excel multiple If is driving them crazy :) Try looking at it at a different angle:
Nested If formula logic

What the formula actually tells Excel to do is to evaluate the logical_test of the first IF function and, if the condition is met, return the value supplied in the value_if_true argument. If the condition of the 1st If function is not met, then test the 2nd If statement, and so on.

IF(check if B2>=249, if true - return "Excellent", or else
IF(check if B2>=200, if true - return "Good", or else
IF(check if B2>150, if true - return "Satisfactory", if false -
return "Poor")))

If you need a nested IF formula with wildcard characters (partial match), check out this example: If cell contains, then return different values.

Example 2. Multiple If with arithmetic calculations

Here's another typical task: the unit price varies depending on the specified quantity, and your goal is to write a formula that calculates the total price for any amount of items input in a specific cell. In other words, your formula needs to check multiple conditions and perform different calculations depending on what amount range the specified quantity falls in:

Unit Quantity Price per unit
1 to 10 $20
11 to 19 $18
20 to 49 $16
50 to 100 $13
Over 101 $12

This task can also be accomplished by using multiple IF functions. The logic is the same as in the above example, the only difference is that you multiply the specified quantity by the value returned by nested IFs (i.e. the corresponding price per unit).

Assuming the user enters the quantity in cell B8, the formula is as follows:

=B8*IF(B8>=101, 12, IF(B8>=50, 13, IF(B8>=20, 16, IF( B8>=11, 18, IF(B8>=1, 20, "")))))

And the result will look something similar to this:
Nested IF formula to perform different calculations on numbers within a certain range

As you understand, this example demonstrates only the general approach, and you can easily customize this nested If function depending on your particular task.

For example, instead of "hard-coding" the prices in the formula, you can reference the cells containing those values (cells B2 to B6). This will enable your users to edit the source data without having to update the formula:

=B8*IF(B8>=101,B6, IF(B8>=50, B5, IF(B8>=20, B4, IF( B8>=11, B3, IF(B8>=1, B2, "")))))
An improved formula with multiple IF functions

Or, you may want to include an additional IF function(s) that fixes an upper, lower or both bounds of the amount range. When the quantity is outside the range, the formula will display an "out of the range" message. For example:

=IF(OR(B8>200,B8<1), "Qty. out of range", B8*IF(B8>=101,12, IF(B8>=50, 13, IF(B8>=20, 16, IF( B8>=11, 18, IF(B8>=1, 20, ""))))))
Nested IF's formula with fixed bounds

The nested IF formulas described above work in all versions of Excel. In Excel 365 and Excel 2021, you can also use the IFS function for the same purpose.

Advanced Excel users that are familiar with array formulas, can use this formula that basically does the same thing as the nested IF function discussed above. Though the array formula is far more difficult to comprehend, let along to write, it has one indisputable advantage - you specify the range of cells containing your conditions rather than referencing each condition individually. This makes the formula more flexible, and if your users happen to change any of the existing conditions or add a new one, you will only have to update a single range reference in the formula.

Excel nested IF - tips and tricks

As you have just seen, there is no rocket science in using multiple IF in Excel. The following tips will help you improve your nested IF formulas and prevent common mistakes.

Nested IF limits

In Excel 2007 - Excel 365, you can nest up to 64 IF functions. In older versions of Excel 2003 and lower, up to 7 nested IF functions can be used. However, the fact that you can nest a lot of IFs in one formula doesn't mean you should. Please keep in mind that each additional level makes your formula more difficult to understand and troubleshoot. If your formula has too many nested levels, you may want to optimize it by using one of these alternatives.

The order of nested IF functions matters

The Excel nested IF function evaluates the logical tests in the order they appear in the formula, and as soon as one of the conditions evaluates to TRUE, the subsequent conditions are not tested. In other words, the formula stops after the first TRUE result.

Let's see how it works in practice. With B2 equal to 274, the nested IF formula below evaluates the first logical test (B2>249), and returns "Excellent" because this logical test is TRUE:

=IF(B2>249, "Excellent", IF(B2>=200, "Good", IF(B2>150, "Satisfactory", "Poor")))

Now, let's reverse the order of IF functions:

=IF(B2>150, "Satisfactory", IF(B2>200, "Good", IF(B2>249, "Excellent", "Poor")))

The formula tests the first condition, and because 274 is greater than 150, the result of this logical test is also TRUE. Consequently, the formula returns "Satisfactory" without testing other conditions.

You see, changing the order of IF functions changes the result:
The order of nested IF functions matters

Evaluate the formula logic

To watch the logical flow of your nested IF formula step-by-step, use the Evaluate Formula feature located on the Formula tab, in the Formula Auditing group. The underlined expression is the part currently under evaluation, and clicking the Evaluate button will show you all the steps in the evaluation process.

For example, the evaluation of the first logical test of the nested IF formula shown in the screenshot below will go as follows: B2>249; 274>249; TRUE; Excellent.
Watch the logical flow of your nested IF formula by using the Evaluate Formula feature.

Balance the parenthesis of nested IF functions

One of the main challenges with nested IFs in Excel is matching parenthesis pairs. If the parentheses do not match, your formula won't work. Luckily, Microsoft Excel provides a couple of features that can help you to balance the parentheses when editing a formula:

  • If you have more than one set of parentheses, the parenthesis pairs are shaded in different colors so that the opening parenthesis matches the closing one.
  • When you close a parenthesis, Excel briefly highlights the matching pair. The same bolding, or "flickering", effect is produced when you move through the formula by using the arrow keys.

Balance the parenthesis of nested IF functions

For more information, please see Match parenthesis pairs in Excel formulas.

Treat text and numbers differently

When building logical tests of your nested IF formulas, remember that text and numbers should be treated differently - always enclose text values in double quotes, but never put quotes around numbers:

Right: =IF(B2>249, "Excellent",…)

Wrong: =IF(B2>"249", "Excellent",…)

The logical test of the second formula will return FALSE even if the value in B2 is greater than 249. Why? Because 249 is a number and "249" is a numeric string, which are two different things.

Add spaces or line breaks to make nested IFs easier to read

When building a formula with multiple nested IF levels, you can make the formula's logic clearer by separating different IF functions with spaces or line breaks. Excel doesn't care about extra spacing in a formula, so you may not worry about mangling it.

To move a certain part of the formula to the next line, just click where you want to insert a line break, and press Alt + Enter. Then, expand the formula bar as much as needed and you will see that your nested IF formula has become much easier to understand.
Add line breaks to improve the readability of nested IFs.

Alternatives to nested IF in Excel

To get around the limit of seven nested IF functions in Excel 2003 and older versions and to make your formulas more compact and fast, consider using the following alternatives to nested Excel IF functions.

  1. To test multiple conditions and return different values based on the results of those tests, you can use the CHOOSE function instead of nested IFs.
  2. Build a reference table and a use VLOOKUP with approximate match as shown in this example: VLOOKUP instead of nested IF in Excel.
  3. Use IF with logical functions OR / AND, as demonstrated in the these examples.
  4. Use an array formula like shown in this example.
  5. Combine multiple IF statements by using the CONCATENATE function or the concatenate operator (&). A formula example can be found here.
  6. For experienced Excel users, the best alternative to using multiple nested IF functions might be creating a custom worksheet function using VBA.

This is how you use an If formula in Excel with multiple conditions. I thank you for reading and hope to see you on our blog next week.

Practice workbook for download

Nested If Excel statements (.xlsx file)

Table of contents

649 comments

  1. Hello
    I am trying to write a formula for a behavioural rating at a given time point (second by second) where a rating is available for a given time range. So if the time point falls withing the range then the relevant behavioural rating applies, but if it falls in the next time range then a different behavioural rating applies. I hope this makes sense?! So Column 1 = behavioural rating, column 2 & 3 = the time range in which that behaviour occurs, column 4 & 5 = one second time range and I want column 6 to apply the behavioural rating that is associated with the value in column 5 (it's okay to ignore column 4). Any assistance is greatly appreciated.
    Kindest regards :)

  2. Thanks a lot...this helped me really !!!

  3. Hello!
    I'm trying to create a nested formula with 12 arguments. example, farmer, hair dresser, okada driver, pastor, teacher, student, trader, petty trade, agricultural activities, tailor, and banker. I want to group this into 4 groups using the nested IF formula like this: =IF(columnH=farmer,hair dresser,okada driver,pastor,"Baseline2016",IF(columnH=teacher,student,trader,petty trade,"Baseline2016",). But the formula isn't working, please help.

  4. I am trying to write a formula to look in cell V1, if the value = 11 or 12 and V3 is less than 25 in V73 I want the result to read 25, but if V1 = 16 and the vale is less than 28 I want it to read 28.....when I have 16 in V1 the formula I am using does not work....any help would be greatly appreciated. Here is my current formula:

    =IF(OR(AND(V1=11,V73<25),AND(V1=12,V73<25)),25,V73)*(OR(IF(V1=16,V73<28),28,V73))

  5. Svetlana Cheusheva mam please hlep i have table in which i will waive charges on those which are lay at our company after 7 days but which i used if formula then system calculate amount less then seven days its shows amount in minus i want to stop this and system reflected 0 amount instead of amount in minus kindly help and guide me thanks
    my formula is following and just add the above condition if possible.
    =IF(C7=20,H7*750,IF(C7=40,H7*1500,IF(C7=45,H7*1750)))

  6. Svetlana Cheusheva mam please hlep i have table in which i will waive charges on those which are lay at our company after 7 days but which i used if formula then system calculate amount less then seven days its shows amount in minus i want to stop this and system reflected 0 amount instead of amount in minus kindly help and guide me thanks

  7. Hello,
    What is the wroung in this formula plz help
    =IF(F5>=100%,IF(I5>=100%,"1.0%",IF(F5>=100%,IF(I5=85%,IF(I5>=100%,"0.20%",IF(F5=100%,"0.00%",))))))))

  8. HI

    I have 4 scenarios I'm working with and created 4 columns with these formulas, which all work.
    =IF($EJ5="","",IF(AND($BF5="y",$EJ5"",$EA5="A"),$EJ5&" - A, "&$EH5,""))
    =IF($EJ5="","",IF(AND($BF5="n",$EJ5"",$EA5="A"),$EH5&", "&$EJ5&" - A",""))
    =IF($EJ5="","",IF(AND($BF5="y",$EJ5"",$EA5=""),$EJ5&", "&$EH5,""))
    =IF($EJ5="","",IF(AND($BF5="n",$EJ5"",$EA5=""),$EH5&", "&$EJ5,""))

    And then I created a 5th column with: =EL5&EN5&EP5&ER5 so the results are in one column.

    Is there anyway to take the 4 column formulas and merge them into one column.... not doing it the manual way I created?

    Thanks,

    Lisa

  9. How would go about writing an excel formula for the following:

    Start Date must be later than April 1st following the calendar year in which you attain age 70 1/2.

    Eg DOB = 10/17/1954, Age 70 1/2 = 04/17/2025 the start date would be 04/01/2026 because the Age 70 1/2 date is after 04/01 and has to go to the following year.

  10. I am trying to use IF function to assign different ore types to different stockpiles. The ore types are based on source of material( PIT A, PIT B or PIT C), type of material (FRESH, TRANSITION or OXIDE), and the grade of the ore (HIGH or LOW).

    For example, I want to allocate High Grade Fresh Material from Pit A to stockpile F12, and High Grade Oxide Material from Pit B to stockpile F15 and so on

  11. I need help. I am trying to come up with a formula for a grading system, but there are two factors involved.

    For the students grades they have two categories that they have Summative and Synthesis.

    To get Honors, they need to get 72 pts in Summative and 18 pts in Synthesis
    To get High Pass, they need 68 pts in Summative and 17 pts in Synthesis
    To get Pass, theye need 56 pts in Summative and 14 pts in Synthesis.

    Help please. What formula would I use for that. I already have the calculations for each students summative and synthesis grades, just need to get their letter grade.

  12. I'm trying to set up a nest. One column is why and if order error is chosen, then I'd like the next column to give me a drop down of choices for only that answer. Such as: Customer Service
    Sales, Dealer. Any ideas

    • Hello, Lynnie,

      Unfortunately, it is not possible to solve your task using standard Excel tools and functions. Most likely you need a special macro. I am really sorry we can’t help you with this.

      You may try to find the solution in VBA sections on mrexcel.com or excelforum.com.

      I wish I could assist you better.

  13. Hi...
    I want to check two conditions, e.g. if associate contract end date is less than today then i want result "LEFT" and if associate has put resignation and his LWD is entered in cell then i want result "LEFT" and if if contract end date is not less than today then want result "ACTIVE" and if contract end date is not less than today but his LWD is entered in LWD cell then want result "LEFT".

    Please give formula for the same.

  15. I need to write a formula that checks two columns for values and return one of three values based on the results. Specifically:

    - If the two column cells are null, return a null.
    - If they both have a value of zero, return the number 0.
    - Otherwise if the first cell is greater than zero, return the first cell divided by the second.

    I've tried several formulae, using both AND and IFBLANK. The most concise to illustrate what I want is:

    =IF(AND(B132=””, C132=””),””, IF(AND(B132=0, C132=0),"100%", IF(B132>0,C132/B132,0)))

    All of the individual bits work, but I can't seem to string them together without making syntax errors. I get either a "too many arguments" error or a name error.

  16. Stefanie:
    Try entering lowest variable to highest and check the logic of the statement. Something like this where the data is in A2:
    =IF(A2<65,"Less Than 65%",IF(A2<=69,"65%-69%",IF(A2<=70,"70%-79%",IF(A2<=80,"80%-89%",IF(A2<=90,"90%-100%","Fail")))))

  17. Hello -

    I am wondering why the formula I copied from above is not picking up the various conditions, rather only returns "Fail" for all rows.

    =IF($Z2>89,"90%-100%",IF($Z2>79,"80%-89%",IF($Z2>69,"70%-79%",IF($Z2>64,
    "65%-69%","Fail"))))

  18. Hi, and thank you for all of the above, but still having an issue:

    E134 Review Posted F134 No
    E135 Job Posted F135 No
    E136 Work Complete F136 N/A
    E137 Overtime F137 Yes

    I now need to Executive Summary Cell C150, to show all those equal in Col F to No, but to show whats in Col E, through the use of IF and CONCATENATE as there will be several responses (Col E to fit into Cell C150

    IE Cell 150 to show Review Posted
    Job Posted

  19. HI,I have the followimg information.

    political political party.
    if Bosco NRM,
    BESIGYE FDC,
    BOBO POWERESS,
    MAO DP
    KAMYA FDC
    OTUNU UPC
    MUNTU FDC
    RUGUNDA NRM,
    OTAFIRE NRM

    Use nested if function to assign each of them the respective political party.Assuming that entries start from cell A1.
    thanks.

  20. I have A2=28, B2=45 to get a smaller value i applied the formula =IF(A2>B2,A2-B2,A2). So i got an answer has 28.

    My question is if i change a value in A2=50 now i should get a value has B2 in C2 cell.

    So i have entered has =IF(A2>B2,A2-B2,A2)*OR(IF(A2<B2,B2,B2))

    Still it is not working, can someone assist me how to put a formula with a proper condition?

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)