by The tutorial explains how to use Excel functions to convert text to date and number to date, and how to turn text strings into dates in a non-formula way. You will also learn how to quickly change a number to date format.
Since Excel is not the only application you work with, sometimes you'll find yourself working with dates imported in an Excel worksheet from a .csv file or another external source. When that happens, chances are the dates will export as text entries. Even though they look like dates, Excel won't not recognize them as such.
There are many ways to convert text to date in Excel and this tutorial aims to cover them all, so that you can choose a text-to-date conversion technique most suitable for your data format and your preference for a formula or non-formula way.
How to distinguish normal Excel dates from "text dates"
When importing data into Excel, there is often a problem with date formatting. The imported entries may look like normal Excel dates to you, but they don't behave like dates. Microsoft Excel treats such entries as text, meaning you cannot sort your table by date properly, nor can you use those "text dates" in formulas, PivotTables, charts or any other Excel tool that recognizes dates.
There are a few signs that can help you determine whether a given entry is a date or a text value.
| Dates | Text values |
|
|
How to convert number to date in Excel
Since all Excel functions that change text to date return a number as a result, let's have a closer look at converting numbers to dates first.
As you probably know, Excel stores dates and times as serial numbers and it is only a cell's formatting that forces a number to be displayed as a date. For example, 1-Jan-1900 is stored as number 1, 2-Jan-1900 is stored as 2, and 1-Jan-2015 is stored as 42005. For more information on how Excel stores dates and times, please see Excel date format.
When calculating dates in Excel, the result returned by different date functions is often a serial number representing a date. For example, if =TODAY()+7 returns a number like 44286 instead of the date that is 7 days after today, that does not mean the formula is wrong. Simply, the cell format is set to General or Text while it should be Date.
To convert such serial number to date, all you have to do is change the cell number format. For this, simply pick Date in the Number Format box on the Home tab.
To apply a format other than default, then select the cells with serial numbers and press Ctrl+1 to open the Format Cells dialog. On the Number tab, choose Date, select the desired date format under Type and click OK.
Yep, it's that easy! If you want something more sophisticated than predefined Excel date formats, please see how to create a custom date format in Excel.
If some stubborn number refuses to change to a date, check out Excel date format not working - troubleshooting tips.
How to convert 8-digit number to date in Excel
It's a very common situation when a date is input as an 8-digit number like 10032016, and you need to convert it into a date value that Excel can recognize (10/03/2016). In this case, simply changing the cell format to Date won't work - you will get ########## as the result.
To convert such a number to date, you will have to use the DATE function in combination with RIGHT, LEFT and MID functions. Unfortunately, it is not possible to make a universal formula that will work in all scenarios because the original number can be input in a variety of different formats. For example:
| Number | Format | Date |
| 10032016 | ddmmyyyy | 10-Mar-2016 |
| 20160310 | yyyymmdd | |
| 20161003 | yyyyddmm |
Anyway, I will try to explain the general approach to converting such numbers to dates and provide a few formula examples.
For starters, remember the order of the Excel Date function arguments:
So, what you need to do is extract a year, month and date from the original number and supply them as the corresponding arguments to the Date function.
For example, let's see how you can convert number 10032016 (stored in cell A1) to date 3/10/2016.
- Extract the year. It's the last 4 digits, so we use the RIGHT function to pick the last 4 characters: RIGHT(A1, 4).
- Extract the month. It's the 3rd and 4th digits, so we employ the MID function to get them MID(A1, 3, 2). Where 3 (second argument) is the start number, and 2 (third argument) is the number of characters to extract.
- Extract the day. It's the first 2 digits, so we have the LEFT function to return the first 2 characters: LEFT(A2,2).
Finally, embed the above ingredients into the Date function, and you get a formula to convert number to date in Excel:
=DATE(RIGHT(A1,4), MID(A1,3,2), LEFT(A1,2))
The following screenshot demonstrates this and a couple more formulas in action:
Please pay attention to the last formula in the above screenshot (row 6). The original number-date (161003) contains only 2 chars representing a year (16). So, to get the year of 2016, we concatenate 20 and 16 using the following formula: 20&LEFT(A6,2). If you don't do this, the Date function will return 1916 by default, which is a bit weird as if Microsoft still lived in the 20th century :)
Note. The formulas demonstrated in this example work correctly as long as all numbers you want to convert to dates follow the same pattern.
How to convert text to date in Excel
When you spot text dates in your Excel file, most likely you would want to convert those text strings to normal Excel dates so that you can refer to them in your formulas to perform various calculations. And as is often the case in Excel, there are a few ways to tackle the task.
Excel DATEVALUE function - change text to date
The DATEVALUE function in Excel converts a date in the text format to a serial number that Excel recognizes as a date.
The syntax of Excel's DATEVALUE is very straightforward:
So, the formula to convert a text value to date is as simple as =DATEVALUE(A1), where A1 is a cell with a date stored as a text string.
Because the Excel DATEVALUE function converts a text date to a serial number, you will have to make that number look like a date by applying the Date format to it, as we discussed a moment ago.
The following screenshots demonstrates a few Excel DATEVALUE formulas in action:
Excel DATEVALUE function - things to remember
When converting a text string to a date using the DATEVALUE function, please keep in mind that:
- Time information in text strings is ignored, as you can see in rows 6 and 8 above. To convert text values containing both dates and times, use the VALUE function.
- If the year is omitted in a text date, Excel's DATEVALUE will pick the current year from your computer's system clock, as demonstrated in row 4 above.
- Since Microsoft Excel stores dates since January 1, 1900 , the use of the Excel DATEVALUE function on earlier dates will result in the #VALUE! error.
- The DATEVALUE function cannot convert a numeric value to date, nor can it process a text string that looks like a number, for that you will need to use the Excel VALUE function, and this is exactly what we are going to discuss next.
Excel VALUE function - convert a text string to date
Compared to DATEVALUE, the Excel VALUE function is more versatile. It can convert any text string that looks like a date or number into a number, which you can easily change to a date format of your choosing.
The syntax of the VALUE function is as follows:
Where text is a text string or reference to a cell containing the text you want to convert to number.
The Excel VALUE function can process both date and time, the latter is converted to a decimal portion, as you can see in row 6 in the following screenshot:
Mathematical operations to convert text to dates
Apart from using specific Excel functions such as VALUE and DATEVALUE, you can perform a simple mathematical operation to force Excel to do a text-to-date conversion for you. The required condition is that an operation should not change the date's value (serial number). Sounds a bit tricky? The following examples will make things easy!
Assuming that your text date is in cell A1, you can use any of the following formulas, and then apply the Date format to the cell:
- Addition:
=A1 + 0 - Multiplication:
=A1 * 1 - Division:
=A1 / 1 - Double negation:
=--A1
As you can see in the above screenshot, mathematical operations can convert dates (rows 2 and 4), times (row 6) as well as numbers formatted as text (row 8). Sometimes the result is even displayed as a date automatically, and you don't have to bother about changing the cell format.
How to convert text strings with custom delimiters to dates
If your text dates contain some delimiter other than a forward slash (/) or dash (-), Excel functions won't be able to recognize them as dates and return the #VALUE! error.
To fix this, you can run Excel's Find and Replace tool to replace your delimiter with a slash (/), all in one go:
- Select all the text strings you want to convert to dates.
- Press Ctrl+H to open the Find and Replace dialog box.
- Enter your custom separator (a dot in this example) in the Find what field, and a slash in the Replace with
- Click the Replace All
Now, the DATEVALUE or VALUE function should have no problem with converting the text strings to dates. In the same manner, you can fix dates containing any other delimiter, e.g. a space or a backward slash.
If you prefer a formula solution, you can use Excel's SUBSTITUTE function instead of Replace All to switch your delimiters to slashes.
Assuming the text strings are in column A, a SUBSTITUTE formula may look as follows:
=SUBSTITUTE(A1, ".", "/")
Where A1 is a text date and "." is the delimiter your strings are separated with.
Now, let's embed this SUBSTITUTE function into the VALUE formula:
=VALUE(SUBSTITUTE(A1, ".", "/"))
And have the text strings converted to dates, all with a single formula.
As you see, the Excel DATEVALUE and VALUE functions are quite powerful, but both have their limits. For example, if you are trying to convert complex text strings like Thursday, January 01, 2015, neither function could help. Luckily, there is a non-formula solution that can handle this task and the next section explains the detailed steps.
Text to Columns wizard - formula-free way to covert text to date
If you are a non-formula user type, a long-standing Excel feature called Text To Columns will come in handy. It can cope with simple text dates demonstrated in Example 1 as well as multi-part text strings shown in Example 2.
Example 1. Converting simple text strings to dates
If the text strings you want to convert to dates look like any of the following:
- 1.1.2015
- 1.2015
- 01 01 2015
- 2015/1/1
You don't really need formulas, nor exporting or importing anything. All it takes is 5 quick steps.
In this example, we will be converting text strings like 01 01 2015 (day, month and year are separated with spaces) to dates.
- In your Excel worksheet, select a column of text entries you want to convert to dates.
- Switch to the Data tab, Data Tools group, and click Text to Columns.
- In step 1 of the Convert Text to Columns Wizard, select Delimited and click Next.
- In step 2 of the wizard, uncheck all delimiter boxes and click Next.
- In the final step, select Date under Column data format, choose the format corresponding to your dates, and click Finish.
In this example, we are converting the text dates formatted as "01 02 2015" (month day year), so we select MDY from the drop down box.
Now, Excel recognizes your text strings as dates, automatically converts them to your default date format and displays right-aligned in the cells. You can change the date format in the usual way via the Format Cells dialog.
Note. For the Text to Column wizard to work correctly, all of your text strings should be formatted identically. For example, if some of your entries are formatted like day/month/year format while others are month/day/year, you would get incorrect results.
Example 2. Converting complex text strings to dates
If your dates are represented by multi-part text strings, such as:
- Thursday, January 01, 2015
- January 01, 2015 3 PM
You will have to put a bit more effort and use both the Text to Columns wizard and Excel DATE function.
- Select all text strings to be converted to dates.
- Click the Text to Columns button on the Data tab, Data Tools group.
- On step 1 of the Convert Text to Columns Wizard, select Delimited and click Next.
- On step 2 of the wizard, select the delimiters your text strings contain.
For example, if you are converting strings separated by commas and spaces, like "Thursday, January 01, 2015", you should choose both delimiters - Comma and Space.
It also makes sense to select the "Treat consecutive delimiters as one" option to ignore extra spaces, if your data has any.
And finally, have a look at the Data preview window and verify if the text strings are split to columns correctly, then click Next.
- On step 3 of the wizard, make sure all columns in the Data Preview section have the General format. If they don't, click on a column and select General under the Column data format options.
Note. Do not choose the Date format for any column because each column contains only one component, so Excel won't be able to understand this is a date.
If you don't need some column, click on it and select Do not import column (skip).
If you don't want to overwrite the original data, specify where the columns should be inserted - enter the address for the top left cell in the Destination field.
When done, click the Finish button.
As you see in the screenshot above, we are skipping the first column with the days of the week, splitting the other data into 3 columns (in the General format) and inserting these columns beginning from cell C2.
The following screenshot shows the result, with the original data in column A and the split data in columns C, D and E.
- Finally, you have to combine the date parts together by using a DATE formula. The syntax of the Excel DATE function is self-explanatory:
DATE(year, month, day)
In our case,
yearis in column E anddayis in column D, no problem with these.It's not so easy with
monthbecause it is text while the DATE function needs a number. Luckily, Microsoft Excel provides a special MONTH function that can change a month's name to a month's number:=MONTH(serial_number)For the MONTH function to understand it deals with a date, we put it like this:
=MONTH(1&C2)Where C2 contains the name of the month, January in our case. "1&" is added to concatenate a date (1 January) so that the MONTH function can convert it to the corresponding month number.
And now, let's embed the MONTH function into the
month; argument of our DATE formula:=DATE(F2,MONTH(1&D2),E2)
And voila, our complex text strings are successfully converted to dates:
Quick conversion of text dates using Paste Special
To quickly convert a range of simple text strings to dates, you can use the following trick.
- Copy any empty cell (select it and press Ctrl + C).
- Select the range with text values you want to convert to dates.
- Right-click the selection, click Paste Special, and select Add in the Paste Special dialog box:
- Click OK to complete the conversion and close the dialog.
What you have just done is tell Excel to add a zero (empty cell) to your text dates. To be able to do this, Excel converts a text string to a number, and since adding a zero does not change the value, you get exactly what you wanted - the date's serial number. As usual, you change a number to the date format by using the Format Cells dialog.
To learn more about the Paste Special feature, please see How to use Paste Special in Excel.
Fixing text dates with two-digit years
The modern versions of Microsoft Excel are smart enough to spot some obvious errors in your data, or better say, what Excel considers an error. When this happens, you will see an error indicator (a small green triangle) in the upper-left corner of the cell and when you select the cell, an exclamation mark appears:
Clicking the exclamation mark will display a few options relevant to your data. In case of a 2-digit year, Excel will ask if you want to convert it to 19XX or 20XX.
If you have multiple entries of this type, you can fix them all in one fell swoop - select all the cells with errors, then click on the exclamation mark and select the appropriate option.
How to turn on Error Checking in Excel
Usually, Error Checking is enabled in Excel by default. To make sure, click File > Options > Formulas, scroll down to the Error Checking section and verify if the following options are checked:
- Enable background error checking under Error Checking;
- Cells containing years represented as 2 digits under Error checking rules.
How to change text to date in Excel an easy way
As you see, converting text to date in Excel is far from being a trivial one-click operation. If you are confused by all different use cases and formulas, let me show you a quick and straightforward way.
Install our Ultimate Suite (a free trial version can be downloaded here), switch to the Ablebits Tools tab (2 new tabs containing 70+ awesome tools will be added to your Excel!) and find the Text to Date button:
To convert text-dates to normal dates, here's what you do:
- Select the cells with text strings and click the Text to Date button.
- Specify the date order (days, months and years) in the selected cells.
- Choose whether to include or not include time in the converted dates.
- Click Convert.
That's it! The results of conversion will appear in the adjacent column, your source data will be preserved. If something goes wrong, you can simply delete the results and try again with a different date order.
Tip. If you chose to convert times as well as dates, but the time units are missing in the results, be sure to apply a number format that shows both the date and time values. For more info, please see How to create custom date and time formats.
If you are curious to learn more about this wonderful tool, please check out its home page: Text to Date for Excel.
This is how you convert text to date in Excel and change dates to text. Hopefully, you have been able to find a technique to your liking. In the next article, we will tackle the opposite task and explore different ways of converting Excel dates to text strings. I thank you for reading and hope to see you next week.
723 comments
HELP? There is no way to convert this "2022-FEB" from text to a date. I have 40 charts to build each where, and the exports always put the months/years in text format. I am spending time manually retyping the dates for them to work. Is there no formula to make the date a REAL date in excel, All the methods online wont work for this?
Hello!
Here is the formula that should work perfectly for you:
=DATE(LEFT(A1,4),VLOOKUP(RIGHT(A1,3), {"JAN",1;"FEB",2;"MAR",3;"APR",4;"May",5;"JUN",6;"JUL",7;"AUG",8;"Sep",9;"OCT",10;"NOV",11;"DEC",12}, 2,0),1)
You can learn more about DATE function in Excel in this article on our blog.
Hi! Could someone help me if there is a formula to convert general format 07-12-2021 to a date format of 07-Dec-2021? I tried changing the format but it doesn’t work. Thank you!
Hello!
Here is the article that may be helpful to you: How to change Excel date format and create custom formatting.
This blog is much helpful. Thanks Ablebits team. Especially Mr. Alexander Trifuntov.
How can I convert a lot code into a date? Lot code is XX02282A which iquals 02/28/2022 which is an expiry date: PPMMDDYS
XX - producing plant code
02 - month
28 - day
2 for the year
A - producing shift
Hello!
If I got you right, the formula below will help you with your task:
=DATE("202"&MID(A1,7,1),MID(A1,3,2),MID(A1,5,2))
You can learn more about DATE function in Excel in this article on our blog.
I have a column of dates as e.g. 31 Mar, 2022 and have been using the formula =DATE(RIGHT(E4,4), MONTH(DATEVALUE(LEFT(E4,3)&"1")), MID(E4,5,FIND(",",E4)-FIND(" ",E4)-1)). It's a weekly report that I convert but lately it has been throwing back #VALUE!. Do you have any idea why one week it will work and another it won't. I can't see any change in the original dates including any spaces. Thank you.
Hello!
This formula converts the text "Mar 31, 2022" into a date. To convert the text "31 Mar, 2022" to date, you can use the DATEVALUE function, as described in the article above.
Importing a text file date shows as per left column... desired output in right column.. Any formula recommendations to get the desired result? (issue is that excel drops the zero in front of the first string)
String text Desired Answer
7122021 12/7/2021
25102021 10/25/2021
Hello!
Use Excel substring functions to insert the desired delimiters:
=DATEVALUE(LEFT(A1,LEN(A1)-6)&"."&MID(A1,LEN(A1)-5,2)&"."&RIGHT(A1,4))
This should solve your task.
Hi guys
Any way to convert 2m 19d (2 months and 19 days...!) to an excel recognised date format?
I realise it is the most ridiculous export, please help!
Hello!
The information you provided is not enough to understand your case and give you any advice. There are a different number of days in a month. What should be the result? March 19, 1900?
I have a similar request for help. My Excel sheet has the length of service written as "1 year 2 months 28 days". Can I write a formula to convert that to total number of days? And then can Excel convert the number of days to determine the exact hire date.
Hello!
Extract numbers from a text string using the substring functions.
=LEFT(A1,2)*365 + MID(A1,SEARCH("month",A1)-3,3)*30 + MID(A1,SEARCH("day",A1)-3,3)
Also take a look at this guide: Extract number from text string in Excel.
How to convert this text value to date only:
Wed Sep 01 00:07:00 UTC 2021
Hello!
The formula below to solve your task:
=DATE(RIGHT(A1,4),VLOOKUP(MID(A1,5,3), {"JAN",1;"FEB",2;"MAR",3;"APR",4;"May",5;"JUN",6;"JUL",7;"AUG",8;"Sep",9;"OCT",10;"NOV",11;"DEC",12},2,0), MID(A1,9,2))+ TIMEVALUE(MID(A1,12,8))
Hi , I have a question.
Emp ID Name Tenure Year Tenure Month Workout Core Time Productivity Productivity Q2 Productivity Q3 Workout Q2 Workout Q3 Time Worked
20 Pat 2 10 1064.99 893.65 119.17% 119.17% 120.82% 1064.99 1079.71 1008.52
30 Him 5 9 502.15 421.47 119.14% 119.14% 120.82% 502.15 509.22 469
32 Piy 2 7 825.75 697.75 118.34% 118.34% 120.82% 825.75 843.04 926
34 Sak 2 4 939.56 811.97 115.71% 115.71% 120.82% 939.56 981.03 950.6
33 Rav 8 8 917.66 803.18 114.25% 114.25% 120.82% 917.66 970.41 943.38
28 Dee 2 9 861.31 754.28 114.19% 114.22% 120.82% 861.54 911.30 902.3
35 Sam 6 2 907.71 807.12 112.46% 114.22% 120.82% 921.92 975.17 908.45
31 Om 9 0 892.36 797.5 111.89% 114.22% 120.82% 910.94 963.56 938.4
19 Log 5 8 834.71 788.82 105.82% 114.22% 120.82% 900.97 953.01 908.28
Based on this data I want to get maximum and minimum potential benefits from Productivity @ quartile 2 and quartile 3.
Productivity baseline = sum of workout / sum of core time.
Productivity at quartile 2 = total workout at Quartile 2 / core time and
Productivity at quartile 3 = total workout at Quartile 3 / core time and
and productivity variance
can you please help
thanks, Maddy
Hi!
If I understand correctly, your task is to find the sum of the column and divide the numbers. This has nothing to do with the topic of the article. If you have a question about a specific formula, ask it in the required section.
SAMPLE…
DATA A1 6
A2 EA
A3 11/04/21
USED FORMULA: =CONCATENATE("SHORTAGE OF ",ABS(A1),"(",A2,")",", ISSUED ON ",A3," (NO VARIANCE)"
OUTPUT : SHORTAGE OF 6(EA), ISSUED ON 44297 (NO VARIANCE)
How to convert the value format 44297 to date format using the formula.
Hello!
To convert a number to a date in text form, replace 44297 with the formula:
TEXT(44297,"mm/dd/yy")
Thanks for the help... Happy.
formula:
=TEXT(44297;"mm/dd/yy")
results in:
00/dd/yy
Can you pls help?
Hi!
The date in Excel is stored as a number. But you must provide to the TEXT function not a number, but a date. Use the DATE function:
=TEXT(DATE(2021;4;11);"mm/dd/yy")
I hope it’ll be helpful.
Hello,
The date in csv document was exported as the following:
1.57775E+12 (it displays as 1577750400000) in the formula field.
The cells with the dates are in General format.
How can I convert such number in the Date?
All the dates supposed to be Dec.31 of various years.
Thank you very much for your help!
Hi!
I cannot guess what date this number corresponds to.
Hi Alexander, I have a text format like this 15/06/2021 and I want to convert as date 2021/09/22.
Hello!
See the answer in this comment.
You will receive a date that you can write in any custom date format.
I have data from an export that gave me dates formatted as text or general (applying other pre-formatted date styles has no effect): 960212 (YYMMDD) and I need to convert it to a date in this format: 02/12/1996 (MM/DD/YYYY).
Any help for this?
Ken
Hello!
The formula below will do the trick for you:
=DATE(LEFT(A1,2),MID(A1,3,2),RIGHT(A1,2))
You are a genius, thank you so much. Was struggling a lot because of this.
Hi, I would like to convert this date and time string (Nov 15, 2019 02:34 PM) exported from a system to a valid date field in excel so that I can use the =WORKINGDAYS formula. Many thanks Laura
Hello!
How to convert your text to date and time, see this comment.
I hope I answered your question. If you have any other questions, please don’t hesitate to ask.
Hi Alexander, the formula works however, it returns a #VALUE error when the date is a single date eg. 4th rather than 14th of a month.
Jan 4, 2021 09:22 AM returns #VALUE!
Jan 15, 2021 08:27 AM returns 15/01/2021 as expected.
Can you help me identify what in the formula needs to change or if there is a second step I need to complete. The WORKINGDAYS formula works well on the result
Hi!
I wrote this formula based on the description you provided in your original comment. Please note that if you’d provided me with the precise and detailed description of your task from the very beginning, I’d have created a different formula that would have worked for your case.
=DATE(MID(A1,FIND("~",SUBSTITUTE(A1," ","~",2),1)+1,4), VLOOKUP(LEFT(A1,3), {"JAN",1;"FEB",2;"MAR",3;"APR",4;"May",5;"JUN",6;"JUL",7;"AUG",8;"Sep",9;"OCT",10;"NOV",11;"DEC",12},2,0), MID(A1,FIND(" ",A1,1)+1,SEARCH(",",A1,1)-5))
Thank you for your help.
Hello all,
I have a question, I get amount of data as a text genereated in .csv file, for e.g. "02-NOV-18" I would like to convert this as a date in excel format "yyyy-mm-dd". I was trying to use text as a column method, but nothing change, or when I use formula =Value or date.value nothing also change. Someone can help me with that ? Thanks in advance
I WANT TO CONVERT A DATE INTO A DAY EXAMPLE 28/02/1968 IN A GRAPH I WANT TO HAVE ONLY 28 THE LABLE THE THE GRAPH AS BELOW FREBRUARY
Hi!
If I understand your task correctly, here is the article that may be helpful to you: Excel date functions - formula examples.
Hello, my question is how can i convert text to set as date example 12232021 >>> 12/23/2021
Hi!
Read the article above carefully and pay attention to the paragraph: How to convert 8-digit numbers to date in Excel.
What is the equivalent function in excel of the "to_date" in Google Sheets?
Thanks in advance!
I need to convert a text string with military time and date to number so that can calculate total time in minutes. Its currently in hhmm ddmmmyyyyy (i.e start 2345 04JUL2020 stop 0231 05JUL2020). I would appreciate any help.
Hello!
Please use the following formula/the formula below to solve your task:
=DATE(RIGHT(A1,4),VLOOKUP(MID(A1,8,3), {"JAN",1;"FEB",2;"MAR",3;"APR",4;"May",5;"JUN",6;"JUL",7;"AUG",8;"Sep",9;"OCT",10;"NOV",11;"DEC",12},2,0), MID(A1,6,2)) + TIME(LEFT(A1,2),MID(A1,3,2),0)
Good Morning Alexander
This formula was just what I needed.
Thanks for the tip.
--Mark
I have this text output from an sql query, but I need to convert it to date so it can be sorted by date and time. Apr 14 2021 8:15AM. I would appreciate your advice.
Hello!
I believe the following formula will help you solve your task:
=DATE(MID(A1,FIND("~",SUBSTITUTE(A1," ","~",2),1)+1,4), VLOOKUP(LEFT(A1,3), {"JAN",1;"FEB",2;"MAR",3;"APR",4;"May",5;"JUN",6;"JUL",7;"AUG",8;"Sep",9;"OCT",10;"NOV",11;"DEC",12},2,0), MID(A1,FIND(" ",A1,1)+1,2)) + TIMEVALUE(MID(A1,LEN(A1)-6,5)&" "&RIGHT(A1,2))
Set the date and time format in this cell.