INDEX & MATCH in Excel - better alternative to VLOOKUP

This tutorial shows how to use INDEX and MATCH in Excel and how it is better than VLOOKUP.

In a couple of recent articles, we made a good effort to explain the basics of VLOOKUP function to beginners and provide more complex VLOOKUP formula examples to power users. And now, I will try if not to talk you out of using VLOOKUP, then at least show you an alternative way to do a vertical lookup in Excel.

"What do I need that for?" you may wonder. Because VLOOKUP has numerous limitations that can prevent you from getting the desired result in many situations. On the other hand, the INDEX MATCH combination is more flexible and has many awesome features that make it superior to VLOOKUP in many respects.
Excel VLOOKUP or INDEX / MATCH - which is better?

Excel INDEX and MATCH functions - the basics

Since the aim of this tutorial is to demonstrate an alternative way to do a vlookup in Excel by using a combination of INDEX and MATCH functions, we won't dwell much on their syntax and uses. We will cover only the minimum necessary for understanding the general idea and then take an in-depth look at formula examples that reveal all the advantages of using INDEX MATCH instead of VLOOKUP.

INDEX function - syntax and usage

The Excel INDEX function returns a value in an array based on the row and column numbers you specify. The syntax of the INDEX function is straightforward:

INDEX(array, row_num, [column_num])

Here is a very simple explanation of each parameter:

  • array - a range of cells that you want to return a value from.
  • row_num - the row number in array from which you want to return a value. If omitted, the column_num is required.
  • column_num - the column number in array from which you want to return a value. If omitted, row_num is required.

For more information, please see Excel INDEX function.

And here is an example of the INDEX formula in its simplest form:

=INDEX(A1:C10,2,3)

The formula searches in cells A1 through C10 and returns a value of the cell in the 2nd row and the 3rd column, i.e. cell C2.

Very easy, right? However, when working with real data you would hardly ever know which row and column you want, that's where the MATCH function comes in handy.

MATCH function - syntax and usage

The Excel MATCH function searches for a lookup value in a range of cells and returns the relative position of that value in the range.

The syntax of the MATCH function is as follows:

MATCH(lookup_value, lookup_array, [match_type])
  • lookup_value - the number or text value you are looking for.
  • lookup_array - a range of cells being searched.
  • match_type - specifies whether to return an exact match or the nearest match:
    • 1 or omitted (default) - approximate match (next smaller).
    • 0 - exact match. In the INDEX / MATCH combination, you almost always need an exact match, so you set the third argument of your MATCH function to 0.
    • -1 - approximate match (next larger).

For example, if the range B1:B3 contains the values "New-York", "Paris", "London", the below formula returns the number 3, because "London" is the third entry in the range:

=MATCH("London",B1:B3,0)

For more information, please see Excel MATCH function.

At first sight, the usefulness of the MATCH function may seem questionable. Who cares about the position of a value in a range? What we do want to know is the value itself.

Let me remind you that the relative position of the lookup value (i.e. row and column numbers) is exactly what you need to supply to the row_num and column_num arguments of the INDEX function. As you remember, Excel INDEX can find the value at the juncture of a given row and column, but it cannot determine which exactly row and column you want.

How to use INDEX MATCH function in Excel

Now that you know the basics, I believe it has already started making sense how MATCH and INDEX work together. In a nutshell, INDEX finds the lookup value by column and row numbers, and MATCH provides those numbers. That's it!

For vertical lookup, you use the MATCH function only to determine the row number and supply the column range directly to INDEX:

INDEX(column to return a value from, MATCH(lookup value, column to look up against, 0))

Still having difficulties to figure that out? It might be easier to understand from an example. Suppose you have a list of national capitals and their population:
Source data for INDEX MATCH formula

To find the population of a certain capital, say the capital of Japan, use the following INDEX MATCH formula:

=INDEX(C2:C10, MATCH("Japan", A2:A10, 0))

Now, let's analyze what each component of this formula actually does:

  • The MATCH function searches for the lookup value "Japan" in the range A2:A10, and returns the number 3, because "Japan" is third in the lookup array.
  • The row number goes directly to the row_num argument of INDEX instructing it to return a value from that row.

