How to use SUMIF in Excel with multiple OR conditions

Do you know how to sum numbers in a certain column when a value in another column meets any of the specified conditions? In this article, you will learn 3 different ways to do SUMIF using multiple criteria and OR logic.

Microsoft Excel has a special function to sum cells with multiple conditions - the SUMIFS function. This function is designed to work with AND logic - a cell is added only when all of the specified criteria are TRUE for that cell. In some situations, however, you may need to sum with multiple OR criteria, i.e. to add a cell when any of the conditions is TRUE. And this is when the SUMIF function comes in handy.

SUMIF + SUMIF to sum cells equal to this or that

When you are looking to sum numbers in one column when another column is equal to either A or B, the most obvious solution is to handle each condition individually, and then add the results together:

SUMIF(range, criteria1, sum_range) + SUMIF(range, criteria2, sum_range)

In the table below, suppose you want to add up sales for two different products, say Apples and Lemons. For this, you can supply the items of interest directly in the criteria arguments of 2 different SUMIF functions:

=SUMIF(A2:A10, "apples", B2:B10) + SUMIF(A2:A10, "lemons", B2:B10)

Or you can enter the criteria in separate cells, and refer to those cells:

=SUMIF(A2:A10, E1, B2:B10) + SUMIF(A2:A10, E2, B2:B10)

Where A2:A10 is the list of items (range), B2:B10 are the numbers to sum (sum_rage), E1 and E2 are the target items (criteria):
Excel SUMIF formula with multiple criteria

How this formula works:

The first SUMIF function adds up the Apples sales, the second SUMIF sums the Lemons sales. The addition operation adds the sub-totals together and outputs the total.

SUMIF with array constant - compact formula with multiple criteria

The SUMIF + SUMIF approach works fine for 2 conditions. If you need to sum with 3 or more criteria, the formula will become too big and difficult to read. To achieve the same result with a more compact formula, supply your criteria in an array constant:

SUM(SUMIF(range, {crireria1, crireria2, crireria3, …}, sum_range))

Please remember that this formula works based on OR logic - a cell is summed when any single condition is met.

In our case, to sum sales for 3 different items, the formula is:

=SUM(SUMIF(A2:A10, {"Apples","Lemons","Oranges"}, B2:B10))
SUMIF formula with array constant to sum cells with multiple OR criteria

In the above screenshot, the conditions are hardcoded in an array, meaning you will have to update the formula with every change in the criteria. To avoid this, you can input the criteria in predefined cells and supply to a formula as a range reference (E1:E3 in this example).

=SUM(SUMIF(A2:A10, E1:E3, B2:B10))

In Excel 365 that supports dynamic arrays, it works as a regular formula completed with the Enter key. In pre-dynamic versions of Excel 2019, Excel 2016, Excel 2013 and earlier, it should be entered as an array formula with the Ctrl + Shift + Enter shortcut:
SUM and SUMIF formula with multiple criteria in different cells

How this formula works:

An array constant plugged into SUMIF's criteria forces it to return multiple results in the form of an array. In our case, it's 3 different amounts: for Apples, Lemons and Oranges:

{425;425;565}

To get the total, we use the SUM function and wrap it around the SUMIF formula.

SUMPRODUCT and SUMIF to sum cells with multiple OR conditions

Don't like arrays and are looking for a normal formula that would allow you to sum with multiple criteria in different cells? No problem. Instead of SUM, use the SUMPRODUCT function that handles arrays natively:

SUMPRODUCT(SUMIF(range, crireria_range, sum_range))

Assuming the conditions are in cells E1, E2 and E3, the formula takes this shape:

=SUMPRODUCT(SUMIF(A2:A10, E1:E3, B2:B10))
SUMPRODUCT and SUMIF to sum cells with multiple OR conditions

How this formula works:

Like in the previous example, the SUMIF function returns an array of numbers, representing the sums for each individual condition. SUMPRODUCT adds these numbers together and outputs a final total. Unlike the SUM function, SUMPRODUCT is designed to process arrays, so it works as a regular formula without you having to press Ctrl + Shift + Enter.

SUMIF using multiple criteria with wildcards

Since the Excel SUMIF function supports wildcards, you can include them in multiple criteria if needed.

For example, to sum sales for all sorts of Apples and Bananas, the formula is:

=SUM(SUMIF(A2:A10, {"*Apples","*Bananas"}, B2:B10))

If your conditions are supposed to be input in individual cells, you can type wildcards directly in those cells and provide a range reference as criteria for the SUMPRODUCT SUMIF formula:
SUMIF using multiple criteria with wildcards

In this example, we put a wildcard character (*) before the item names to match any preceding sequence of characters such as Green apples and Goldfinger bananas. To get a total for items that contain specific text anywhere in a cell, place an asterisk on both sides, e.g. "*apple*".

That's how to use SUMIF in Excel with multiple conditions. I thank you for reading and hope to see you on our blog next week!

Practice workbook for download

SUMIF multiple criteria (.xlsx file)

Table of contents

