by If you are a regular visitor of this blog, you've probably noticed a few articles covering different aspects of Excel conditional formatting. And now we will leverage this knowledge and create spreadsheets that differentiate between weekdays and weekends, highlight public holidays and display a coming deadline or delay. In other words, we are going to apply Excel conditional formatting to dates.
If you have some basic knowledge of Excel formulas, then you are most likely familiar with some of date and time functions such as NOW, TODAY, DATE, WEEKDAY, etc. In this tutorial, we are going to take this functionality a step further to conditionally format Excel dates in the way you want.
Excel conditional formatting for dates (built-in rules)
Microsoft Excel provides 10 options to format selected cells based on the current date.
- To apply the formatting, you simply go to the Home tab > Conditional Formatting > Highlight Cell Rules and select A Date Occurring.
- Select one of the date options from the drop-down list in the left-hand part of the window, ranging from last month to next month.
- Finally, choose one of the pre-defined formats or set up your custom format by choosing different options on the Font, Border and Fill tabs. If the Excel standard palette does not suffice, you can always click the More colors… button.
- Click OK and enjoy the result! : )
However, this fast and straightforward way has two significant limitations - 1) it works for selected cells only and 2) the conditional format is always applied based on the current date.
Excel conditional formatting formulas for dates
If you want to highlight cells or entire rows based on a date in another cell, or create rules for greater time intervals (i.e. more than a month from the current date), you will have to create your own conditional formatting rule based on a formula. Below you will find a few examples of my favorite Excel conditional formats for dates.
How to highlight weekends in Excel
Regrettably, Microsoft Excel does not have a built-in calendar similar to Outlook's. Well, let's see how you can create your own automated calendar with quite little effort.
When designing your Excel calendar, you can use the =DATE(year,month,date) function to display the days of the week. Simply enter the year and the month's number somewhere in your spreadsheet and reference those cells in the formula. Of course, you could type the numbers directly in the formula, but this is not a very efficient approach because you would have to adjust the formula for each month.
The screenshot below demonstrates the DATE function in action. I used the formula =DATE($B$2,$B$1,B$4) which is copied across row 5.
Tip. If you want to display only the days of the week like you see in the image above, select the cells with the formula (row 5 in our case), right-click and choose Format Cells…> Number > Custom. From the drop-down list under Type, select either dddd or ddd to show full day names or abbreviated names, respectively.
Your Excel calendar is almost done, and you only need to change the color of weekends. Naturally, you are not going to color the cells manually. We'll have Excel format the weekends automatically by creating a conditional formatting rule based on the WEEKDAY formula.
- You start by selecting your Excel calendar where you want to shade the weekends. In our case, it is the range $B$4:$AE$10. Be sure to start the selection with the 1st date column - Colum B in this example.
- On the Home tab, click Conditional Formatting menu > New Rule.
- Create a new conditional formatting rule based on a formula as explained in the above linked guide.
- In the "Format values where this formula is true" box, enter the following WEEKDAY formula that will determine which cells are Saturdays and Sundays:
=WEEKDAY(B$5,2)>5 - Click the Format… button and set up your custom format by switching between the Font, Border and Fill tabs and playing with different formatting options. When done, click the OK button to preview the rule.
Now, let me briefly explain the WEEKDAY(serial_number,[return_type]) formula so that you can quickly adjust it for your own spreadsheets.
- The
serial_numberparameter represents the date you are trying to find. You enter a reference to your first cell with a date, B$5 in our case. - The
[return_type]parameter determines the week type (square brackets imply it is optional). You enter 2 as the return type for a week starting from Monday (1) through Sunday (7). You can find the full list of available return types here. - Finally, you write >5 to highlight only Saturdays (6) and Sundays (7).
The screenshot below demonstrates the result in Excel 2013 - the weekends are highlighted in the reddish colour.
Tips:
- If you have non-standard weekends in your company, e.g. Fridays and Saturdays, then you would need to tweak the formula so that it starts counting from Sunday (1) and highlight days 6 (Friday) and 7 (Saturday) -
WEEKDAY(B$5,1)>5. - If you are creating a horizontal (landscape) calendar, use a relative column (without $) and absolute row (with $) in a cell reference because you should lock the reference of the row - in the above example it is row 5, so we entered B$5. But if you are designing a calendar in vertical orientation, you should do the opposite, i.e. use an absolute column and relative row, e.g. $B5 as you can see in the screenshot below:
How to highlight holidays in Excel
To improve your Excel calendar further, you can shade public holidays as well. To do that, you will need to list the holidays you want to highlight in the same or some other spreadsheet.
For example, I've added the following holidays in column A ($A$14:$A$17). Of course, not all of them are real public holidays, but they will do for demonstration purposes : )
Again, you open Conditional Formatting > New Rule. In the case of holidays, you are going to use either MATCH or COUNTIF function:
=COUNTIF($A$14:$A$17,B$5)>0=MATCH(B$5,$A$14:$A$17,0)
Note. If you have chosen a different color for holidays, you need to move the public holiday rule to the top of the rules list via Conditional Formatting > Manage Rules…
The following image shows the result in Excel 2013:
Conditionally format a cell when a value is changed to a date
It's not a big problem to conditionally format a cell when a date is added to that cell or any other cell in the same row as long as no other value type is allowed. In this case, you could simply use a formula to highlight non-blanks, as described in Excel conditional formulas for blanks and non-blanks. But what if those cells already have some values, e.g. text, and you want to change the background color when text is changed to a date?
The task may sound a bit intricate, but the solution is very simple.
- First off, you need to determine the format code of your date. Here are just a few examples:
- D1: dd-mmm-yy or d-mmm-yy
- D2: dd-mmm or d-mmm
- D3: mmm-yy
- D4: mm/dd/yy or m/d/yy or m/d/yy h:mm
You can find the complete list of date codes in this article.
- Select a column where you want to change the color of cells or the entire table in case you want to highlight rows.
- And now create a conditional formatting rule using a formula similar to this one:
=CELL("format",$A2)="D1". In the formula, A is the column with dates and D1 is the date format.If your table contains dates in 2 or more formats, then use the OR operator, e.g.
=OR(cell("format", $A2)="D1", cell("format",$A2)="D2", cell("format", $A2)="D3")The screenshot below demonstrates the result of such conditional formatting rule for dates.
How to highlight rows based on a certain date in a certain column
Suppose, you have a large Excel spreadsheet that contains two date columns (B and C). You want to highlight every row that has a certain date, say 13-May-14, in column C.
To apply Excel conditional formatting to a certain date, you need to find its numerical value first. As you probably know, Microsoft Excel stores dates as sequential serial numbers, starting from January 1, 1900. So, 1-Jan-1900 is stored as 1, 2-Jan-1900 is stored as 2… and 13-May-14 as 41772.
To find the date's number, right-click the cell, select Format Cells > Number and choose the General format. Write down the number you see and click Cancel because you do not really want to change the date's format.
That was actually the major part of the work and now you only need to create a conditional formatting rule for the entire table with this very simple formula: =$C2=41772. The formula implies that your table has headers and row 2 is your first row with data.
An alternative way is to use the DATEVALUE formula that converts the date to the number format is which it is stored, e.g. =$C2=DATEVALUE("5/13/2014")
Whichever formula you use, it will have the same effect:
Conditionally format dates in Excel based on the current date
As you probably know Microsoft Excel provides the TODAY() functions for various calculations based on the current date. Here are just a few examples of how you can use it to conditionally format dates in Excel.
Example 1. Highlight dates equal to, greater than or less than today
To conditionally format cells or entire rows based on today's date, you use the TODAY function as follows:
Equal to today: =$B2=TODAY()
Greater than today: =$B2>TODAY()
Less than today: =$B2<TODAY()
The screenshot below demonstrates the above rules in action. Please note, at the moment of writing TODAY was 12-Jun-2014.
Example 2. Conditionally format dates in Excel based on several conditions
In a similar fashion, you can use the TODAY function in combination with other Excel functions to handle more complex scenarios. For example, you may want your Excel conditional formatting date formula to color the Invoice column when the Delivery Date is equal to or greater than today BUT you want the formatting to disappear when you enter the invoice number.
For this task, you would need an additional column with the following formula (where E is your Delivery column and F the Invoice column):
=IF(E2>=TODAY(),IF(F2="", 1, 0), 0)
If the delivery date is greater than or equal to the current date and there is no number in the Invoice column, the formula returns 1, otherwise it's 0.
After that you create a simple conditional formatting rule for the Invoice column with the formula =$G2=1 where G is your additional column. Of course, you will be able to hide this column later.
Example 3. Highlight upcoming dates and delays
Suppose you have a project schedule in Excel that lists tasks, their start dates and durations. What you want is to have the end date for each task calculated automatically. An additional challenge is that the formula should also consider the weekends. For example, if the starting date is 13-Jun-2014 and the number of days of work (Duration) is 2, the ending date should come as 17-Jun-2014, because 14-Jun and 15-Jun are Saturday and Sunday.
To do this, we will use the WORKDAY.INTL(start_date,days,[weekend],[holidays]) function, more precisely =WORKDAY.INTL(B2,C2,1).
In the formula, we enter 1 as the 3rd parameter since it indicates Saturday and Sunday as holidays. You can use another value if your weekends are different, say, Fri and Sat. The full list of the weekend values is available here. Optionally, you can also use the 4th parameter [holidays], which is a set of dates (range of cells) that should be excluded from the working day calendar.
And finally, you may want to highlight rows depending on how far away the deadline is. For example, the conditional formatting rules based on the following 2 formulas highlight upcoming and recent end dates, respectively:
=AND($D2-TODAY()>=0,$D2-TODAY()<=7)- highlight all rows where the End Date (column D) is within the next 7 days. This formula is really handy when it comes to tracking upcoming expiration dates or payments.=AND(TODAY()-$D2>=0,TODAY()-$D2<=7)- highlight all rows where the End Date (column D) is within the last 7 days. You can use this formula to track the latest overdue payments and other delays.
Here are a few more formula examples that can be applied to the table above:
=$D2<TODAY() - highlights all passed dates (i.e. dates less than the current date). Can be used to format expired subscriptions, overdue payments etc.
=$D2>TODAY() - highlights all future dates (i.e. dates greater than the current date). You can use it to highlight upcoming events.
Of course, there can be infinite variations of the above formulas, depending on your particular task. For instance:
=$D2-TODAY()>=6 - highlights dates that occur in 6 or more days.
=$D2=TODAY()-14 - highlights dates occurring exactly 2 weeks ago.
How to highlight dates within a date range
If you have a long list of dates in your worksheet, you may also want to highlight the cells or rows that fall within a certain date range, i.e. highlight all dates that are between two given dates.
You can fulfil this task using the TODAY() function again. You will just have to construct a little bit more elaborate formulas as demonstrated in the examples below.
Formulas to highlight past dates
- More than 30 days ago:
=TODAY()-$A2>30 - From 30 to 15 days ago, inclusive:
=AND(TODAY()-$A2>=15, TODAY()-$A2<=30) - Less than 15 days ago:
=AND(TODAY()-$A2>=1, TODAY()-$A2<15)
The current date and any future dates are not colored.
Formulas to highlight future dates
- Will occur in more than 30 days from now:
=$A2-TODAY()>30 - In 30 to 15 days, inclusive:
=AND($A2-TODAY()>=15, $A2-TODAY()<=30) - In less than 15 days:
=AND($A2-TODAY()>=1, $A2-TODAY()<15)
The current date and any past dates are not colored.
How to shade gaps and time intervals
In this last example, we are going to utilize yet another Excel date function - DATEDIF(start_date, end_date, interval). This function calculates the difference between two dates based on the specified interval. It differs from all other functions we've discussed in this tutorial in the way that it lets you ignore months or years and calculate the difference only between days or months, whichever you choose.
Don't see how this could work for you? Think about it in another way… Suppose you have a list of birthdays of your family members and friends. Would you like to know how many days there are until their next birthday? Moreover, how many days exactly are left until your wedding anniversary and other events you wouldn't want to miss? Easily!
The formula you need is this (where A is your Date column):
=DATEDIF(TODAY(), DATE((YEAR(TODAY())+1), MONTH($A2), DAY($A2)), "yd")
The "yd" interval type at the end of the formula is used to ignore years and calculate the difference between the days only. For the full list of available interval types, look here.
Tip. If you happen to forget or misplace that complex formula, you can use this simple one instead: =365-DATEDIF($A2,TODAY(),"yd"). It produces exactly the same results, just remember to replace 365 with 366 in leap years : )
And now let's create an Excel conditional formatting rule to shade different gaps in different colors. In this case, it makes more sense to utilize Excel Color Scales rather than create a separate rule for each period.
The screenshot below demonstrates the result in Excel - a gradient 3-color scale with tints from green to red through yellow.
"Days Until Next Birthday" Excel Web App
We have created this Excel Web App to show you the above formula in action. Just enter your events in 1st column and change the corresponding dates in the 2nd column to experiment with the result.
If you are curious to know how to create such interactive Excel spreadsheets, check out this article on how to make web-based Excel spreadsheets.
Hopefully, at least one of the Excel conditional formats for dates discussed in this article has proven useful to you. If you are looking for a solution to some different task, you are most welcome to post a comment. Thank you for reading!
1237 comments
I would like to create a formula to find duplicate company names, as well as find those that occur quarterly (ex: In Oct,Nov, and Dec because current month is January).
I have a date in column b that i want highlighted if it is 61 days older than the date in column a
Hello,
I am working on a spreadsheet where I am tracking IP addresses that show up in our IDS logs. Column B contains the IP address, Column C contains the country code for the IP address, and Column D contains the date that the IP address was reported. I want to highlight the IP address's if it has already be entered into the spreadsheet. I did this with this formula in a conditional format: =COUNTIF($B$2:$B$99,$B2)>1
I want to take it one step further. I only want to highlight the IP address in Column B if the date of the previous match is greater than 7 days from today. I can't figure out how to get this additional condition. Any help would be really appreciated!
Jon
Hi, I have a column with different dates (ex: Expected Dates of Arrival) that I need to change colors:
yellow - 60 days before arrival
orange - 30 days before arrival
red - 14 days before arrival
how can i highlight greater dates from today dates
I have a simple spreadsheet that I input dates when a customer is billed. Can I apply conditional formatting to highlight the latest date entered? In other words, say this one customer was billed on 12/30/16 (which is highlighted because it is the latest date) and then he is billed on 1/15/17. I would like the 1/15/17 date to then be highlighted, and the 12/30/16 to become unhighlighted. Is this possible?
I need formula help on the below date related conditional formatting:
i have leave start date in e5 & end date in f5 and i have allocated 365 individual columns from column i5 for individual dates.
i want the cells to be highlighted in different color once i have input the Leave Start date & End Date.
How to do it?
Thanks,
I have a worksheet to track workorders. I have a column that gives Start Date as "1/1/17 6:00 AM" or "M/D/YY TIME"
I have seen a few comments on Time, I would like the cell to "fill" if the time is before 7:00 AM or after 5:00 PM.
Is there a way to make this happen?
Thank you for your "Time" ;)
I am trying to use conditional formatting to highlight a cell if another cell has a date that is after 1/1/17 and before 12/31/17
I have a yearly calendar set up days and months and all I want to do is change just the year. There has to be a faster way than hitting each individual spot and backspace 1 spot, type new number and then hit enter. Is there a formula that I haven't been able to find or a shortcut to do the whole thing at once? I can send it via email if needs be to show what I am working with. Any help will be greatly appreciated.
hi,
thanks alot for this useful tutorial, and i have a question :
i am trying to use those 2 conditional formatting formulas :
=AND(E$2:K$2=TODAY()+1,HOUR(NOW())>2)
and this formula :
=AND(E$2:K$2=TODAY(),HOUR(NOW())<=2)
where the range E$2:K$2 is a table head and contains a sequence of current week dates
i want to highlight the column in the table which has tomorrow's date on the table head cell only if the current real time is after 3:00 AM, And if not, i want to highligt the column which has today's date (not tomorrow's) ?????
note : the range that each of the 2 conditional formatting formulas applies to is $E$4:$K$134 which is my table without the head cuz i don't want to highlight the head.
i am getting tired trying to do that, can u help me?
and thanks alot :)
hhhhhhhhhhh finally it worked ! Yes !!
the right formulas should be :
=AND(E$2=TODAY()+1,HOUR(NOW())>2)
=AND(E$2=TODAY(),HOUR(NOW())<=2)
still really want to thank u, ur tutorial helped me alot, thanks.
Hi team,
Please, can you help me with this?
I have a spread sheet which contains a date range i.e. 12/02/17 ( column B ) and 13/04/17 ( Column C ) ( Both in Row 2 ). I would like column B and C to turn yellow if Today's date is in that range only.
Thank you in advance ! Really appreciated !
try selecting column B & C then make conditional formating which contain the following formula :
=B$2:C$2=TODAY()
and choose the wanted formatting
Thanks Jim, but that formula did not work. We are looking to use a formula that will format a time period window. Example we need Cell B2 and C2 to change formatting when todays date is less then C2 and greater than B2.
Hello,
I have a spreadsheet where all I need to do is for the row colour to change to grey when the date at the beginning of the row is in the past. I can't find the formula anywhere that will make it work!
Thanks
try selecting the rows then make conditional formating which contain the following formula :
=$A1:$A9<TODAY()
where i suppose that A is the column that has the dates (the rows heading), and the rows is 1 to 9
and choose the wanted formatting (gray)
Hello: Hoping that someone can assist. I have a spreadsheet that has column E containing 'approval dates' and column F containing 'expiration dates'. I want to use conditional formatting to column F to turn green if the date in the cell is 30 days or more from expiration date; yellow if it is within 30 days of the expiration date and red if it is 30 days or less from the expiration date. Thank you.
Hi there,
wonder if you could assist with a problem I'm having?
I have a spread sheet which contains a date range i.e. 01/01/16 - 10/01/16. Each date in a separate cell.
On another sheet I have a calendar. I am wondering if there is any way I can have a formula so that the day in the calendar is automatically filled with a number/coulour when that date range has been entered in previous sheet or else the day remains blank.
Many thanks
Hi,
Thank you for the great assistance you all are providing in this blog.
My question is, I have a column in excel that contains (varying dates in certain cells and blank cells with dates yet to be entered).
I am hoping to create a formula for the entire column that initiates a green fill in the cell that contains a date (30 days after the date range specified). I hope this makes sense.
Your advice would be greatly appreciated.
Kind Regards, Paul
Hi,
I want to conditional format date & time (in same cell dd/mm/yy hh:mm) with respect to another cell(in reference cell dd/mm/yy hh:mm), please help
Hi.
I'm looking to generate an automatic RAG (Red, Amber, Green)status for a spread sheet based on today's date and future dates calculated on today's date.
In other words, if an activity is on time, it will format as green, if it is behind time by, say, 2 weeks, it will be amber and anything beyond, say, 4 weeks will format as red.
The icons seem to be the way to do this, however, I am struggling with the correct formula.
Can you help please?
Thanks
sorry should read B5 B6 etc
i have successfully formatted dates in relation to today as i wanted, with your help thanks.
however it is formatting when no date is inputted in the cell. how do i correct this?
=TODAY()-$B$4>=15 (highlighted RED) this is the format used.
Hi jane,
Please try the following formula:
=AND(NOT(ISBLANK($B$4)), (TODAY()-$B$4)>=15)
Works great thanks.
another i can do this for a single row, however when i try to apply to the rest of the page this is still referencing the original cell $B$4.
how to I make it reference the corresponding row C4 D4 etc.
i have tried removing the $ but this makes the formula invalid.
help