How to convert text to date and number to date in Excel

The tutorial explains how to use Excel functions to convert text to date and number to date, and how to turn text strings into dates in a non-formula way. You will also learn how to quickly change a number to date format.

Since Excel is not the only application you work with, sometimes you'll find yourself working with dates imported in an Excel worksheet from a .csv file or another external source. When that happens, chances are the dates will export as text entries. Even though they look like dates, Excel won't not recognize them as such.

There are many ways to convert text to date in Excel and this tutorial aims to cover them all, so that you can choose a text-to-date conversion technique most suitable for your data format and your preference for a formula or non-formula way.

How to distinguish normal Excel dates from "text dates"

When importing data into Excel, there is often a problem with date formatting. The imported entries may look like normal Excel dates to you, but they don't behave like dates. Microsoft Excel treats such entries as text, meaning you cannot sort your table by date properly, nor can you use those "text dates" in formulas, PivotTables, charts or any other Excel tool that recognizes dates.

There are a few signs that can help you determine whether a given entry is a date or a text value.

Dates Text values
  • Right-aligned by default.
  • Have Date format in the Number Format box on the Home tab > Number.
  • If several dates are selected, the Status Bar shows Average, Count and SUM.
  • Left-aligned by default.
  • General format displays in the Number Format box on the Home tab > Number.
  • If several text dates are selected, the Status Bar only shows Count.
  • There may be a leading apostrophe visible in the formula bar.

How to distinguish dates from text strings in Excel

How to convert number to date in Excel

Since all Excel functions that change text to date return a number as a result, let's have a closer look at converting numbers to dates first.

As you probably know, Excel stores dates and times as serial numbers and it is only a cell's formatting that forces a number to be displayed as a date. For example, 1-Jan-1900 is stored as number 1, 2-Jan-1900 is stored as 2, and 1-Jan-2015 is stored as 42005. For more information on how Excel stores dates and times, please see Excel date format.

When calculating dates in Excel, the result returned by different date functions is often a serial number representing a date. For example, if =TODAY()+7 returns a number like 44286 instead of the date that is 7 days after today, that does not mean the formula is wrong. Simply, the cell format is set to General or Text while it should be Date.

To convert such serial number to date, all you have to do is change the cell number format. For this, simply pick Date in the Number Format box on the Home tab.

To apply a format other than default, then select the cells with serial numbers and press Ctrl+1 to open the Format Cells dialog. On the Number tab, choose Date, select the desired date format under Type and click OK.
Converting numbers to dates in Excel

Yep, it's that easy! If you want something more sophisticated than predefined Excel date formats, please see how to create a custom date format in Excel.

If some stubborn number refuses to change to a date, check out Excel date format not working - troubleshooting tips.

How to convert 8-digit number to date in Excel

It's a very common situation when a date is input as an 8-digit number like 10032016, and you need to convert it into a date value that Excel can recognize (10/03/2016). In this case, simply changing the cell format to Date won't work - you will get ########## as the result.

To convert such a number to date, you will have to use the DATE function in combination with RIGHT, LEFT and MID functions. Unfortunately, it is not possible to make a universal formula that will work in all scenarios because the original number can be input in a variety of different formats. For example:

Number Format Date
10032016 ddmmyyyy 10-Mar-2016
20160310 yyyymmdd
20161003 yyyyddmm

Anyway, I will try to explain the general approach to converting such numbers to dates and provide a few formula examples.

For starters, remember the order of the Excel Date function arguments:

DATE(year, month, day)

So, what you need to do is extract a year, month and date from the original number and supply them as the corresponding arguments to the Date function.

For example, let's see how you can convert number 10032016 (stored in cell A1) to date 3/10/2016.

  • Extract the year. It's the last 4 digits, so we use the RIGHT function to pick the last 4 characters: RIGHT(A1, 4).
  • Extract the month. It's the 3rd and 4th digits, so we employ the MID function to get them MID(A1, 3, 2). Where 3 (second argument) is the start number, and 2 (third argument) is the number of characters to extract.
  • Extract the day. It's the first 2 digits, so we have the LEFT function to return the first 2 characters: LEFT(A2,2).