So, the above formula turns into a simple INDEX(C2:C,3) that says to search in cells C2 through C10 and pull the value from the 3rd cell in that range, i.e. C4 because we start counting from the second row.

Don't want to hardcode the city in the formula? Input it in some cell, say F1, supply the cell reference to MATCH, and you will get a dynamic lookup formula:

=INDEX(C2:C10, MATCH(F1,A2:A10,0))
Excel INDEX MATCH formula

Important note! The number of rows in the array argument of INDEX should match the number of rows in the lookup_array argument of MATCH, otherwise the formula will produce an incorrect result.

Wait, wait… why don't we simply use the following Vlookup formula? What's the point in wasting time trying to figure out the arcane twists of Excel MATCH INDEX?

=VLOOKUP(F1, A2:C10, 3, FALSE)

In this case, no point at all :) This simple example is for demonstration purposes only, so that you get a feel of how the INDEX and MATCH functions work together. Other examples that follow below will show you the real power of this combination that easily copes with many complex scenarios when VLOOKUP stumbles.

Tips:

INDEX MATCH vs. VLOOKUP

When deciding which function to use for vertical lookups, most Excel gurus agree that INDEX MATCH is far better than VLOOKUP. However, many people still stay with VLOOKUP, firstly, because it's simpler and, secondly, because they do not fully understand all benefits of using the INDEX MATCH formula in Excel. Without such understanding no one is willing to invest their time to learn a more complex syntax.

Below, I will point out the key advantages of MATCH INDEX over VLOOKUP, and you decide whether it's a worthy addition to your Excel arsenal.

4 main reasons to use INDEX MATCH instead of VLOOKUP

  1. Right to left lookup. As any educated user knows, VLOOKUP cannot look to its left, meaning your lookup value should always reside in the leftmost column of the table. INDEX MATCH can do left lookup with ease! The following example shows it in action: How to Vlookup a value to the left in Excel.
  2. Insert or delete columns safely. VLOOKUP formulas get broken or delivers incorrect results when a new column is deleted from or added to a lookup table because VLOOKUP's syntax requires specifying the index number of the column you want to pull the data from. Naturally, when you add or delete columns, the index number changes.

    With INDEX MATCH, you specify the return column range, not an index number. As the result, you are free to insert and remove as many columns as you want without worrying about updating every associated formula.

  3. No limit for a lookup value's size. When using the VLOOKUP function, the total length of your lookup criteria cannot exceed 255 characters, otherwise you will end up having the #VALUE! error. So, if your dataset contains long strings, INDEX MATCH is the only working solution.
  4. Higher processing speed. If your tables are relatively small, there will hardly be any significant difference in Excel performance. But if your worksheets contain hundreds or thousands of rows, and consequently hundreds or thousands of formulas, MATCH INDEX will work much faster than VLOOKUP because Excel will have to process only the lookup and return columns rather than the entire table array.

    VLOOKUP's impact on Excel's performance may be especially noticeable if your workbook contains complex array formulas like VLOOKUP and SUM. The point is that checking each value in the array requires a separate call of the VLOOKUP function. So, the more values your array contains and the more array formulas you have in a workbook, the slower Excel performs.

To discover the nuanced differences between INDEX MATCH and XLOOKUP, explore the in-depth analysis in this guide: Excel XLOOKUP vs INDEX MATCH.

Excel INDEX MATCH - formula examples

Knowing the reasons to learn the MATCH INDEX function, let's get to the most interesting part and see how you can apply the theoretical knowledge in practice.

INDEX MATCH formula to look up from right to left

As already mentioned, VLOOKUP cannot look at its left. So, unless your lookup values are is the leftmost column, there's no chance that a Vlookup formula will bring you the result you want. The INDEX MATCH function in Excel is more versatile and does not really care where the lookup and return columns are located.

For this example, we will add the Rank column to the left of our sample table and try to figure out how the Russian capital, Moscow, ranks in terms of population.

With the lookup value in G1, use the following formula to search in C2:C10 and return a corresponding value from A2:A10:

=INDEX(A2:A10,MATCH(G1,C2:C10,0))
Look up values to left using INDEX MATCH

Tip. If you plan to use your INDEX MATCH formula for more than one cell, be sure to lock both ranges with absolute cell references (like $A$2:$A$10 and $C$2:4C$10) so they won't get distorted when copying the formula.

