by In this tutorial, we will continue exploring the fascinating world of Excel Conditional Formatting. If you do not feel very comfortable in this area, you may want to look through the previous article first to revive the basics - How to use conditional formatting in Excel.
Today are going to dwell on how to use Excel formulas to format individual cells and entire rows based on the values you specify or based on another cell's value. This is often considered advanced aerobatics of Excel conditional formatting and once mastered, it will help you push the formats in your spreadsheets far beyond their common uses.
Excel conditional formatting based on another cell value
Excel's predefined conditional formatting, such as Data Bars, Color Scales and Icon Sets, are mainly purposed to format cells based on their own values. If you want to apply conditional formatting based on another cell or format an entire row based on a single cell's value, then you will need to use formulas.
So, let's see how you can make a rule using a formula and after discuss formula examples for specific tasks.
How to create a conditional formatting rule based on formula
To set up a conditional formatting rule based on a formula in any version of Excel 2010 through Excel 365, carry out these steps:
- Select the cells you want to format. You can select one column, several columns or the entire table if you want to apply your conditional format to rows.
Tip. If you plan to add more data in the future and you want the conditional formatting rule to get applied to new entries automatically, you can either:
- Convert a range of cells to a table (Insert tab > Table). In this case, the conditional formatting will be automatically applied to all new rows.
- Select some empty rows below your data, say 100 blank rows.
- On the Home tab, in the Styles group, click Conditional formatting > New Rule…
- In the New Formatting Rule window, select Use a formula to determine which cells to format.
- Enter the formula in the corresponding box.
- Click the Format… button to choose your custom format.
- Switch between the Font, Border and Fill tabs and play with different options such as font style, pattern color and fill effects to set up the format that works best for you. If the standard palette does not suffice, click More colors… and choose any RGB or HSL color to your liking. When done, click the OK button.
- Make sure the Preview section displays the format you want and if it does, click the OK button to save the rule. If you are not quite happy with the format preview, click the Format… button again and make the edits.
Tip. Whenever you need to edit a conditional formatting formula, press F2 and then move to the needed place within the formula using the arrow keys. If you try arrowing without pressing F2, a range will be inserted into the formula rather than just moving the insertion pointer. To add a certain cell reference to the formula, press F2 a second time and then click that cell.
Excel conditional formatting formula examples
Now that you know how to create and apply Excel conditional formatting based on another cell, let's move on and see how to use various Excel formulas in practice.
Tip. For your Excel conditional formatting formula to work correctly, please always follow these simple rules.
Formulas to compare values (numbers and text)
As you know Microsoft Excel provides a handful of ready-to-use rules to format cells with values greater than, less than or equal to the value you specify (Conditional Formatting >Highlight Cells Rules). However, these rules do not work if you want to conditionally format certain columns or entire rows based on a cell's value in another column. In this case, you use analogous formulas:
| Condition | Formula example |
|---|---|
| Equal to | =$B2=10 |
| Not equal to | =$B2<>10 |
| Greater than | =$B2>10 |
| Greater than or equal to | =$B2>=10 |
| Less than | =$B2<10 |
| Less than or equal to | =$B2<=10 |
| Between | =AND($B2>5, $B2<10) |
The screenshot below shows an example of the Greater than formula that highlights product names in column A if the number of items in stock (column C) is greater than 0. Please pay attention that the formula applies to column A only ($A$2:$A$8). But if you select the whole table (in our case, $A$2:$E$8), this will highlight entire rows based on the value in column C.
In a similar fashion, you can create a conditional formatting rule to compare values of two cells. For example:
=$A2<$B2 - format cells or rows if a value in column A is less than the corresponding value in column B.
=$A2=$B2 - format cells or rows if values in columns A and B are the same.
=$A2<>$B2 - format cells or rows if a value in column A is not the same as in column B.
As you can see in the screenshot below, these formulas work for text values as well as for numbers.
AND and OR formulas
If you want to format your Excel table based on 2 or more conditions, then use either =AND or =OR function:
| Condition | Formula | Description |
|---|---|---|
| If both conditions are met | =AND($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, and if the value in column C is less than in column D. |
| If one of the conditions is met | =OR($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, or if the value in column C is less than in column D. |
In the screenshot below, we use the formula =AND($C2>0, $D2="Worldwide") to change the background color of rows if the number of items in stock (Column C) is greater than 0 and if the product ships worldwide (Column D). Please pay attention that the formula works with text values as well as with numbers.
Naturally, you can use two, three or more conditions in your AND and OR formulas. To see how this works in practice, watch Video: Conditional formatting based on another cell.
These are the basic conditional formatting formulas you use in Excel. Now let's consider a bit more complex but far more interesting examples.
Conditional formatting for empty and non-empty cells
I think everyone knows how to format empty and not empty cells in Excel - you simply create a new rule of the "Format only cells that contain" type and choose either Blanks or No Blanks.
But what if you want to format cells in a certain column if a corresponding cell in another column is empty or not empty? In this case, you will need to utilize Excel formulas again:
Formula for blanks: =$B2="" - format selected cells / rows if a corresponding cell in Column B is blank.
Formula for non-blanks: =$B2<>"" - format selected cells / rows if a corresponding cell in Column B is not blank.
Note. The formulas above will work for cells that are "visually" empty or not empty. If you use some Excel function that returns an empty string, e.g. =if(false,"OK", ""), and you don't want such cells to be treated as blanks, use the following formulas instead =isblank(A1)=true or =isblank(A1)=false to format blank and non-blank cells, respectively.
And here is an example of how you can use the above formulas in practice. Suppose, you have a column (B) which is "Date of Sale" and another column (C) "Delivery". These 2 columns have a value only if a sale has been made and the item delivered. So, you want the entire row to turn orange when you've made a sale; and when an item is delivered, a corresponding row should turn green. To achieve this, you need to create 2 conditional formatting rules with the following formulas:
- Orange rows (a cell in column B is not empty):
=$B2<>"" - Green rows (cells in column B and column C are not empty):
=AND($B2<>"", $C2<>"")
One more thing for you to do is to move the second rule to the top and select the Stop if true check box next to this rule:
In this particular case, the "Stop if true" option is actually superfluous, and the rule will work with or without it. You may want to check this box just as an extra precaution, in case you add a few other rules in the future that may conflict with any of the existing ones.
For more information, please see Excel conditional formatting for blank cells.
Excel formulas to work with text values
If you want to format a certain column(s) when another cell in the same row contains a certain word, you can use a formula discussed in one of the previous examples (like =$D2="Worldwide"). However, this will only work for exact match.
For partial match, you will need to use either SEARCH (case insensitive) or FIND (case sensitive).
For example, to format selected cells or rows if a corresponding cell in column D contains the word "Worldwide", use the below formula. This formula will find all such cells, regardless of where the specified text is located in a cell, including "Ships Worldwide", "Worldwide, except for…", etc:
=SEARCH("Worldwide", $D2)>0
If you'd like to shade selected cells or rows if the cell's content starts with the search text, use this one:
=SEARCH("Worldwide", $D2)>1
Excel formulas to highlight duplicates
If your task is to conditionally format cells with duplicate values, you can go with the pre-defined rule available under Conditional formatting > Highlight Cells Rules > Duplicate Values… The following article provides a detailed guidance on how to use this feature: How to automatically highlight duplicates in Excel.
However, in some cases the data looks better if you color selected columns or entire rows when a duplicate values occurs in another column. In this case, you will need to employ an Excel conditional formatting formula again, and this time we will be using the COUNTIF formula. As you know, this Excel function counts the number of cells within a specified range that meet a single criterion.
Highlight duplicates including 1st occurrences
=COUNTIF($A$2:$A$10,$A2)>1 - this formula finds duplicate values in the specified range in Column A (A2:A10 in our case), including first occurrences.
If you choose to apply the rule to the entire table, the whole rows will get formatted, as you see in the screenshot below. I've decided to change a font color in this rule, just for a change : )
Highlight duplicates without 1st occurrences
To ignore the first occurrence and highlight only subsequent duplicate values, use this formula: =COUNTIF($A$2:$A2,$A2)>1
Highlight consecutive duplicates in Excel
If you'd rather highlight only duplicates on consecutive rows, you can do this in the following way. This method works for any data types: numbers, text values and dates.
- Select the column where you want to highlight duplicates, without the column header.
- Create a conditional formatting rule(s) using these simple formulas:
Rule 1 (blue):=$A1=$A2- highlights the 2nd occurrence and all subsequent occurrences, if any.
Rule 2 (green):=$A2=$A3- highlights the 1st occurrence.
In the above formulas, A is the column you want to check for dupes, $A1 is the column header, $A2 is the first cell with data.
Important! For the formulas to work correctly, it is essential that Rule 1, which highlights the 2nd and all subsequent duplicate occurrences, should be the first rule in the list, especially if you are using two different colors.
Highlight duplicate rows
If you want apply the conditional format when duplicate values occur in two or more columns, you will need to add an extra column to your table in which you concatenate the values from the key columns using a simple formula like this one =A2&B2. After that you apply a rule using either variation of the COUNTIF formula for duplicates (with or without 1st occurrences). Naturally, you can hide an additional column after creating the rule.
Alternatively, you can use the COUNTIFS function that supports multiple criteria in a single formula. In this case, you won't need a helper column.
In this example, to highlight duplicate rows with 1st occurrences, create a rule with the following formula:
=COUNTIFS($A$2:$A$11, $A2, $B$2:$B$11, $B2)>1
To highlight duplicate rows without 1st occurrences, use this formula:
=COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)>1
Compare 2 columns for duplicates
One of the most frequent tasks in Excel is to check 2 columns for duplicate values - i.e. find and highlight values that exist in both columns. To do this, you will need to create an Excel conditional formatting rule for each column with a combination of =ISERROR() and =MATCH() functions:
For Column A: =ISERROR(MATCH(A1,$B$1:$B$10000,0))=FALSE
For Column B: =ISERROR(MATCH(B1,$A$1:$A$10000,0))=FALSE
Note. For such conditional formulas to work correctly, it's very important that you apply the rules to the entire columns, e.g. =$A:$A and =$B:$B.
You can see an example of practical usage in the following screenshot that highlights duplicates in Columns E and F.
As you can see, Excel conditional formatting formulas cope with dupes pretty well. However, for more complex cases, I would recommend using the Duplicate Remover add-in that is especially designed to find, highlight and remove duplicates in Excel, in one sheet or between two spreadsheets.
Formulas to highlight values above or below average
When you work with several sets of numeric data, the AVERAGE() function may come in handy to format cells whose values are below or above the average in a column.
For example, you can use the formula =$E2<AVERAGE($E$2:$E$8) to conditionally format the rows where the sale numbers are below the average, as shown in the screenshot below. If you are looking for the opposite, i.e. to shade the products performing above the average, replace "<" with ">" in the formula: =$E2>AVERAGE($E$2:$E$8).
How to highlight the nearest value in Excel
If I have a set of numbers, is there a way I can use Excel conditional formatting to highlight the number in that set that is closest to zero? This is what one of our blog readers, Jessica, wanted to know. The question is very clear and straightforward, but the answer is a bit too long for the comments sections, that's why you see a solution here :)
Example 1. Find the nearest value, including exact match
In our example, we'll find and highlight the number that is closest to zero. If the data set contains one or more zeroes, all of them will be highlighted. If there is no 0, then the value closest to it, either positive or negative, will be highlighted.
First off, you need to enter the following formula to any empty cell in your worksheet, you will be able to hide that cell later, if needed. The formula finds the number in a given range that is closest to the number you specify and returns the absolute value of that number (absolute value is the number without its sign):
=MIN(ABS(B2:D13-(0)))
In the above formula, B2:D13 is your range of cells and 0 is the number for which you want to find the closest match. For example, if you are looking for a value closest to 5, the formula will change to: =MIN(ABS(B2:D13-(5)))
Note. This is an array formula, so you need to press Ctrl + Shift + Enter instead of a simple Enter stroke to complete it.
And now, you create a conditional formatting rule with the following formula, where B3 is the top-right cell in your range and $C$2 in the cell with the above array formula:
=OR(B3=0-$C$2,B3=0+$C$2)
Please pay attention to the use of absolute references in the address of the cell containing the array formula ($C$2), because this cell is constant. Also, you need to replace 0 with the number for which you want to highlight the closest match. For example, if we wanted to highlight the value nearest to 5, the formula would change to: =OR(B3=5-$C$2,B3=5+$C$2)
Example 2. Highlight a value closest to the given value, but NOT exact match
In case you do not want to highlight the exact match, you need a different array formula that will find the closest value but ignore the exact match.
For example, the following array formula finds the value closest to 0 in the specified range, but ignores zeroes, if any:
=MIN(ABS(B3:C13-(0))+(10^0*(B3:C13=0)))
Please remember to press Ctrl + Shift + Enter after you finished typing your array formula.
The conditional formatting formula is the same as in the above example:
=OR(B3=0-$C$2,B3=0+$C$2)
However, since our array formula in cell C2 ignores the exact match, the conditional formatting rule ignores zeroes too and highlights the value 0.003 that is the closest match.
If you want to find the value nearest to some other number in your Excel sheet, just replace "0" with the number you want both in the array and conditional formatting formulas.
I hope the conditional formatting formulas you have learned in this tutorial will help you make sense of whatever project you are working on. If you need more examples, please check out the following articles:
Why isn't my Excel conditional formatting working correctly?
If your conditional formatting rule is not working as expected, though the formula is apparently correct, do not get upset! Most likely it is not because of some weird bug in Excel conditional formatting, rather due to a tiny mistake, not evident at the first sight. Please try out 6 simple troubleshooting steps below and I'm sure you will get your formula to work:
- Use absolute & relative cell addresses correctly. It's very difficult to deduce a general rule that will work in 100 per cent of cases. But most often you would use an absolute column (with $) and relative row (without $) in your cell references, e.g.
=$A1>1.Please keep in mind that the formulas
=A1=1,=$A$1=1and=A$1=1will produce different results. If you are not sure which one is correct in your case, you can try all : ) For more information, please see Relative and absolute cell references in Excel conditional formatting. - Verify the applied range. Check whether your conditional formatting rule applies to the correct range of cells. A rule of thumb is this - select all the cells / rows you want to format but do not include column headers.
- Write the formula for the top-left cell. In conditional formatting rules, cell references are relative to the top-left most cell in the applied range. So, always write your conditional formatting formula for the 1st row with data.
For example, if your data starts in row 2, you put
=A$2=10to highlight cells with values equal to 10 in all the rows. A common mistake is to always use a reference to the first row (e.g.=A$1=10). Please remember, you reference row 1 in the formula only if your table does not have headers and your data really starts in row 1. The most obvious indication of this case is when the rule is working, but formats values not in the rows it should. - Check the rule you created. Double-check the rule in the Conditional Formatting Rules Manager. Sometimes, for no reason at all, Microsoft Excel distorts the rule you have just created. So, if the rule is not working, go to Conditional Formatting > Manage Rules and check both the formula and the range it applies to. If you have copied the formula from the web or some other external source, make sure the straight quotes are used.
- Adjust cell references when copying the rule. If you copy Excel conditional formatting using Format Painter, don't forget to adjust all cell references in the formula.
- Split complex formulas into simple elements. If you use a complex Excel formula that includes several different functions, split it into simple elements and verify each function individually.
And finally, if you've tried all the steps but your conditional formatting rule is still not working correctly, drop me a line in comments and we will try to fathom it out together :)
In my next article we are going to look into the capabilities of Excel conditional formatting for dates. See you next week and thanks for reading!
1701 comments
Hi
i would like to know if it is possible to format a cell depending from other cell, my case is as follows.
i´m doing a vlookup from severals values but in some cases the values are percentages and other integers, in that cases a need to change the format to % or $ so i need the values keeps there format after the retrieve from the vlookup.
thanks
Hi Svetlana,
I need to conditional format cells based on a changing value.
B20 contains a percentage that changes each day (30%, 35%, 40%, etc).
I want cells G23:G37 to conditional format if they are equal to value in B20, within 5% of B20, above B20, and below B20.
Do I need a separate rule for each set of criteria I have or can I combine into one formula line?
Hi Dillon,
You will need a separate rule for each criteria because you would want to use different colors, right?
And you can create the rules based on the following formulas:
Equal to value in B20: =$G23=$B$20
Within 5% of B20: =ABS(($G23-$B$20)/$B$20)>5%
Above B20:=$G23>$B$20
Below B20:=$G23<$B$20
Hi,
I want to get greatest value among two cells to be in new cell how do I do that.
Regards,
Ahmed
Hi Ahmed,
You can use a formula similar to this:
=MAX(A1,A2)
Thanks a lot.
The following formula looks correct to me, but only affects the first cell in the range. I'm trying to change the fill color in cells B through M of a given row when cell D of that row contains a particular text string. Using row 23 as an example:
Rule =D23="TEST"
Format (pick a fill color)
Applies to =$B$23:$M$23
When I type TEST into cell D, only cell B changes fill color. I've tried this with and without "Stop If True" and both with and without dollar signs in all combinations. I can change any single cell on the worksheet, but putting in a range only affects the first cell.
Thanks very much for any insight you can provide! :)
Hi
I am having a hard time getting some conditional formatting to work, maybe you can help..??
I have a spreadsheet with columns of data
What I want to do is apply a rule to a column that will highlight the cell of a manually entered figure orange, and leave the cells that contain a formula with an unaltered format.
thanks in advance
:-)!
Hi Rick,
To leave the cells with formula blank, create a rule with the ISFORMULA function (no background or fill color is selected for this rule) and make sure it comes first in the list of rules, e.g. =ISFORMULA($A1)
To highlight the numbers entered manually with orange, you can create a rule with the formula like =ISNUMBER($A1)
To highlight
Hi Rick,
To leave the cells with formula blank, create a rule with the ISFORMULA function (no background or fill color is selected for this rule) and make sure it comes first in the list of rules, e.g. =ISFORMULA($A1)
To highlight the numbers entered manually with orange, you can create a rule with the formula like =ISNUMBER($A1)
To highlight all cells with values other than formulas, use the formula like =AND(ISFORMULA($A1)=FALSE, $A1<>"") The non-format rule with the ISFORMULA function is not needed in this case.
How can I create a condition for a spreadsheet in which column A will tell me which cell on that row has a value of $0.00? Not a blank value but the actual value of $0.00.
Hi Nikki,
Select the entire column A and create a rule with the following formula:
=AND($A1=0, $A1<>"")
I have a date in my one cell and I want to highlight the another cell only if the date in particular month and also I want to count if my color code change from above condition.
please help....
Hi PRATIK,
To highlight one cell if another falls withing a certain month, you can create a rule with the following formula:
=MONTH($A2)=1
Where A2 is the top-most cell in the dates column and 1 is the month (Jan in this example).
One revision to the document that I believe would be helpful is to explain the relationship between the "Applies to" range and the row number to use in a formula.
For example, if you had selected $A$2:$E$8 then the first row of the range is 2 and your formula should reference cells in row 2 such as $A2, $C2, etc. If you use a row number other than 2 then your formula will be relative to the row it's running on. For example, using $C1 in a formula will reference the value from column C in the previous row and using $C3 will reference the value from column C in the row below the row for the cell the formula is being evaluated on.
The columns are also relative which is why we always use $C2 and not C2 without the leading $. If you were to use C2 in a formula then the excel will fetch data from a cell that both column and row relative to the cell that it's evaluating the formula on. The relative distance is based on the column and row of the upper-left cell in the applies-to range.
Related to this is if while writing a formula you click on cell C2 then Excel inserts the address in your formula as $C$2. This means Excel will always reference cell C2 regardless of what cell it's evaluating when processing condition formulas.
Once you understand how this works then can take advantage of it by having the formatting of a range of cells controlled by one of:
* A single cell ($C$2).
* Cells in a fixed column relative to the current row ($C2).
* Cells in a fixed row relative to the current column (C$2).
* Cells in columns and rows both relative to the current cell (C2).
I am currently having an issue with a format. I have column G (cells 4-20) that have a name populated. I am querying a rotating list of names that populate in column L (typically go down to row 60 or farther). If even one of the names from column G populate in a single row of column L, I would like that row (using L2 as an example) A2:M2 to be highlighted blue.
This has been truly frustrating. Please tell me if there is a fix.
Hi Svetlana
I have 1 empty colum with fill by any color but when i put anything the color will be disappear, please help me to solve the problem.
Hi Svetlana
I have a large data set in a single column that I want to apply conditional formatting to.
Data in cells A1 and A2 are duplicates, A3 and A4 are duplicates and so on...
I want to format cells were one member of the duplicate differs from the other by more than 1 or less than -1.
This formula: =OR(SUM(A1-A2)>=1,SUM(A1-A2)<=-1) works. But if i use it in conditional formatting on the entire column it pairs [A1 with A2] then [A2 with A3] and [A3 with A4] and so on... Giving me analysis between cells which are not duplicates.
I want the formula to be applied only to 'every other' row?
Can you help? Thanks in advance.
Hello,
I need to conditional format cells based on a changing value.
B20 contains a percentage that changes each day (30%, 35%, 40%, etc).
I want cells G23:G37 to conditional format if they are equal to value in B20, within 5% of B20, above B20, and below B20.
Do I need a separate rule for each set of criteria I have or can I combine into one formula line?
Hi
I am having a hard time getting some conditional formatting to work, maybe you can help..??
I have a spreadsheet with columns of data
What I want to do is apply a rule to a column, or various columns, that will highlight the cell of a a manually entered figure orange, and leave the cells that contain a formula unaltered.
thanks in advance
hye, I want to ask about how to highlight green for passed and red for failed based on another cell result? mind if you can show me the way? thankyou
Hi Husna,
Simply select the column(s) you want to highlight and create a rule with the formula that references another cells. For example:
Green: =$A2="passed"
Red: =$A2="failed"
Hi Svetlana
I would like to highlight cells in a column where the corresponding cells in an adjacent row return a formula error (#N/A). Can this be done with conditional formatting?
Thank you.
Ruth
Hi Ruth,
You can create a rule with a formula similar to =ISNA($A2) where A2 is first row with data in the column that contains #N/A errors.
Hi !
How can I creat a conditional formating with a formula I have in a cell of another sheet of the same document? or How can I use the same formula that for conditional formating in another part of the document?
Thank you
Mary
Dear Madam,
I am preparing a attendance sheet but I have some confusion with this sheet because I want if a personnel make holiday at Saturday and Monday to I can acquire 3 absent but I design sheet with A for absent and P for Present to that is why I have to face problem I am continuously thinking and applying but still I am unable to get rid of this hindrance kindly help me out.
many thanks.
i have a sheet with a matrix of users and whether they have access to a security role (roles are columns, names are rows, values are Yes/No). I want to use conditional formatting to compare this to a matrix of classes and highlight where the user's roles differ from the class they are assigned to. is this possible? i tried using a vlookup formula in a rule, and it didn't seem to work. Any thoughts?
i have a sheet with a matrix of users and whether they have access to a security role (roles are columns, names are rows, values are Yes/No). I want to use conditional formatting to compare this to a matrix of classes and highlight where the user's roles differ from the class they are assigned to. is this possible? i tried using a vlookup formula in a rule, and it didn't seem to work. Any thoughts?
Sorry to bother you, but have been trying to get this to work for ages. I have what will eventually be a large table of data. Column A is a word and B to O are a mix of numbers and words.
I need the following to make the cell in column A to be filled say, green if certain criteria are met, orange if others and red if others.
I can't even get the green section to work. This is what I have so far:
I highlight either A2 or B2 to O2 (it doesn't seem to matter what I highlight, nothing works)then enter this:
=and(D2<20, E2<55, F2<50, G2=Low, h2=Nil, j2<15, k2<20, m2<100, 0270 for red, G2 = high for red etc.
If it's impossible to have the other two colours working in conjunction that's fine, even having the green working will be a great help.
Thanks in advance if you can get to it,
regards Liz