Finally, embed the above ingredients into the Date function, and you get a formula to convert number to date in Excel:

=DATE(RIGHT(A1,4), MID(A1,3,2), LEFT(A1,2))

The following screenshot demonstrates this and a couple more formulas in action:
Converting number to date in Excel

Please pay attention to the last formula in the above screenshot (row 6). The original number-date (161003) contains only 2 chars representing a year (16). So, to get the year of 2016, we concatenate 20 and 16 using the following formula: 20&LEFT(A6,2). If you don't do this, the Date function will return 1916 by default, which is a bit weird as if Microsoft still lived in the 20th century :)

Note. The formulas demonstrated in this example work correctly as long as all numbers you want to convert to dates follow the same pattern.

How to convert text to date in Excel

When you spot text dates in your Excel file, most likely you would want to convert those text strings to normal Excel dates so that you can refer to them in your formulas to perform various calculations. And as is often the case in Excel, there are a few ways to tackle the task.

Excel DATEVALUE function - change text to date

The DATEVALUE function in Excel converts a date in the text format to a serial number that Excel recognizes as a date.

The syntax of Excel's DATEVALUE is very straightforward:

DATEVALUE(date_text)

So, the formula to convert a text value to date is as simple as =DATEVALUE(A1), where A1 is a cell with a date stored as a text string.

Because the Excel DATEVALUE function converts a text date to a serial number, you will have to make that number look like a date by applying the Date format to it, as we discussed a moment ago.

The following screenshots demonstrates a few Excel DATEVALUE formulas in action:
Convert text to date using the Excel DATEVALUE function.

Excel DATEVALUE function - things to remember

When converting a text string to a date using the DATEVALUE function, please keep in mind that:

  • Time information in text strings is ignored, as you can see in rows 6 and 8 above. To convert text values containing both dates and times, use the VALUE function.
  • If the year is omitted in a text date, Excel's DATEVALUE will pick the current year from your computer's system clock, as demonstrated in row 4 above.
  • Since Microsoft Excel stores dates since January 1, 1900 , the use of the Excel DATEVALUE function on earlier dates will result in the #VALUE! error.
  • The DATEVALUE function cannot convert a numeric value to date, nor can it process a text string that looks like a number, for that you will need to use the Excel VALUE function, and this is exactly what we are going to discuss next.

Excel VALUE function - convert a text string to date

Compared to DATEVALUE, the Excel VALUE function is more versatile. It can convert any text string that looks like a date or number into a number, which you can easily change to a date format of your choosing.

The syntax of the VALUE function is as follows:

VALUE(text)

Where text is a text string or reference to a cell containing the text you want to convert to number.

The Excel VALUE function can process both date and time, the latter is converted to a decimal portion, as you can see in row 6 in the following screenshot:
Using the Excel VALUE function to convert a text string to date

Mathematical operations to convert text to dates

Apart from using specific Excel functions such as VALUE and DATEVALUE, you can perform a simple mathematical operation to force Excel to do a text-to-date conversion for you. The required condition is that an operation should not change the date's value (serial number). Sounds a bit tricky? The following examples will make things easy!

Assuming that your text date is in cell A1, you can use any of the following formulas, and then apply the Date format to the cell:

  • Addition: =A1 + 0
  • Multiplication: =A1 * 1
  • Division: =A1 / 1
  • Double negation: =--A1

Converting text to dates via mathematical operations

As you can see in the above screenshot, mathematical operations can convert dates (rows 2 and 4), times (row 6) as well as numbers formatted as text (row 8). Sometimes the result is even displayed as a date automatically, and you don't have to bother about changing the cell format.

How to convert text strings with custom delimiters to dates

If your text dates contain some delimiter other than a forward slash (/) or dash (-), Excel functions won't be able to recognize them as dates and return the #VALUE! error.

