by Is your VLOOKUP pulling wrong data or you cannot get it to work at all? This tutorial shows how you can quickly fix common VLOOKUP errors and overcome its main limitations.
In a few earlier articles, we explored different aspects of the Excel VLOOKUP function. If you have been following us closely, by now you should be an expert in this area :)
However, it's not without reason that many Excel specialists consider VLOOKUP to be one of the most intricate Excel functions. It has a ton of limitations, which are the source of various problems and errors.
In this article, you will find simple explanations of the main causes of VLOOKUP errors such as #N/A, #NAME and #VALUE, as well as their solutions and fixes. We will start with the most obvious reasons why VLOOKUP is not working, so it might be a good idea to check out the below troubleshooting steps in order.
Fixing #N/A error in VLOOKUP
In VLOOKUP formulas, the #N/A error message (meaning "not available") is displayed when Excel cannot find a lookup value. There can be several reasons why that may happen.
1. The lookup value is misspelt
It's always a good idea to check the most obvious thing first : ) Misprints frequently occur when you are working with really large data sets consisting of thousands of rows, or when a lookup value is typed directly in the formula.
2. #N/A in approximate match VLOOKUP
If your formula looks up the closest match, (range_lookup argument set to TRUE or omitted), the #N/A error can appear in two cases:
- The lookup value is smaller than the smallest value in the lookup array.
- The lookup column is not sorted in ascending order.
3. #N/A in exact match VLOOKUP
If you are searching for exact match (range_lookup argument set to FALSE), the #N/A error occurs when a value exactly equal to the lookup value is not found. For more information, see VLOOKUP exact match vs. approximate match.
4. The lookup column is not the leftmost column of the table array
One of the most significant limitations of Excel VLOOKUP is that it cannot look to its left. Consequently, a lookup column should always be the leftmost column in the table array. In practice, we often forget about this and end up with #N/A errors.
Solution: If it is not possible to restructure your data so that the lookup column is the left-most column, you can use the INDEX and MATCH functions together as an alternative to VLOOKUP. Here's a formula example: INDEX MATCH formula to look up values to left.
5. Numbers are formatted as text
Another common source #N/A errors in VLOOKUP formulas is numbers formatted as text, either in the main or lookup table.
This usually occurs when you import data from some external database or if you've typed an apostrophe before a number to show leading zeros.
Here are the most obvious indicators of numbers formatted as text:
Solution: Select all the problematic numbers, click on the error icon and choose Convert to Number from the context menu. For more information, please see How to convert text to number in Excel.
6. Leading or trailing spaces
This is the least obvious cause of the VLOOKUP #N/A error because a human eye can hardly spot those extra spaces, especially when working with big datasets where most of the entries are below the scroll.
Solution 1: Extra spaces in the lookup value
To ensure the correct work of your VLOOKUP formula, wrap the lookup value in the TRIM function:
=VLOOKUP(TRIM(E1), A2:C10, 2, FALSE)
Solution 2: Extra spaces in the lookup column
If extra spaces occur in the lookup column, there is no easy way to avoid #N/A errors in VLOOKUP. Instead, you can use a combination of INDEX, MATCH and TRIM functions as an array formula:
=INDEX(B2:B10, MATCH(TRUE, TRIM(A$2:A$10)=TRIM(E1), 0))
Since this is an array formula, don't forget to press Ctrl + Shift + Enter to properly complete it (in Excel 365 and Excel 2021 where arrays are native, this also works as a regular formula).
Tip. A quick alternative is running the Trim Spaces tool that will eliminate excess spaces both in the lookup and main tables in seconds, making your VLOOKUP formulas error-free.
#VALUE! error in VLOOKUP formulas
In general, Microsoft Excel displays the #VALUE! error if a value used in the formula is of a wrong data type. In respect to VLOOKUP, there are three common sources of the VALUE! error.
1. Lookup value exceeds 255 characters
Please be aware that VLOOKUP cannot look up values containing more than 255 characters. If your lookup values exceed this limit, a #VALUE! error will be displayed:
Solution: Use an INDEX MATCH formula instead. In our case, this formula works perfectly:
=INDEX(B2:B7, MATCH(TRUE, INDEX(A2:A7= E1, 0), 0))
2. Full path to the lookup workbook is not supplied
If you are pulling data from another workbook, you have to include the full path to it. More precisely, you have to enclose the workbook's name including the extension in [square brackets] and specify the sheet's name followed by the exclamation mark. If the workbook name or sheet name, or both, contain spaces or any non-alphabetical characters, the path must be enclosed in single quotation marks.
Here's the structure of the table_array argument to Vlookup from another workbook:
'[workbook name]sheet name'!range
A real formula might look similar to this:
=VLOOKUP($A$2,'[New Prices.xls]Sheet1'!$B:$D, 3, FALSE)
The above formula will search for the value of A2 in column B of Sheet1 in the New Prices workbook, and return a matching value from column D.
If any element of the path is missing, your VLOOKUP formula won't work and return the #VALUE error (unless the lookup workbook is currently open).
For more information, please see:
3. The col_index_num argument is less than 1
It's hard to imagine a situation when someone intentionally enter a number less than 1 to specify the column to return values from. But it may happen if this argument is returned by some other function nested in your VLOOKUP formula.
So, if the col_index_num argument is than 1, your formula will return the #VALUE! error too.
If col_index_num is greater than the number of the columns in the table array, VLOOKUP produces the #REF! error.
Solving VLOOKUP #NAME error
This is the easiest case - the #NAME? error appears if you've accidentally misspelled the function's name.
The solution is obvious - check the spelling :)
The main causes of errors in Excel VLOOKUP
Apart from having a fairly complicated syntax, VLOOKUP has arguably more limitations than any other Excel function. Because of these limitations, a seemingly correct formula may often deliver results different from what you expected. Below you will find solutions for a few typical scenarios when VLOOKUP fails.
VLOOKUP is case-insensitive
The VLOOKUP function does not distinguish the letter case and teats lowercase and uppercase characters as identical.
Solution: Use VLOOKUP, XLOOKUP or INDEX MATCH in combination with the EXACT function that can match text case. You can find the detailed explanations and formula examples in this tutorial: 5 ways to do a case-sensitive Vlookup in Excel.
A new column was inserted or removed from the table
Regrettably, VLOOKUP formulas stop working every time when a new column is deleted from or added to the lookup table. This happens because the syntax of the VLOOKUP function requires defining the index number of the return column. When a new column is added to/removed from the table array, obviously that index number changes.
Solution: The INDEX MATCH formula comes to the rescue again : ) With INDEX MATCH, you specify the lookup and return ranges separately, so you are free to delete or insert as many columns as you want without worrying about updating every associated formula.
Cell references change when copying the formula to other cells
The heading gives an exhaustive explanation of the problem, right?
Solution: Always use absolute references (with the $ sign) for the table_array argument, e.g. $A$2:$C$100 or $A:$C. You can quickly switch between different reference types by pressing the F4 key.
VLOOKUP returns the first found value
As you already know, Excel VLOOKUP returns the first value it finds. However, you can force it to bring the 2nd, 3rd, 4th or any other occurrence you want. There is also a way to get the last match or all found matches.
Solutions: Formula examples are available here:
Why does my VLOOKUP work for some cells but not others?
When your VLOOKUP formula returns the correct data I some cells and #N/A errors in others, there can be a few possible reasons why that happens.
1. The table array is not locked
Suppose you have this formula in row 2 (say in E2), which works nicely:
=VLOOKUP(D2, A2:B10, 2, FALSE)
When copied to row 3, the formula changes to:
=VLOOKUP(D3, A3:B11, 2, FALSE)
Because a relative reference is used for table_array, it changes based on the relative position of the row where the formula is copied, in our case from A2:B10 to A3:B11. So, if the match is in row 2, it won't be found!
Solution: When using a VLOOKUP formula for more than one cell, always lock the table array reference with the $ sign like $A$2:$B$10.
2. Text values or data types do not match
Another common reason for VLOOKUP failure is the difference between your lookup value and a similar value in the lookup column. In some cases, the difference is so subtle that it's hard to spot visually.
Solution: When VLOOKUP is returning an #N/A error while you can clearly see the lookup value in the lookup column, and apparently both are spelt exactly the same, the first thing you need to do is to determine the root cause of the problem - the formula or the source data.
To see whether the two values are the same or different, make a direct comparison in this way:
=E1=A4
Where E1 is your lookup value and A4 is an identical value in the lookup column.
If the formula returns FALSE, that means the values differ in some way, though they look absolutely alike.
In case of numeric values, the most possible reason is numbers formatted as text.
In case of text values, most likely the problem is in excess spaces. To verify this, find out the total length of the two strings using the LEN function:
=LEN(E1)
=LEN(A4)
If the resulting numbers are different (like in the screenshot below), then you've pinpointed the culprit - extra spaces:
To solve the issue, either remove extra spaces or use this INDEX MATCH TRIM formula as a workaround.
Why does my VLOOKUP pull wrong data?
There could be even more reasons why your VLOOKUP returns a wrong value:
- Incorrect search mode. If you want an exact match, be sure to set the range_lookup argument to FALSE. The default is TRUE, so if you omit this argument, VLOOKUP will assume you are looking for an approximate match and search for the closest value that is smaller than the lookup value.
- The lookup column is not sorted. For approximate match VLOOKUP (range_lookup set to TRUE) to work correctly, the first column in the table array must be sorted in ascending order, from smallest to largest.
- Duplicates in the lookup column. If the lookup column contains two or more duplicate values, VLOOKUP will return the first found match, which may not be the one you expect.
- Incorrect return column. Double-check the index number in the 3rd argument :)
VLOOKUP not working between two sheets
First off, it should be noted that the common reasons of #N/A, #VALUE, and #REF errors discussed above may cause the same problems when looking up from another sheet. If it's not the case, check out the following points:
- Make sure the external reference to another sheet or a different workbook is correct.
- When doing a Vlookup from another workbook which is closed at the moment, verify that your formula contains the full path to the closed workbook.
- If VLOOKUP cannot pick a table array in another worksheet (i.e. when you highlight a range in the lookup sheet, nothing appears in the table_array argument in the formula or in the corresponding box of the formula wizard), then most likely the two sheets are open in separate instances of Excel and cannot communicate with each other. For more info, please see How to determine which Excel files are in which instance. To fix this, simply close all Excel windows, and then reopen the sheets/workbooks in the same instance (the default behavior).
How to Vlookup without errors in Excel
If you do not want to intimidate your users with standard Excel error notations, you can display your own user-friendly text instead or return a blank cell if nothing is found. This can be done by using VLOOKUP with IFERROR or IFNA function.
Catch all errors
In Excel 2007 and later, you can use the IFERROR function to check a VLOOKUP formula for errors and return your own text (or an empty string) if any error is detected.
For example:
=IFERROR(VLOOKUP(E1, A2:B10, 2, FALSE), "Oops, something went wrong")
In Excel 2003 and earlier, you can use the IF ISERROR formula for the same purpose:
=IF(ISERROR(VLOOKUP(E1, A2:B10, 2, FALSE)), "Oops, something went wrong", VLOOKUP(E1, A2:B10, 2, FALSE))
For more details, please see Using IFERROR with VLOOKUP in Excel.
Handle #N/A errors
To trap only #N/A errors ignoring all other error types, use the IFNA function (in Excel 2013 and higher) or IF ISNA formula (in all versions).
For example:
=IFNA(VLOOKUP(E1, A2:B10, 2, FALSE), "Oops, no match is found. Please try again!")
=IF(ISNA(VLOOKUP(E1, A2:B10, 2, FALSE)), "Oops, no match is found. Please try again!", VLOOKUP(E1, A2:B10, 2, FALSE))
That's all for today. Hopefully, this tutorial will help you get rid of VLOOKUP errors and have your formulas working in the way you want.
How to VLOOKUP in Excel - video tutorial
228 comments
Hi, Will you be kind enough to explain following formula
=IFERROR(INDEX($B$4:$F$15,MATCH(1,(INDEX($B$4:$F$15,,MATCH(L$10,$B$3:$F$3,0))"")*($A$4:$A$15=$K11),0),MATCH(L$10,$B$3:$F$3,0)),"")
I would appreciate if part by part formula is explained
Thanks in advance!!
Hey All,
I have been looking into a few options to try and rectify a lookup I am doing which pulls from another tab. Currently I can replace the blank cells which are showing as 0 with the following formula, however I now also need to eradicate n/as that show when the lookup returns no match against the cell targeted. Please see below:
=IF(VLOOKUP([extract]],Table13[[Num]:[extract1 ]],13,FALSE)="","",VLOOKUP([extract],Table13[[Num]:[extract1]],13,FALSE))
The above works fine, however returns n/a's. I have tried to use "iferror" without success. I need to exclude both 0's and n/a's
Thanks.
In Excel 2013 you can go do the following to remove the zeros:
File>Options>Advanced>Display options for this worksheet: (use the drop down arrow to select the correct worksheet if more than one in your file).
Make sure that the following option is deselected: Show a zero in cells that have a zero value
Good luck with the #N/A issue.
You can also try the following for the "N/A issue:
File>Options>Formulas>Error checking rules:
Make sure that the following option is deselected: Formulas referring to emtpy cells
Good solutions..i'm really happy on seeing your solutions n solve many issues easily:) :)
i have a spreedsheet that i am running the following function thru =REPLACE($D344,1,2,VLOOKUP(LEFT($D344,2)+0,$AB$3:$AF$14,2,0)). Column D contains 4 digit values, ranging from 3700-37DF, i do have a few cells in coulmn D that contain 3A00, 3B00, 3C00 and on these cells i am getting #VALUE! errors. can someone help?
Hi,
In vlook up is it possible that value can be increased in row?
Exp
=Vlookup(A3,a2:C8,2,false)
And in second row
=Vlookup(A3,a2:c8,3,false)
,2,&,3, value increased with dragging
Hello!
I am doing match. If we put =iferror...;" ") we get blank cells instead of #N/A. That is ok, BUT in that case I want to keep my original number. Is it possible?
Thank you for the answer!
Convert to number, convert to number, convert to number..... I always forget to do that :P
I have 2 sheets with below data and i want to copy data(value) from sheet 2 to sheet1
sheet1:
id value
1
3
2
sheet2:
1 A
2 BB
3 C
vlookup used: =VLOOKUP(Sheet2!A2,Sheet2!A2:B4,2,0)
Result:
1 A
3 BB
2 C
Expected:
1 A
3 C
2 BB
I am looking for exact match for the value being searched. However, it is giving me values as per sequence.
Any help would be appreciated.
AMAZING WORK THANK YOU VERY MUCH
Hi All,
There is a problem when I try to compare two excel sheets using vlookup and if both the columns are empty which are compared. It returns an error. what to do in this condition???
Best Regards,
Faraz
Very nice post. Solve my problem.
I have pay grade coded as 4-X1, 4-X2 representing salary 50,000 and 65,000 in two columns.
I get #N/A error using vlookup function when looking for any pay grade.. for example 4-X1
Why do I get this error? please assist!!
I need some VLOOKUP formula help
I have been struggling with the following issue and all the recommended fixes have not worked.
I am using vlookup to pull data from four other sheets. I need to be able to use the results in cell to trigger the next search, however what happens is that the next vlookup looks up the values in the formuala, not the result.
I.E.
=VLOOKUP(E3, DATA!A2:Z480, 4, FALSE)
and in E3 I have:
=VLOOKUP(A2, OTHER! A1:Z400, 2, FALSE)
Instead of looking for the displayed value in E3, it goes chasing down the previous VLOOKUP and tries to find A2, and if THAT was another formula, it just keeps going.
I have changed all cell formats to general, number or anything but text and have turned off 'display formulas'.
Anyone got any suggestions?
Thank you.
Hi
How can i change format of 112-65-4171
to
812-48-7524
I have a tale on excel file that contain vlookup function when i open that excel file on other network computer its convert to range what is the problam with that anyone please help me
Hi
how can I use some Vlookups in a cell;means I want to Vlookup some tables and show one of answer(or even first on)in a cell?
The symbol &(between Vlookups) didn't work here!:-(
thanks for Help
AMS
while using vlookup for row and column detail not showing... pls help
This is driving me nuts. The VLOOKUP worked on my 2015 data. but when I replicated it with 2016, using the same formulas, the lookup fails retunring #N/A...
Col B is a list of names, such as
Name
Jaclyn Smith - Sr
Yvette Burcescu - Jr
Mychael Vernon - Fr
Kiara Adams - Jr
the lookup array is
Name_(11) Name Section Award
Aida Rossi Aida Rossi - Valhalla All Conference Honorable Mention
Alexandra A Alexandra Antony - Blind Brook All Conference Honorable Mention
Amanda Marj Amanda Marji - Yonkers All Conference Honorable Mention
Anjali Seba Anjali Sebastian - Clarkstown North All Section
Formula is =IFERROR(VLOOKUP(LEFT(B42,11),Names_Awards_2016,3,FALSE),"") returns an #N/A error, however, if I replace the LEFT(B42,11) with the actual texts string ex:"Jaclyn Smit", the formula appears to work.
Help.
Hi,
I am trying to create a vlookup and it is not getting executed. The below formula is shown in the column instead of the result
=VLOOKUP(A3,'[11i Extract 300000.xlsx]Sheet1'!$A$1:$A$3995,1,false)