INDEX MATCH MATCH to search in rows and columns

In the above examples, we used INDEX MATCH as the replacement for classic VLOOKUP to return a value from a predefined one-column range. But what if you need to look up in multiple rows and columns? In other words, what if you want to perform the so-called matrix or two-way lookup?

This may sound tricky, but the formula is very similar to the basic Excel INDEX MATCH function, with just one difference. Guess what?

Simply, use two MATCH functions – one to get a row number and the other to get a column number. And I congratulate those of you who have guessed right :)

INDEX(array, MATCH(vlookup value, column to look up against, 0), MATCH(hlookup value, row to look up against, 0))

And now, please take a look at the below table and let's build an INDEX MATCH MATCH formula to find the population (in millions) in a given country for a given year.

With the target country in G1 (vlookup value) and the target year in G2 (hlookup value), the formula takes this shape:

=INDEX(B2:D11, MATCH(G1,A2:A11,0), MATCH(G2,B1:D1,0))
INDEX MATCH MATCH formula for two-way lookup in Excel

How this formula works

Whenever you need to understand a complex Excel formula, break it down into smaller parts and see what each individual function does:

MATCH(G1,A2:A11,0) – searches through A2:A11 for the value in cell G1 ("China") and returns its position, which is 2.

MATCH(G2,B1:D1,0)) – searches through B1:D1 to get the position of the value in cell G2 ("2015"), which is 3.

The above row and column numbers go to the corresponding arguments of the INDEX function:

INDEX(B2:D11, 2, 3)

As the result, you get a value at the intersection of the 2nd row and 3rd column in the range B2:D11, which is the value in cell D3. Easy? Yep!

Excel INDEX MATCH to look up multiple criteria

If you had a chance to read our Excel VLOOKUP tutorial, you have probably already tested a formula to Vlookup with multiple criteria. However, a significant limitation of that approach is the necessity to add a helper column. The good news is that Excel's INDEX MATCH function can look up with two or more criteria too, without modifying or restructuring your source data!

Here's the generic INDEX MATCH formula with multiple criteria:

{=INDEX(return_range, MATCH(1, (criteria1=range1) * (criteria2=range2), 0))}

Note. This is an array formula that must be completed with the Ctrl + Shift + Enter shortcut.

In the sample table below, supposing you want to find the amount based on 2 criteria, Customer and Product.

The following INDEX MATCH formula works a treat:

=INDEX(C2:C10, MATCH(1, (F1=A2:A10) * (F2=B2:B10), 0))

Where C2:C10 is the range to return a value from, F1 is criteria1, A2:A10 is the range to compare against criteria1, F2 is criteria 2, and B2:B10 is the range to compare against criteria2.

Remember to enter the formula correctly by pressing Ctrl + Shift + Enter, and Excel will automatically enclose it curly brackets as shown in the screenshot:
The INDEX MATCH formula to look up multiple criteria

If you'd rather not use array formulas in your worksheets, add one more INDEX function to the formula and complete it with a usual Enter hit:
A non-array INDEX MATCH formula with multiple criteria

How these formulas work

The formulas use the same approach as the basic INDEX MATCH function that looks through a single column. To evaluate multiple criteria, you create two or more arrays of TRUE and FALSE values that represent matches and non-matches for each individual criterion, and then multiply the corresponding elements of these arrays. The multiplication operation converts TRUE and FALSE into 1 and 0, respectively, and produces an array where 1's correspond to rows that match all the criteria. The MATCH function with a lookup value of 1 finds the first "1" in the array and passes its position to INDEX, which returns a value in this row from the specified column.

The non-array formula relies on the ability of the INDEX function to handle arrays natively. The second INDEX is configured with 0 row_num so that it will pass the entire column array to MATCH.

That is a high-level explanation of the formula's logic. For full details, please see Excel INDEX MATCH with multiple criteria.

Excel INDEX MATCH with AVERAGE, MAX, MIN

Microsoft Excel has special functions to find a minimum, maximum and average value in a range. But what if you need to get a value from another cell that is associated with those values? In this case, use the MAX, MIN or AVERAGE function together with INDEX MATCH.

INDEX MATCH with MAX

To find the largest value in column D and return a value from column C in the same row, use this formula:

=INDEX(C2:C10, MATCH(MAX(D2:D10), D2:D10, 0))

INDEX MATCH with MIN

To locate the smallest value in column D and pull an associated value from column C, use this one:

=INDEX(C2:C10, MATCH(MIN(D2:D10), D2:D10, 0))

INDEX MATCH with AVERAGE

To work out the value closest to the average in D2:D10 and get a corresponding value from column C, this is the formula to use:

=INDEX(C2:C10, MATCH(AVERAGE(D2:D10), D2:D10, -1 ))

Depending on how your data is organized, supply either 1 or -1 to the third argument (match_type) of the MATCH function:

  • If your lookup column (column D in our case) is sorted ascending, put 1. The formula will calculate the largest value that is less than or equal to the average value.
  • If your lookup column is sorted descending, enter -1. The formula will compute the smallest value that is greater than or equal to the average value.
  • If your lookup array contains a value exactly equal to the average, you can enter 0 for exact match. No sorting is required.

In our example, the populations in column D are sorted in descending order, so we use -1 for match type. As the result, we get "Tokyo" since its population (13,189,000) is the closest match that is greater than average (12,269,006).
Using INDEX MATCH with AVERAGE, MAX, MIN

You may be curious to know that VLOOKUP can perform such calculations too, but as an array formula: VLOOKUP with AVERAGE, MAX, MIN.

Using INDEX MATCH with IFNA / IFERROR

As you have probably noticed, if an INDEX MATCH formula in Excel cannot find a lookup value, it produces an #N/A error. If you wish to replace the standard error notation with something more meaningful, wrap your INDEX MATCH formula in the IFNA function. For example:

=IFNA(INDEX(C2:C10, MATCH(F1,A2:A10,0)), "No match is found")

And now, if someone inputs a lookup table that does not exist in the lookup range, the formula will explicitly inform the user that no match is found:
Using INDEX / MATCH with IFNA function to trap N/A errors

If you'd like to catch all errors, not only #N/A, use the IFERROR function instead of IFNA:

=IFERROR(INDEX(C2:C10, MATCH(F1,A2:A10,0)), "Oops, something went wrong!")

Please keep in mind that in many situations it might be unwise to disguise all errors because they alert you about possible faults in your formula.

That's how to use INDEX and MATCH in Excel. I hope our formula examples will prove helpful for you and look forward to seeing you on our blog next week!

Practice workbook for download

Excel INDEX MATCH examples (.xlsx file)

Table of contents