To fix this, you can run Excel's Find and Replace tool to replace your delimiter with a slash (/), all in one go:

  • Select all the text strings you want to convert to dates.
  • Press Ctrl+H to open the Find and Replace dialog box.
  • Enter your custom separator (a dot in this example) in the Find what field, and a slash in the Replace with
  • Click the Replace All

Replacing a custom delimiter with a slash

Now, the DATEVALUE or VALUE function should have no problem with converting the text strings to dates. In the same manner, you can fix dates containing any other delimiter, e.g. a space or a backward slash.

If you prefer a formula solution, you can use Excel's SUBSTITUTE function instead of Replace All to switch your delimiters to slashes.

Assuming the text strings are in column A, a SUBSTITUTE formula may look as follows:

=SUBSTITUTE(A1, ".", "/")

Where A1 is a text date and "." is the delimiter your strings are separated with.

Now, let's embed this SUBSTITUTE function into the VALUE formula:

=VALUE(SUBSTITUTE(A1, ".", "/"))

And have the text strings converted to dates, all with a single formula.
Converting text strings with custom delimiters to dates

As you see, the Excel DATEVALUE and VALUE functions are quite powerful, but both have their limits. For example, if you are trying to convert complex text strings like Thursday, January 01, 2015, neither function could help. Luckily, there is a non-formula solution that can handle this task and the next section explains the detailed steps.

Text to Columns wizard - formula-free way to covert text to date

If you are a non-formula user type, a long-standing Excel feature called Text To Columns will come in handy. It can cope with simple text dates demonstrated in Example 1 as well as multi-part text strings shown in Example 2.

Example 1. Converting simple text strings to dates

If the text strings you want to convert to dates look like any of the following:

  • 1.1.2015
  • 1.2015
  • 01 01 2015
  • 2015/1/1

You don't really need formulas, nor exporting or importing anything. All it takes is 5 quick steps.

In this example, we will be converting text strings like 01 01 2015 (day, month and year are separated with spaces) to dates.

  1. In your Excel worksheet, select a column of text entries you want to convert to dates.
  2. Switch to the Data tab, Data Tools group, and click Text to Columns.
    Switch to the Data tab and click Text to Columns.
  3. In step 1 of the Convert Text to Columns Wizard, select Delimited and click Next.
    In step 1 of the Convert Text to Columns Wizard, select Delimited and click Next.
  4. In step 2 of the wizard, uncheck all delimiter boxes and click Next.
    On step 2, uncheck all delimiter boxes and click Next.
  5. In the final step, select Date under Column data format, choose the format corresponding to your dates, and click Finish.

In this example, we are converting the text dates formatted as "01 02 2015" (month day year), so we select MDY from the drop down box.
Choose the format corresponding to your dates, and click Finish.

Now, Excel recognizes your text strings as dates, automatically converts them to your default date format and displays right-aligned in the cells. You can change the date format in the usual way via the Format Cells dialog.

Note. For the Text to Column wizard to work correctly, all of your text strings should be formatted identically. For example, if some of your entries are formatted like day/month/year format while others are month/day/year, you would get incorrect results.

Example 2. Converting complex text strings to dates

If your dates are represented by multi-part text strings, such as:

  • Thursday, January 01, 2015
  • January 01, 2015 3 PM

