How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4813 comments

  1. Pls give me formula of
    if i m enter A1 Cell 15000 so B1 cell value set under 5000 and C1 set value 5001 to 10000 and D1 set value 10001 to 15000
    means A1 cell value automatic divided into 3 conditional parts

    1. Hi! Since the sum of these three cells will always be greater than 15000 according to your conditions, it is impossible to propose a formula for your problem.
      RANDBETWEEN function returns random integers in the range that you specify.
      For example:

      =IF(A1=15000,RANDBETWEEN(1,5000),0)

  2. Is this even possible? I was trying to write a formula that would give me specific data based on the data of a single cell. All conditions would need to be based on the same cell. Some are easy IF A2 = 0, then the output would be 50, If A2 = 100, then the output is 150. The others are a range so if the number in the cell is between 1-49 the output would be 75, and between 51-99 the output would be 100. Finally I wanted the formula to also know that IF A2 is GREATER than 100 - I want it to multiply the number in the cell x 1.20 as the output.

    Thank you!!!!!!!!!!!!!!!!!!!!

  3. Hi Sir,

    Could you please help me with below as I need to narration From B956 Cell to F954 Cell.

    Hear I have share the Screen shot for reference. Please let me know if there any formula.

    Marketing Exp.(Water Front) Dr 5445.69 Being $5445.69 (AED 19,975) booked as Marketing expense for water front villa project towards Video shoot at dubai vide attached Invoice No- 411-001 01-Feb-24
    Choice Agency Cr 5445.69
    Being $5445.69 (AED 19,975) booked as Marketing expense for water front villa project towards Video shoot at dubai vide attached Invoice No- 411-001 Cr 0

  4. I'm looking for an excel if statement to 'normal' if statement converter or translator.
    By normal I mean
    IF something THEN result
    ELSE IF ...

      1. Thanks! Helpful, but for other uses.

  5. Hi everybody, I am looking for help to check " If a date exist in Cell A then in Cell K to tell me what date will follow in -30 days.."
    Example Date of 10/Jun/2025 (cell A),-30 days (cell K) will result on 14/May/2025.
    I have the basic rule working but I would like the "IF" option.
    thank you in advance!

    1. Hi Lorenzo!
      I hope you have studied the recommendations in the tutorial above. It contains answers to your question. If the cell is not blank, subtract 30.

      =IF(ISBLANK(A1),"",A1-30)

  6. Use If statement and compare against the database (Table 1) to to see if ID is Correct.
    Fill the red area with Correct or Incorrect result

    Name ID Correct ? Table 1 Database
    Wayne 5 Name ID
    Bruce 3
    Wayne 2
    John 1

  7. Hello!
    How do I pull the a three digit number from a cell with text but if there are no numbers to just pull the text that is there in the cell?

    1. Hello!
      You can extract a number from text in any of the ways described in this article and in the comments below this article: How to extract number from string in Excel.
      Then check the result using ISNUMBER function. If the number is not extracted, simply put in the text from the cell.
      For example:

      =IF(ISNUMBER(--CONCAT(IF(ISNUMBER(--MID(A1,ROW($1:$50),1)),MID(A1,ROW($1:$50),1),""))), CONCAT(IF(ISNUMBER(--MID(A1,ROW($1:$50),1)),MID(A1,ROW($1:$50),1),"")), A1)

  8. Hello! I have a budget spreadsheet with spending categories (Gas, rent, utilities) and I'd like to create a formula so that when I enter my new completed month (September for example), my sheet can automatically assign the Gas category for any line items that have "Shell" as the description. I would like that formula to do so for every recurring description I may have for grocery stores and gas stations I frequent the most. How would I write that out?

  9. I need a formula that looks in column B and if the contents are matching, adds together the corresponding column E value. I'm not positive if an if/then formula will work since there are so many requirements. Thanks in advance for any help!
    Example: the answer would be A 3, D 3

    A 2
    D 3
    A 1

  10. How would I do a function that says "if cell 1 or greater than cell 2 by 10 more more ..."
    it's the "by 10 or more part i'm stumped on

  11. I need to sum by text from the number by multiple raw and.

    1. Hi! Sorry, I do not fully understand the task.
      As it's currently written, it's hard to tell exactly what you're asking.

  12. I think i need to write an if formaula with text. If a "number" is input into a cell i want it to return a "name". This is the formula i'm using but it's not returning the value needed...

    IF(D5=1, DIGIOVANI, IF(D5=2, DURAN, IF(D5=3, GALLION-GOODMAN, IF(D5=4, PRO, IF(D5=5, RICHTER)))))

  13. I would like to have an IF formula that does the following.

    If the word check appears in G then the value in H should be the value of F
    If the word check does not appear in G then the value in H should be F + G

    Here are the cells
    $23.00 $(1.29) $24.29
    $23.00 check $23.00

  14. Im sorry ahead of time if its hard to understand my question, but how do I get the cell to fill with "N/A" if another cell says "Annual"?

    Also if the cell that says "annual" says anything else how do I get it to allow me to just put a number in the same cell that would've said "N/A"?

    Thank you in advance for your time.

    1. Hi! You can show a value in a cell by condition using the IF function. To do this, carefully read the article above. You can manually enter any other value into this cell and replace the formula with it.

      1. Thank you,

        I have the formula, =IF(H5>=96, "EWQ", IF(H5>=90, "Outstanding", IF(H5>=80, "Satisfactory", "Unsatisfactory"))), but Im unsure how to add in the same formula for the input of "N/A" in H5 to give the output of "N/A" in the requested formula. I was just trying to find something more specific to inputs that were numbers and letters, and where in the formula should the letters go.

  15. When using the following command, how do I get the result "Service required" to display in red text?
    =IF(J3<6;"Service required";"Service up to date")

    1. Hello Johan!
      The IF formula does not allow you to change color and formatting of a cell. Conditional formatting allows you to change color of a cell depending on its value. You can find the examples and detailed instructions here: Excel Conditional Formatting tutorial with examples and Two ways to change color in Excel based on cell value.
      Example of a conditional formatting formula depending on the result of an IF formula:

      =K1="Service required"

      You can also change the color depending on the values in column J. Follow this instruction: Excel conditional formatting formulas based on another cell.

      =J1<6

  16. Hi! Is this possible to use if function in this situation?

    Like overtime hours is:
    1:19 how can I get a result to this 1.25 hours in decimal?

    And what is the formula to get night differential in morning time in like this:
    time in is 3:00am how can get 3hours of night differential?

    Thank you

      1. Hi! I already get the formula to my question. But I have another question how can I round off the time 9:15am to 9:59am is equal to 10:00am?

        Thank you.

          1. Thank you for your response. Can you help me this one?

            Time in: 6:46am
            Time out: 11:22am

            I can't get the correct total number of working hours if I use this formula
            =(B1-A1)*24

            The result appear is 14:24hours it should be 4:36hours

            The regular time formula is the same result If I use this formula
            =MIN(8,C1)
            It appears also 14:24

  17. Hi all,

    I need to use an if formula that need to have in the return value if true and value if false, both a phrase and a value from a cell (better if the format of the number is showing as accounting).

    Ex.:=IF('page1'!O39>0,"Please see attached. Increased day over day by 'page1'!O39 ,Please see attached. Decreased day over day by 'page1'!O39")

  18. Hi all I need help
    No is 0 to 1000, I need 3 results,
    1 if the calculated no is less than 350 then use it , if more use 350.
    2 if the calculated no is more than 350 but less than 500, use it, less the 350, if more use 500
    3 if the calculated no is more than 500, use that no , less the 500
    Tks

  19. Hi,
    the apostrophe in true/false options has solved many of my problems
    thanks and regards

  20. Hello, I am trying to populate a cell with another cell value only if the cell is more than $0, but I can't find a formula to do this. I do not need it colored, or yes,no, or true,false. I need the value of the cell only if it's positive. Can someone help me?

    1. Hi! You cannot replace a value in a cell with another value using an Excel formula. You can do it manually or by using VBA. You can get the value you want in another cell using the recommendations in the article above.

      1. Alexander I tried the formulas above, but I do not need a true or false. I was thinking a formula with the IF function, like =IF(A2>0,"A2") but that does not work. It doesn't populate the value of the cell, it populates whatever I put inside the "", so in this case A2. Technically I could use =A2 but I need it to only populate if the value is over $0 because if the value is negative is going to affect the other calculations.

        1. Hi! Please read the above article carefully. If you are specifying a cell reference, do not use quotation marks. In your formula - "A2" is text, not a reference.

          =IF(A2>0,A2,"")

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)