by The tutorial explains how to use Excel functions to convert text to date and number to date, and how to turn text strings into dates in a non-formula way. You will also learn how to quickly change a number to date format.
Since Excel is not the only application you work with, sometimes you'll find yourself working with dates imported in an Excel worksheet from a .csv file or another external source. When that happens, chances are the dates will export as text entries. Even though they look like dates, Excel won't not recognize them as such.
There are many ways to convert text to date in Excel and this tutorial aims to cover them all, so that you can choose a text-to-date conversion technique most suitable for your data format and your preference for a formula or non-formula way.
How to distinguish normal Excel dates from "text dates"
When importing data into Excel, there is often a problem with date formatting. The imported entries may look like normal Excel dates to you, but they don't behave like dates. Microsoft Excel treats such entries as text, meaning you cannot sort your table by date properly, nor can you use those "text dates" in formulas, PivotTables, charts or any other Excel tool that recognizes dates.
There are a few signs that can help you determine whether a given entry is a date or a text value.
| Dates | Text values |
|
|
How to convert number to date in Excel
Since all Excel functions that change text to date return a number as a result, let's have a closer look at converting numbers to dates first.
As you probably know, Excel stores dates and times as serial numbers and it is only a cell's formatting that forces a number to be displayed as a date. For example, 1-Jan-1900 is stored as number 1, 2-Jan-1900 is stored as 2, and 1-Jan-2015 is stored as 42005. For more information on how Excel stores dates and times, please see Excel date format.
When calculating dates in Excel, the result returned by different date functions is often a serial number representing a date. For example, if =TODAY()+7 returns a number like 44286 instead of the date that is 7 days after today, that does not mean the formula is wrong. Simply, the cell format is set to General or Text while it should be Date.
To convert such serial number to date, all you have to do is change the cell number format. For this, simply pick Date in the Number Format box on the Home tab.
To apply a format other than default, then select the cells with serial numbers and press Ctrl+1 to open the Format Cells dialog. On the Number tab, choose Date, select the desired date format under Type and click OK.
Yep, it's that easy! If you want something more sophisticated than predefined Excel date formats, please see how to create a custom date format in Excel.
If some stubborn number refuses to change to a date, check out Excel date format not working - troubleshooting tips.
How to convert 8-digit number to date in Excel
It's a very common situation when a date is input as an 8-digit number like 10032016, and you need to convert it into a date value that Excel can recognize (10/03/2016). In this case, simply changing the cell format to Date won't work - you will get ########## as the result.
To convert such a number to date, you will have to use the DATE function in combination with RIGHT, LEFT and MID functions. Unfortunately, it is not possible to make a universal formula that will work in all scenarios because the original number can be input in a variety of different formats. For example:
| Number | Format | Date |
| 10032016 | ddmmyyyy | 10-Mar-2016 |
| 20160310 | yyyymmdd | |
| 20161003 | yyyyddmm |
Anyway, I will try to explain the general approach to converting such numbers to dates and provide a few formula examples.
For starters, remember the order of the Excel Date function arguments:
So, what you need to do is extract a year, month and date from the original number and supply them as the corresponding arguments to the Date function.
For example, let's see how you can convert number 10032016 (stored in cell A1) to date 3/10/2016.
- Extract the year. It's the last 4 digits, so we use the RIGHT function to pick the last 4 characters: RIGHT(A1, 4).
- Extract the month. It's the 3rd and 4th digits, so we employ the MID function to get them MID(A1, 3, 2). Where 3 (second argument) is the start number, and 2 (third argument) is the number of characters to extract.
- Extract the day. It's the first 2 digits, so we have the LEFT function to return the first 2 characters: LEFT(A2,2).
Finally, embed the above ingredients into the Date function, and you get a formula to convert number to date in Excel:
=DATE(RIGHT(A1,4), MID(A1,3,2), LEFT(A1,2))
The following screenshot demonstrates this and a couple more formulas in action:
Please pay attention to the last formula in the above screenshot (row 6). The original number-date (161003) contains only 2 chars representing a year (16). So, to get the year of 2016, we concatenate 20 and 16 using the following formula: 20&LEFT(A6,2). If you don't do this, the Date function will return 1916 by default, which is a bit weird as if Microsoft still lived in the 20th century :)
Note. The formulas demonstrated in this example work correctly as long as all numbers you want to convert to dates follow the same pattern.
How to convert text to date in Excel
When you spot text dates in your Excel file, most likely you would want to convert those text strings to normal Excel dates so that you can refer to them in your formulas to perform various calculations. And as is often the case in Excel, there are a few ways to tackle the task.
Excel DATEVALUE function - change text to date
The DATEVALUE function in Excel converts a date in the text format to a serial number that Excel recognizes as a date.
The syntax of Excel's DATEVALUE is very straightforward:
So, the formula to convert a text value to date is as simple as =DATEVALUE(A1), where A1 is a cell with a date stored as a text string.
Because the Excel DATEVALUE function converts a text date to a serial number, you will have to make that number look like a date by applying the Date format to it, as we discussed a moment ago.
The following screenshots demonstrates a few Excel DATEVALUE formulas in action:
Excel DATEVALUE function - things to remember
When converting a text string to a date using the DATEVALUE function, please keep in mind that:
- Time information in text strings is ignored, as you can see in rows 6 and 8 above. To convert text values containing both dates and times, use the VALUE function.
- If the year is omitted in a text date, Excel's DATEVALUE will pick the current year from your computer's system clock, as demonstrated in row 4 above.
- Since Microsoft Excel stores dates since January 1, 1900 , the use of the Excel DATEVALUE function on earlier dates will result in the #VALUE! error.
- The DATEVALUE function cannot convert a numeric value to date, nor can it process a text string that looks like a number, for that you will need to use the Excel VALUE function, and this is exactly what we are going to discuss next.
Excel VALUE function - convert a text string to date
Compared to DATEVALUE, the Excel VALUE function is more versatile. It can convert any text string that looks like a date or number into a number, which you can easily change to a date format of your choosing.
The syntax of the VALUE function is as follows:
Where text is a text string or reference to a cell containing the text you want to convert to number.
The Excel VALUE function can process both date and time, the latter is converted to a decimal portion, as you can see in row 6 in the following screenshot:
Mathematical operations to convert text to dates
Apart from using specific Excel functions such as VALUE and DATEVALUE, you can perform a simple mathematical operation to force Excel to do a text-to-date conversion for you. The required condition is that an operation should not change the date's value (serial number). Sounds a bit tricky? The following examples will make things easy!
Assuming that your text date is in cell A1, you can use any of the following formulas, and then apply the Date format to the cell:
- Addition:
=A1 + 0 - Multiplication:
=A1 * 1 - Division:
=A1 / 1 - Double negation:
=--A1
As you can see in the above screenshot, mathematical operations can convert dates (rows 2 and 4), times (row 6) as well as numbers formatted as text (row 8). Sometimes the result is even displayed as a date automatically, and you don't have to bother about changing the cell format.
How to convert text strings with custom delimiters to dates
If your text dates contain some delimiter other than a forward slash (/) or dash (-), Excel functions won't be able to recognize them as dates and return the #VALUE! error.
To fix this, you can run Excel's Find and Replace tool to replace your delimiter with a slash (/), all in one go:
- Select all the text strings you want to convert to dates.
- Press Ctrl+H to open the Find and Replace dialog box.
- Enter your custom separator (a dot in this example) in the Find what field, and a slash in the Replace with
- Click the Replace All
Now, the DATEVALUE or VALUE function should have no problem with converting the text strings to dates. In the same manner, you can fix dates containing any other delimiter, e.g. a space or a backward slash.
If you prefer a formula solution, you can use Excel's SUBSTITUTE function instead of Replace All to switch your delimiters to slashes.
Assuming the text strings are in column A, a SUBSTITUTE formula may look as follows:
=SUBSTITUTE(A1, ".", "/")
Where A1 is a text date and "." is the delimiter your strings are separated with.
Now, let's embed this SUBSTITUTE function into the VALUE formula:
=VALUE(SUBSTITUTE(A1, ".", "/"))
And have the text strings converted to dates, all with a single formula.
As you see, the Excel DATEVALUE and VALUE functions are quite powerful, but both have their limits. For example, if you are trying to convert complex text strings like Thursday, January 01, 2015, neither function could help. Luckily, there is a non-formula solution that can handle this task and the next section explains the detailed steps.
Text to Columns wizard - formula-free way to covert text to date
If you are a non-formula user type, a long-standing Excel feature called Text To Columns will come in handy. It can cope with simple text dates demonstrated in Example 1 as well as multi-part text strings shown in Example 2.
Example 1. Converting simple text strings to dates
If the text strings you want to convert to dates look like any of the following:
- 1.1.2015
- 1.2015
- 01 01 2015
- 2015/1/1
You don't really need formulas, nor exporting or importing anything. All it takes is 5 quick steps.
In this example, we will be converting text strings like 01 01 2015 (day, month and year are separated with spaces) to dates.
- In your Excel worksheet, select a column of text entries you want to convert to dates.
- Switch to the Data tab, Data Tools group, and click Text to Columns.
- In step 1 of the Convert Text to Columns Wizard, select Delimited and click Next.
- In step 2 of the wizard, uncheck all delimiter boxes and click Next.
- In the final step, select Date under Column data format, choose the format corresponding to your dates, and click Finish.
In this example, we are converting the text dates formatted as "01 02 2015" (month day year), so we select MDY from the drop down box.
Now, Excel recognizes your text strings as dates, automatically converts them to your default date format and displays right-aligned in the cells. You can change the date format in the usual way via the Format Cells dialog.
Note. For the Text to Column wizard to work correctly, all of your text strings should be formatted identically. For example, if some of your entries are formatted like day/month/year format while others are month/day/year, you would get incorrect results.
Example 2. Converting complex text strings to dates
If your dates are represented by multi-part text strings, such as:
- Thursday, January 01, 2015
- January 01, 2015 3 PM
You will have to put a bit more effort and use both the Text to Columns wizard and Excel DATE function.
- Select all text strings to be converted to dates.
- Click the Text to Columns button on the Data tab, Data Tools group.
- On step 1 of the Convert Text to Columns Wizard, select Delimited and click Next.
- On step 2 of the wizard, select the delimiters your text strings contain.
For example, if you are converting strings separated by commas and spaces, like "Thursday, January 01, 2015", you should choose both delimiters - Comma and Space.
It also makes sense to select the "Treat consecutive delimiters as one" option to ignore extra spaces, if your data has any.
And finally, have a look at the Data preview window and verify if the text strings are split to columns correctly, then click Next.
- On step 3 of the wizard, make sure all columns in the Data Preview section have the General format. If they don't, click on a column and select General under the Column data format options.
Note. Do not choose the Date format for any column because each column contains only one component, so Excel won't be able to understand this is a date.
If you don't need some column, click on it and select Do not import column (skip).
If you don't want to overwrite the original data, specify where the columns should be inserted - enter the address for the top left cell in the Destination field.
When done, click the Finish button.
As you see in the screenshot above, we are skipping the first column with the days of the week, splitting the other data into 3 columns (in the General format) and inserting these columns beginning from cell C2.
The following screenshot shows the result, with the original data in column A and the split data in columns C, D and E.
- Finally, you have to combine the date parts together by using a DATE formula. The syntax of the Excel DATE function is self-explanatory:
DATE(year, month, day)
In our case,
yearis in column E anddayis in column D, no problem with these.It's not so easy with
monthbecause it is text while the DATE function needs a number. Luckily, Microsoft Excel provides a special MONTH function that can change a month's name to a month's number:=MONTH(serial_number)For the MONTH function to understand it deals with a date, we put it like this:
=MONTH(1&C2)Where C2 contains the name of the month, January in our case. "1&" is added to concatenate a date (1 January) so that the MONTH function can convert it to the corresponding month number.
And now, let's embed the MONTH function into the
month; argument of our DATE formula:=DATE(F2,MONTH(1&D2),E2)
And voila, our complex text strings are successfully converted to dates:
Quick conversion of text dates using Paste Special
To quickly convert a range of simple text strings to dates, you can use the following trick.
- Copy any empty cell (select it and press Ctrl + C).
- Select the range with text values you want to convert to dates.
- Right-click the selection, click Paste Special, and select Add in the Paste Special dialog box:
- Click OK to complete the conversion and close the dialog.
What you have just done is tell Excel to add a zero (empty cell) to your text dates. To be able to do this, Excel converts a text string to a number, and since adding a zero does not change the value, you get exactly what you wanted - the date's serial number. As usual, you change a number to the date format by using the Format Cells dialog.
To learn more about the Paste Special feature, please see How to use Paste Special in Excel.
Fixing text dates with two-digit years
The modern versions of Microsoft Excel are smart enough to spot some obvious errors in your data, or better say, what Excel considers an error. When this happens, you will see an error indicator (a small green triangle) in the upper-left corner of the cell and when you select the cell, an exclamation mark appears:
Clicking the exclamation mark will display a few options relevant to your data. In case of a 2-digit year, Excel will ask if you want to convert it to 19XX or 20XX.
If you have multiple entries of this type, you can fix them all in one fell swoop - select all the cells with errors, then click on the exclamation mark and select the appropriate option.
How to turn on Error Checking in Excel
Usually, Error Checking is enabled in Excel by default. To make sure, click File > Options > Formulas, scroll down to the Error Checking section and verify if the following options are checked:
- Enable background error checking under Error Checking;
- Cells containing years represented as 2 digits under Error checking rules.
How to change text to date in Excel an easy way
As you see, converting text to date in Excel is far from being a trivial one-click operation. If you are confused by all different use cases and formulas, let me show you a quick and straightforward way.
Install our Ultimate Suite (a free trial version can be downloaded here), switch to the Ablebits Tools tab (2 new tabs containing 70+ awesome tools will be added to your Excel!) and find the Text to Date button:
To convert text-dates to normal dates, here's what you do:
- Select the cells with text strings and click the Text to Date button.
- Specify the date order (days, months and years) in the selected cells.
- Choose whether to include or not include time in the converted dates.
- Click Convert.
That's it! The results of conversion will appear in the adjacent column, your source data will be preserved. If something goes wrong, you can simply delete the results and try again with a different date order.
Tip. If you chose to convert times as well as dates, but the time units are missing in the results, be sure to apply a number format that shows both the date and time values. For more info, please see How to create custom date and time formats.
If you are curious to learn more about this wonderful tool, please check out its home page: Text to Date for Excel.
This is how you convert text to date in Excel and change dates to text. Hopefully, you have been able to find a technique to your liking. In the next article, we will tackle the opposite task and explore different ways of converting Excel dates to text strings. I thank you for reading and hope to see you next week.
723 comments
Nice formual to use in excel. Thanks.
Dear Svetlana, Alexander,
Unless I misread and missed an answer to my issue in your post and other solutions, would you be able to give a hint how to deal with the following situation?
I am working on a Dutch machine and receive dates hard-coded in the csv file as "21MAR2024". Data import GUI offers "DMY" option how you suggest, but my Excel is unable to read the result. It would it read it had it "21MRT2024" written been.
Without installing another language pack, writing a macro or substituting "MAR" with "MRT", is there any other way to force Excel to recognize the correct date in my case?
Regards,
Hi! Excel in dates uses your computer's local settings. So the best choice, I think, would be substituting.
Dear Alexander,
Thank you for a quick answer!
I have a date that shows as 18/11/2015 10:04:38 AM that is generated from an external database. The number format is General. I have tried several tips you suggested above to convert to a date format i can use for my pivot table, but none works. Can you help?
Hi! To convert the text date and time to the normal date and time, I recommend trying the Text to Date tool. It is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and check how it works for free.
how to covert Friday, March 03, 2023 4:42:12 PM to 3/3/2023 16:42
Hi!
I recommend paying attention to the Text to Date tool. This tool easily converts text strings of different formats to dates. It is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and check how it works for free.
Thank you much. You helped me a lot!
if Feb'23 then result should be 1-Feb-2023 and in next cell 28-Feb-2023 (ie. start date and end date); if its Jan23-Mar23 it should be 1-Jan-2023 and 31-Mar-2023. Please help me with this
Hi!
I think you will find the EOMONTH function useful, which get date of the last day of month.
Please use the formula below:
=EOMONTH(A1,-1)+1
=EOMONTH(A1,0)
I have dates in the format 02-12-2022 and I want to convert them to 02-Dec-2022. I am using the below formula but it does not see to work after day 12th.
=IF(ISNUMBER(C2),DATE(YEAR(C2),DAY(C2),MONTH(C2)),DATE(MID(C2,LEN(C2)-3,4),LEFT(C2,LEN(C2)-8),MID(C2,LEN(C2)-6,2)))
If I apply this formula to 12-12-2022 it gives me 12-Dec-2022 but as soon as the day value changes to 13 i.e, 13-12-2022 it gives 12-Jan-2023.
Please help!!!!
Hi!
If I understand your task correctly, try the following formula:
=IF(ISNUMBER(C2),DATE(YEAR(C2),DAY(C2),MONTH(C2)),DATE(MID(C2,LEN(C2)-3,4),MID(C2,LEN(C2)-6,2),LEFT(C2,LEN(C2)-8)))
I'd recommend you to have a look at our Text to Date tool. This simple tool effortlessly converts text strings of different formats into dates without formulas. It is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and check how it works for free.
Hello. Is there a way to translate a sequence of numbers in to date and time. As an example, to convert 2303252000 to 25/03/2023 20:00. This format is used by ICAO on NOTAM YYMMDDhhmm.
Hello!
Use the MID function to extract the necessary digits to create the date and time. Use the DATE and TIME functions to do this.
=DATE(MID(A1,1,2),MID(A1,3,2),MID(A1,5,2))+TIME(MID(A1,7,2),MID(A1,9,2),0)
For more information, please visit: Excel MID function – extract text from the middle of a string and Excel DATE function with formula examples to calculate dates.
Hello. Thank you very much for your reply. It was very helpfull! I used the following formula (with ; rather , (excel2007 user :( ) and adding 20& for 2000+ year and it worked
=DATE((20&MID(A1;1;2));MID(A1;3;2);MID(A1;5;2))+TIME(MID(A1;7;2);MID(A1;9;2);0)
Thank you very much again!
Hello,
Im trying to insert data from MSSQL with SSIS into Excel. In MSSQL date is DATETIME or DATETIME2, everything looks good until insert into excel when excel formats it by itself to DATE without TIME in the rows and date with time is shown only in formula box. How to set Excel so it will show exactly as im importing from database with DATETIME in rows and it is DATE type in excel also with time in rows?
Thanks for your help.
Hello!
Set the cells to the date and time format you want. Use these guidelines: How to change Excel date format and create custom formatting. I hope this will help.
Hi. I have a problem that I can not solve. I have a Serial Number of equipment i.e 1Z6A08655AT. I need to take out from it the production date - these is represented by two first characters 1Z. 1 stands for 2021, Z stands for December.
First character indicating Year
1 is 2021,
2 is 2022,
3 is 2023
...
Second represent months:
1,2,3,4,5,6,7,8,9, X,Y,Z
I need to have outcome in mmm-yy format
No idea how to deal with it. Appreciate if you could share how to fix this ;)
Hi!
Use the MATCH function to find a match for the month character.
=MATCH(MID(A1,2,1), {"1","2","3","4","5","6","7","8","9","X","Y","Z"}, 0)
To get the year, use this formula
LEFT(A1,1)+2020
Use the DATE function to get the production date.
=DATE(LEFT(A1,1)+2020, MATCH(MID(A1,2,1), {"1","2","3","4","5","6","7","8","9","X","Y","Z"},0),1)
Hope this is what you need.
This was awesome. I just coincidentally had the same challenge and this helped massively. Thank you
Hi,
I have extracted data from my netbank and receive the dates in decimal numbers, such as;
Date
0,150497685
0,108831019
0,067164352
0,858136574
How can I concert this to dates?
Hi!
I have no idea what result you want to get, so I recommend this article: How to convert number to date in Excel.
Hi,
I have dates in the format 02-12-2022 and I want to convert them to 02-Dec-2022. I am using the below formula but it does not see to work after day 12th.
=IF(ISNUMBER(C2),DATE(YEAR(C2),DAY(C2),MONTH(C2)),DATE(MID(C2,LEN(C2)-3,4),LEFT(C2,LEN(C2)-8),MID(C2,LEN(C2)-6,2)))
If I apply this formula to 12-12-2022 it gives me 12-Dec-2022 but as soon as the day value changes to 13 i.e, 13-12-2022 it gives 12-Jan-2023.
Can you please help me?
Hi Team,
Can someone please respond here?
By reading the comments I am sure you can help. I exported a report from a tool, the report has a date column but the column has two different date formats, one format interprets the date correctly, but the other format interprets the day as the month, so even all data is from January from example, when I filter the date what should be Jan 1- Jan 12 shows as Jan 1st, Feb 1st, march 1st and so on, how can I correct that, Thank you in advance.
Hi!
Your tool receives data from two different sources in different formats. Set up the instrument so that there is one format. Or set the date format in Excel manually.
I found a solution.
Hi i have an issue, i got sent a table that has Date column as 18-Oct, 18-Nov, 18-Dec, 19-Jan, 19-Feb, 19-March but excel reads it as 10/18/2023 but the column is actually suppose to read October 2018 ... Jan 2019, so this is affecting my work, and have tried what i know, the result i get is NAME ERROR
I have the below text structure downloaded from a dataset that I need to convert into a date format that SPSS or Jamovi can use. I do not need the day of the week, just a numeric MM/DD/YYYY. I've tried converting by formatting the cells as dates, using the flash fill tool, and using =DATEVALUE, but none worked (no change at all). I will ultimately have thousands of entries; so, manual conversion is not feasible! Any ideas on how I can convert? The original date selection was made using a calendar tool where one selects a specific date and the text date is produced in the .csv download, if that's helpful.
Mon Dec 27 2021
Thank you!
Hello!
Use substring functions to extract the desired parts of the text for the DATE function. We have a more universal and simple solution that will solve the problem in a couple of clicks. I recommend paying attention to the Text to Date tool. It is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and check how it works for free.
=DATE(RIGHT(D1,4), MONTH(1&MID(D1,5,3)), MID(D1,9,2))
Thanks so much! I'll give these recommendations a try.
Hey there! I am trying to show a range of dates - "Number of Days" - that calls back to two other dates outside the print area. But the two dates keep showing up as text.
I am using the following super basic formula. =C9&" ("&C11&" - "&C10&")"
C11 and C10 are my two dates that show up as text. I want them to show up s mm/dd/yyyy. Can you help a newb out?
Hello!
You can convert the date to text in the format you need using the TEXT function. See examples at the link above. I hope it’ll be helpful.
Hi, I've got
"Tue Nov 29 2022 15:50:53 GMT-0600 (Central Standard Time)" and would like it formatted into: "MM YYYY"
Any ideas are greatly appreciated! Thank you!
Hi,
You can get the result as a text or as a date. Apply the date format of your choice to the date.
=MONTH("1"&MID(A1,5,3))&" "&MID(A1,12,4)
=DATE(MID(A1,12,4),MONTH("1"&MID(A1,5,3)),1)
We have a tool that can solve your task in a couple of clicks - Text to Date tool. It is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and check how it works for free.
Hi, hope you can help
I have the following "Apr 3, 2021 3:54am" and want to convert it to UK Date format using a formula - 03/04/21
I know I can use the text to columns function but there are multiple columns like this so would be helpful if there was a formula, I tried looking above at the other solutions but could not see one like mine
Thanks in advance
Hello!
To convert your text to a date, use this formula.
=DATE(MID(A1,FIND("~",SUBSTITUTE(A1," ","~",2),1)+1,4), VLOOKUP(LEFT(A1,3), {"JAN",1;"FEB",2;"MAR",3;"APR",4;"May",5;"JUN",6;"JUL",7;"AUG",8;"Sep",9;"OCT",10;"NOV",11;"DEC",12},2,0), MID(A1,FIND(" ",A1,1)+1,SEARCH(",",A1,1)-5))
In one click, the text is converted to a date using the Text to Date tool. It is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and check how it works for free.
Here's a "neat" method to convert an 8-digit number into a valid dd/mm/yyyy date:
(Don't forget to format the result as "short date" 😎 )
if cell A1 contains: 20220512
then this formula: =TEXT(A1,"0000\/00\/00")+0
will yield the date: 12/05/2022
This is, of course, much simpler method than your solution, explained above:
=DATE(RIGHT(A1,4), MID(A1,3,2), LEFT(A1,2))
Enjoy
I'm doing a complicated append formula and when I pull the cell that has the date information it translates it into the Date Value. Is there a way inside of the append formula to have it display the date from the date value? For example, Y2 holds the date displayed as 4/1/2022
My append formula (I'm keeping it simple as there are about 10 other appends in the cell I'm merging everything into) is ="Paid Thru Date: "&Y2&"... "
This formula is displaying: Paid Thru Date: 44652...
I would like it to display: Paid Thru Date: 4/1/2022...
I can't quite figure out how to get it to convert that 44652 back to the 4/1/2022 inside of the appended formula
Hello!
To display the date as text, use the TEXT function when concatenating values.
Please check the formula below, it should work for you:
="Paid Thru Date: "&TEXT(Y2,"m/d/yyyy")
Awesome - Thank you so much!