You will have to put a bit more effort and use both the Text to Columns wizard and Excel DATE function.

  1. Select all text strings to be converted to dates.
  2. Click the Text to Columns button on the Data tab, Data Tools group.
  3. On step 1 of the Convert Text to Columns Wizard, select Delimited and click Next.
  4. On step 2 of the wizard, select the delimiters your text strings contain.

    For example, if you are converting strings separated by commas and spaces, like "Thursday, January 01, 2015", you should choose both delimiters - Comma and Space.
    Select the delimiters your text strings contain.

    It also makes sense to select the "Treat consecutive delimiters as one" option to ignore extra spaces, if your data has any.

    And finally, have a look at the Data preview window and verify if the text strings are split to columns correctly, then click Next.

  5. On step 3 of the wizard, make sure all columns in the Data Preview section have the General format. If they don't, click on a column and select General under the Column data format options.

    Note. Do not choose the Date format for any column because each column contains only one component, so Excel won't be able to understand this is a date.

    If you don't need some column, click on it and select Do not import column (skip).

    If you don't want to overwrite the original data, specify where the columns should be inserted - enter the address for the top left cell in the Destination field.

    When done, click the Finish button.
    Make sure all columns have the General format and choose where to insert the columns.

    As you see in the screenshot above, we are skipping the first column with the days of the week, splitting the other data into 3 columns (in the General format) and inserting these columns beginning from cell C2.

    The following screenshot shows the result, with the original data in column A and the split data in columns C, D and E.

    Text strings are split into 3 different columns.

  6. Finally, you have to combine the date parts together by using a DATE formula. The syntax of the Excel DATE function is self-explanatory:
    DATE(year, month, day)

    In our case, year is in column E and day is in column D, no problem with these.

    It's not so easy with month because it is text while the DATE function needs a number. Luckily, Microsoft Excel provides a special MONTH function that can change a month's name to a month's number:

    =MONTH(serial_number)

    For the MONTH function to understand it deals with a date, we put it like this:

    =MONTH(1&C2)

    Where C2 contains the name of the month, January in our case. "1&" is added to concatenate a date (1 January) so that the MONTH function can convert it to the corresponding month number.

    And now, let's embed the MONTH function into the month; argument of our DATE formula:

    =DATE(F2,MONTH(1&D2),E2)

And voila, our complex text strings are successfully converted to dates:
The text strings are successfully converted to dates.

Quick conversion of text dates using Paste Special

To quickly convert a range of simple text strings to dates, you can use the following trick.

  • Copy any empty cell (select it and press Ctrl + C).
  • Select the range with text values you want to convert to dates.
  • Right-click the selection, click Paste Special, and select Add in the Paste Special dialog box:
    Quick conversion of text dates using Paste Special
  • Click OK to complete the conversion and close the dialog.

What you have just done is tell Excel to add a zero (empty cell) to your text dates. To be able to do this, Excel converts a text string to a number, and since adding a zero does not change the value, you get exactly what you wanted - the date's serial number. As usual, you change a number to the date format by using the Format Cells dialog.

To learn more about the Paste Special feature, please see How to use Paste Special in Excel.

Fixing text dates with two-digit years

The modern versions of Microsoft Excel are smart enough to spot some obvious errors in your data, or better say, what Excel considers an error. When this happens, you will see an error indicator (a small green triangle) in the upper-left corner of the cell and when you select the cell, an exclamation mark appears:
Error indicators in Excel

Clicking the exclamation mark will display a few options relevant to your data. In case of a 2-digit year, Excel will ask if you want to convert it to 19XX or 20XX.

If you have multiple entries of this type, you can fix them all in one fell swoop - select all the cells with errors, then click on the exclamation mark and select the appropriate option.
Fixing text dates with two-digit years using Excel Error Checking

How to turn on Error Checking in Excel

Usually, Error Checking is enabled in Excel by default. To make sure, click File > Options > Formulas, scroll down to the Error Checking section and verify if the following options are checked:

  • Enable background error checking under Error Checking;
  • Cells containing years represented as 2 digits under Error checking rules.

Turning on Error Checking in Excel

How to change text to date in Excel an easy way

As you see, converting text to date in Excel is far from being a trivial one-click operation. If you are confused by all different use cases and formulas, let me show you a quick and straightforward way.

Install our Ultimate Suite (a free trial version can be downloaded here), switch to the Ablebits Tools tab (2 new tabs containing 70+ awesome tools will be added to your Excel!) and find the Text to Date button:
Text to Date tool for Excel

