by Comparing columns in Excel is something that we all do once in a while. Microsoft Excel offers a number of options to compare and match data, but most of them focus on searching in one column. In this tutorial, we will explore several techniques to compare two columns in Excel and find matches and differences between them.
How to compare 2 columns in Excel row-by-row
When you do data analysis in Excel, one of the most frequent tasks is comparing data in each individual row. This task can be done by using the IF function, as demonstrated in the following examples.
Example 1. Compare two columns for matches or differences in the same row
To compare two columns in Excel row-by-row, write a usual IF formula that compares the first two cells. Enter the formula in some other column in the same row, and then copy it down to other cells by dragging the fill handle (a small square in the bottom-right corner of the selected cell). As you do this, the cursor changes to the plus sign:
To find cells within the same row having the same content, A2 and B2 in this example, the formula is as follows: To find cells in the same row with different values, simply replace the equals sign with the non-equality sign (<>): And of course, nothing prevents you from finding both matches and differences with a single formula: Or The result may look similar to this:
As you see, the formula handles numbers, dates, times and text strings equally well. Tip. You can also compare two columns row-by-row using Excel Advanced Filter. Here is an example showing how to filter matches and differences between 2 columns.
Formula for matches
=IF(A2=B2,"Match","")
Formula for differences
=IF(A2<>B2,"No match","")
Matches and differences
=IF(A2=B2,"Match","No match")=IF(A2<>B2,"No match","Match")
Example 2. Compare two lists for case-sensitive matches in the same row
As you have probably noticed, the formulas from the previous example ignore case when comparing text values, as in row 10 in the screenshot above. If you want to find case-sensitive matches between 2 columns in each row, then use the EXACT function:
=IF(EXACT(A2, B2), "Match", "")
To find case-sensitive differences in the same row, enter the corresponding text ("Unique" in this example) in the 3rd argument of the IF function, e.g.:
=IF(EXACT(A2, B2), "Match", "Unique")
Compare multiple columns for matches in the same row
In your Excel worksheets, multiple columns can be compared based on the following criteria:
- Find rows with the same values in all columns (Example 1)
- Find rows with the same values in any 2 columns (Example 2)
Example 1. Find matches in all cells within the same row
If your table has three or more columns and you want to find rows that have the same values in all cells, an IF formula with an AND statement will work a treat:
=IF(AND(A2=B2, A2=C2), "Full match", "")
If your table has a lot of columns, a more elegant solution would be using the COUNTIF function:
=IF(COUNTIF($A2:$E2, $A2)=5, "Full match", "")
Where 5 is the number of columns you are comparing.
Example 2. Find matches in any two cells in the same row
If you are looking for a way to compare columns for any two or more cells with the same values within the same row, use an IF formula with an OR statement:
=IF(OR(A2=B2, B2=C2, A2=C2), "Match", "")
In case there are many columns to compare, your OR statement may grow too big in size. In this case, a better solution would be adding up several COUNTIF functions. The first COUNTIF counts how many columns have the same value as in the 1st column, the second COUNTIF counts how many of the remaining columns are equal to the 2nd column, and so on. If the count is 0, the formula returns "Unique", "Match" otherwise. For example:
=IF(COUNTIF(B2:D2,A2)+COUNTIF(C2:D2,B2)+(C2=D2)=0,"Unique","Match")
How to compare two columns in Excel for matches and differences
Suppose you have 2 lists of data in Excel, and you want to find all values (numbers, dates or text strings) which are in column A but not in column B.
For this, you can embed the COUNTIF($B:$B, $A2)=0 function in IF's logical test and check if it returns zero (no match is found) or any other number (at least 1 match is found).
For instance, the following IF/COUNTIF formula searches across the entire column B for the value in cell A2. If no match is found, the formula returns "No match in B", an empty string otherwise:
=IF(COUNTIF($B:$B, $A2)=0, "No match in B", "")
Tip. If your table has a fixed number of rows, you can specify a certain range (e.g. $B2:$B10) rather than the entire column ($B:$B) for the formula to work faster on large data sets.
The same result can be achieved by using an IF formula with the embedded ISERROR and MATCH functions:
=IF(ISERROR(MATCH($A2,$B$2:$B$10,0)),"No match in B","")
Or, by using the following array formula (remember to press Ctrl + Shift + Enter to enter it correctly):
=IF(SUM(--($B$2:$B$10=$A2))=0, " No match in B", "")
If you want a single formula to identify both matches (duplicates) and differences (unique values), put some text for matches in the empty double quotes ("") in any of the above formulas. For example:
=IF(COUNTIF($B:$B, $A2)=0, "No match in B", "Match in B")
How to compare two lists in Excel and pull matches
Sometimes you may need not only match two columns in two different tables, but also pull matching entries from the lookup table. Microsoft Excel provides a special function for this - the VLOOKUP function. As an alternative, you can use a more powerful and versatile INDEX MATCH formula. The users of Excel 2021 and Excel 365, can accomplish the task with the XLOOKUP function.
For example, the following formulas compare the product names in columns D against the names in column A and pull a corresponding sales figure from column B if a match is found, otherwise the #N/A error is returned.
=VLOOKUP(D2, $A$2:$B$6, 2, FALSE)
=INDEX($B$2:$B$6, MATCH($D2, $A$2:$A$6, 0))
=XLOOKUP(D2, $A$2:$A$6, $B$2:$B$6)
For more information, please see How to compare two columns using VLOOKUP.
If you don't feel very comfortable with formulas, you can have the job done using a fast and intuitive solution - Merge Tables Wizard.
Compare two lists and highlight matches and differences
When you compare columns in Excel, you may want to "visualize" the items that are present in one column but missing in the other. You can shade such cells in any color of your choosing by using the Excel Conditional Formatting feature and the following examples demonstrate the detailed steps.
Example 1. Highlight matches and differences in each row
To compare two columns and Excel and highlight cells in column A that have identical entries in column B in the same row, do the following:
- Select the cells you want to highlight (you can select cells within one column or in several columns if you want to color entire rows).
- Click Conditional formatting > New Rule… > Use a formula to determine which cells to format.
- Create a rule with a simple formula like
=$B2=$A2(assuming that row 2 is the first row with data, not including the column header). Please double check that you use a relative row reference (without the $ sign) like in the formula above.
To highlight differences between column A and B, create a rule with this formula:
=$B2<>$A2
If you are new to Excel conditional formatting, please see How to create a formula-based conditional formatting rule for step-by-step instructions.
Example 2. Highlight unique entries in each list
Whenever you are comparing two lists in Excel, there are 3 item types that you can highlight:
- Items that are only in the 1st list (unique)
- Items that are only in the 2nd list (unique)
- Items that are in both lists (duplicates) - demonstrated in the next example.
This example demonstrates how to color the items that are only in one list.
Supposing your List 1 is in column A (A2:A6) and List 2 in column C (C2:C5). You create the conditional formatting rules with the following formulas:
Highlight unique values in List 1 (column A):
=COUNTIF($C$2:$C$5, $A2)=0
Highlight unique values in List 2 (column C):
=COUNTIF($A$2:$A$6, $C2)=0
And get the following result:
Example 3. Highlight matches (duplicates) between 2 columns
If you closely followed the previous example, you won't have difficulties adjusting the COUNTIF formulas so that they find the matches rather than differences. All you have to do is to set the count greater than zero:
Highlight matches in List 1 (column A):
=COUNTIF($C$2:$C$5, $A2)>0
Highlight matches in List 2 (column C):
=COUNTIF($A$2:$A$6, $C2)>0
Highlight row differences and matches in multiple columns
When comparing values in several columns row-by-row, the quickest way to highlight matches is creating a conditional formatting rule, and the fastest way to shade differences is embracing the Go To Special feature, as demonstrated in the following examples.
Example 1. Compare multiple columns and highlight row matches
To highlight rows that have identical values in all columns, create a conditional formatting rule based on one of the following formulas:
=AND($A2=$B2, $A2=$C2)
or
=COUNTIF($A2:$C2, $A2)=3
Where A2, B2 and C2 are the top-most cells and 3 is the number of columns to compare.
Of course, neither AND nor COUNTIF formula is limited to comparing only 3 columns, you can use similar formulas to highlight rows with the same values in 4, 5, 6 or more columns.
Example 2. Compare multiple columns and highlight row differences
To quickly highlight cells with different values in each individual row, you can use Excel's Go To Special feature.
- Select the range of cells you want to compare. In this example, I've selected cells A2 to C8.
By default, the top-most cell of the selected range is the active cell, and the cells from the other selected columns in the same row will be compared to that cell. As you can see in the screenshot above, the active cell is white while all other cells of the selected range are highlighted. In this example, the active cell is A2, so the comparison column is column A.
To change the comparison column, use either the Tab key to navigate through selected cells from left to right, or the Enter key to move from top to bottom.
Tip. To select non-adjacent columns, select the first column, press and hold Ctrl, and then select the other columns. The active cell will be in the last column (or in the last block of adjacent columns). To change the comparison column, use the Tab or Enter key as described above.
- On the Home tab, go to Editing group, and click Find & Select > Go To Special… Then select Row differences and click the OK button.
- The cells whose values are different from the comparison cell in each row are colored. If you want to shade the highlighted cells in some color, simply click the Fill Color icon on the ribbon and select the color of your choosing.
How to compare two cells in Excel
In fact, comparing 2 cells is a particular case of comparing two columns in Excel row-by-row except that you don't have to copy the formulas down to other cells in the column.
For example, to compare cells A1 and C1, you can use the following formulas.
For matches:
=IF(A1=C1, "Match", "")
For differences:
=IF(A1<>C1, "Difference", "")
To learn a few other ways to compare cells in Excel, please see:
Formula-free way to compare two columns / lists in Excel
Now that you know Excel's offerings for comparing and matching columns, let me show you our own solution for this task. This tool is named Compare Two Tables and it is included in our Ultimate Suite.
The add-in can compare two tables or lists by any number of columns and both identify matches/differences (as we did with formulas) and highlight them (as we did with conditional formatting).
For the purpose of this article, we'll be comparing the following 2 lists to find common values that are present in both.
To compare two lists, here are the steps you need to follow:
- Start with clicking the Compare Tables button on the Ablebits Data tab.
- Select the first column/list and click Next. In terms of the add-in, this is your Table 1.
- Select the second column/list and click Next. In terms of the add-in, it is your Table 2, and it can reside in the same or different worksheet or even in another workbook.
- Choose what kind of data to look for:
- Duplicate values (matches) - the items that exist in both lists.
- Unique values (differences) - the items that are present in list 1, but not in list 2.
Since our aim is to find matches, we select the first option and click Next.
- This is the key step where you select the columns for comparison. In our case, the choice is obvious as we are only comparing 2 columns: 2000 Winners against 2021 Winners. In bigger tables, you can select several column pairs to compare by.
- In the final step, you choose how to deal with the found items and click Finish.
A few different options are available here. For our purposes, these two are most useful:
- Highlight with color - shades matches or differences in the selected color (like Excel conditional formatting does).
- Identify in the Status column - inserts the Status column with the "Duplicate" or "Unique" labels (like IF formulas do).
For this example, I've decided to highlight duplicates in the following color:
And in a moment, got the following result:
With the Status column, the result would look as follows:
Tip. If the lists you are comparing are in different worksheets or workbooks, it might be helpful to view Excel sheets side by side.
This is how you compare columns in Excel for matches (duplicates) and differences (unique values). If you are interested to try this tool, you are welcome to download an evaluation version using the below link.
I thank you for reading and encourage you to check out other helpful tutorials that we have :)
Available downloads
Compare Excel Lists - examples (.xlsx file)
Ultimate Suite - trial version (.exe file)
550 comments
Really amazing and simplifying the efforts.
Hi,
What I'm trying to do is highlight a row if there is any text found in cells in column E and column I.
So it would look something like:
IF text in Cell E
AND
Text in Cell I
Colour row red
There will always be text in the E column, so I only need the row to highlight if there is text found in the I column.
How do I go about doing this?
Thanks in advance :)
Hi
I want to compare Data in 2 columns A and B and want to highlight the different words only. Eg . my A1 CELL contain Apple, Sweets, good
B1 cell contains
Apple, sweets, pizza, car
In above two cells in A1 good is extra word which is not present in CELL B1. Where as Cell B1 contains words " Pizza, car "which are not present in excel so how to highlight only these different words
I have lot of Data
Hi, Sandy,
I’m afraid there’s no way to highlight only duplicate words in Excel. All the formulas and our add-ins will select or highlight the entire cell.
I can only advise you to ask around Mr.Excel forum in case they come up with some VBA code for you.
I wish I could assist you better.
Is there a way where we can identify
1. % similarity
2. between 2 columns
3. With strings as data.
Example:
Column A | Column B | Match
Cat is back | Dog is back | 33%
Superman | Spiderman | 0%
Compare to worksheets Sheet2 to Sheet1, find sheet2 match and then return data sheet1 from in 1st cell of this matched column.
2 work sheets
1st sheet contains A=data to return (1234) + B-H data to match 456,789,012
2nd sheet contains criteria to match - look for 456 then return A (1234)
hi, i need a formula to detect the values of the weight in a column and if it is more than the value then to add 7.50 but if it is less then the value to add 4.
so for example if the products weigh less than 0.4 then i need the cell to add 4 but if they weigh more than to add 7.5
hi
i have three unequal column and i want to extract unique cells for first column in compare with two another columns. how can i do it?
Thank you very much. Its working. worth full article!
Salaam everyone.
I have two excel columns each containing 63,000 values. I want to find out all the values where entries of column A are greater than those of column B. How can I do that?
Thanks in advance
Stay blessed.
Hello Fiaz,
You can enter the following formula in the first cell with data, say A1:
=IF(A1>B1, TRUE, "")
Then, copy the formula to the entire column. And after that sort or filter your dataset by the formula column.
I am working on aligning university rankings, as you can see the universities are ranked differently in 2008-2009. Is there a way to use excel to align the universities with corresponding rankings? There are hundreds of them for 12 years, so you can see it is mammoth task.
2008 2008 2009 2009
Sussex 26 cardifff 26
Cardiff 27 Sussex 27
Queen's 28 Reading 28
Reading 29 Sussex 29
Glasgow 30 Surrey 30
Birming 31 Strathclyde 31
Manches 32 Manche 32
I need a formula that will help me identify duplicate parts/product at different pricing. When I use the conditional formatting on both columns all of the cells are highlighted because it's looking at just the columns as duplicates.
Hi, Eva,
I managed to do that in the following way:
1) I decided to use a helper column (C) that checks if the product (A1) is duplicated and its price (B1) is unique with the following formula:
=COUNTIFS(A:A,$A2,B:B,"<>"&B2)
If the condition is true the formula returns 0, since it can't find any duplicated products with unique prices. Otherwise, it returns 1.
2) I created a following conditional formatting rule:
=$C1>=1
and applied it to my table =$A:$C
As a result, I can see all the duplicate products with unique prices highlighted in yellow.
Try to do the same with your data, hope it helps!
Hi,
I need to compare two columns that should be the same, but the data in each comes from different sources.
Both columns are dd/mm/yyyy hh:mm format.
My issue is that in one column, there's an extra " " between the date and time, and when I run my comparison =AND formula, the extra space is causing it to fail.
Can you suggest a way I can easily remove the extra space, or get Excel to ignore the extra space?
Hi
I have tow columns of data. in column2 there is sum of data of column1 how i can compare tow columns and recognize which numbers is sum one number in other column? for example column1 is contains 1,2,5,3,6 and column 2 is 8,9 how i can determine 8 in column2 is sum of which numbers in column 1
thank you
Hi,
I have 3 columns of data and am comparing Column 3 data with Column 1 and 2 for duplicates. I could use the conditional formatting but I was thinking if there is an excel formula that I could use?
Column 1 Column 2 Column 3
15 14 12
12 17 11
11 18 14
10 17 16
20 25 15
Thank you.
I have 2 columns, each column have value. Is it possible to move a value beside its same value? for example:
Column 1 Column 2 OUTPUT
1 1 1
2 3
3 3
=IF(COUNTIF($A:$A, $B2 )=0, "REQUIRED", "NOT REQUIRED")
I want this formula to be stopped when $Bx is null...
wow!!!!!!!!!!!!great...thanks...really useful....
Hello,
I am wanting to compare two columns of data and if those columns are equal, I'd like to execute a calculation.
I am using the formula:
=IF('Raw Data'!A:A=Analysis!A:A,SUMPRODUCT('Raw Data'!C:C,'Raw Data'!I:I)/SUM('Raw Data'!I:I))
This returns FALSE. How do I fix it?
thanks, this page information help me a lot
Hi,
Context - i have 2 versions of a document. In it i have 2 tables with alphanumeric values which i want to compare to see if any changes have been made in the recent version.
Requirement - i want to compare the alphanumeric values of the two columns (one column from each table as mentioned above) tables and want to highlight only the part that has been changed instead of the whole cell and want the result in a third column.
Question - is there a resolution to the above scenario?