70 comments

  1. Company 1 Company 1 Company 2 Company 2
    Jan Feb Jan Feb

    Green 1 4 9 12
    Blue 2 5 7 9
    Orange 3 8 4 4

    How do I sum up (not vlook up) Company 1 in Feb for Green please? I tried sumifs, index match but doesnt work think it doesnt like two criteria on the horizontal perhaps?

  2. Hi there, dont think I have fully understand the array, or the "OR" listing
    Data (column A B C)
    f h 1
    f y 1
    f h 1
    g y 1
    g h 1

    Result and Formula used
    2 =SUM(SUMIFS(C1:C5,A1:A5,{"f","g"},B1:B5,{"y","h"}))
    5 =SUM(SUMIFS(C1:C5,A1:A5,{"f";"g"},B1:B5,{"y","h"}))
    2 =SUM(SUMIFS(C1:C5,A1:A5,{"f";"g"},B1:B5,{"y";"h"}))
    5 =SUM(SUMIFS(C1:C5,A1:A5,{"f","g"},B1:B5,{"y";"h"}))

    Difference is essentially only ; or , used. Anywhere I could understand this better?
    Appreciate the advice.

  3. Not getting the result I need with the following equation. Any ideas on how this could work? I am not familiar with arrays, so if that is the solution please provide detail instructions.

    =Sum(If(AND(
    HX!DU:DU="18",
    HX!Q:Q="0735",'HX'!BB:BB,0))

    +If(OR(
    HX!K:K="225",
    HX!K:K="390",
    HX!K:K="407",
    HX!K:K="408",
    HX!K:K="467",
    HX!K:K="468",'HX'!BB:BB,0))

    +If(Or(
    HX!P:P="05862",
    HX!P:P="13001",
    HX!P:P="13002",
    HX!P:P="90327",
    HX!P:P="91142",
    HX!P:P="99327",
    HX!P:P=" ",'HX'!BB:BB,0)))

  4. How would i go about Simplifying =((E7*$B7)+(E8*$B8)+(E9*$B9)+(E10*$B10)+(E11*$B11)+(E12*$B12)+(E18*$B18)+(E19*$B19)+(E21*$B21)+(E23*$B23)+(E24*$B24)+(E25*$B25)+(E26*$B26)+(E27*$B27)+(E28*$B28)+(E29*$B29)+(E30*$B30)+(E31*$B31)+(E32*$B32)+(E33*$B33)+(E40*$B40)+(E43*$B43)+(E46*$B46)+(E60*$B60)+(E63*$B63)+(E65*$B65)+(E66*$B66)+(E68*$B68)+(E69*$B69)+(E70*$B70)+(E71*$B71)+(E75*$B75)+(E78*$B78)+(E79*$B79)+(E80*$B80)+(E90*$B90)+(E34*$B34)+(E35*$B35)+(E36*$B36)+(E37*$B37)+(E47*$B47)+(E48*$B48)+(E49*$B49)+(E50*$B50)+(E51*$B51)+(E53*$B53)+(E55*$B55)+(E61*$B61)+(E54*$B54)+(E57*$B57)+(E58*$B58))

    I need to break it down into =If(a5="c",B5*E5,0) but need it to do this for the whole of column A and B to total into 1 cell

    • Hi! Based on your description, it is hard to completely understand your task. However, I’ll try to guess and offer you:

      (E7*$B7)*(A7="c")+(E8*$B8)*(A8="c")+... etc.

  5. Hi,
    Thanks for all the info/help... just wondering if you can tell me which function to use in this case: I want to add amounts in column A if either column B, C, D, E contain "x". "X" is a destination from a table in column AA (AA1:AA10). What would be the most efficient way to do this?
    Thanks!

  6. I would like to sum under both an and AND an or condition. Is this possible?
    For example If the text in column A is either x OR y, AND the text in column B is z, then Sum column C.

  7. Thanks

  8. Hi,
    Sum with Sumifs isn't working when there are two criteria in two or more criteria range

  9. Hi Alexander

    I have two formulas that I'd like your assistance with please:

    1. What formula should I use to allow the sum of multiple text options (potential, yes and no) in column AE. I tried the below but it doesn't work.

    =SUMIFS('WCC Sites'!Z3:Z84, 'Sites'!AE3:AE84, {"Potential", "Yes", "No"}, 'Sites'!H3:H84, "=23/24")

    2. How can I shorten the below? There's two worksheets (Sites & Stone), each with three options (potential, yes and no) that I would like the sum of the price for (Q2:Q86).

    =SUMIF('WCC Sites'!AE2:AE85, "Potential", 'Sites'!Z2:Z85) + SUMIF('Sites'!AE2:AE85, "Yes", 'Sites'!Z2:Z85) + SUMIF('Sites'!AE2:AE85, "No", 'Sites'!Z2:Z85) + SUMIF('Stone'!V2:V86, "Potential", 'Stone'!Q2:Q86) + SUMIF('Stone'!V2:V86, "No", 'Stone'!Q2:Q86) + SUMIF('Stone'!V2:V86, "Yes", 'Stone'!Q2:Q86)

    Many thanks

    • Hi! I can't check your formula, but it should return 3 values. Use the SUM function.

      =SUM(SUMIFS('WCC Sites'!Z3:Z84, 'Sites'!AE3:AE84, {"Potential", "Yes", "No"}, 'Sites'!H3:H84, "=23/24"))

      You can use this in the second formula as well. For example:

      SUM(SUMIF('Sites'!AE2:AE85, {"Yes","No"}, 'Sites'!Z2:Z85))

  10. does anybody now how to solve the following problem:
    How to sum-up values considering two column with each multiple critera, e.g. sales revenue per (1) market per (2) segment,
    for (1) want to include US and France, but not UK
    for (2) want to include apples & peaches but no bananas
    Thanks for help

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)