To convert text-dates to normal dates, here's what you do:

  1. Select the cells with text strings and click the Text to Date button.
  2. Specify the date order (days, months and years) in the selected cells.
  3. Choose whether to include or not include time in the converted dates.
  4. Click Convert.

That's it! The results of conversion will appear in the adjacent column, your source data will be preserved. If something goes wrong, you can simply delete the results and try again with a different date order.
Converting text-dates to normal dates

Tip. If you chose to convert times as well as dates, but the time units are missing in the results, be sure to apply a number format that shows both the date and time values. For more info, please see How to create custom date and time formats.

If you are curious to learn more about this wonderful tool, please check out its home page: Text to Date for Excel.

This is how you convert text to date in Excel and change dates to text. Hopefully, you have been able to find a technique to your liking. In the next article, we will tackle the opposite task and explore different ways of converting Excel dates to text strings. I thank you for reading and hope to see you next week.

Table of contents

723 comments

  1. Hey! :)
    I see you explained how to go from an 8 digit number to a date, is it possible to do it the other way around? I need to generate a specific 8-digit code for every test I do, and connect it to the specific date. In some instances, I run more than one test a day so I need to add an extra digit at the end. Eg: on 10.11.2022 I run 3 tests and I need to convert the date to 101120221, 101120222 and 101120223, or even more ideally to a six digit + 1 (1011221, 1011222, 1011223)
    I would appreciate your help

    • Hello!
      To count the number of matching dates, use the COUNTIF function.
      You can convert a date to a number using the TEXT function and the "ddmmyy" format.

      =IF(COUNTIF($A$1:$A$100,A1)=1, TEXT(A1,"ddmmyy"), TEXT(A1,"ddmmyy")&COUNTIF($A$1:A1,A1))

      Copy this formula down along the column.
      Hope this is what you need.

      • Thank you for your help.

  2. how can I calculate a month like "January" into Days

  3. Trying to convert text to dates: example : 15-01-1749 (old church records from the 1500's to 1900's)
    Used this formula, like your example:
    =DATE(RIGHT(B14,4),MID(B14,4,2),LEFT(B14,2))

    It returned: 15-Jan-3649

    All of the day/months are correct, but all the years are off by 1900 years.
    What am I doing wrong? Thank you for your help.
    Ann

    • Hello!
      Excel does not work with dates prior to 1900. If the year number is between 0 and 1899 inclusive, Excel calculates the year by adding that number to 1900.

      • Thank you - I thought I was losing my mind!
        Trying to think of a workaround. I can make value combined with the right function to turn the year into a number in a new column, and then just display the m/d in a separate column. Is that the best I can do?
        Would any of the date functions in Ablebits help me with this?

        I'm taking data from Family Tree Maker for church parishes with birth, marriage and death dates, with other text fields, so I need to be able to play with different sorts to come up with birth rates, causes of death over time, and other statistical info. Lots of calendar math needed. There are between 7-17k records in each of the 3 parishes.

        Once again, thank your for your help,
        Ann

  4. In A1 i have 1984 B1 i have Apple
    A2 I have Jun-1990 B2 i have Orange
    A3 i have 01-May-2020 B3 I have Grape

    i need to join the text as in C1 =Apple (1984)
    C2 =Orange (Jun-1990)
    C3 = Grape (01-May-2020)
    Used text function its not working for C1.

    Please help me in resolving this issue

      • i have year as 1984 in A1, and 28-Feb-18 in A2,

        if use text to convert it date, 1984 comes as 07-Jul-1909, A2 comes as 28-Feb-2018 correctly, but i need it 1984 as 1984 only instead of 07-Jul-1909.

  5. Is it possible determine the number of days from a month text such as "August"

    Many thanks

    • Hello!
      Convert text to date and determine the first day of the month using the DATEVALUE function. Determine the last day of the month using the EOMONTH function. Find the difference between dates and add 1 day.
      Please check the formula below, it should work for you:

      =EOMONTH(DATEVALUE(1&A1),0)-DATEVALUE(1&A1)+1

  6. Hey,

    I need to covert 20200818 (Aug 18 - 2020) to be 08/18/2020 (mm/dd/yyyy) using a single formula!
    Please help!

    • Hi!
      Pay attention to the following paragraph of the article above – How to convert 8-digit number to date in Excel.
      It covers your case completely.

  7. How could I convert this to date? JAN01/19
    I'd be forever grateful!

  8. I have two strings.
    #1: 72222 and need it to be 7/22/22
    #2: 120121 and need it to be 12/1/21

    Thank you!

  9. hello
    i have a set of text 551231-02-4556 in which i would extract the first 6 character to be converted to date value result to be 31-12-1955

    any solution to this?
    Thank you

      • Thank you very much, it works, great.

  10. Hello, Mr. Alexander.. Is there a way to swap the data and month VALUE? Not just the formatting. When I paste date values from a text file or PDF, Excel auto-interprets the values incorrectly. I.e. 02-03-2019 is imported as 03rd Feb instead of 02nd Mar. Simply changing the formatting does not fix this problem.

  11. I have date formatted field(12/20/1984) in excel, when i am saving data as xml. Date is converted to number. What i need to do in excel to save this as date. I used below custom validation to allow field string(Delete) and date

    =OR(AND(ISNUMBER(J3),LEFT(CELL("format",J3),1)="D"),J3="Delete")

      • Final data I need in XML . I am not clear on statement - Save the file as an Excel file (.xlsx) and then you can write the date as a date, not as a number. Can you give me one example.

  12. How do I convert this date

    Jan-01-1985 TO 1985-01-01

    • Hello!
      To convert text to date, extract the desired characters using the substring functions.

      =DATE(MID(A1,FIND("~",SUBSTITUTE(A1,"-","~",2),1)+1,4), VLOOKUP(LEFT(A1,3), {"JAN",1;"FEB",2;"MAR",3;"APR",4;"May",5;"JUN",6;"JUL",7;"AUG",8;"Sep",9;"OCT",10;"NOV",11;"DEC",12},2,0), MID(A1,FIND("-",A1,1)+1,2))

      Then use DATE function. Set the cell to the custom date format that you need. For example, "yyyy-mm-dd".

      To convert text to date, you can also use the Text to Date tool.
      It is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and check how it works for free.

  13. Hi, I have this exact date values in my worksheet:
    a. 10/06/2022 8:00:48 p. m. ----> Type: Date ---> Format: d/mm/yyyy h:mm:ss AM/PM
    b. 10/06/2022 8:00:48 p. m. ----> Type: General ---> Format: d/mm/yyyy h:mm:ss AM/PM

    When I compare a=b the result is FALSE. I can't convert b. to date but I'm seeing the exact same values.
    Any suggestions would be very welcome.

  14. Hi I have this data of date from CSV 2022-06-12T20:30:59.611Z may I know how to convert it to Date & Time in excel?

  15. Current format: 12 25 20 22
    How can I convert this to 12/25/2022??

  16. You own a Altroz XM+ 1.2 P car no UK00AA0000;you had serviced your vehicle from OBERAI MOTORS (0000000-Sv&Pa-Dehradun-OberaiM)3 days ago on 29-APR-22,which was a Second Free Service. I require your feedback regarding the same. I Need 29-APR-22 separately from this sentence using a formula in excel. Plz help out.

  17. My formula is not working and not sure what I am doing incorrectly:
    Original w/formula needs to be
    9122004 12/9/2004 9/12/2004

    Here is the formula used:

    =DATE(RIGHT(O434,4),MID(O434,2,2),LEFT(O434,1))

    Any help is appreciated

  18. Monday, February 21, 2022
    WANT IN 02-21-2022

  19. hello
    i typed so many dates
    and i suddenly received a combination of numbers and text in the cell, and I need to return the value to date
    these are examples of the values I'm receiving
    30637514H
    310038084H

  20. Thank you! Great help!

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)