614 comments

  1. Hi,
    Hi, I'm trying to create a formula that allows me to search a column for a product number which exactly matches the product number (in a column) in another workbook. The first workbook has a product cost associated with it, in a separate column. The second workbook has a price associated also (which is a price change in a separate column).
    I would like to populate a new column in Workbook 1 with the new price. (price increase)
    Workbook 1 has hundreds of items and cost prices.
    Workbook 2 (only select items from original list in Workbook 1) Price Increases
    The item numbers are not on the same line in the two workbooks.
    I need to match the item numbers from the two workbooks and bring the price increase associated with the product item number (from Workbook 2) into the original workbook. (Workbook 1)

  2. Hi - I tried to use INDEX and MATCH together and have been getting a #VALUE! error. I tried to break it down, and created a cell with just the MATCH part in it. But no luck.

    So I put the cells with identical (perfectly identical) long strings of text in them. I know they are identical because I pasted from one cell to the other. Next to these cells I created a cell with a simple IF condition to return YES if the cells with the text are equal. Indeed, it returned "YES" So I then created a MATCH formua in the next cell which reads something like: =MATCH(K850,J800:J900,0). The identical cells are in J850 and K850 respectively. Yet - no luck at all.

    The text btw is "Care Instructions: Lid Cork, Use only for its intended purposes. Immediately wash and dry well after use, and keep dry when not in use. Do not overheat in the microwave or heat without water. Wash with care. Don't use abrasive cleansers or steel wool. Don't place near fire. Sudden temperature changes may break or shatter the product. While the glass is hot, don't pour cold liquids into it and don't place it to on a wet cloth or in a wet sink. Be aware that the lid may become stained with the odor or color of some foodstuffs.". Nothing personal or confidential so I decided to paste it here.

    What am I doing wrong?

    • Hello!
      Unfortunately, without seeing your data it is difficult to give you any advice. Could you please describe your task in more detail and send us a small sample workbook with the source data and expected result to support@ablebits.com? Please shorten your tables to 10-20 rows/columns and include the link to your blog comment.

      We'll look into your task and try to help.

  3. When I put in this formula I get the N/A
    result, =INDEX(MIN(IF(F2:F77>0,F2:F77)),MATCH(1,INDEX((L22=A2:A77)*(M22=B2:B77),0,1),0))
    Column F is the result of another formula, What should I change to make this formula work.

    • Hello!
      INDEX MATCH formula in Excel cannot find a lookup value. This N/A error is explained in this article above. Unfortunately, without seeing your data it is difficult to give you any advice.

  4. Thank you for this, I have used it so often and it has saved me SO MUCH time. Just one thought, there has been a change in how Excel handles the function and you now need to add "@" before "lookup value" to prevent a SPILL error. Perhaps you can update the formula?

  5. Hello excel Guru's, I am hoping someone may be able to asst me with creating a formular for the below? It's beyond my basic excel capabilities.

    Column A contains task numbers (i.e SMT001) and column P contains a task duration in seconds(i.e 11040). I need a formula that can search column A for duplicate task numbers and add the corresponding task durations in column P to give me a total task duration. is this even possible in excel?

    Any guidance would be appreciated.

  6. Hi, i'm trying to create a formula that allows me to search a column for a reference number which exactly matches the reference number on another worksheet within the same workbook. I need it to return a Yes or No.
    On worksheet 2 In cell H3, I would like it to return a Yes if the ref number in Cell E3 matches any of the ref numbers on Worksheet 1 Column E Range E2:E500.

    • Hello Lisa!
      If I understand your task correctly, the following formula should work for you:

      =IF(ISNUMBER(MATCH(E3,Sheet1!E2:E500,0)),"Yes","No")

      I hope my advice will help you solve your task.

  7. Thank you so much Alexander! I really appreciate your help.
    When I tried your formula, the cell defaults to Y, even if B16:B46 are blank. But as soon as an N is put in any of the cells, the cell will turn to N. So anything but an N will keep the cell as Y. I was trying to have it such that even a blank cell in B16:B46 would result in the cell having an N. This will work for now, though. Thank you again! I very much appreciate it!

  8. How do I write the following formula:
    If B16:B46 are all Y, then this cell should be Y. If any of the cells between B16:B46 are N, then this cell should be N.
    Also, how do I write this formula with two factors:
    If B16:B46 AND C16:C46 are all Y, then this cell will be Y. If any of those cells have an N, then this cell should be N.

    • Hello Mohammed!
      If I understand your task correctly, the following formula should work for you:

      =IF(ISNUMBER(MATCH("N",B16:B46,0)),"N",IF(IFERROR(MATCH(1,IF(B16:B46="Y",0,1),0),"Y")="Y","Y",""))

      I hope this will help

  9. I have a result set as below:
    COL A COL B
    1111987 1224
    1119361 1072
    1119361 1223
    1119361 1224
    1123961 1223
    1123961 1224
    1124136 1072
    1124136 1223

    Since No# - 1124136, isn't having a combo of 1224, I wish to have that as a result.
    Please assist.

    • Hello!
      If I understand your task correctly, the following formula should work for you:

      =INDEX(A1:A8,MATCH(0,COUNTIFS(A1:A8,"="&A1:A8,B1:B8,"=1224"),0))

      I hope this will help

  10. I have name of students in column B and grade scored in column BT in sheet 1. I want to pull the name of students who scored A to sheet 2, B to sheet 3, C to sheet 4 etc

  11. I am looking to match based on two unique numbers that have the same result. The lookup tables or array results are in a different
    Example.

    Column A = US product ID #
    Column B = CA product ID #
    Column C = the product name of both Column A and Column B of that Same row, so can have either a corresponding US or CA Product ID

    Example: US1234 or CA123 = pencils

    For the entry, they will only enter in product ID number below, and I want to dynamically return the product name without knowing if it will be a US ID or a CA iD
    Product ID Product Name

    Thanks

    • Hello Joseph!
      If I understand your task correctly, the following formula should work for you:

      =IFERROR(INDEX(C1:C5,MAX(IFERROR(MATCH("*"&$E$1&"*",A1:A5,0),-1), IFERROR(MATCH("*"&$E$1&"*",B1:B5,0),-1))),"ERROR")

      where E1 -- Product ID

      I hope this will help, otherwise please do not hesitate to contact me anytime.

  12. Hi all,Good day
    I need some help.
    I have a list of 5000 items.
    For each item, many Purchase orders have been raised.
    how to extract item wise Purchase order numbers. Tried VLOOKUP and pivot , not able to get.

    • Hello ANAND!
      I’m sorry but your task is not entirely clear to me.
      What is " item wise Purchase order numbers"? What exactly do you want to count? How many purchase orders were there? Amount?
      For me to be able to help you better, please describe your task in more detail. It’ll help me understand it better and find a solution for you. Thank you.

  13. I am using the formula to copy values from one sheet to other, from a table with 8 columns. The value has to come from the 8th column. The formula is working fine. Kindly inform if any variable can be put instead of writing 8.
    Thanks.
    Sheets("EXE_1").Select
    Range("O4").Select
    ActiveCell.FormulaR1C1 = _
    "=IFERROR((INDEX(MIN_WIP!R4C17:R20C25, MATCH(EXE_1!RC[-13],MIN_WIP!R4C17:R20C17,0),8)),""0"")"

    • Hello Manas!
      It is possible to insert an expression, which will return a number, instead of "8" in your formula. However, to give you a full and accurate answer, additional information on the result you would like to get is required. Moreover, I would like to see your formula in standard view, not R1C1.

  14. Hello,
    I have a table of values where I want to pick a specific unit, look for the last (previous) "on" for that unit, and record/calculate the time in between when the unit was turned on and when it was turned off.

    I.E. - Lights - Jerry turned the lights ON @ 11/1/2019 10:56AM and OFF @ 11:05AM so the DURATION = 00:09:00.

    Person TIME ON/OFF UNIT DURATION
    Dan 11/1/2019 10:00AM OFF Lamp
    Jerry 11/1/2019 10:56AM ON Lights
    Tom 11/1/2019 10:59AM ON Door
    Dan 11/1/2019 11:02AM ON Car
    Dan 11/1/2019 11:03AM OFF Car 00:01:00
    Jerry 11/1/2019 11:05AM OFF Lights 00:09:00

    How do I get the DURATION cell in the "Lights" "OFF" line to populate based off the TIME from the last "Lights" "ON" line?

    Thank you!

  15. Hi,
    I try to lookup formula match with any of two different range. It means first look with A4 suppose if details not available means get the data with B4 cell.

  16. It seems a Windows update has now broken this formula and it produces a #SPILL error message. Can you produce a workaround for this?

    • Hi Graham,

      I've retested the formulas in our sample worksheet. All seem to be working normally. Can you please specify exactly which one returns an error?

  17. NEW STOCK
    TOTAL
    32

    OLD STOCK
    TOTAL
    45

    OLD 0-100 DAYS
    40
    OLD 100+ DAYS
    5
    NEW 0-100 DAYS
    RESULT REQUIRED
    32
    NEW 100+ DAYS
    0

  18. Hi, if there a “name “in a2,a6,a7,a16 etc how can I fetch data of b2,b6,b7 and so on? I tried using index but it ends up with showing result of b2 only

  19. Hi Team,
    I am trying to use index match in the following situation, could you please assist with this? :
    tab1 : current month data - FTE details containing staff number, name, FTE,Position,auto pay-Y/N
    Tab2 : previous month data - FTE details containing staff number, name, FTE,Position,auto pay-Y/N
    I want to see all the leavers so I am using the following formula, please let me know how to correct this :
    =if(index(current month staff id,match(1,(current month auto pay=Y)*(current month=Jul19)*(previous month staff id=current month),0))=previous month staff id," ","Leaver")

  20. Hi! How can I add more criteria to the INDEX MATCH formula when looking up at let's say 5 parameters to get more than one return, i.e. looking up suppliers criteria to return supplier names? I've managed to utilize INDEX MATCH but if there is more than one supplier matching the criteria, the formula only returns the first supplier name.
    THanks!

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)