by In this tutorial, we will continue exploring the fascinating world of Excel Conditional Formatting. If you do not feel very comfortable in this area, you may want to look through the previous article first to revive the basics - How to use conditional formatting in Excel.
Today are going to dwell on how to use Excel formulas to format individual cells and entire rows based on the values you specify or based on another cell's value. This is often considered advanced aerobatics of Excel conditional formatting and once mastered, it will help you push the formats in your spreadsheets far beyond their common uses.
Excel conditional formatting based on another cell value
Excel's predefined conditional formatting, such as Data Bars, Color Scales and Icon Sets, are mainly purposed to format cells based on their own values. If you want to apply conditional formatting based on another cell or format an entire row based on a single cell's value, then you will need to use formulas.
So, let's see how you can make a rule using a formula and after discuss formula examples for specific tasks.
How to create a conditional formatting rule based on formula
To set up a conditional formatting rule based on a formula in any version of Excel 2010 through Excel 365, carry out these steps:
- Select the cells you want to format. You can select one column, several columns or the entire table if you want to apply your conditional format to rows.
Tip. If you plan to add more data in the future and you want the conditional formatting rule to get applied to new entries automatically, you can either:
- Convert a range of cells to a table (Insert tab > Table). In this case, the conditional formatting will be automatically applied to all new rows.
- Select some empty rows below your data, say 100 blank rows.
- On the Home tab, in the Styles group, click Conditional formatting > New Rule…
- In the New Formatting Rule window, select Use a formula to determine which cells to format.
- Enter the formula in the corresponding box.
- Click the Format… button to choose your custom format.
- Switch between the Font, Border and Fill tabs and play with different options such as font style, pattern color and fill effects to set up the format that works best for you. If the standard palette does not suffice, click More colors… and choose any RGB or HSL color to your liking. When done, click the OK button.
- Make sure the Preview section displays the format you want and if it does, click the OK button to save the rule. If you are not quite happy with the format preview, click the Format… button again and make the edits.
Tip. Whenever you need to edit a conditional formatting formula, press F2 and then move to the needed place within the formula using the arrow keys. If you try arrowing without pressing F2, a range will be inserted into the formula rather than just moving the insertion pointer. To add a certain cell reference to the formula, press F2 a second time and then click that cell.
Excel conditional formatting formula examples
Now that you know how to create and apply Excel conditional formatting based on another cell, let's move on and see how to use various Excel formulas in practice.
Tip. For your Excel conditional formatting formula to work correctly, please always follow these simple rules.
Formulas to compare values (numbers and text)
As you know Microsoft Excel provides a handful of ready-to-use rules to format cells with values greater than, less than or equal to the value you specify (Conditional Formatting >Highlight Cells Rules). However, these rules do not work if you want to conditionally format certain columns or entire rows based on a cell's value in another column. In this case, you use analogous formulas:
| Condition | Formula example |
|---|---|
| Equal to | =$B2=10 |
| Not equal to | =$B2<>10 |
| Greater than | =$B2>10 |
| Greater than or equal to | =$B2>=10 |
| Less than | =$B2<10 |
| Less than or equal to | =$B2<=10 |
| Between | =AND($B2>5, $B2<10) |
The screenshot below shows an example of the Greater than formula that highlights product names in column A if the number of items in stock (column C) is greater than 0. Please pay attention that the formula applies to column A only ($A$2:$A$8). But if you select the whole table (in our case, $A$2:$E$8), this will highlight entire rows based on the value in column C.
In a similar fashion, you can create a conditional formatting rule to compare values of two cells. For example:
=$A2<$B2 - format cells or rows if a value in column A is less than the corresponding value in column B.
=$A2=$B2 - format cells or rows if values in columns A and B are the same.
=$A2<>$B2 - format cells or rows if a value in column A is not the same as in column B.
As you can see in the screenshot below, these formulas work for text values as well as for numbers.
AND and OR formulas
If you want to format your Excel table based on 2 or more conditions, then use either =AND or =OR function:
| Condition | Formula | Description |
|---|---|---|
| If both conditions are met | =AND($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, and if the value in column C is less than in column D. |
| If one of the conditions is met | =OR($B2<$C2, $C2<$D2) |
Formats cells if the value in column B is less than in column C, or if the value in column C is less than in column D. |
In the screenshot below, we use the formula =AND($C2>0, $D2="Worldwide") to change the background color of rows if the number of items in stock (Column C) is greater than 0 and if the product ships worldwide (Column D). Please pay attention that the formula works with text values as well as with numbers.
Naturally, you can use two, three or more conditions in your AND and OR formulas. To see how this works in practice, watch Video: Conditional formatting based on another cell.
These are the basic conditional formatting formulas you use in Excel. Now let's consider a bit more complex but far more interesting examples.
Conditional formatting for empty and non-empty cells
I think everyone knows how to format empty and not empty cells in Excel - you simply create a new rule of the "Format only cells that contain" type and choose either Blanks or No Blanks.
But what if you want to format cells in a certain column if a corresponding cell in another column is empty or not empty? In this case, you will need to utilize Excel formulas again:
Formula for blanks: =$B2="" - format selected cells / rows if a corresponding cell in Column B is blank.
Formula for non-blanks: =$B2<>"" - format selected cells / rows if a corresponding cell in Column B is not blank.
Note. The formulas above will work for cells that are "visually" empty or not empty. If you use some Excel function that returns an empty string, e.g. =if(false,"OK", ""), and you don't want such cells to be treated as blanks, use the following formulas instead =isblank(A1)=true or =isblank(A1)=false to format blank and non-blank cells, respectively.
And here is an example of how you can use the above formulas in practice. Suppose, you have a column (B) which is "Date of Sale" and another column (C) "Delivery". These 2 columns have a value only if a sale has been made and the item delivered. So, you want the entire row to turn orange when you've made a sale; and when an item is delivered, a corresponding row should turn green. To achieve this, you need to create 2 conditional formatting rules with the following formulas:
- Orange rows (a cell in column B is not empty):
=$B2<>"" - Green rows (cells in column B and column C are not empty):
=AND($B2<>"", $C2<>"")
One more thing for you to do is to move the second rule to the top and select the Stop if true check box next to this rule:
In this particular case, the "Stop if true" option is actually superfluous, and the rule will work with or without it. You may want to check this box just as an extra precaution, in case you add a few other rules in the future that may conflict with any of the existing ones.
For more information, please see Excel conditional formatting for blank cells.
Excel formulas to work with text values
If you want to format a certain column(s) when another cell in the same row contains a certain word, you can use a formula discussed in one of the previous examples (like =$D2="Worldwide"). However, this will only work for exact match.
For partial match, you will need to use either SEARCH (case insensitive) or FIND (case sensitive).
For example, to format selected cells or rows if a corresponding cell in column D contains the word "Worldwide", use the below formula. This formula will find all such cells, regardless of where the specified text is located in a cell, including "Ships Worldwide", "Worldwide, except for…", etc:
=SEARCH("Worldwide", $D2)>0
If you'd like to shade selected cells or rows if the cell's content starts with the search text, use this one:
=SEARCH("Worldwide", $D2)>1
Excel formulas to highlight duplicates
If your task is to conditionally format cells with duplicate values, you can go with the pre-defined rule available under Conditional formatting > Highlight Cells Rules > Duplicate Values… The following article provides a detailed guidance on how to use this feature: How to automatically highlight duplicates in Excel.
However, in some cases the data looks better if you color selected columns or entire rows when a duplicate values occurs in another column. In this case, you will need to employ an Excel conditional formatting formula again, and this time we will be using the COUNTIF formula. As you know, this Excel function counts the number of cells within a specified range that meet a single criterion.
Highlight duplicates including 1st occurrences
=COUNTIF($A$2:$A$10,$A2)>1 - this formula finds duplicate values in the specified range in Column A (A2:A10 in our case), including first occurrences.
If you choose to apply the rule to the entire table, the whole rows will get formatted, as you see in the screenshot below. I've decided to change a font color in this rule, just for a change : )
Highlight duplicates without 1st occurrences
To ignore the first occurrence and highlight only subsequent duplicate values, use this formula: =COUNTIF($A$2:$A2,$A2)>1
Highlight consecutive duplicates in Excel
If you'd rather highlight only duplicates on consecutive rows, you can do this in the following way. This method works for any data types: numbers, text values and dates.
- Select the column where you want to highlight duplicates, without the column header.
- Create a conditional formatting rule(s) using these simple formulas:
Rule 1 (blue):=$A1=$A2- highlights the 2nd occurrence and all subsequent occurrences, if any.
Rule 2 (green):=$A2=$A3- highlights the 1st occurrence.
In the above formulas, A is the column you want to check for dupes, $A1 is the column header, $A2 is the first cell with data.
Important! For the formulas to work correctly, it is essential that Rule 1, which highlights the 2nd and all subsequent duplicate occurrences, should be the first rule in the list, especially if you are using two different colors.
Highlight duplicate rows
If you want apply the conditional format when duplicate values occur in two or more columns, you will need to add an extra column to your table in which you concatenate the values from the key columns using a simple formula like this one =A2&B2. After that you apply a rule using either variation of the COUNTIF formula for duplicates (with or without 1st occurrences). Naturally, you can hide an additional column after creating the rule.
Alternatively, you can use the COUNTIFS function that supports multiple criteria in a single formula. In this case, you won't need a helper column.
In this example, to highlight duplicate rows with 1st occurrences, create a rule with the following formula:
=COUNTIFS($A$2:$A$11, $A2, $B$2:$B$11, $B2)>1
To highlight duplicate rows without 1st occurrences, use this formula:
=COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)>1
Compare 2 columns for duplicates
One of the most frequent tasks in Excel is to check 2 columns for duplicate values - i.e. find and highlight values that exist in both columns. To do this, you will need to create an Excel conditional formatting rule for each column with a combination of =ISERROR() and =MATCH() functions:
For Column A: =ISERROR(MATCH(A1,$B$1:$B$10000,0))=FALSE
For Column B: =ISERROR(MATCH(B1,$A$1:$A$10000,0))=FALSE
Note. For such conditional formulas to work correctly, it's very important that you apply the rules to the entire columns, e.g. =$A:$A and =$B:$B.
You can see an example of practical usage in the following screenshot that highlights duplicates in Columns E and F.
As you can see, Excel conditional formatting formulas cope with dupes pretty well. However, for more complex cases, I would recommend using the Duplicate Remover add-in that is especially designed to find, highlight and remove duplicates in Excel, in one sheet or between two spreadsheets.
Formulas to highlight values above or below average
When you work with several sets of numeric data, the AVERAGE() function may come in handy to format cells whose values are below or above the average in a column.
For example, you can use the formula =$E2<AVERAGE($E$2:$E$8) to conditionally format the rows where the sale numbers are below the average, as shown in the screenshot below. If you are looking for the opposite, i.e. to shade the products performing above the average, replace "<" with ">" in the formula: =$E2>AVERAGE($E$2:$E$8).
How to highlight the nearest value in Excel
If I have a set of numbers, is there a way I can use Excel conditional formatting to highlight the number in that set that is closest to zero? This is what one of our blog readers, Jessica, wanted to know. The question is very clear and straightforward, but the answer is a bit too long for the comments sections, that's why you see a solution here :)
Example 1. Find the nearest value, including exact match
In our example, we'll find and highlight the number that is closest to zero. If the data set contains one or more zeroes, all of them will be highlighted. If there is no 0, then the value closest to it, either positive or negative, will be highlighted.
First off, you need to enter the following formula to any empty cell in your worksheet, you will be able to hide that cell later, if needed. The formula finds the number in a given range that is closest to the number you specify and returns the absolute value of that number (absolute value is the number without its sign):
=MIN(ABS(B2:D13-(0)))
In the above formula, B2:D13 is your range of cells and 0 is the number for which you want to find the closest match. For example, if you are looking for a value closest to 5, the formula will change to: =MIN(ABS(B2:D13-(5)))
Note. This is an array formula, so you need to press Ctrl + Shift + Enter instead of a simple Enter stroke to complete it.
And now, you create a conditional formatting rule with the following formula, where B3 is the top-right cell in your range and $C$2 in the cell with the above array formula:
=OR(B3=0-$C$2,B3=0+$C$2)
Please pay attention to the use of absolute references in the address of the cell containing the array formula ($C$2), because this cell is constant. Also, you need to replace 0 with the number for which you want to highlight the closest match. For example, if we wanted to highlight the value nearest to 5, the formula would change to: =OR(B3=5-$C$2,B3=5+$C$2)
Example 2. Highlight a value closest to the given value, but NOT exact match
In case you do not want to highlight the exact match, you need a different array formula that will find the closest value but ignore the exact match.
For example, the following array formula finds the value closest to 0 in the specified range, but ignores zeroes, if any:
=MIN(ABS(B3:C13-(0))+(10^0*(B3:C13=0)))
Please remember to press Ctrl + Shift + Enter after you finished typing your array formula.
The conditional formatting formula is the same as in the above example:
=OR(B3=0-$C$2,B3=0+$C$2)
However, since our array formula in cell C2 ignores the exact match, the conditional formatting rule ignores zeroes too and highlights the value 0.003 that is the closest match.
If you want to find the value nearest to some other number in your Excel sheet, just replace "0" with the number you want both in the array and conditional formatting formulas.
I hope the conditional formatting formulas you have learned in this tutorial will help you make sense of whatever project you are working on. If you need more examples, please check out the following articles:
Why isn't my Excel conditional formatting working correctly?
If your conditional formatting rule is not working as expected, though the formula is apparently correct, do not get upset! Most likely it is not because of some weird bug in Excel conditional formatting, rather due to a tiny mistake, not evident at the first sight. Please try out 6 simple troubleshooting steps below and I'm sure you will get your formula to work:
- Use absolute & relative cell addresses correctly. It's very difficult to deduce a general rule that will work in 100 per cent of cases. But most often you would use an absolute column (with $) and relative row (without $) in your cell references, e.g.
=$A1>1.Please keep in mind that the formulas
=A1=1,=$A$1=1and=A$1=1will produce different results. If you are not sure which one is correct in your case, you can try all : ) For more information, please see Relative and absolute cell references in Excel conditional formatting. - Verify the applied range. Check whether your conditional formatting rule applies to the correct range of cells. A rule of thumb is this - select all the cells / rows you want to format but do not include column headers.
- Write the formula for the top-left cell. In conditional formatting rules, cell references are relative to the top-left most cell in the applied range. So, always write your conditional formatting formula for the 1st row with data.
For example, if your data starts in row 2, you put
=A$2=10to highlight cells with values equal to 10 in all the rows. A common mistake is to always use a reference to the first row (e.g.=A$1=10). Please remember, you reference row 1 in the formula only if your table does not have headers and your data really starts in row 1. The most obvious indication of this case is when the rule is working, but formats values not in the rows it should. - Check the rule you created. Double-check the rule in the Conditional Formatting Rules Manager. Sometimes, for no reason at all, Microsoft Excel distorts the rule you have just created. So, if the rule is not working, go to Conditional Formatting > Manage Rules and check both the formula and the range it applies to. If you have copied the formula from the web or some other external source, make sure the straight quotes are used.
- Adjust cell references when copying the rule. If you copy Excel conditional formatting using Format Painter, don't forget to adjust all cell references in the formula.
- Split complex formulas into simple elements. If you use a complex Excel formula that includes several different functions, split it into simple elements and verify each function individually.
And finally, if you've tried all the steps but your conditional formatting rule is still not working correctly, drop me a line in comments and we will try to fathom it out together :)
In my next article we are going to look into the capabilities of Excel conditional formatting for dates. See you next week and thanks for reading!
1701 comments
I use conditional formatting to change the color of the cell from green for good to red for bad, works good. My boss just asked me to modify this to put the conditional formatted color into another cell. So what he wants will look like this, cell A5 has conditional formatting that will turn green or red depending on the text value and on the same page cell AW83 will turn the same color as cell A5. I need help with the last part cell AW83 working
forgot to mention cell AW83 has a numeric value that needs to remain after the cell changes color thanks
Hello Mike,
The easiest way to go would be creating the same rules for AW83 that you have for cell A5.
Otherwise you will need to add a user-defined function to your file as there is no function in Excel that checks colors. The following blog post describes the steps to get our GetCellColor function:
https://www.ablebits.com/office-addins-blog/count-sum-by-color-excel/#count-cells-color
You need to copy just the first function from the code in the post.
Then you can use this function to get the color code from A5 in another cell, e.g. enter =GetCellColor(A5). Finally, you'll need to create a conditional formatting rule for AW83 and use the following type of formula in it:
=GetCellColor($A$5)=5287936
5287936 is the color code you need to replace with the code of green or red color you may have in A5.
Hello,
If the cells in the column have negative and positive value (ex. A1 = -1, A2 = 9), how can I create a formula to fill cell with red color if negative value and green if positive value?
Thanks,
Hello Tim,
You need to create two conditional formatting rules: one for each color.
You can use this simple formula for positive numbers to fill with green color:
=$A1>=0
Here is a formula for negative numbers with red fill format:
=$A1<0
Hi Sako,
How exactly is the date range defined in sheet2? Is it 2 cells with the start date and end date?
how do i color a cell if the date in worksheet 1 equals to a date in a date range in worksheet 2?
Hello-
New to "Advanced" excel. On Sheet 1 I have a sheet that I am importing numbers in from another excel document. It's for fitness testing. So there's different tests in A10 A11 A12, etc. Then in B10, B11, B12, etc there's the results. In sheet 2 I have the normative values. So in column A I have the test In Column B I have the low values for the 60-65 year group. In Column C I have the high values for the 60-65 year group (B1 and C1 are merged and say "60-65"). Then In Column D low values for 65-69, Column E high values for 65-69, etc.
I'm trying to get it so that on sheet 1 it will read their results and then if it's below the low value (Column B) for their age, turn red. If it's within the low value (Column B) and high value (Column C), then turn green, and if it's above the high value (Column C), turn blue.
First- I can't get it so that it will read the age in one box and then decide which 2 columns it should read from.
Second- Even if I try to change the formatting of the cell by manually click on the individual cells that it should compare to, still no colors change.
Anyone have any ideas or know any good resources?
Thanks!
Hello, Erin,
To help you better, we need a sample table with your data in Excel. You can email it to support@ablebits.com. Please add the link to this article and your comment number.
Hello, I'm not sure if this is even possible with Excel.
I want to change the colour of a cell based on whether another cell is SELECTED.
E.g. If any cell in Row 1 is selected then cell A1 should turn grey.
If any cell in Row 2 is selected then cell B1 should turn grey, etc
Thanks
Hello,
This is possible in Excel if you use VBA: you need a macro that will react to the Worksheet.SelectionChange event. I'm sorry, we don't write macros, you can try posting your question on the VBA branches of the following websites: https://www.excelforum.com/ or https://www.mrexcel.com/
Hello,
I am trying to make cell, for example, A4, be filled blue if in cell I4 it says "RCT".
I've managed to do this for single cells but selecting the cells in question. However I have attempted to apply this to the whole column so that any cell in column A turns blue if cell in columnn I of the the same row says "RCT", however I've been unsuccessful.
The rule which I Have used says
=$I$2:$I$49="RCT"
which applies to
=$A$2:$A$49
Can anyone explain why this isn't working at all??
Thanks a lot,
Freya
Hello Freya,
Please select the entire column I and create a conditional formatting rule using the following formula:
=$I2=$A2
Excel will automatically change it to =$I3=$A3 for line 3, and so on.
I have a spreadsheet that in one column (P) has a list of temporary badge numbers in it; then in column A I insert and assign one of the badge numbers from column P to a person. What I would like to have happen would be when I insert one of the badge numbers from column P in column A the corresponding badge number in column P would automatically highlight. That way I can tell at a glance which badge numbers have already been used and which have not. I have not been able to figure out how to get this to happen, your assistance would be appreciated. Thank you
Hello Ceci,
Please select column P and create a rule that uses a formula to highlight the cells:
=Countif($1A$1:$A1000,$P1)>0
Here P1 is the first selected cell, $1A$1:$A1000 is the range you use to assign the numbers.
I am selecting a font color for cells in the first three columns of a range when the value in column H is greater than 0. So, if H1 is greater than zero, I want A1, B1 and C1 to be in red font. If H2 is greater than zero, I want A2, B2, and C2 to be red font, and so on. I thought I had it working, but what happens in a list of say 40 rows where 10 meet the criteria, the 8 of the entries in column A turn red, but two do not. Maybe half the entries in column B turn red, none of column C turn red. The rule seems to indicate out to column C (it is a number where the others are texts so that may be the problem with C). I don't understand how it formats some and not others. thank you
Hello, Roger,
To help you better, we need a sample table with your data in Excel. You can email it to support@ablebits.com. Please add the link to this article and your comment number.
Hi, I have a spread sheet to calculate when major plant items are due for replacement (year purchased (2000) + expected life in years (10) = Year of disposal (2010), very basic (cells formatted as numbers). In a single cell I have the current financial year i.e. 2016 (number format), I would like to conditional format any year that is equal & prior too 2016 red, and any year greater than 2016 (i.e. 2017) green.
Hello Dave,
Please select the column with dates and create two rules that use formulas. One rule to highlight earlier years in red:
=B2<=2016
The second rule for highlighting later years in green:
=B2>2016
Here B2 is the first selected cell.
Hi,
I am using conditional formatting to display blanks and to make it easier for team members filtered on their names and recorded macros with short cuts so as to save time.
However when I reuse the shortcuts instead of displaying cells with blanks it is higlighting the whole rows which contain blanks.How do I solve this.
Also I am unable to go back to original sheet after using macro shortcuts. Temporarily I created another macro which removes all the rules but is there any other way.
Regards,
Sharon Dev
Hi, Could you clarify how to fill a Gender field of a table in excel work sheet? for a example if male:M,if Female:F
Thank you for sharing. Is there a way to highlight my "b" column if my "a" column has a date past today's date (today())? thanks.
Hi Yer,
Try creating a rule for column B with this formula: =$A2>Today()
Great Article..
I have a set of data with -ve and +ve values. I just need to highlight the least -ve value and least +ve value
Ex: -20, -15, -8, 1, 3, 6, 15 . In this case only -8 and 1 needs to be highlighted with different colors. can you please help with any formula for this?
Hi all, I have 2 columns each have a date. Column (1)being a test date and column (2) being a set date 7 days after the test date, for reoccurrence of the test. I need to format so that column (2) has to actions.
1. it turns orange when it is 5ays from its next test.
2. it turns red when it runs over the due date.
any help would be appreciated.
Hi Darren,
If we understand your task correctly, you can do this by creating two conditional formatting rules:
1) To color cells red when the date in column 2 is the current date or earlier:
=$B2<=TODAY()
2) To color cells orange when there are 5 days left to the test date:
=AND($B2-TODAY()>0,$B2-TODAY()<=5)
JANUARY 2016
Week Sun Mon Tue Wed Thur Fri Sat
1 2
1 3 4 5 6 7 8 9
2 10 11 12 13 14 15 16
3 17 18 19 20 21 23 23
4 24 25 26 27 28 29 30
5 31
I made this calendar manualy and I want to highlight the number date automatically and link to Friday, January 1, 2016 (=Today())on the other row. Can you please give an answer
thanks
ronald
Hello Ronald,
If your task is to highlight the current date, you can use the following formula in your conditional formatting rule:
=IF(ISBLANK(B9),FALSE,DATE(YEAR(TODAY()),2,B9)=TODAY())
This rule will work for February. You will need to change the month number for each month, e.g. replace "2" with "3" in the formula for March.
As for linking it to January 1, could you please clarify your task? What way do you want to link the dates?
Hi Svetlana, I have been wrestling with this problem for a while and I am completely stumped.
I have a spreadsheet which uses a formula (=INDEX('TMA Tracking'!K:K,MATCH(HelpSheet!$D$5,'TMA Tracking'!A:A,0))), in order to pull data off other multiple sheets within the workbook and display all the data in one place on one page (based on a key field common to all spreadsheets).
My issue is that sometimes there is a null value that the formula is trying to retrieve and, so for a date for example, it displays 1900-01-00. I would like to highlight the result, but the conditional formatting in the cell only looks at the INDEX formula and not the resultant data that it displays.
How do I fix that? Thanks so much in advance!
Hello Mark,
Conditional formatting rules look at the values in the range. If there is no date, your formula returns number 0 (the number of days starting from 01/01/1900) that is displayed in the date format. If you are trying to find such dates in your range, please replace the date 1900-01-00 with 0 in your conditional formatting rule.
If your task is different, please describe it in more detail and share the formula you use in your rule.
We'll do our best to assist you.
I have a row with 5 columns and each cell in the 5 columns have numbers in them. I have another column with serialized numbered rows (1-50) and want to color the cell's background only if a number in this column matches any of he 5 numbers in the row (described at the beginning of this problem). How to write the conditional rule(s)?
Spa-see-ba
Hello George,
You can use the following formula with your conditional formatting rule:
=IF(ISNA(MATCH(A3,B3:F3,0)),FALSE,TRUE)
We hope this helps!
How can I compare two e.g. a1:d1 with f1:i1 please need urgently
Hello,
If you are trying to find complete row matches, you can use our Duplicate Remover add-in:
https://www.ablebits.com/excel-suite/find-remove-duplicates.php
Click on the Compare Two Tables icon, select A1:D1 (or as many rows as needed) as your first table, and F1:I1 as your second table, choose the necessary key columns for comparison and the action for the results, e.g. you can highlight all matching rows in your main table.
I am using conditional formatting quite extensively on a work plan template. I have set up for different sections to format according to about 7 or 8 exclusively alternate options.
However, I don't understand why the applicable ranges for the formats seem to adjust themselves without prompt, splitting out across separate ranges. I have tried to remedy this by displaying the format list to show 'This sheet' and reducing each rule to just one appearance, so it shows one (comprehensive)range per rule. However, it soon changes itself again! I have tried playing around with the $s too and can't get it to stick.
To add to that, I now have a problem that when you insert a row within one of the conditionally formatted ranges, it automatically adjusts the first choice format (no format for blanks). It changes it so that it no longer applies to any rows previous to, and including, the new one. So, where the format range might have been set as $F$1:$U$80, if you add a row at row 6, all of a sudden the first choice formula becomes $F$7:$U$80.
Where am I going wrong??
Many thanks.
Hello Jo,
Please try to convert your data to a table in Excel (Ctrl+T), it may help with different issues, such as when a range of data gets broken.